New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC – NEMO

Context Navigation

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 2664

Last change on this file since 2664 was 2664, checked in by trackstand2, 13 years ago
Moved call to nemo_alloc() to after set-up of numout so wrk_nemo error output can use it.
Property svn:keywords set to `Id`
File size: 28.5 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 4.0 ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!!----------------------------------------------------------------------
31
32	!!----------------------------------------------------------------------
33	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
34	!! nemo_init : initialization of the NEMO system
35	!! nemo_ctl : initialisation of the contol print
36	!! nemo_closefile : close remaining open files
37	!! nemo_alloc : dynamical allocation
38	!! nemo_partition : calculate MPP domain decomposition
39	!! factorise : calculate the factors of the no. of MPI processes
40	!!----------------------------------------------------------------------
41	USE step_oce ! module used in the ocean time stepping module
42	USE sbc_oce ! surface boundary condition: ocean
43	USE cla ! cross land advection (tra_cla routine)
44	USE domcfg ! domain configuration (dom_cfg routine)
45	USE mppini ! shared/distributed memory setting (mpp_init routine)
46	USE domain ! domain initialization (dom_init routine)
47	USE obcini ! open boundary cond. initialization (obc_ini routine)
48	USE bdyini ! unstructured open boundary cond. initialization (bdy_init routine)
49	USE istate ! initial state setting (istate_init routine)
50	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
51	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
52	USE zdfini ! vertical physics setting (zdf_init routine)
53	USE phycst ! physical constant (par_cst routine)
54	USE trdmod ! momentum/tracers trends (trd_mod_init routine)
55	USE asminc ! assimilation increments (asm_inc_init routine)
56	USE asmtrj ! writing out state trajectory
57	USE sshwzv ! vertical velocity used in asm
58	USE diaptr ! poleward transports (dia_ptr_init routine)
59	USE diaobs ! Observation diagnostics (dia_obs_init routine)
60	USE step ! NEMO time-stepping (stp routine)
61	#if defined key_oasis3
62	USE cpl_oasis3 ! OASIS3 coupling
63	#elif defined key_oasis4
64	USE cpl_oasis4 ! OASIS4 coupling (not working)
65	#endif
66	USE c1d ! 1D configuration
67	USE step_c1d ! Time stepping loop for the 1D configuration
68	#if defined key_top
69	USE trcini ! passive tracer initialisation
70	#endif
71	USE lib_mpp ! distributed memory computing
72	#if defined key_iomput
73	USE mod_ioclient
74	#endif
75
76	IMPLICIT NONE
77	PRIVATE
78
79	PUBLIC nemo_gcm ! called by model.F90
80	PUBLIC nemo_init ! needed by AGRIF
81
82	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
83
84	!!----------------------------------------------------------------------
85	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
86	!! $Id$
87	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
88	!!----------------------------------------------------------------------
89	CONTAINS
90
91	SUBROUTINE nemo_gcm
92	!!----------------------------------------------------------------------
93	!! * ROUTINE nemo_gcm *
94	!!
95	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
96	!! curvilinear mesh on the sphere.
97	!!
98	!! ** Method : - model general initialization
99	!! - launch the time-stepping (stp routine)
100	!! - finalize the run by closing files and communications
101	!!
102	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
103	!! Madec, 2008, internal report, IPSL.
104	!!----------------------------------------------------------------------
105	INTEGER :: istp ! time step index
106	!!----------------------------------------------------------------------
107	!
108	#if defined key_agrif
109	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
110	#endif
111
112	! !-----------------------!
113	CALL nemo_init !== Initialisations ==!
114	! !-----------------------!
115
116	! check that all process are still there... If some process have an error,
117	! they will never enter in step and other processes will wait until the end of the cpu time!
118	IF( lk_mpp ) CALL mpp_max( nstop )
119
120	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
121
122	! !-----------------------!
123	! !== time stepping ==!
124	! !-----------------------!
125	istp = nit000
126	#if defined key_c1d
127	DO WHILE ( istp <= nitend .AND. nstop == 0 )
128	CALL stp_c1d( istp )
129	istp = istp + 1
130	END DO
131	#else
132	IF( lk_asminc ) THEN
133	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
134	IF( ln_trjwri ) CALL asm_trj_wri( nit000 - 1 ) ! Output trajectory fields
135	IF( ln_asmdin ) THEN ! Direct initialization
136	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
137	IF( ln_dyninc ) THEN
138	CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
139	IF ( ln_asmdin ) CALL ssh_wzv ( nit000 - 1 ) ! update vertical velocity
140	ENDIF
141	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
142	ENDIF
143	ENDIF
144
145	DO WHILE ( istp <= nitend .AND. nstop == 0 )
146	#if defined key_agrif
147	CALL Agrif_Step( stp ) ! AGRIF: time stepping
148	#else
149	CALL stp( istp ) ! standard time stepping
150	#endif
151	istp = istp + 1
152	IF( lk_mpp ) CALL mpp_max( nstop )
153	END DO
154	#endif
155
156	IF( lk_diaobs ) CALL dia_obs_wri
157
158	! !------------------------!
159	! !== finalize the run ==!
160	! !------------------------!
161	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
162	!
163	IF( nstop /= 0 .AND. lwp ) THEN ! error print
164	WRITE(numout,cform_err)
165	WRITE(numout,*) nstop, ' error have been found'
166	ENDIF
167	!
168	CALL nemo_closefile
169	#if defined key_oasis3 \|\| defined key_oasis4
170	CALL cpl_prism_finalize ! end coupling and mpp communications with OASIS
171	#else
172	IF( lk_mpp ) CALL mppstop ! end mpp communications
173	#endif
174	!
175	END SUBROUTINE nemo_gcm
176
177
178	SUBROUTINE nemo_init
179	!!----------------------------------------------------------------------
180	!! * ROUTINE nemo_init *
181	!!
182	!! ** Purpose : initialization of the NEMO GCM
183	!!----------------------------------------------------------------------
184	INTEGER :: ji ! dummy loop indices
185	INTEGER :: ilocal_comm ! local integer
186	CHARACTER(len=80), DIMENSION(10) :: cltxt
187	!!
188	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
189	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, nn_bench
190	!!----------------------------------------------------------------------
191	!
192	cltxt = ''
193	!
194	! ! open Namelist file
195	CALL ctl_opn( numnam, 'namelist', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
196	!
197	READ( numnam, namctl ) ! Namelist namctl : Control prints & Benchmark
198	!
199	! !--------------------------------------------!
200	! ! set communicator & select the local node !
201	! !--------------------------------------------!
202	#if defined key_iomput
203	IF( Agrif_Root() ) THEN
204	# if defined key_oasis3 \|\| defined key_oasis4
205	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
206	# endif
207	CALL init_ioclient( ilocal_comm ) ! exchange io_server nemo local communicator with the io_server
208	ENDIF
209	narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection
210	#else
211	# if defined key_oasis3 \|\| defined key_oasis4
212	IF( Agrif_Root() ) THEN
213	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
214	ENDIF
215	narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection (control print return in cltxt)
216	# else
217	ilocal_comm = 0
218	narea = mynode( cltxt, numnam, nstop ) ! Nodes selection (control print return in cltxt)
219	# endif
220	#endif
221	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
222
223	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
224
225	! Decide on size of grid now that we have our communicator size
226
227	#if defined key_mpp_mpi \|\| defined key_mpp_shmem
228	CALL nemo_partition(mppsize)
229	#else
230	jpni = 1
231	jpnj = 1
232	jpnij = jpni*jpnj
233	#endif
234	! Calculate domain dimensions given calculated jpni and jpnj
235	! This used to be done in par_oce.F90 when they were parameters rather
236	! than variables
237	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci !: first dim.
238	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj !: second dim.
239	jpk = jpkdta !: third dim
240	jpim1 = jpi-1 !: inner domain indices
241	jpjm1 = jpj-1 !: " "
242	jpkm1 = jpk-1 !: " "
243	jpij = jpi*jpj !: jpi x j
244
245	IF(lwp) THEN ! open listing units
246	!
247	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
248	!
249	WRITE(numout,*)
250	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean'
251	WRITE(numout,*) ' NEMO team'
252	WRITE(numout,*) ' Ocean General Circulation Model'
253	WRITE(numout,*) ' version 3.3 (2010) '
254	WRITE(numout,*)
255	WRITE(numout,*)
256	DO ji = 1, SIZE(cltxt)
257	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
258	END DO
259	WRITE(numout,cform_aaa) ! Flag AAAAAAA
260	!
261	ENDIF
262
263	! Now we know the dimensions of the grid and numout has been set we can
264	! allocate arrays
265	CALL nemo_alloc()
266
267	! !-------------------------------!
268	! ! NEMO general initialization !
269	! !-------------------------------!
270
271	CALL nemo_ctl ! Control prints & Benchmark
272
273	! ! Domain decomposition
274	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
275	ELSE ; CALL mpp_init2 ! eliminate land processors
276	ENDIF
277	!
278	! ! General initialization
279	CALL phy_cst ! Physical constants
280	CALL eos_init ! Equation of state
281	CALL dom_cfg ! Domain configuration
282	CALL dom_init ! Domain
283
284	IF( ln_ctl ) CALL prt_ctl_init ! Print control
285
286	IF( lk_obc ) CALL obc_init ! Open boundaries
287	IF( lk_bdy ) CALL bdy_init ! Unstructured open boundaries
288
289	CALL istate_init ! ocean initial state (Dynamics and tracers)
290
291	! ! Ocean physics
292	CALL sbc_init ! Forcings : surface module
293	! ! Vertical physics
294	CALL zdf_init ! namelist read
295	CALL zdf_bfr_init ! bottom friction
296	IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz
297	IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme
298	IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme
299	IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme
300	IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing
301	IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) &
302	& CALL zdf_ddm_init ! double diffusive mixing
303	! ! Lateral physics
304	CALL ldf_tra_init ! Lateral ocean tracer physics
305	CALL ldf_dyn_init ! Lateral ocean momentum physics
306	IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
307
308	! ! Active tracers
309	CALL tra_qsr_init ! penetrative solar radiation qsr
310	CALL tra_bbc_init ! bottom heat flux
311	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
312	IF( lk_tradmp ) CALL tra_dmp_init ! internal damping trends
313	CALL tra_adv_init ! horizontal & vertical advection
314	CALL tra_ldf_init ! lateral mixing
315	CALL tra_zdf_init ! vertical mixing and after tracer fields
316
317	! ! Dynamics
318	CALL dyn_adv_init ! advection (vector or flux form)
319	CALL dyn_vor_init ! vorticity term including Coriolis
320	CALL dyn_ldf_init ! lateral mixing
321	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
322	CALL dyn_zdf_init ! vertical diffusion
323	CALL dyn_spg_init ! surface pressure gradient
324
325	! ! Misc. options
326	IF( nn_cla == 1 ) CALL cla_init ! Cross Land Advection
327
328	#if defined key_top
329	! ! Passive tracers
330	CALL trc_init
331	#endif
332	! ! Diagnostics
333	CALL iom_init ! iom_put initialization
334	IF( lk_floats ) CALL flo_init ! drifting Floats
335	IF( lk_diaar5 ) CALL dia_ar5_init ! ar5 diag
336	CALL dia_ptr_init ! Poleward TRansports initialization
337	CALL dia_hsb_init ! heat content, salt content and volume budgets
338	CALL trd_mod_init ! Mixed-layer/Vorticity/Integral constraints trends
339	IF( lk_diaobs ) THEN ! Observation & model comparison
340	CALL dia_obs_init ! Initialize observational data
341	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
342	ENDIF
343	! ! Assimilation increments
344	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
345	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
346	!
347	END SUBROUTINE nemo_init
348
349
350	SUBROUTINE nemo_ctl
351	!!----------------------------------------------------------------------
352	!! * ROUTINE nemo_ctl *
353	!!
354	!! ** Purpose : control print setting
355	!!
356	!! ** Method : - print namctl information and check some consistencies
357	!!----------------------------------------------------------------------
358	!
359	IF(lwp) THEN ! control print
360	WRITE(numout,*)
361	WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
362	WRITE(numout,*) '~~~~~~~ '
363	WRITE(numout,*) ' Namelist namctl'
364	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
365	WRITE(numout,*) ' level of print nn_print = ', nn_print
366	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
367	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
368	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
369	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
370	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
371	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
372	WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench
373	ENDIF
374	!
375	nprint = nn_print ! convert DOCTOR namelist names into OLD names
376	nictls = nn_ictls
377	nictle = nn_ictle
378	njctls = nn_jctls
379	njctle = nn_jctle
380	isplt = nn_isplt
381	jsplt = nn_jsplt
382	nbench = nn_bench
383	! ! Parameter control
384	!
385	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
386	IF( lk_mpp ) THEN
387	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
388	ELSE
389	IF( isplt == 1 .AND. jsplt == 1 ) THEN
390	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
391	& ' - the print control will be done over the whole domain' )
392	ENDIF
393	ijsplt = isplt * jsplt ! total number of processors ijsplt
394	ENDIF
395	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
396	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
397	!
398	! ! indices used for the SUM control
399	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
400	lsp_area = .FALSE.
401	ELSE ! print control done over a specific area
402	lsp_area = .TRUE.
403	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
404	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
405	nictls = 1
406	ENDIF
407	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
408	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
409	nictle = jpiglo
410	ENDIF
411	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
412	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
413	njctls = 1
414	ENDIF
415	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
416	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
417	njctle = jpjglo
418	ENDIF
419	ENDIF
420	ENDIF
421	!
422	IF( nbench == 1 ) THEN ! Benchmark
423	SELECT CASE ( cp_cfg )
424	CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' )
425	CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', &
426	& ' key_gyre must be used or set nbench = 0' )
427	END SELECT
428	ENDIF
429	!
430	IF( lk_c1d .AND. .NOT.lk_iomput ) CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ', &
431	& 'with the IOM Input/Output manager. ' , &
432	& 'Compile with key_iomput enabled' )
433	!
434	END SUBROUTINE nemo_ctl
435
436
437	SUBROUTINE nemo_closefile
438	!!----------------------------------------------------------------------
439	!! * ROUTINE nemo_closefile *
440	!!
441	!! ** Purpose : Close the files
442	!!----------------------------------------------------------------------
443	!
444	IF( lk_mpp ) CALL mppsync
445	!
446	CALL iom_close ! close all input/output files managed by iom_*
447	!
448	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
449	IF( numsol /= -1 ) CLOSE( numsol ) ! solver file
450	IF( numnam /= -1 ) CLOSE( numnam ) ! oce namelist
451	IF( numnam_ice /= -1 ) CLOSE( numnam_ice ) ! ice namelist
452	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
453	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
454	!
455	numout = 6 ! redefine numout in case it is used after this point...
456	!
457	END SUBROUTINE nemo_closefile
458
459
460	SUBROUTINE nemo_alloc
461	!!----------------------------------------------------------------------
462	!! * ROUTINE nemo_alloc *
463	!!
464	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
465	!!
466	!! ** Method :
467	!!----------------------------------------------------------------------
468	USE diawri, ONLY: dia_wri_alloc
469	USE dom_oce, ONLY: dom_oce_alloc
470	USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
471	USE ldftra_oce, ONLY: ldftra_oce_alloc
472	USE trc_oce, ONLY: trc_oce_alloc
473
474	USE wrk_nemo, ONLY: wrk_alloc
475
476	INTEGER :: ierr
477	INTEGER :: i
478	!!----------------------------------------------------------------------
479
480	ierr = oce_alloc () ! ocean
481	ierr = ierr + dia_wri_alloc ()
482	ierr = ierr + dom_oce_alloc () ! ocean domain
483	ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics
484	ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers
485	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
486	!
487	ierr = ierr + lib_mpp_alloc (numout) ! mpp exchanges
488	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
489
490	ierr = ierr + wrk_alloc(numout, lwp) ! workspace
491
492	IF( lk_mpp ) CALL mpp_sum( ierr )
493	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
494	!
495	END SUBROUTINE nemo_alloc
496
497
498	SUBROUTINE nemo_partition( num_pes )
499	!!----------------------------------------------------------------------
500	!! * ROUTINE nemo_partition *
501	!!
502	!! ** Purpose :
503	!!
504	!! ** Method :
505	!!----------------------------------------------------------------------
506	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
507	!
508	INTEGER, PARAMETER :: nfactmax = 20
509	INTEGER :: nfact ! The no. of factors returned
510	INTEGER :: ierr ! Error flag
511	INTEGER :: ji
512	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
513	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
514	!!----------------------------------------------------------------------
515
516	ierr = 0
517
518	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
519
520	IF( nfact <= 1 ) THEN
521	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
522	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
523	jpnj = 1
524	jpni = num_pes
525	ELSE
526	! Search through factors for the pair that are closest in value
527	mindiff = 1000000
528	imin = 1
529	DO ji = 1, nfact-1, 2
530	idiff = ABS( ifact(ji) - ifact(ji+1) )
531	IF( idiff < mindiff ) THEN
532	mindiff = idiff
533	imin = ji
534	ENDIF
535	END DO
536	jpnj = ifact(imin)
537	jpni = ifact(imin + 1)
538	ENDIF
539	jpnij = jpni*jpnj
540
541	WRITE(,) 'ARPDBG: jpni = ',jpni,'jpnj = ',jpnj,'jpnij = ',jpnij
542	!
543	END SUBROUTINE nemo_partition
544
545
546	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
547	!!----------------------------------------------------------------------
548	!! * ROUTINE factorise *
549	!!
550	!! ** Purpose : return the prime factors of n.
551	!! knfax factors are returned in array kfax which is of
552	!! maximum dimension kmaxfax.
553	!! ** Method :
554	!!----------------------------------------------------------------------
555	INTEGER , INTENT(in ) :: kn, kmaxfax
556	INTEGER , INTENT( out) :: kerr, knfax
557	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
558	!
559	INTEGER :: ifac, jl, inu
560	INTEGER, PARAMETER :: ntest = 14
561	INTEGER :: ilfax(ntest)
562
563	! lfax contains the set of allowed factors.
564	data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256, &
565	& 128, 64, 32, 16, 8, 4, 2 /
566	!!----------------------------------------------------------------------
567
568	! Clear the error flag and initialise output vars
569	kerr = 0
570	kfax = 1
571	knfax = 0
572
573	! Find the factors of n.
574	IF( kn == 1 ) GOTO 20
575
576	! nu holds the unfactorised part of the number.
577	! knfax holds the number of factors found.
578	! l points to the allowed factor list.
579	! ifac holds the current factor.
580
581	inu = kn
582	knfax = 0
583
584	DO jl = ntest, 1, -1
585	!
586	ifac = ilfax(jl)
587	IF( ifac > inu ) CYCLE
588
589	! Test whether the factor will divide.
590
591	IF( MOD(inu,ifac) == 0 ) THEN
592	!
593	knfax = knfax + 1 ! Add the factor to the list
594	IF( knfax > kmaxfax ) THEN
595	kerr = 6
596	write (,) 'FACTOR: insufficient space in factor array ', knfax
597	return
598	ENDIF
599	kfax(knfax) = ifac
600	! Store the other factor that goes with this one
601	knfax = knfax + 1
602	kfax(knfax) = inu / ifac
603	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
604	ENDIF
605	!
606	END DO
607
608	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
609	!
610	END SUBROUTINE factorise
611
612	!!======================================================================
613	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: