New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfric.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfric.F90 @ 2633

Last change on this file since 2633 was 2633, checked in by trackstand2, 13 years ago

Renamed wrk_use => wrk_in_use and wrk_release => wrk_not_released
  • Property svn:keywords set to Id
File size: 11.4 KB
Line 
1MODULE zdfric
2   !!======================================================================
3   !!                       ***  MODULE  zdfric  ***
4   !! Ocean physics:  vertical mixing coefficient compute from the local
5   !!                 Richardson number dependent formulation
6   !!======================================================================
7   !! History :  OPA  ! 1987-09  (P. Andrich)  Original code
8   !!            4.0  ! 1991-11  (G. Madec)
9   !!            7.0  ! 1996-01  (G. Madec)  complet rewriting of multitasking suppression of common work arrays
10   !!            8.0  ! 1997-06 (G. Madec)  complete rewriting of zdfmix
11   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
12   !!            3.3  ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
13   !!----------------------------------------------------------------------
14#if defined key_zdfric   ||   defined key_esopa
15   !!----------------------------------------------------------------------
16   !!   'key_zdfric'                                             Kz = f(Ri)
17   !!----------------------------------------------------------------------
18   !!   zdf_ric      : update momentum and tracer Kz from the Richardson
19   !!                  number computation
20   !!   zdf_ric_init : initialization, namelist read, & parameters control
21   !!----------------------------------------------------------------------
22   USE oce             ! ocean dynamics and tracers variables
23   USE dom_oce         ! ocean space and time domain variables
24   USE zdf_oce         ! ocean vertical physics
25   USE in_out_manager  ! I/O manager
26   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   zdf_ric         ! called by step.F90
32   PUBLIC   zdf_ric_init    ! called by opa.F90
33
34   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfric = .TRUE.   !: Richardson vertical mixing flag
35
36   !                                    !!* Namelist namzdf_ric : Richardson number dependent Kz *
37   INTEGER  ::   nn_ric   = 2            ! coefficient of the parameterization
38   REAL(wp) ::   rn_avmri = 100.e-4_wp   ! maximum value of the vertical eddy viscosity
39   REAL(wp) ::   rn_alp   =   5._wp      ! coefficient of the parameterization
40
41   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   tmric       ! coef. for the horizontal mean at t-point
42
43   !! * Substitutions
44#  include "domzgr_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
47   !! $Id$
48   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   INTEGER FUNCTION zdf_ric_alloc()
53      !!----------------------------------------------------------------------
54      !!                 ***  FUNCTION zdf_ric_alloc  ***
55      !!----------------------------------------------------------------------
56      ALLOCATE( tmric(jpi,jpj,jpk)     , STAT=zdf_ric_alloc )
57      !
58      IF( lk_mpp             )   CALL mpp_sum ( zdf_ric_alloc )
59      IF( zdf_ric_alloc /= 0 )   CALL ctl_warn('zdf_ric_alloc: failed to allocate arrays.')
60   END FUNCTION zdf_ric_alloc
61
62
63   SUBROUTINE zdf_ric( kt )
64      !!----------------------------------------------------------------------
65      !!                 ***  ROUTINE zdfric  ***
66      !!                   
67      !! ** Purpose :   Compute the before eddy viscosity and diffusivity as
68      !!              a function of the local richardson number.
69      !!
70      !! ** Method  :   Local richardson number dependent formulation of the
71      !!              vertical eddy viscosity and diffusivity coefficients.
72      !!                The eddy coefficients are given by:
73      !!                    avm = avm0 + avmb
74      !!                    avt = avm0 / (1 + rn_alp*ri)
75      !!              with ri  = N^2 / dz(u)**2
76      !!                       = e3w**2 * rn2/[ mi( dk(ub) )+mj( dk(vb) ) ]
77      !!                   avm0= rn_avmri / (1 + rn_alp*ri)**nn_ric
78      !!      Where ri is the before local Richardson number,
79      !!            rn_avmri is the maximum value reaches by avm and avt
80      !!            avmb and avtb are the background (or minimum) values
81      !!            and rn_alp, nn_ric are adjustable parameters.
82      !!      Typical values used are : avm0=1.e-2 m2/s, avmb=1.e-6 m2/s
83      !!      avtb=1.e-7 m2/s, rn_alp=5. and nn_ric=2.
84      !!      a numerical threshold is impose on the vertical shear (1.e-20)
85      !!        N.B. the mask are required for implicit scheme, and surface
86      !!      and bottom value already set in zdfini.F90
87      !!
88      !! References : Pacanowski & Philander 1981, JPO, 1441-1451.
89      !!----------------------------------------------------------------------
90      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
91      USE wrk_nemo, ONLY: zwx => wrk_2d_1
92      !!
93      INTEGER, INTENT( in ) ::   kt         ! ocean time-step indexocean time step
94      !!
95      INTEGER  ::   ji, jj, jk               ! dummy loop indices
96      REAL(wp) ::   zcoef, zdku, zdkv, zri, z05alp     ! temporary scalars
97      !!----------------------------------------------------------------------
98
99      IF(wrk_in_use(2, 1) ) THEN
100         CALL ctl_stop('zdf_ric : requested workspace array unavailable')   ;   RETURN
101      END IF
102      !                                                ! ===============
103      DO jk = 2, jpkm1                                 ! Horizontal slab
104         !                                             ! ===============
105         ! Richardson number (put in zwx(ji,jj))
106         ! -----------------
107         DO jj = 2, jpjm1
108            DO ji = 2, jpim1
109               zcoef = 0.5 / fse3w(ji,jj,jk)
110               !                                            ! shear of horizontal velocity
111               zdku = zcoef * (  ub(ji-1,jj,jk-1) + ub(ji,jj,jk-1)   &
112                  &             -ub(ji-1,jj,jk  ) - ub(ji,jj,jk  )  )
113               zdkv = zcoef * (  vb(ji,jj-1,jk-1) + vb(ji,jj,jk-1)   &
114                  &             -vb(ji,jj-1,jk  ) - vb(ji,jj,jk  )  )
115               !                                            ! richardson number (minimum value set to zero)
116               zri = rn2(ji,jj,jk) / ( zdku*zdku + zdkv*zdkv + 1.e-20 )
117               zwx(ji,jj) = MAX( zri, 0.e0 )
118            END DO
119         END DO
120         CALL lbc_lnk( zwx, 'W', 1. )                       ! Boundary condition   (sign unchanged)
121
122
123         ! Vertical eddy viscosity and diffusivity coefficients
124         ! -------------------------------------------------------
125         z05alp = 0.5 * rn_alp
126         DO jj = 1, jpjm1                                   ! Eddy viscosity coefficients (avm)
127            DO ji = 1, jpim1
128               avmu(ji,jj,jk) = umask(ji,jj,jk)   &
129                  &           * rn_avmri / ( 1. + z05alp*( zwx(ji+1,jj)+zwx(ji,jj) ) )**nn_ric
130               avmv(ji,jj,jk) = vmask(ji,jj,jk)   &
131                  &           * rn_avmri / ( 1. + z05alp*( zwx(ji,jj+1)+zwx(ji,jj) ) )**nn_ric
132            END DO
133         END DO
134         DO jj = 2, jpjm1                                   ! Eddy diffusivity coefficients (avt)
135            DO ji = 2, jpim1
136               avt(ji,jj,jk) = tmric(ji,jj,jk) / ( 1. + rn_alp * zwx(ji,jj) )   &
137                  &          * (  avmu(ji,jj,jk) + avmu(ji-1, jj ,jk)        &
138                  &             + avmv(ji,jj,jk) + avmv( ji ,jj-1,jk)  )     &
139                  &          + avtb(jk) * tmask(ji,jj,jk)
140               !                                            ! Add the background coefficient on eddy viscosity
141               avmu(ji,jj,jk) = avmu(ji,jj,jk) + avmb(jk) * umask(ji,jj,jk)
142               avmv(ji,jj,jk) = avmv(ji,jj,jk) + avmb(jk) * vmask(ji,jj,jk)
143            END DO
144         END DO
145         !                                             ! ===============
146      END DO                                           !   End of slab
147      !                                                ! ===============
148      !
149      CALL lbc_lnk( avt , 'W', 1. )                         ! Boundary conditions   (unchanged sign)
150      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
151      !
152      IF(wrk_not_released(2, 1) )   CALL ctl_stop('zdf_ric : failed to release workspace array')
153      !
154   END SUBROUTINE zdf_ric
155
156
157   SUBROUTINE zdf_ric_init
158      !!----------------------------------------------------------------------
159      !!                 ***  ROUTINE zdfbfr_init  ***
160      !!                   
161      !! ** Purpose :   Initialization of the vertical eddy diffusivity and
162      !!      viscosity coef. for the Richardson number dependent formulation.
163      !!
164      !! ** Method  :   Read the namzdf_ric namelist and check the parameter values
165      !!
166      !! ** input   :   Namelist namzdf_ric
167      !!
168      !! ** Action  :   increase by 1 the nstop flag is setting problem encounter
169      !!----------------------------------------------------------------------
170      INTEGER :: ji, jj, jk        ! dummy loop indices
171      !!
172      NAMELIST/namzdf_ric/ rn_avmri, rn_alp, nn_ric
173      !!----------------------------------------------------------------------
174      !
175      REWIND( numnam )               ! Read Namelist namzdf_ric : richardson number dependent Kz
176      READ  ( numnam, namzdf_ric )
177      !
178      IF(lwp) THEN                   ! Control print
179         WRITE(numout,*)
180         WRITE(numout,*) 'zdf_ric : Ri depend vertical mixing scheme'
181         WRITE(numout,*) '~~~~~~~'
182         WRITE(numout,*) '   Namelist namzdf_ric : set Kz(Ri) parameters'
183         WRITE(numout,*) '      maximum vertical viscosity     rn_avmri = ', rn_avmri
184         WRITE(numout,*) '      coefficient                    rn_alp   = ', rn_alp
185         WRITE(numout,*) '      coefficient                    nn_ric   = ', nn_ric
186      ENDIF
187      !
188      !                              ! allocate zdfric arrays
189      IF( zdf_ric_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_ric_init : unable to allocate arrays' )
190      !
191      DO jk = 1, jpk                 ! weighting mean array tmric for 4 T-points
192         DO jj = 2, jpj              ! which accounts for coastal boundary conditions           
193            DO ji = 2, jpi
194               tmric(ji,jj,jk) =  tmask(ji,jj,jk)                                  &
195                  &            / MAX( 1.,  umask(ji-1,jj  ,jk) + umask(ji,jj,jk)   &
196                  &                      + vmask(ji  ,jj-1,jk) + vmask(ji,jj,jk)  )
197            END DO
198         END DO
199      END DO
200      tmric(:,1,:) = 0._wp
201      !
202      DO jk = 1, jpk                 ! Initialization of vertical eddy coef. to the background value
203         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
204         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
205         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
206      END DO
207      !
208   END SUBROUTINE zdf_ric_init
209
210#else
211   !!----------------------------------------------------------------------
212   !!   Dummy module :              NO Richardson dependent vertical mixing
213   !!----------------------------------------------------------------------
214   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfric = .FALSE.   !: Richardson mixing flag
215CONTAINS
216   SUBROUTINE zdf_ric_init         ! Dummy routine
217   END SUBROUTINE zdf_ric_init
218   SUBROUTINE zdf_ric( kt )        ! Dummy routine
219      WRITE(*,*) 'zdf_ric: You should not have seen this print! error?', kt
220   END SUBROUTINE zdf_ric
221#endif
222
223   !!======================================================================
224END MODULE zdfric
Note: See TracBrowser for help on using the repository browser.