New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/TOP_SRC/TRP/trcadv.F90 @ 2636

Last change on this file since 2636 was 2636, checked in by gm, 13 years ago

dynamic mem: #785 ; move ctl_stop & warn in lib_mpp to avoid a circular dependency + ctl_stop improvment
  • Property svn:keywords set to Id
File size: 10.8 KB
Line 
1MODULE trcadv
2   !!==============================================================================
3   !!                       ***  MODULE  trcadv  ***
4   !! Ocean passive tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  05-11  (G. Madec)  Original code
7   !!            3.0  !  10-06  (C. Ethe)   Adapted to passive tracers
8   !!----------------------------------------------------------------------
9#if defined key_top
10   !!----------------------------------------------------------------------
11   !!   'key_top'                                                TOP models
12   !!----------------------------------------------------------------------
13   !!   trc_adv      : compute ocean tracer advection trend
14   !!   trc_adv_ctl  : control the different options of advection scheme
15   !!----------------------------------------------------------------------
16   USE oce_trc         ! ocean dynamics and active tracers
17   USE trc             ! ocean passive tracers variables
18   USE trcnam_trp      ! passive tracers transport namelist variables
19   USE traadv_cen2     ! 2nd order centered scheme (tra_adv_cen2   routine)
20   USE traadv_tvd      ! TVD      scheme           (tra_adv_tvd    routine)
21   USE traadv_muscl    ! MUSCL    scheme           (tra_adv_muscl  routine)
22   USE traadv_muscl2   ! MUSCL2   scheme           (tra_adv_muscl2 routine)
23   USE traadv_ubs      ! UBS      scheme           (tra_adv_ubs    routine)
24   USE traadv_qck      ! QUICKEST scheme           (tra_adv_qck    routine)
25   USE traadv_eiv      ! eddy induced velocity     (tra_adv_eiv    routine)
26   USE ldftra_oce      ! lateral diffusion coefficient on tracers
27   USE in_out_manager  ! I/O manager
28   USE lib_mpp         ! MPP library
29   USE prtctl_trc      ! Print control
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   trc_adv          ! routine called by step module
35   PUBLIC   trc_adv_alloc    ! routine called by nemogcm module
36
37   INTEGER ::   nadv   ! choice of the type of advection scheme
38   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) ::   r2dt  ! vertical profile time-step, = 2 rdttra
39      !                                ! except at nit000 (=rdttra) if neuler=0
40
41   !! * Substitutions
42#  include "domzgr_substitute.h90"
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49
50CONTAINS
51
52   FUNCTION trc_adv_alloc()
53      !!----------------------------------------------------------------------
54      !!                  ***  ROUTINE trc_adv_alloc  ***
55      !!----------------------------------------------------------------------
56      INTEGER :: trc_adv_alloc
57      !!----------------------------------------------------------------------
58
59      ALLOCATE(r2dt(jpk), Stat=trc_adv_alloc)
60
61      IF(trc_adv_alloc /= 0)THEN
62         CALL ctl_warn('trc_adv_alloc : failed to allocate array.')
63      END IF
64
65   END FUNCTION trc_adv_alloc
66
67
68   SUBROUTINE trc_adv( kt )
69      !!----------------------------------------------------------------------
70      !!                  ***  ROUTINE trc_adv  ***
71      !!
72      !! ** Purpose :   compute the ocean tracer advection trend.
73      !!
74      !! ** Method  : - Update the tracer with the advection term following nadv
75      !!----------------------------------------------------------------------
76      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
77      USE wrk_nemo, ONLY: zun => wrk_3d_1, zvn => wrk_3d_2, &
78                          zwn => wrk_3d_3   ! effective velocity
79      !!
80      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
81      !
82      INTEGER :: jk 
83      CHARACTER (len=22) :: charout
84      !!----------------------------------------------------------------------
85
86      IF(wrk_in_use(3, 1,2,3))THEN
87         CALL ctl_stop('trc_adv : requested workspace arrays unavailable.')
88         RETURN
89      END IF
90
91      IF( kt == nit000 )   CALL trc_adv_ctl          ! initialisation & control of options
92
93#if ! defined key_pisces
94      IF( neuler == 0 .AND. kt == nit000 ) THEN     ! at nit000
95         r2dt(:) =  rdttrc(:)           ! = rdttrc (restarting with Euler time stepping)
96      ELSEIF( kt <= nit000 + nn_dttrc ) THEN          ! at nit000 or nit000+1
97         r2dt(:) = 2. * rdttrc(:)       ! = 2 rdttrc (leapfrog)
98      ENDIF
99#else
100      r2dt(:) =  rdttrc(:)              ! = rdttrc (for PISCES use Euler time stepping)
101#endif
102
103      !                                                   ! effective transport
104      DO jk = 1, jpkm1
105         !                                                ! eulerian transport only
106         zun(:,:,jk) = e2u(:,:) * fse3u(:,:,jk) * un(:,:,jk)
107         zvn(:,:,jk) = e1v(:,:) * fse3v(:,:,jk) * vn(:,:,jk)
108         zwn(:,:,jk) = e1t(:,:) * e2t(:,:)      * wn(:,:,jk)
109         !
110      END DO
111      zwn(:,:,jpk) = 0.e0                                 ! no transport trough the bottom
112
113      !                                                   ! add the eiv transport (if necessary)
114      IF( lk_traldf_eiv )   CALL tra_adv_eiv( kt, zun, zvn, zwn, 'TRC' )
115      !
116      SELECT CASE ( nadv )                            !==  compute advection trend and add it to general trend  ==!
117      CASE ( 1 )   ;    CALL tra_adv_cen2  ( kt, 'TRC',       zun, zvn, zwn, trb, trn, tra, jptra )   !  2nd order centered
118      CASE ( 2 )   ;    CALL tra_adv_tvd   ( kt, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )   !  TVD
119      CASE ( 3 )   ;    CALL tra_adv_muscl ( kt, 'TRC', r2dt, zun, zvn, zwn, trb,      tra, jptra )   !  MUSCL
120      CASE ( 4 )   ;    CALL tra_adv_muscl2( kt, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )   !  MUSCL2
121      CASE ( 5 )   ;    CALL tra_adv_ubs   ( kt, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )   !  UBS
122      CASE ( 6 )   ;    CALL tra_adv_qck   ( kt, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )   !  QUICKEST
123      !
124      CASE (-1 )                                      !==  esopa: test all possibility with control print  ==!
125         CALL tra_adv_cen2  ( kt, 'TRC',       zun, zvn, zwn, trb, trn, tra, jptra )         
126         WRITE(charout, FMT="('adv1')")  ; CALL prt_ctl_trc_info(charout)
127                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
128         CALL tra_adv_tvd   ( kt, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )         
129         WRITE(charout, FMT="('adv2')")  ; CALL prt_ctl_trc_info(charout)
130                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
131         CALL tra_adv_muscl ( kt, 'TRC', r2dt, zun, zvn, zwn, trb,      tra, jptra )         
132         WRITE(charout, FMT="('adv3')")  ; CALL prt_ctl_trc_info(charout)
133                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
134         CALL tra_adv_muscl2( kt, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )         
135         WRITE(charout, FMT="('adv4')")  ; CALL prt_ctl_trc_info(charout)
136                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
137         CALL tra_adv_ubs   ( kt, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )         
138         WRITE(charout, FMT="('adv5')")  ; CALL prt_ctl_trc_info(charout)
139                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
140         CALL tra_adv_qck   ( kt, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )         
141         WRITE(charout, FMT="('adv6')")  ; CALL prt_ctl_trc_info(charout)
142                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
143         !
144      END SELECT
145
146      !                                              ! print mean trends (used for debugging)
147      IF( ln_ctl )   THEN
148         WRITE(charout, FMT="('adv ')")  ;  CALL prt_ctl_trc_info(charout)
149                                            CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
150      END IF
151      !
152      IF(wrk_not_released(3, 1,2,3))THEN
153         CALL ctl_stop('trc_adv : failed to release workspace arrays.')
154      END IF
155      !
156   END SUBROUTINE trc_adv
157
158
159   SUBROUTINE trc_adv_ctl
160      !!---------------------------------------------------------------------
161      !!                  ***  ROUTINE trc_adv_ctl  ***
162      !!               
163      !! ** Purpose : Control the consistency between namelist options for
164      !!              passive tracer advection schemes and set nadv
165      !!----------------------------------------------------------------------
166      INTEGER ::   ioptio
167      !!----------------------------------------------------------------------
168
169      ioptio = 0                      ! Parameter control
170      IF( ln_trcadv_cen2   )   ioptio = ioptio + 1
171      IF( ln_trcadv_tvd    )   ioptio = ioptio + 1
172      IF( ln_trcadv_muscl  )   ioptio = ioptio + 1
173      IF( ln_trcadv_muscl2 )   ioptio = ioptio + 1
174      IF( ln_trcadv_ubs    )   ioptio = ioptio + 1
175      IF( ln_trcadv_qck    )   ioptio = ioptio + 1
176      IF( lk_esopa         )   ioptio =          1
177
178      IF( ioptio /= 1 )   CALL ctl_stop( 'Choose ONE advection scheme in namelist namtrc_adv' )
179
180      !                              ! Set nadv
181      IF( ln_trcadv_cen2   )   nadv =  1
182      IF( ln_trcadv_tvd    )   nadv =  2
183      IF( ln_trcadv_muscl  )   nadv =  3
184      IF( ln_trcadv_muscl2 )   nadv =  4
185      IF( ln_trcadv_ubs    )   nadv =  5
186      IF( ln_trcadv_qck    )   nadv =  6
187      IF( lk_esopa         )   nadv = -1
188
189      IF(lwp) THEN                   ! Print the choice
190         WRITE(numout,*)
191         IF( nadv ==  1 )   WRITE(numout,*) '         2nd order scheme is used'
192         IF( nadv ==  2 )   WRITE(numout,*) '         TVD       scheme is used'
193         IF( nadv ==  3 )   WRITE(numout,*) '         MUSCL     scheme is used'
194         IF( nadv ==  4 )   WRITE(numout,*) '         MUSCL2    scheme is used'
195         IF( nadv ==  5 )   WRITE(numout,*) '         UBS       scheme is used'
196         IF( nadv ==  6 )   WRITE(numout,*) '         QUICKEST  scheme is used'
197         IF( nadv == -1 )   WRITE(numout,*) '         esopa test: use all advection scheme'
198      ENDIF
199      !
200   END SUBROUTINE trc_adv_ctl
201#else
202   !!----------------------------------------------------------------------
203   !!   Default option                                         Empty module
204   !!----------------------------------------------------------------------
205CONTAINS
206   SUBROUTINE trc_adv( kt )
207      INTEGER, INTENT(in) :: kt
208      WRITE(*,*) 'trc_adv: You should not have seen this print! error?', kt
209   END SUBROUTINE trc_adv
210#endif
211  !!======================================================================
212END MODULE trcadv
Note: See TracBrowser for help on using the repository browser.