New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limrhg_2.F90 in branches/devmercator2010/NEMO/LIM_SRC_2 – NEMO

source: branches/devmercator2010/NEMO/LIM_SRC_2/limrhg_2.F90 @ 2076

Last change on this file since 2076 was 2076, checked in by cbricaud, 14 years ago

add change dev_1784_EVP
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 33.5 KB
Line 
1MODULE limrhg_2
2   !!======================================================================
3   !!                     ***  MODULE  limrhg_2  ***
4   !!   Ice rheology :  performs sea ice rheology
5   !!======================================================================
6   !! History :  0.0  !  93-12  (M.A. Morales Maqueda.)  Original code
7   !!            1.0  !  94-12  (H. Goosse)
8   !!            2.0  !  03-12  (C. Ethe, G. Madec)  F90, mpp
9   !!            " "  !  06-08  (G. Madec)  surface module, ice-stress at I-point
10   !!            " "  !  09-09  (G. Madec)  Huge verctor optimisation
11   !!            3.3  !  09-05  (G.Garric) addition of the lim2_evp case
12   !!----------------------------------------------------------------------
13#if defined key_lim2 &&  defined key_lim2_vp
14   !!----------------------------------------------------------------------
15   !!   'key_lim2'                                    LIM 2.0 sea-ice model
16   !!----------------------------------------------------------------------
17   !!----------------------------------------------------------------------
18   !!   lim_rhg_2   : computes ice velocities
19   !!----------------------------------------------------------------------
20   USE par_oce        ! ocean parameter
21   USE dom_oce        ! ocean space and time domain
22   USE sbc_oce        ! surface boundary condition: ocean variables
23   USE sbc_ice        ! surface boundary condition: ice variables
24   USE dom_ice_2      ! domaine: ice variables
25   USE phycst         ! physical constant
26   USE ice_2          ! ice variables
27   USE lbclnk         ! lateral boundary condition
28   USE lib_mpp        ! MPP library
29   USE in_out_manager ! I/O manager
30   USE prtctl         ! Print control
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   lim_rhg_2 ! routine called by lim_dyn
36
37   REAL(wp) ::   rzero   = 0.e0   ! constant value: zero
38   REAL(wp) ::   rone    = 1.e0   !            and  one
39
40   !! * Substitutions
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !!   LIM 2.0,  UCL-LOCEAN-IPSL (2006)
44   !! $Id$
45   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47
48CONTAINS
49
50   SUBROUTINE lim_rhg_2( k_j1, k_jpj )
51      !!-------------------------------------------------------------------
52      !!                 ***  SUBROUTINR lim_rhg_2  ***
53      !!
54      !! ** purpose :   determines the velocity field of sea ice by using
55      !!  atmospheric (wind stress) and oceanic (water stress and surface
56      !!  tilt) forcings. Ice-ice interaction is described by a non-linear
57      !!  viscous-plastic law including shear strength and a bulk rheology.
58      !!
59      !! ** Action  : - compute u_ice, v_ice the sea-ice velocity defined
60      !!              at I-point
61      !!-------------------------------------------------------------------
62      INTEGER, INTENT(in) ::   k_j1    ! southern j-index for ice computation
63      INTEGER, INTENT(in) ::   k_jpj   ! northern j-index for ice computation
64      !!
65      INTEGER ::   ji, jj              ! dummy loop indices
66      INTEGER ::   iter, jter          ! temporary integers
67      CHARACTER (len=50) ::   charout
68      REAL(wp) ::   ze11  , ze12  , ze22  , ze21               ! temporary scalars
69      REAL(wp) ::   zt11  , zt12  , zt21  , zt22               !    "         "
70      REAL(wp) ::   zvis11, zvis21, zvis12, zvis22             !    "         "
71      REAL(wp) ::   zgphsx, ztagnx, zgsshx, zunw, zur, zusw    !    "         "
72      REAL(wp) ::   zgphsy, ztagny, zgsshy, zvnw, zvr          !    "         "
73      REAL(wp) ::   zresm,  za, zac, zmod
74      REAL(wp) ::   zmpzas, zstms, zindu, zusdtp, zmassdt, zcorlal
75      REAL(wp) ::   ztrace2, zdeter, zdelta, zmask, zdgp, zdgi, zdiag
76      REAL(wp) ::   za1, zb1, zc1, zd1
77      REAL(wp) ::   za2, zb2, zc2, zd2, zden
78      REAL(wp) ::   zs11_11, zs11_12, zs11_21, zs11_22
79      REAL(wp) ::   zs12_11, zs12_12, zs12_21, zs12_22
80      REAL(wp) ::   zs21_11, zs21_12, zs21_21, zs21_22
81      REAL(wp) ::   zs22_11, zs22_12, zs22_21, zs22_22
82      REAL(wp), DIMENSION(jpi,  jpj  ) ::   zfrld, zmass, zcorl
83      REAL(wp), DIMENSION(jpi,  jpj  ) ::   za1ct, za2ct, zresr
84      REAL(wp), DIMENSION(jpi,  jpj  ) ::   zc1u, zc1v, zc2u, zc2v
85      REAL(wp), DIMENSION(jpi,  jpj  ) ::   zsang
86      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zu0, zv0
87      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zu_n, zv_n
88      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zu_a, zv_a
89      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zviszeta, zviseta
90      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zzfrld, zztms
91      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zi1, zi2, zmasst, zpresh
92
93      !!-------------------------------------------------------------------
94
95!!bug
96!!    u_oce(:,:) = 0.e0
97!!    v_oce(:,:) = 0.e0
98!!    write(*,*) 'rhg min, max u & v', maxval(u_oce), minval(u_oce), maxval(v_oce), minval(v_oce)
99!!bug
100     
101      !  Store initial velocities
102      !  ----------------
103      zztms(:,0    ) = 0.e0       ;    zzfrld(:,0    ) = 0.e0
104      zztms(:,jpj+1) = 0.e0       ;    zzfrld(:,jpj+1) = 0.e0
105      zu0(:,0    ) = 0.e0         ;    zv0(:,0    ) = 0.e0
106      zu0(:,jpj+1) = 0.e0         ;    zv0(:,jpj+1) = 0.e0
107      zztms(:,1:jpj) = tms(:,:)   ;    zzfrld(:,1:jpj) = frld(:,:)
108      zu0(:,1:jpj) = u_ice(:,:)   ;    zv0(:,1:jpj) = v_ice(:,:)
109
110      zu_a(:,:)    = zu0(:,:)     ;   zv_a(:,:) = zv0(:,:)
111      zu_n(:,:)    = zu0(:,:)     ;   zv_n(:,:) = zv0(:,:)
112
113!i
114      zi1   (:,:) = 0.e0
115      zi2   (:,:) = 0.e0
116      zpresh(:,:) = 0.e0
117      zmasst(:,:) = 0.e0
118!i
119!!gm violant
120      zfrld(:,:) =0.e0
121      zcorl(:,:) =0.e0
122      zmass(:,:) =0.e0
123      za1ct(:,:) =0.e0
124      za2ct(:,:) =0.e0
125!!gm end
126
127      zviszeta(:,:) = 0.e0
128      zviseta (:,:) = 0.e0
129
130!i    zviszeta(:,0    ) = 0.e0    ;    zviseta(:,0    ) = 0.e0
131!i    zviszeta(:,jpj  ) = 0.e0    ;    zviseta(:,jpj  ) = 0.e0
132!i    zviszeta(:,jpj+1) = 0.e0    ;    zviseta(:,jpj+1) = 0.e0
133
134
135      ! Ice mass, ice strength, and wind stress at the center            |
136      ! of the grid squares.                                             |
137      !-------------------------------------------------------------------
138
139!CDIR NOVERRCHK
140      DO jj = k_j1 , k_jpj-1
141!CDIR NOVERRCHK
142         DO ji = 1 , jpi
143            ! only the sinus changes its sign with the hemisphere
144            zsang(ji,jj)  = SIGN( 1.e0, fcor(ji,jj) ) * sangvg   ! only the sinus changes its sign with the hemisphere
145            !
146            zmasst(ji,jj) = tms(ji,jj) * ( rhosn * hsnm(ji,jj) + rhoic * hicm(ji,jj) )
147            zpresh(ji,jj) = tms(ji,jj) *  pstarh * hicm(ji,jj) * EXP( -c_rhg * frld(ji,jj) )
148!!gm  :: stress given at I-point (F-point for the ocean) only compute the ponderation with the ice fraction (1-frld)
149            zi1(ji,jj)    = tms(ji,jj) * ( 1.0 - frld(ji,jj) )
150            zi2(ji,jj)    = tms(ji,jj) * ( 1.0 - frld(ji,jj) )
151         END DO
152      END DO
153
154
155      !---------------------------------------------------------------------------
156      !  Wind stress, coriolis and mass terms at the corners of the grid squares |
157      !  Gradient of ice strenght.                                               |
158      !---------------------------------------------------------------------------
159         
160      DO jj = k_j1+1, k_jpj-1
161         DO ji = 2, jpi    ! NO vector opt.
162            zstms = zztms(ji,jj  ) * wght(ji,jj,2,2) + zztms(ji-1,jj  ) * wght(ji,jj,1,2)   &
163               &  + zztms(ji,jj-1) * wght(ji,jj,2,1) + zztms(ji-1,jj-1) * wght(ji,jj,1,1)
164            zusw  = 1.0 / MAX( zstms, epsd )
165
166            zt11 = zztms(ji  ,jj  ) * zzfrld(ji  ,jj  ) 
167            zt12 = zztms(ji-1,jj  ) * zzfrld(ji-1,jj  ) 
168            zt21 = zztms(ji  ,jj-1) * zzfrld(ji  ,jj-1) 
169            zt22 = zztms(ji-1,jj-1) * zzfrld(ji-1,jj-1)
170
171            ! Leads area.
172            zfrld(ji,jj) =  (  zt11 * wght(ji,jj,2,2) + zt12 * wght(ji,jj,1,2)   &
173               &             + zt21 * wght(ji,jj,2,1) + zt22 * wght(ji,jj,1,1) ) * zusw
174
175            ! Mass and coriolis coeff. at I-point
176            zmass(ji,jj) = ( zmasst(ji,jj  ) * wght(ji,jj,2,2) + zmasst(ji-1,jj  ) * wght(ji,jj,1,2)   &
177               &           + zmasst(ji,jj-1) * wght(ji,jj,2,1) + zmasst(ji-1,jj-1) * wght(ji,jj,1,1) ) * zusw
178            zcorl(ji,jj) = zmass(ji,jj) &
179               &           *( fcor(ji,jj  ) * wght(ji,jj,2,2) + fcor(ji-1,jj  )*wght(ji,jj,1,2)   &
180               &            + fcor(ji,jj-1) * wght(ji,jj,2,1) + fcor(ji-1,jj-1)*wght(ji,jj,1,1) ) * zusw
181
182            ! Wind stress.
183            ! always provide stress at I-point
184            ztagnx = ( zi1(ji,jj  ) * wght(ji,jj,2,2) + zi1(ji-1,jj  ) * wght(ji,jj,1,2)   &
185               &     + zi1(ji,jj-1) * wght(ji,jj,2,1) + zi1(ji-1,jj-1) * wght(ji,jj,1,1) ) * zusw * utau_ice(ji,jj)
186            ztagny = ( zi2(ji,jj  ) * wght(ji,jj,2,2) + zi2(ji-1,jj  ) * wght(ji,jj,1,2)   &
187               &     + zi2(ji,jj-1) * wght(ji,jj,2,1) + zi2(ji-1,jj-1) * wght(ji,jj,1,1) ) * zusw * vtau_ice(ji,jj)
188
189            ! Gradient of ice strength
190            zgphsx =   ( alambd(ji,jj,2,2,2,1) - alambd(ji,jj,2,1,2,1) ) * zpresh(ji  ,jj-1)   &
191               &     + ( alambd(ji,jj,2,2,2,2) - alambd(ji,jj,2,1,2,2) ) * zpresh(ji  ,jj  )   &
192               &     - ( alambd(ji,jj,2,2,1,1) + alambd(ji,jj,2,1,1,1) ) * zpresh(ji-1,jj-1)   &
193               &     - ( alambd(ji,jj,2,2,1,2) + alambd(ji,jj,2,1,1,2) ) * zpresh(ji-1,jj  )
194
195            zgphsy = - ( alambd(ji,jj,1,1,2,1) + alambd(ji,jj,1,2,2,1) ) * zpresh(ji  ,jj-1)   &
196               &     - ( alambd(ji,jj,1,1,1,1) + alambd(ji,jj,1,2,1,1) ) * zpresh(ji-1,jj-1)   &
197               &     + ( alambd(ji,jj,1,1,2,2) - alambd(ji,jj,1,2,2,2) ) * zpresh(ji  ,jj  )   &
198               &     + ( alambd(ji,jj,1,1,1,2) - alambd(ji,jj,1,2,1,2) ) * zpresh(ji-1,jj  )
199
200            ! Gradient of the sea surface height
201            zgsshx =  (   (ssh_m(ji  ,jj  ) - ssh_m(ji-1,jj  ))/e1u(ji-1,jj  )   &
202               &       +  (ssh_m(ji  ,jj-1) - ssh_m(ji-1,jj-1))/e1u(ji-1,jj-1)   ) * 0.5
203            zgsshy =  (   (ssh_m(ji  ,jj  ) - ssh_m(ji  ,jj-1))/e2v(ji  ,jj-1)   &
204               &       +  (ssh_m(ji-1,jj  ) - ssh_m(ji-1,jj-1))/e2v(ji-1,jj-1)   ) * 0.5
205
206            ! Computation of the velocity field taking into account the ice-ice interaction.                                 
207            ! Terms that are independent of the ice velocity field.
208            za1ct(ji,jj) = ztagnx - zmass(ji,jj) * grav * zgsshx - zgphsx
209            za2ct(ji,jj) = ztagny - zmass(ji,jj) * grav * zgsshy - zgphsy
210         END DO
211      END DO
212
213
214      ! SOLUTION OF THE MOMENTUM EQUATION.
215      !------------------------------------------
216      !                                                   ! ==================== !
217      DO iter = 1 , 2 * nbiter                            !    loop over iter    !
218         !                                                ! ==================== !       
219         zindu = MOD( iter , 2 )
220         zusdtp = ( zindu * 2.0 + ( 1.0 - zindu ) * 1.0 )  * REAL( nbiter ) / rdt_ice
221
222         ! Computation of free drift field for free slip boundary conditions.
223
224!CDIR NOVERRCHK
225         DO jj = k_j1, k_jpj-1
226!CDIR NOVERRCHK
227            DO ji = 1, fs_jpim1
228               !- Rate of strain tensor.
229               zt11 =   akappa(ji,jj,1,1) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) - zu_a(ji,jj  ) - zu_a(ji  ,jj+1) )  &
230                  &   + akappa(ji,jj,1,2) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) + zv_a(ji,jj  ) + zv_a(ji  ,jj+1) )
231               zt12 = - akappa(ji,jj,2,2) * ( zu_a(ji  ,jj) + zu_a(ji+1,jj  ) - zu_a(ji,jj+1) - zu_a(ji+1,jj+1) )  &
232                  &   - akappa(ji,jj,2,1) * ( zv_a(ji  ,jj) + zv_a(ji+1,jj  ) + zv_a(ji,jj+1) + zv_a(ji+1,jj+1) )
233               zt22 = - akappa(ji,jj,2,2) * ( zv_a(ji  ,jj) + zv_a(ji+1,jj  ) - zv_a(ji,jj+1) - zv_a(ji+1,jj+1) )  &
234                  &   + akappa(ji,jj,2,1) * ( zu_a(ji  ,jj) + zu_a(ji+1,jj  ) + zu_a(ji,jj+1) + zu_a(ji+1,jj+1) )
235               zt21 =   akappa(ji,jj,1,1) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) - zv_a(ji,jj  ) - zv_a(ji  ,jj+1) )  &
236                  &   - akappa(ji,jj,1,2) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) + zu_a(ji,jj  ) + zu_a(ji  ,jj+1) )
237
238               !- Rate of strain tensor.
239               zdgp = zt11 + zt22
240               zdgi = zt12 + zt21
241               ztrace2 = zdgp * zdgp 
242               zdeter  = zt11 * zt22 - 0.25 * zdgi * zdgi
243
244               !  Creep limit depends on the size of the grid.
245               zdelta = MAX( SQRT( ztrace2 + ( ztrace2 - 4.0 * zdeter ) * usecc2 ),  creepl)
246
247               !-  Computation of viscosities.
248               zviszeta(ji,jj) = MAX( zpresh(ji,jj) / zdelta, etamn )
249               zviseta (ji,jj) = zviszeta(ji,jj) * usecc2
250            END DO
251         END DO
252
253         !-  Determination of zc1u, zc2u, zc1v and zc2v.
254         DO jj = k_j1+1, k_jpj-1
255            DO ji = 2, fs_jpim1   ! NO vector opt.
256               !* zc1u , zc2v
257               zvis11 = 2.0 * zviseta (ji-1,jj-1) + dm
258               zvis12 =       zviseta (ji-1,jj-1) + dm
259               zvis21 =       zviseta (ji-1,jj-1)
260               zvis22 =       zviszeta(ji-1,jj-1) - zviseta(ji-1,jj-1)
261               zdiag  = zvis22 * ( akappa(ji-1,jj-1,1,1) + akappa(ji-1,jj-1,2,1) )
262               zs11_11 =  zvis11 * akappa(ji-1,jj-1,1,1) + zdiag
263               zs12_11 =  zvis12 * akappa(ji-1,jj-1,2,2) - zvis21 * akappa(ji-1,jj-1,1,2)
264               zs21_11 = -zvis12 * akappa(ji-1,jj-1,1,2) + zvis21 * akappa(ji-1,jj-1,2,2)
265               zs22_11 =  zvis11 * akappa(ji-1,jj-1,2,1) + zdiag
266
267               zvis11 = 2.0 * zviseta (ji,jj-1) + dm
268               zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
269               zvis12 =       zviseta (ji,jj-1) + dm
270               zvis21 =       zviseta (ji,jj-1)
271               zdiag = zvis22 * ( -akappa(ji,jj-1,1,1) + akappa(ji,jj-1,2,1) )
272               zs11_21 = -zvis11 * akappa(ji,jj-1,1,1) + zdiag
273               zs12_21 =  zvis12 * akappa(ji,jj-1,2,2) - zvis21 * akappa(ji,jj-1,1,2)
274               zs22_21 =  zvis11 * akappa(ji,jj-1,2,1) + zdiag
275               zs21_21 = -zvis12 * akappa(ji,jj-1,1,2) + zvis21 * akappa(ji,jj-1,2,2)
276
277               zvis11 = 2.0 * zviseta (ji-1,jj) + dm
278               zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
279               zvis12 =       zviseta (ji-1,jj) + dm
280               zvis21 =       zviseta (ji-1,jj)
281               zdiag = zvis22 * ( akappa(ji-1,jj,1,1) + akappa(ji-1,jj,2,1) )
282               zs11_12 =  zvis11 * akappa(ji-1,jj,1,1) + zdiag
283               zs12_12 = -zvis12 * akappa(ji-1,jj,2,2) - zvis21 * akappa(ji-1,jj,1,2)
284               zs22_12 =  zvis11 * akappa(ji-1,jj,2,1) + zdiag
285               zs21_12 = -zvis12 * akappa(ji-1,jj,1,2) - zvis21 * akappa(ji-1,jj,2,2)
286
287               zvis11 = 2.0 * zviseta (ji,jj) + dm
288               zvis22 =       zviszeta(ji,jj) - zviseta(ji,jj)
289               zvis12 =       zviseta (ji,jj) + dm
290               zvis21 =       zviseta (ji,jj)
291               zdiag = zvis22 * ( -akappa(ji,jj,1,1) + akappa(ji,jj,2,1) )
292               zs11_22 = -zvis11 * akappa(ji,jj,1,1) + zdiag
293               zs12_22 = -zvis12 * akappa(ji,jj,2,2) - zvis21 * akappa(ji,jj,1,2)
294               zs22_22 =  zvis11 * akappa(ji,jj,2,1) + zdiag
295               zs21_22 = -zvis12 * akappa(ji,jj,1,2) - zvis21 * akappa(ji,jj,2,2)
296
297               zc1u(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs11_21 + alambd(ji,jj,2,2,2,2) * zs11_22   &
298                  &          - alambd(ji,jj,2,2,1,1) * zs11_11 - alambd(ji,jj,2,2,1,2) * zs11_12   &
299                  &          - alambd(ji,jj,1,1,2,1) * zs12_21 - alambd(ji,jj,1,1,1,1) * zs12_11   &
300                  &          + alambd(ji,jj,1,1,2,2) * zs12_22 + alambd(ji,jj,1,1,1,2) * zs12_12   &
301                  &          + alambd(ji,jj,1,2,1,1) * zs21_11 + alambd(ji,jj,1,2,2,1) * zs21_21   &
302                  &          + alambd(ji,jj,1,2,1,2) * zs21_12 + alambd(ji,jj,1,2,2,2) * zs21_22   &
303                  &          - alambd(ji,jj,2,1,1,1) * zs22_11 - alambd(ji,jj,2,1,2,1) * zs22_21   &
304                  &          - alambd(ji,jj,2,1,1,2) * zs22_12 - alambd(ji,jj,2,1,2,2) * zs22_22
305
306               zc2u(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs21_21 + alambd(ji,jj,2,2,2,2) * zs21_22   &
307                  &          - alambd(ji,jj,2,2,1,1) * zs21_11 - alambd(ji,jj,2,2,1,2) * zs21_12   &
308                  &          - alambd(ji,jj,1,1,2,1) * zs22_21 - alambd(ji,jj,1,1,1,1) * zs22_11   &
309                  &          + alambd(ji,jj,1,1,2,2) * zs22_22 + alambd(ji,jj,1,1,1,2) * zs22_12   &
310                  &          - alambd(ji,jj,1,2,1,1) * zs11_11 - alambd(ji,jj,1,2,2,1) * zs11_21   &
311                  &          - alambd(ji,jj,1,2,1,2) * zs11_12 - alambd(ji,jj,1,2,2,2) * zs11_22   &
312                  &          + alambd(ji,jj,2,1,1,1) * zs12_11 + alambd(ji,jj,2,1,2,1) * zs12_21   &
313                  &          + alambd(ji,jj,2,1,1,2) * zs12_12 + alambd(ji,jj,2,1,2,2) * zs12_22
314
315               !* zc1v , zc2v.
316               zvis11 = 2.0 * zviseta (ji-1,jj-1) + dm
317               zvis22 =       zviszeta(ji-1,jj-1) - zviseta(ji-1,jj-1)
318               zvis12 =       zviseta (ji-1,jj-1) + dm
319               zvis21 =       zviseta (ji-1,jj-1)
320               zdiag = zvis22 * ( akappa(ji-1,jj-1,1,2) + akappa(ji-1,jj-1,2,2) )
321               zs11_11 =  zvis11 * akappa(ji-1,jj-1,1,2) + zdiag
322               zs12_11 = -zvis12 * akappa(ji-1,jj-1,2,1) + zvis21 * akappa(ji-1,jj-1,1,1)
323               zs22_11 =  zvis11 * akappa(ji-1,jj-1,2,2) + zdiag
324               zs21_11 =  zvis12 * akappa(ji-1,jj-1,1,1) - zvis21 * akappa(ji-1,jj-1,2,1)
325 
326               zvis11 = 2.0 * zviseta (ji,jj-1) + dm
327               zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
328               zvis12 =       zviseta (ji,jj-1) + dm
329               zvis21 =       zviseta (ji,jj-1)
330               zdiag = zvis22 * ( akappa(ji,jj-1,1,2) + akappa(ji,jj-1,2,2) )
331               zs11_21 =  zvis11 * akappa(ji,jj-1,1,2) + zdiag
332               zs12_21 = -zvis12 * akappa(ji,jj-1,2,1) - zvis21 * akappa(ji,jj-1,1,1)
333               zs22_21 =  zvis11 * akappa(ji,jj-1,2,2) + zdiag
334               zs21_21 = -zvis12 * akappa(ji,jj-1,1,1) - zvis21 * akappa(ji,jj-1,2,1)
335
336               zvis11 = 2.0 * zviseta (ji-1,jj) + dm
337               zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
338               zvis12 =       zviseta (ji-1,jj) + dm
339               zvis21 =       zviseta (ji-1,jj)
340               zdiag = zvis22 * ( akappa(ji-1,jj,1,2) - akappa(ji-1,jj,2,2) )
341               zs11_12 =  zvis11 * akappa(ji-1,jj,1,2) + zdiag
342               zs12_12 = -zvis12 * akappa(ji-1,jj,2,1) + zvis21 * akappa(ji-1,jj,1,1)
343               zs22_12 = -zvis11 * akappa(ji-1,jj,2,2) + zdiag
344               zs21_12 =  zvis12 * akappa(ji-1,jj,1,1) - zvis21 * akappa(ji-1,jj,2,1)
345
346               zvis11 = 2.0 * zviseta (ji,jj) + dm
347               zvis22 =       zviszeta(ji,jj) - zviseta(ji,jj)
348               zvis12 =       zviseta (ji,jj) + dm
349               zvis21 =       zviseta (ji,jj)
350               zdiag = zvis22 * ( akappa(ji,jj,1,2) - akappa(ji,jj,2,2) )
351               zs11_22 =  zvis11 * akappa(ji,jj,1,2) + zdiag
352               zs12_22 = -zvis12 * akappa(ji,jj,2,1) - zvis21 * akappa(ji,jj,1,1)
353               zs22_22 = -zvis11 * akappa(ji,jj,2,2) + zdiag
354               zs21_22 = -zvis12 * akappa(ji,jj,1,1) - zvis21 * akappa(ji,jj,2,1)
355
356               zc1v(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs11_21 + alambd(ji,jj,2,2,2,2) * zs11_22   &
357                  &          - alambd(ji,jj,2,2,1,1) * zs11_11 - alambd(ji,jj,2,2,1,2) * zs11_12   &
358                  &          - alambd(ji,jj,1,1,2,1) * zs12_21 - alambd(ji,jj,1,1,1,1) * zs12_11   &
359                  &          + alambd(ji,jj,1,1,2,2) * zs12_22 + alambd(ji,jj,1,1,1,2) * zs12_12   &
360                  &          + alambd(ji,jj,1,2,1,1) * zs21_11 + alambd(ji,jj,1,2,2,1) * zs21_21   &
361                  &          + alambd(ji,jj,1,2,1,2) * zs21_12 + alambd(ji,jj,1,2,2,2) * zs21_22   &
362                  &          - alambd(ji,jj,2,1,1,1) * zs22_11 - alambd(ji,jj,2,1,2,1) * zs22_21   &
363                  &          - alambd(ji,jj,2,1,1,2) * zs22_12 - alambd(ji,jj,2,1,2,2) * zs22_22
364
365               zc2v(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs21_21 + alambd(ji,jj,2,2,2,2) * zs21_22   &
366                  &          - alambd(ji,jj,2,2,1,1) * zs21_11 - alambd(ji,jj,2,2,1,2) * zs21_12   &
367                  &          - alambd(ji,jj,1,1,2,1) * zs22_21 - alambd(ji,jj,1,1,1,1) * zs22_11   &
368                  &          + alambd(ji,jj,1,1,2,2) * zs22_22 + alambd(ji,jj,1,1,1,2) * zs22_12   &
369                  &          - alambd(ji,jj,1,2,1,1) * zs11_11 - alambd(ji,jj,1,2,2,1) * zs11_21   &
370                  &          - alambd(ji,jj,1,2,1,2) * zs11_12 - alambd(ji,jj,1,2,2,2) * zs11_22   &
371                  &          + alambd(ji,jj,2,1,1,1) * zs12_11 + alambd(ji,jj,2,1,2,1) * zs12_21   &
372                  &          + alambd(ji,jj,2,1,1,2) * zs12_12 + alambd(ji,jj,2,1,2,2) * zs12_22
373            END DO
374         END DO
375
376         ! GAUSS-SEIDEL method
377         !                                                      ! ================ !
378iflag:   DO jter = 1 , nbitdr                                   !    Relaxation    !
379            !                                                   ! ================ !
380!CDIR NOVERRCHK
381            DO jj = k_j1+1, k_jpj-1
382!CDIR NOVERRCHK
383               DO ji = 2, fs_jpim1   ! NO vector opt.
384                  !
385                  ze11 =   akappa(ji,jj-1,1,1) * zu_a(ji+1,jj) + akappa(ji,jj-1,1,2) * zv_a(ji+1,jj)
386                  ze12 = + akappa(ji,jj-1,2,2) * zu_a(ji+1,jj) - akappa(ji,jj-1,2,1) * zv_a(ji+1,jj)
387                  ze22 = + akappa(ji,jj-1,2,2) * zv_a(ji+1,jj) + akappa(ji,jj-1,2,1) * zu_a(ji+1,jj)
388                  ze21 =   akappa(ji,jj-1,1,1) * zv_a(ji+1,jj) - akappa(ji,jj-1,1,2) * zu_a(ji+1,jj)
389                  zvis11 = 2.0 * zviseta (ji,jj-1) + dm
390                  zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
391                  zvis12 =       zviseta (ji,jj-1) + dm
392                  zvis21 =       zviseta (ji,jj-1)
393                  zdiag = zvis22 * ( ze11 + ze22 )
394                  zs11_21 =  zvis11 * ze11 + zdiag
395                  zs12_21 =  zvis12 * ze12 + zvis21 * ze21
396                  zs22_21 =  zvis11 * ze22 + zdiag
397                  zs21_21 =  zvis12 * ze21 + zvis21 * ze12
398
399                  ze11 =   akappa(ji-1,jj,1,1) * ( zu_a(ji  ,jj+1) - zu_a(ji-1,jj+1) )   &
400                     &   + akappa(ji-1,jj,1,2) * ( zv_a(ji  ,jj+1) + zv_a(ji-1,jj+1) )
401                  ze12 = + akappa(ji-1,jj,2,2) * ( zu_a(ji-1,jj+1) + zu_a(ji  ,jj+1) )   &
402                     &   - akappa(ji-1,jj,2,1) * ( zv_a(ji-1,jj+1) + zv_a(ji  ,jj+1) )
403                  ze22 = + akappa(ji-1,jj,2,2) * ( zv_a(ji-1,jj+1) + zv_a(ji  ,jj+1) )   &
404                     &   + akappa(ji-1,jj,2,1) * ( zu_a(ji-1,jj+1) + zu_a(ji  ,jj+1) )
405                  ze21 =   akappa(ji-1,jj,1,1) * ( zv_a(ji  ,jj+1) - zv_a(ji-1,jj+1) )   &
406                     &   - akappa(ji-1,jj,1,2) * ( zu_a(ji  ,jj+1) + zu_a(ji-1,jj+1) )
407                  zvis11 = 2.0 * zviseta (ji-1,jj) + dm
408                  zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
409                  zvis12 =       zviseta (ji-1,jj) + dm
410                  zvis21 =       zviseta (ji-1,jj)
411                  zdiag = zvis22 * ( ze11 + ze22 )
412                  zs11_12 =  zvis11 * ze11 + zdiag
413                  zs12_12 =  zvis12 * ze12 + zvis21 * ze21
414                  zs22_12 =  zvis11 * ze22 + zdiag
415                  zs21_12 =  zvis12 * ze21 + zvis21 * ze12
416
417                  ze11 =   akappa(ji,jj,1,1) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) - zu_a(ji  ,jj+1) )   &
418                     &   + akappa(ji,jj,1,2) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) + zv_a(ji  ,jj+1) )
419                  ze12 = - akappa(ji,jj,2,2) * ( zu_a(ji+1,jj) - zu_a(ji  ,jj+1) - zu_a(ji+1,jj+1) )   &
420                     &   - akappa(ji,jj,2,1) * ( zv_a(ji+1,jj) + zv_a(ji  ,jj+1) + zv_a(ji+1,jj+1) )
421                  ze22 = - akappa(ji,jj,2,2) * ( zv_a(ji+1,jj) - zv_a(ji  ,jj+1) - zv_a(ji+1,jj+1) )   &
422                     &   + akappa(ji,jj,2,1) * ( zu_a(ji+1,jj) + zu_a(ji  ,jj+1) + zu_a(ji+1,jj+1) )
423                  ze21 =   akappa(ji,jj,1,1) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) - zv_a(ji  ,jj+1) )   &
424                     &   - akappa(ji,jj,1,2) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) + zu_a(ji  ,jj+1) )
425                  zvis11 = 2.0 * zviseta (ji,jj) + dm
426                  zvis22 =       zviszeta(ji,jj) - zviseta(ji,jj)
427                  zvis12 =       zviseta (ji,jj) + dm
428                  zvis21 =       zviseta (ji,jj)
429                  zdiag = zvis22 * ( ze11 + ze22 )
430                  zs11_22 =  zvis11 * ze11 + zdiag
431                  zs12_22 =  zvis12 * ze12 + zvis21 * ze21
432                  zs22_22 =  zvis11 * ze22 + zdiag
433                  zs21_22 =  zvis12 * ze21 + zvis21 * ze12
434
435            ! 2nd part
436                  ze11 =   akappa(ji-1,jj-1,1,1) * ( zu_a(ji  ,jj-1) - zu_a(ji-1,jj-1) - zu_a(ji-1,jj) )   &
437                     &   + akappa(ji-1,jj-1,1,2) * ( zv_a(ji  ,jj-1) + zv_a(ji-1,jj-1) + zv_a(ji-1,jj) )
438                  ze12 = - akappa(ji-1,jj-1,2,2) * ( zu_a(ji-1,jj-1) + zu_a(ji  ,jj-1) - zu_a(ji-1,jj) )   &
439                     &   - akappa(ji-1,jj-1,2,1) * ( zv_a(ji-1,jj-1) + zv_a(ji  ,jj-1) + zv_a(ji-1,jj) )
440                  ze22 = - akappa(ji-1,jj-1,2,2) * ( zv_a(ji-1,jj-1) + zv_a(ji  ,jj-1) - zv_a(ji-1,jj) )   &
441                     &   + akappa(ji-1,jj-1,2,1) * ( zu_a(ji-1,jj-1) + zu_a(ji  ,jj-1) + zu_a(ji-1,jj) )
442                  ze21 =   akappa(ji-1,jj-1,1,1) * ( zv_a(ji  ,jj-1) - zv_a(ji-1,jj-1) - zv_a(ji-1,jj) )   &
443                     &  -  akappa(ji-1,jj-1,1,2) * ( zu_a(ji  ,jj-1) + zu_a(ji-1,jj-1) + zu_a(ji-1,jj) )
444                  zvis11 = 2.0 * zviseta (ji-1,jj-1) + dm
445                  zvis22 =       zviszeta(ji-1,jj-1) - zviseta(ji-1,jj-1)
446                  zvis12 =       zviseta (ji-1,jj-1) + dm
447                  zvis21 =       zviseta (ji-1,jj-1)
448                  zdiag = zvis22 * ( ze11 + ze22 )
449                  zs11_11 =  zvis11 * ze11 + zdiag
450                  zs12_11 =  zvis12 * ze12 + zvis21 * ze21
451                  zs22_11 =  zvis11 * ze22 + zdiag
452                  zs21_11 =  zvis12 * ze21 + zvis21 * ze12
453
454                  ze11 =   akappa(ji,jj-1,1,1) * ( zu_a(ji+1,jj-1) - zu_a(ji  ,jj-1) )   &
455                     &   + akappa(ji,jj-1,1,2) * ( zv_a(ji+1,jj-1) + zv_a(ji  ,jj-1) )
456                  ze12 = - akappa(ji,jj-1,2,2) * ( zu_a(ji  ,jj-1) + zu_a(ji+1,jj-1) )   &
457                     &   - akappa(ji,jj-1,2,1) * ( zv_a(ji  ,jj-1) + zv_a(ji+1,jj-1) )
458                  ze22 = - akappa(ji,jj-1,2,2) * ( zv_a(ji  ,jj-1) + zv_a(ji+1,jj-1) )   &
459                     &   + akappa(ji,jj-1,2,1) * ( zu_a(ji  ,jj-1) + zu_a(ji+1,jj-1) )
460                  ze21 =   akappa(ji,jj-1,1,1) * ( zv_a(ji+1,jj-1) - zv_a(ji  ,jj-1) )   &
461                     &   - akappa(ji,jj-1,1,2) * ( zu_a(ji+1,jj-1) + zu_a(ji  ,jj-1) )
462                  zvis11 = 2.0 * zviseta (ji,jj-1) + dm
463                  zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
464                  zvis12 =       zviseta (ji,jj-1) + dm
465                  zvis21 =       zviseta (ji,jj-1)
466                  zdiag = zvis22 * ( ze11 + ze22 )
467                  zs11_21 =  zs11_21 + zvis11 * ze11 + zdiag
468                  zs12_21 =  zs12_21 + zvis12 * ze12 + zvis21 * ze21
469                  zs22_21 =  zs22_21 + zvis11 * ze22 + zdiag
470                  zs21_21 =  zs21_21 + zvis12 * ze21 + zvis21 * ze12
471
472                  ze11 = - akappa(ji-1,jj,1,1) * zu_a(ji-1,jj) + akappa(ji-1,jj,1,2) * zv_a(ji-1,jj)
473                  ze12 = - akappa(ji-1,jj,2,2) * zu_a(ji-1,jj) - akappa(ji-1,jj,2,1) * zv_a(ji-1,jj)
474                  ze22 = - akappa(ji-1,jj,2,2) * zv_a(ji-1,jj) + akappa(ji-1,jj,2,1) * zu_a(ji-1,jj)
475                  ze21 = - akappa(ji-1,jj,1,1) * zv_a(ji-1,jj) - akappa(ji-1,jj,1,2) * zu_a(ji-1,jj)
476                  zvis11 = 2.0 * zviseta (ji-1,jj) + dm
477                  zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
478                  zvis12 =       zviseta (ji-1,jj) + dm
479                  zvis21 =       zviseta (ji-1,jj)
480                  zdiag = zvis22 * ( ze11 + ze22 )
481                  zs11_12 =  zs11_12 + zvis11 * ze11 + zdiag
482                  zs12_12 =  zs12_12 + zvis12 * ze12 + zvis21 * ze21
483                  zs22_12 =  zs22_12 + zvis11 * ze22 + zdiag
484                  zs21_12 =  zs21_12 + zvis12 * ze21 + zvis21 * ze12
485
486                  zd1 = + alambd(ji,jj,2,2,2,1) * zs11_21 + alambd(ji,jj,2,2,2,2) * zs11_22  &
487                     &  - alambd(ji,jj,2,2,1,1) * zs11_11 - alambd(ji,jj,2,2,1,2) * zs11_12  &
488                     &  - alambd(ji,jj,1,1,2,1) * zs12_21 - alambd(ji,jj,1,1,1,1) * zs12_11  &
489                     &  + alambd(ji,jj,1,1,2,2) * zs12_22 + alambd(ji,jj,1,1,1,2) * zs12_12  &
490                     &  + alambd(ji,jj,1,2,1,1) * zs21_11 + alambd(ji,jj,1,2,2,1) * zs21_21  &
491                     &  + alambd(ji,jj,1,2,1,2) * zs21_12 + alambd(ji,jj,1,2,2,2) * zs21_22  &
492                     &  - alambd(ji,jj,2,1,1,1) * zs22_11 - alambd(ji,jj,2,1,2,1) * zs22_21  &
493                     &  - alambd(ji,jj,2,1,1,2) * zs22_12 - alambd(ji,jj,2,1,2,2) * zs22_22
494
495                  zd2 = + alambd(ji,jj,2,2,2,1) * zs21_21 + alambd(ji,jj,2,2,2,2) * zs21_22  &
496                     &  - alambd(ji,jj,2,2,1,1) * zs21_11 - alambd(ji,jj,2,2,1,2) * zs21_12  &
497                     &  - alambd(ji,jj,1,1,2,1) * zs22_21 - alambd(ji,jj,1,1,1,1) * zs22_11  &
498                     &  + alambd(ji,jj,1,1,2,2) * zs22_22 + alambd(ji,jj,1,1,1,2) * zs22_12  &
499                     &  - alambd(ji,jj,1,2,1,1) * zs11_11 - alambd(ji,jj,1,2,2,1) * zs11_21  &
500                     &  - alambd(ji,jj,1,2,1,2) * zs11_12 - alambd(ji,jj,1,2,2,2) * zs11_22  &
501                     &  + alambd(ji,jj,2,1,1,1) * zs12_11 + alambd(ji,jj,2,1,2,1) * zs12_21  &
502                     &  + alambd(ji,jj,2,1,1,2) * zs12_12 + alambd(ji,jj,2,1,2,2) * zs12_22
503
504                  zur     = zu_a(ji,jj) - u_oce(ji,jj)
505                  zvr     = zv_a(ji,jj) - v_oce(ji,jj)
506!!!!
507                  zmod    = SQRT( zur*zur + zvr*zvr ) * ( 1.0 - zfrld(ji,jj) )
508                  za      = rhoco * zmod
509!!!!
510!!gm chg resul    za      = rhoco * SQRT( zur*zur + zvr*zvr ) * ( 1.0 - zfrld(ji,jj) )
511                  zac     = za * cangvg
512                  zmpzas  = alpha * zcorl(ji,jj) + za * zsang(ji,jj)
513                  zmassdt = zusdtp * zmass(ji,jj)
514                  zcorlal = ( 1.0 - alpha ) * zcorl(ji,jj)
515
516                  za1 =  zmassdt * zu0(ji,jj) + zcorlal * zv0(ji,jj) + za1ct(ji,jj)   &
517                     &        + za * ( cangvg * u_oce(ji,jj) - zsang(ji,jj) * v_oce(ji,jj) )
518                  za2 =  zmassdt * zv0(ji,jj) - zcorlal * zu0(ji,jj) + za2ct(ji,jj)   &
519                     &        + za * ( cangvg * v_oce(ji,jj) + zsang(ji,jj) * u_oce(ji,jj) )
520                  zb1    = zmassdt + zac - zc1u(ji,jj)
521                  zb2    = zmpzas        - zc2u(ji,jj)
522                  zc1    = zmpzas        + zc1v(ji,jj)
523                  zc2    = zmassdt + zac - zc2v(ji,jj)
524                  zdeter = zc1 * zb2 + zc2 * zb1
525                  zden   = SIGN( rone, zdeter) / MAX( epsd , ABS( zdeter ) )
526                  zunw   = (  ( za1 + zd1 ) * zc2 + ( za2 + zd2 ) * zc1 ) * zden
527                  zvnw   = (  ( za2 + zd2 ) * zb1 - ( za1 + zd1 ) * zb2 ) * zden
528                  zmask  = ( 1.0 - MAX( rzero, SIGN( rone , 1.0 - zmass(ji,jj) ) ) ) * tmu(ji,jj)
529
530                  zu_n(ji,jj) = ( zu_a(ji,jj) + om * ( zunw - zu_a(ji,jj) ) * tmu(ji,jj) ) * zmask
531                  zv_n(ji,jj) = ( zv_a(ji,jj) + om * ( zvnw - zv_a(ji,jj) ) * tmu(ji,jj) ) * zmask
532               END DO
533            END DO
534
535            CALL lbc_lnk( zu_n(:,1:jpj), 'I', -1. )
536            CALL lbc_lnk( zv_n(:,1:jpj), 'I', -1. )
537
538            ! Test of Convergence
539            DO jj = k_j1+1 , k_jpj-1
540               zresr(:,jj) = MAX( ABS( zu_a(:,jj) - zu_n(:,jj) ) , ABS( zv_a(:,jj) - zv_n(:,jj) ) )
541            END DO
542            zresm = MAXVAL( zresr(1:jpi,k_j1+1:k_jpj-1) )
543!!!! this should be faster on scalar processor
544!           zresm = MAXVAL(  MAX( ABS( zu_a(1:jpi,k_j1+1:k_jpj-1) - zu_n(1:jpi,k_j1+1:k_jpj-1) ),   &
545!              &                  ABS( zv_a(1:jpi,k_j1+1:k_jpj-1) - zv_n(1:jpi,k_j1+1:k_jpj-1) ) )  )
546!!!!
547            IF( lk_mpp )   CALL mpp_max( zresm )   ! max over the global domain
548
549            DO jj = k_j1, k_jpj
550               zu_a(:,jj) = zu_n(:,jj)
551               zv_a(:,jj) = zv_n(:,jj)
552            END DO
553
554            IF( zresm <= resl )   EXIT   iflag
555
556            !                                                   ! ================ !
557         END DO    iflag                                        !  end Relaxation  !
558         !                                                      ! ================ !
559
560         IF( zindu == 0 ) THEN      ! even iteration
561            DO jj = k_j1 , k_jpj-1
562               zu0(:,jj) = zu_a(:,jj)
563               zv0(:,jj) = zv_a(:,jj)
564            END DO
565         ENDIF
566         !                                                ! ==================== !
567      END DO                                              !  end loop over iter  !
568      !                                                   ! ==================== !
569
570      u_ice(:,:) = zu_a(:,1:jpj)
571      v_ice(:,:) = zv_a(:,1:jpj)
572
573      IF(ln_ctl) THEN
574         WRITE(charout,FMT="('lim_rhg  : res =',D23.16, ' iter =',I4)") zresm, jter
575         CALL prt_ctl_info(charout)
576         CALL prt_ctl(tab2d_1=u_ice, clinfo1=' lim_rhg  : u_ice :', tab2d_2=v_ice, clinfo2=' v_ice :')
577      ENDIF
578
579   END SUBROUTINE lim_rhg_2
580
581#else
582   !!----------------------------------------------------------------------
583   !!   Default option          Dummy module       NO 2.0 LIM sea-ice model
584   !!----------------------------------------------------------------------
585CONTAINS
586   SUBROUTINE lim_rhg_2( k1 , k2 )       ! Dummy routine
587      WRITE(*,*) 'lim_rhg_2: You should not have seen this print! error?', k1, k2
588   END SUBROUTINE lim_rhg_2
589#endif
590
591   !!==============================================================================
592END MODULE limrhg_2
Note: See TracBrowser for help on using the repository browser.