New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zflx.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zflx.F90 @ 2690

Last change on this file since 2690 was 2690, checked in by gm, 13 years ago

dynamic mem: #785 ; homogeneization of the coding style associated with dyn allocation
  • Property svn:keywords set to Id
File size: 11.5 KB
Line 
1MODULE p4zflx
2   !!======================================================================
3   !!                         ***  MODULE p4zflx  ***
4   !! TOP :   PISCES CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!----------------------------------------------------------------------
12#if defined key_pisces
13   !!----------------------------------------------------------------------
14   !!   'key_pisces'                                       PISCES bio-model
15   !!----------------------------------------------------------------------
16   !!   p4z_flx       :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
17   !!   p4z_flx_init  :   Read the namelist
18   !!----------------------------------------------------------------------
19   USE trc
20   USE oce_trc         !
21   USE trc
22   USE sms_pisces
23   USE prtctl_trc
24   USE p4zche
25   USE iom
26#if defined key_cpl_carbon_cycle
27   USE sbc_oce , ONLY :  atm_co2
28#endif
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   p4z_flx 
34   PUBLIC   p4z_flx_init 
35   PUBLIC   p4z_flx_alloc 
36
37   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: oce_co2   !: ocean carbon flux
38   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: satmco2   !: atmospheric pco2
39
40   REAL(wp) ::  t_oce_co2_flx               !: Total ocean carbon flux
41   REAL(wp) ::  t_atm_co2_flx               !: global mean of atmospheric pco2
42   REAL(wp) ::  area                        !: ocean surface
43   REAL(wp) ::  atcco2 = 278._wp            !: pre-industrial atmospheric [co2] (ppm) 
44   REAL(wp) ::  atcox  = 0.20946_wp         !:
45   REAL(wp) ::  xconv  = 0.01_wp / 3600._wp !: coefficients for conversion
46
47   !!* Substitution
48#  include "top_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
51   !! $Id$
52   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE p4z_flx ( kt )
57      !!---------------------------------------------------------------------
58      !!                     ***  ROUTINE p4z_flx  ***
59      !!
60      !! ** Purpose :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
61      !!
62      !! ** Method  : - ???
63      !!---------------------------------------------------------------------
64      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
65      USE wrk_nemo, ONLY:   zkgco2 => wrk_2d_1 , zkgo2 => wrk_2d_2 , zh2co3 => wrk_2d_3 
66      USE wrk_nemo, ONLY:   zoflx  => wrk_2d_4 , zkg   => wrk_2d_5
67      USE wrk_nemo, ONLY:   zdpco2 => wrk_2d_6 , zdpo2 => wrk_2d_7
68      !
69      INTEGER, INTENT(in) ::   kt   !
70      !
71      INTEGER  ::   ji, jj, jrorr
72      REAL(wp) ::   ztc, ztc2, ztc3, zws, zkgwan
73      REAL(wp) ::   zfld, zflu, zfld16, zflu16, zfact
74      REAL(wp) ::   zph, zah2, zbot, zdic, zalk, zsch_o2, zalka, zsch_co2
75      CHARACTER (len=25) :: charout
76      !!---------------------------------------------------------------------
77
78      IF( wrk_in_use(2, 1,2,3,4,5,6,7) ) THEN
79         CALL ctl_stop('p4z_flx: requested workspace arrays unavailable')   ;   RETURN
80      ENDIF
81
82      ! SURFACE CHEMISTRY (PCO2 AND [H+] IN
83      !     SURFACE LAYER); THE RESULT OF THIS CALCULATION
84      !     IS USED TO COMPUTE AIR-SEA FLUX OF CO2
85
86#if defined key_cpl_carbon_cycle
87      satmco2(:,:) = atm_co2(:,:)
88#endif
89
90      DO jrorr = 1, 10
91
92!CDIR NOVERRCHK
93         DO jj = 1, jpj
94!CDIR NOVERRCHK
95            DO ji = 1, jpi
96
97               ! DUMMY VARIABLES FOR DIC, H+, AND BORATE
98               zbot  = borat(ji,jj,1)
99               zfact = rhop(ji,jj,1) / 1000. + rtrn
100               zdic  = trn(ji,jj,1,jpdic) / zfact
101               zph   = MAX( hi(ji,jj,1), 1.e-10 ) / zfact
102               zalka = trn(ji,jj,1,jptal) / zfact
103
104               ! CALCULATE [ALK]([CO3--], [HCO3-])
105               zalk  = zalka - (  akw3(ji,jj,1) / zph - zph + zbot / ( 1.+ zph / akb3(ji,jj,1) )  )
106
107               ! CALCULATE [H+] AND [H2CO3]
108               zah2   = SQRT(  (zdic-zalk)**2 + 4.* ( zalk * ak23(ji,jj,1)   &
109                  &                                        / ak13(ji,jj,1) ) * ( 2.* zdic - zalk )  )
110               zah2   = 0.5 * ak13(ji,jj,1) / zalk * ( ( zdic - zalk ) + zah2 )
111               zh2co3(ji,jj) = ( 2.* zdic - zalk ) / ( 2.+ ak13(ji,jj,1) / zah2 ) * zfact
112               hi(ji,jj,1)   = zah2 * zfact
113            END DO
114         END DO
115      END DO
116
117
118      ! --------------
119      ! COMPUTE FLUXES
120      ! --------------
121
122      ! FIRST COMPUTE GAS EXCHANGE COEFFICIENTS
123      ! -------------------------------------------
124
125!CDIR NOVERRCHK
126      DO jj = 1, jpj
127!CDIR NOVERRCHK
128         DO ji = 1, jpi
129            ztc  = MIN( 35., tsn(ji,jj,1,jp_tem) )
130            ztc2 = ztc * ztc
131            ztc3 = ztc * ztc2 
132            ! Compute the schmidt Number both O2 and CO2
133            zsch_co2 = 2073.1 - 125.62 * ztc + 3.6276 * ztc2 - 0.043126 * ztc3
134            zsch_o2  = 1953.4 - 128.0  * ztc + 3.9918 * ztc2 - 0.050091 * ztc3
135            !  wind speed
136            zws  = wndm(ji,jj) * wndm(ji,jj)
137            ! Compute the piston velocity for O2 and CO2
138            zkgwan = 0.3 * zws  + 2.5 * ( 0.5246 + 0.016256 * ztc + 0.00049946  * ztc2 )
139# if defined key_degrad
140            zkgwan = zkgwan * xconv * ( 1.- fr_i(ji,jj) ) * tmask(ji,jj,1) * facvol(ji,jj,1)
141#else
142            zkgwan = zkgwan * xconv * ( 1.- fr_i(ji,jj) ) * tmask(ji,jj,1)
143#endif 
144            ! compute gas exchange for CO2 and O2
145            zkgco2(ji,jj) = zkgwan * SQRT( 660./ zsch_co2 )
146            zkgo2 (ji,jj) = zkgwan * SQRT( 660./ zsch_o2 )
147         END DO
148      END DO
149
150      DO jj = 1, jpj
151         DO ji = 1, jpi
152            ! Compute CO2 flux for the sea and air
153            zfld = satmco2(ji,jj) * tmask(ji,jj,1) * chemc(ji,jj,1) * zkgco2(ji,jj)
154            zflu = zh2co3(ji,jj) * tmask(ji,jj,1) * zkgco2(ji,jj)
155            oce_co2(ji,jj) = ( zfld - zflu ) * rfact * e1e2t(ji,jj) * tmask(ji,jj,1) * 1000.
156            ! compute the trend
157            tra(ji,jj,1,jpdic) = tra(ji,jj,1,jpdic) + ( zfld - zflu ) / fse3t(ji,jj,1)
158
159            ! Compute O2 flux
160            zfld16 = atcox * chemc(ji,jj,2) * tmask(ji,jj,1) * zkgo2(ji,jj)
161            zflu16 = trn(ji,jj,1,jpoxy) * tmask(ji,jj,1) * zkgo2(ji,jj)
162            tra(ji,jj,1,jpoxy) = tra(ji,jj,1,jpoxy) + ( zfld16 - zflu16 ) / fse3t(ji,jj,1)
163
164#if defined key_diatrc 
165            ! Save diagnostics
166#  if ! defined key_iomput
167            zfact = 1. / e1e2t(ji,jj) / rfact
168            trc2d(ji,jj,jp_pcs0_2d    ) = oce_co2(ji,jj) * zfact
169            trc2d(ji,jj,jp_pcs0_2d + 1) = ( zfld16 - zflu16 ) * 1000. * tmask(ji,jj,1)
170            trc2d(ji,jj,jp_pcs0_2d + 2) = zkgco2(ji,jj) * tmask(ji,jj,1)
171            trc2d(ji,jj,jp_pcs0_2d + 3) = ( satmco2(ji,jj) - zh2co3(ji,jj) / ( chemc(ji,jj,1) + rtrn ) ) &
172               &                            * tmask(ji,jj,1)
173#  else
174            zoflx(ji,jj) = ( zfld16 - zflu16 ) * 1000. * tmask(ji,jj,1)
175            zkg  (ji,jj) = zkgco2(ji,jj) * tmask(ji,jj,1)
176            zdpco2(ji,jj) = ( satmco2(ji,jj) - zh2co3(ji,jj) / ( chemc(ji,jj,1) + rtrn ) ) * tmask(ji,jj,1)
177            zdpo2 (ji,jj) = ( atcox  - trn(ji,jj,1,jpoxy) / ( chemc(ji,jj,2) + rtrn ) ) * tmask(ji,jj,1)
178#  endif
179#endif
180         END DO
181      END DO
182
183      t_oce_co2_flx = t_oce_co2_flx + glob_sum( oce_co2(:,:) )                     ! Cumulative Total Flux of Carbon
184      IF( kt == nitend ) THEN
185         t_atm_co2_flx = glob_sum( satmco2(:,:) * e1e2t(:,:) )            ! Total atmospheric pCO2
186         !
187         t_oce_co2_flx = (-1.) * t_oce_co2_flx  * 12. / 1.e15                      ! Conversion in PgC ; negative for out of the ocean
188         t_atm_co2_flx = t_atm_co2_flx  / area                                     ! global mean of atmospheric pCO2
189         !
190         IF( lwp) THEN
191            WRITE(numout,*)
192            WRITE(numout,*) ' Global mean of atmospheric pCO2 (ppm) at it= ', kt, ' date= ', ndastp
193            WRITE(numout,*) '------------------------------------------------------- :  ',t_atm_co2_flx
194            WRITE(numout,*)
195            WRITE(numout,*) ' Cumulative total Flux of Carbon out of the ocean (PgC) :'
196            WRITE(numout,*) '-------------------------------------------------------  ',t_oce_co2_flx
197         ENDIF
198         !
199      ENDIF
200
201      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
202         WRITE(charout, FMT="('flx ')")
203         CALL prt_ctl_trc_info(charout)
204         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
205      ENDIF
206
207# if defined key_diatrc && defined key_iomput
208      CALL iom_put( "Cflx" , oce_co2(:,:) / e1e2t(:,:) / rfact ) 
209      CALL iom_put( "Oflx" , zoflx  )
210      CALL iom_put( "Kg"   , zkg    )
211      CALL iom_put( "Dpco2", zdpco2 )
212      CALL iom_put( "Dpo2" , zdpo2  )
213#endif
214      !
215      IF( wrk_not_released(2, 1,2,3,4,5,6,7) )   CALL ctl_stop('p4z_flx: failed to release workspace arrays')
216      !
217   END SUBROUTINE p4z_flx
218
219
220   SUBROUTINE p4z_flx_init
221      !!----------------------------------------------------------------------
222      !!                  ***  ROUTINE p4z_flx_init  ***
223      !!
224      !! ** Purpose :   Initialization of atmospheric conditions
225      !!
226      !! ** Method  :   Read the nampisext namelist and check the parameters
227      !!      called at the first timestep (nit000)
228      !! ** input   :   Namelist nampisext
229      !!----------------------------------------------------------------------
230      NAMELIST/nampisext/ atcco2
231      !!----------------------------------------------------------------------
232      !
233      REWIND( numnat )                     ! read numnat
234      READ  ( numnat, nampisext )
235      !
236      IF(lwp) THEN                         ! control print
237         WRITE(numout,*) ' '
238         WRITE(numout,*) ' Namelist parameters for air-sea exchange, nampisext'
239         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
240         WRITE(numout,*) '    Atmospheric pCO2      atcco2      =', atcco2
241      ENDIF
242      !
243      area = glob_sum( e1e2t(:,:) )        ! interior global domain surface
244      !
245      oce_co2(:,:)  = 0._wp                ! Initialization of Flux of Carbon
246      t_atm_co2_flx = 0._wp
247      !
248      satmco2(:,:)  = atcco2      ! Initialisation of atmospheric pco2
249      t_oce_co2_flx = 0._wp
250      !
251   END SUBROUTINE p4z_flx_init
252
253
254   INTEGER FUNCTION p4z_flx_alloc()
255      !!----------------------------------------------------------------------
256      !!                     ***  ROUTINE p4z_flx_alloc  ***
257      !!----------------------------------------------------------------------
258      ALLOCATE( oce_co2(jpi,jpj), satmco2(jpi,jpj), STAT=p4z_flx_alloc )
259      !
260      IF( p4z_flx_alloc /= 0 )   CALL ctl_warn('p4z_flx_alloc : failed to allocate arrays')
261      !
262   END FUNCTION p4z_flx_alloc
263
264#else
265   !!======================================================================
266   !!  Dummy module :                                   No PISCES bio-model
267   !!======================================================================
268CONTAINS
269   SUBROUTINE p4z_flx( kt )                   ! Empty routine
270      INTEGER, INTENT( in ) ::   kt
271      WRITE(*,*) 'p4z_flx: You should not have seen this print! error?', kt
272   END SUBROUTINE p4z_flx
273#endif 
274
275   !!======================================================================
276END MODULE  p4zflx
Note: See TracBrowser for help on using the repository browser.