New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtasal.F90 in branches/devmercator2010/NEMO/OPA_SRC/DTA – NEMO

source: branches/devmercator2010/NEMO/OPA_SRC/DTA/dtasal.F90 @ 2077

Last change on this file since 2077 was 2077, checked in by cbricaud, 14 years ago

commit change from DEV_r1784_3DF
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 11.0 KB
Line 
1MODULE dtasal
2   !!======================================================================
3   !!                     ***  MODULE  dtasal  ***
4   !! Ocean data  :  read ocean salinity data from monthly atlas data
5   !!=====================================================================
6#if defined key_dtasal   ||   defined key_esopa
7   !!----------------------------------------------------------------------
8   !!   'key_dtasal'                                          salinity data
9   !!----------------------------------------------------------------------
10   !!   dta_sal      : read ocean salinity data
11   !!----------------------------------------------------------------------
12   !! * Modules used
13   USE oce             ! ocean dynamics and tracers
14   USE dom_oce         ! ocean space and time domain
15   USE fldread         ! read input fields
16   USE in_out_manager  ! I/O manager
17   USE phycst          ! physical constants
18#if defined key_orca_lev10
19   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
20#endif
21
22   IMPLICIT NONE
23   PRIVATE
24
25   !! * Routine accessibility
26   PUBLIC dta_sal   ! called by step.F90 and inidta.F90
27   
28   !! * Shared module variables
29   LOGICAL , PUBLIC, PARAMETER ::   lk_dtasal = .TRUE.    !: salinity data flag
30   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   s_dta    !: salinity data at given time-step
31
32   !! * Module variables
33   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sal       ! structure of input SST (file informations, fields read)
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37   !!----------------------------------------------------------------------
38   !!   OPA 9.0 , LOCEAN-IPSL (2005)
39   !! $Id$
40   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
41   !!----------------------------------------------------------------------
42
43CONTAINS
44
45   !!----------------------------------------------------------------------
46   !!   Default option:                                         NetCDF file
47   !!----------------------------------------------------------------------
48
49   SUBROUTINE dta_sal( kt )
50      !!----------------------------------------------------------------------
51      !!                   ***  ROUTINE dta_sal  ***
52      !!       
53      !! ** Purpose :   Reads monthly salinity data
54      !!             
55      !! ** Method  : - Read on unit numsdt the monthly salinity data interpo-
56      !!     lated onto the model grid.
57      !!              - At each time step, a linear interpolation is applied
58      !!     between two monthly values.
59      !!
60      !! History :
61      !!        !  91-03  ()  Original code
62      !!        !  92-07  (M. Imbard)
63      !!   9.0  !  02-06  (G. Madec)  F90: Free form and module
64      !!----------------------------------------------------------------------
65     
66      !! * Arguments
67      INTEGER, INTENT(in) ::   kt             ! ocean time step
68     
69      !! * Local declarations
70     
71      INTEGER ::   ji, jj, jk, jl, jkk   ! dummy loop indicies
72      INTEGER ::   &
73           imois, iman, i15, ik           ! temporary integers
74      INTEGER            :: ierror
75#if defined key_tradmp
76      INTEGER ::   &
77          il0, il1, ii0, ii1, ij0, ij1   ! temporary integers         
78#endif
79      REAL(wp) ::   zxy, zl
80#if defined key_orca_lev10
81      INTEGER   :: ikr, ikw, ikt, jjk
82      REAL(wp)  :: zfac
83#endif
84      REAL(wp), DIMENSION(jpk) ::   &
85          zsaldta            ! auxiliary array for interpolation
86      CHARACTER(len=100) :: cn_dir          ! Root directory for location of ssr files
87      TYPE(FLD_N)        :: sn_sal
88      LOGICAL , SAVE     :: linit_sal = .FALSE.
89      !!----------------------------------------------------------------------
90      NAMELIST/namdta_sal/cn_dir,sn_sal
91     
92      ! 1. Initialization
93      ! -----------------------
94     
95      IF( kt == nit000 .AND. ( .NOT. linit_sal ) ) THEN
96       
97         !                         ! set file information
98         cn_dir = './'             ! directory in which the model is executed
99         ! ... default values (NB: frequency positive => hours, negative => months)
100         !            !   file    ! frequency !  variable  ! time intep !  clim   ! 'yearly' or ! weights  ! rotation   !
101         !            !   name    !  (hours)  !   name     !   (T/F)    !  (T/F)  !  'monthly'  ! filename ! pairs      !
102         sn_sal = FLD_N( 'salinity',  -1.  ,  'vosaline',  .false.   , .true.  ,  'monthly'  , ''       , ''         )
103
104         REWIND ( numnam )         ! ... read in namlist namdta_sal
105         READ( numnam, namdta_sal ) 
106
107         IF(lwp) THEN              ! control print
108            WRITE(numout,*)
109            WRITE(numout,*) 'dta_sal : Salinity Climatology '
110            WRITE(numout,*) '~~~~~~~ '
111         ENDIF
112         ALLOCATE( sf_sal(1), STAT=ierror )
113         IF( ierror > 0 ) THEN
114             CALL ctl_stop( 'dta_sal: unable to allocate sf_sal structure' )   ;   RETURN
115         ENDIF
116         ALLOCATE( sf_sal(1)%fnow(jpi,jpj,jpk) )
117         ALLOCATE( sf_sal(1)%fdta(jpi,jpj,jpk,2) )
118
119         ! fill sf_sal with sn_sal and control print
120         CALL fld_fill( sf_sal, (/ sn_sal /), cn_dir, 'dta_sal', 'Salinity data', 'namdta_sal' )
121         linit_sal = .TRUE.       
122      ENDIF
123     
124     
125      ! 2. Read monthly file
126      ! -------------------
127     
128      CALL fld_read( kt, 1, sf_sal )
129
130      IF( lwp .AND. kt==nn_it000 ) THEN
131         WRITE(numout,*)
132         WRITE(numout,*) ' read Levitus salinity ok'
133         WRITE(numout,*)
134      ENDIF
135
136#if defined key_tradmp
137      IF( cp_cfg == "orca"  .AND. jp_cfg == 2 ) THEN
138   
139         !                                        ! =======================
140         !                                        !  ORCA_R2 configuration
141         !                                        ! =======================
142         ij0 = 101   ;   ij1 = 109
143         ii0 = 141   ;   ii1 = 155   
144         DO jj = mj0(ij0), mj1(ij1)                  ! Reduced salinity in the Alboran Sea
145            DO ji = mi0(ii0), mi1(ii1)
146               sf_sal(1)%fnow(ji,jj,13:13) = sf_sal(1)%fnow(ji,jj,13:13) - 0.15
147               sf_sal(1)%fnow(ji,jj,14:15) = sf_sal(1)%fnow(ji,jj,14:15) - 0.25
148               sf_sal(1)%fnow(ji,jj,16:17) = sf_sal(1)%fnow(ji,jj,16:17) - 0.30
149               sf_sal(1)%fnow(ji,jj,18:25) = sf_sal(1)%fnow(ji,jj,18:25) - 0.35
150            END DO
151         END DO
152
153         IF( n_cla == 1 ) THEN 
154            !                                         ! New salinity profile at Gibraltar
155            il0 = 138   ;   il1 = 138   
156            ij0 = 101   ;   ij1 = 102
157            ii0 = 139   ;   ii1 = 139   
158            DO jl = mi0(il0), mi1(il1)
159               DO jj = mj0(ij0), mj1(ij1)
160                  DO ji = mi0(ii0), mi1(ii1)
161                        sf_sal(1)%fnow(ji,jj,:) = sf_sal(1)%fnow(jl,jj,:)
162                  END DO
163               END DO
164            END DO
165            !                                         ! New salinity profile at Bab el Mandeb
166            il0 = 164   ;   il1 = 164   
167            ij0 =  87   ;   ij1 =  88
168            ii0 = 161   ;   ii1 = 163   
169            DO jl = mi0(il0), mi1(il1)
170               DO jj = mj0(ij0), mj1(ij1)
171                  DO ji = mi0(ii0), mi1(ii1)
172                     sf_sal(1)%fnow(ji,jj,:) = sf_sal(1)%fnow(jl,jj,:)
173                  END DO
174               END DO
175            END DO
176            !
177         ENDIF
178            !
179      ENDIF
180#endif   
181       
182#if defined key_orca_lev10
183      DO jjk = 1, 5
184         s_dta(:,:,jjk) = sf_sal(1)%fnow(:,:,1)
185      ENDDO
186      DO jk = 1, jpk-20,10
187         ikr =  INT(jk/10) + 1
188         ikw =  (ikr-1) *10 + 1
189         ikt =  ikw + 5
190         DO jjk=ikt,ikt+9
191            zfac = ( gdept_0(jjk   ) - gdepw_0(ikt) ) / ( gdepw_0(ikt+10) - gdepw_0(ikt) )
192            s_dta(:,:,jjk) = sf_sal(1)%fnow(:,:,ikr) + ( sf_sal(1)%fnow(:,:,ikr+1) - sf_sal(1)%fnow(:,:,ikr) ) * zfac
193         END DO
194      END DO
195      DO jjk = jpk-5, jpk
196         s_dta(:,:,jjk) = sf_sal(1)%fnow(:,:,jpkdta-1)
197      END DO
198      ! fill the overlap areas
199      CALL lbc_lnk (s_dta(:,:,:),'Z',-999.,'no0')       
200#else
201      s_dta(:,:,:)=sf_sal(1)%fnow(:,:,:)
202#endif
203       
204      IF( ln_sco ) THEN
205         DO jj = 1, jpj                  ! interpolation of salinites
206            DO ji = 1, jpi
207               DO jk = 1, jpk
208                  zl=fsdept_0(ji,jj,jk)
209                  IF(zl < gdept_0(1)  ) zsaldta(jk) =  s_dta(ji,jj,1    ) 
210                  IF(zl > gdept_0(jpk)) zsaldta(jk) =  s_dta(ji,jj,jpkm1) 
211                  DO jkk = 1, jpkm1
212                     IF((zl-gdept_0(jkk))*(zl-gdept_0(jkk+1)).le.0.0) THEN
213                          zsaldta(jk) = s_dta(ji,jj,jkk)                                 &
214                                     &           + (zl-gdept_0(jkk))/(gdept_0(jkk+1)-gdept_0(jkk))      &
215                                     &                              *(s_dta(ji,jj,jkk+1) - s_dta(ji,jj,jkk))
216                     ENDIF
217                  END DO
218               END DO
219               DO jk = 1, jpkm1
220                  s_dta(ji,jj,jk) = zsaldta(jk) 
221               END DO
222               s_dta(ji,jj,jpk) = 0.0 
223            END DO
224         END DO
225           
226         IF( lwp .AND. kt==nn_it000 ) THEN
227            WRITE(numout,*)
228            WRITE(numout,*) ' Levitus salinity data interpolated to s-coordinate'
229            WRITE(numout,*)
230         ENDIF
231
232      ELSE
233         !                                  ! Mask
234         s_dta(:,:,:) = s_dta(:,:,:) * tmask(:,:,:)
235         s_dta(:,:,jpk) = 0. 
236         IF( ln_zps ) THEN               ! z-coord. partial steps
237            DO jj = 1, jpj               ! interpolation of salinity at the last ocean level (i.e. the partial step)
238               DO ji = 1, jpi
239                  ik = mbathy(ji,jj) - 1
240                  IF( ik > 2 ) THEN
241                     zl = ( gdept_0(ik) - fsdept_0(ji,jj,ik) ) / ( gdept_0(ik) - gdept_0(ik-1) )
242                     s_dta(ji,jj,ik) = (1.-zl) * s_dta(ji,jj,ik) + zl * s_dta(ji,jj,ik-1)
243                  ENDIF
244               END DO
245            END DO
246         ENDIF
247      ENDIF
248       
249      IF( lwp .AND. kt==nn_it000 ) THEN
250         WRITE(numout,*)' salinity Levitus '
251         WRITE(numout,*)
252         WRITE(numout,*)'  level = 1'
253         CALL prihre(s_dta(:,:,1),    jpi,jpj,1,jpi,20,1,jpj,20,1.,numout)
254         WRITE(numout,*)'  level = ',jpk/2
255         CALL prihre(s_dta(:,:,jpk/2),jpi,jpj,1,jpi,20,1,jpj,20,1.,numout)           
256         WRITE(numout,*) '  level = ',jpkm1
257         CALL prihre(s_dta(:,:,jpkm1),jpi,jpj,1,jpi,20,1,jpj,20,1.,numout)
258      ENDIF
259
260   END SUBROUTINE dta_sal
261
262#else
263   !!----------------------------------------------------------------------
264   !!   Default option:                                    NO salinity data
265   !!----------------------------------------------------------------------
266   LOGICAL , PUBLIC, PARAMETER ::   lk_dtasal = .FALSE.   !: salinity data flag
267CONTAINS
268   SUBROUTINE dta_sal( kt )        ! Empty routine
269      WRITE(*,*) 'dta_sal: You should not have seen this print! error?', kt
270   END SUBROUTINE dta_sal
271#endif
272   !!======================================================================
273END MODULE dtasal
Note: See TracBrowser for help on using the repository browser.