| 1 | MODULE sbcice_lim_2 |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcice_lim_2 *** |
|---|
| 4 | !! Surface module : update surface ocean boundary condition over ice |
|---|
| 5 | !! covered area using LIM sea-ice model |
|---|
| 6 | !! Sea-Ice model : LIM 2.0 Sea ice model time-stepping |
|---|
| 7 | !!====================================================================== |
|---|
| 8 | !! History : 1.0 ! 06-2006 (G. Madec) from icestp_2.F90 |
|---|
| 9 | !! 3.0 ! 08-2008 (S. Masson, E. .... ) coupled interface |
|---|
| 10 | !! 3.3 ! 05-2009 (G.Garric) addition of the lim2_evp case |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | #if defined key_lim2 |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! 'key_lim2' : LIM 2.0 sea-ice model |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! sbc_ice_lim_2 : sea-ice model time-stepping and |
|---|
| 17 | !! update ocean sbc over ice-covered area |
|---|
| 18 | !!---------------------------------------------------------------------- |
|---|
| 19 | USE oce ! ocean dynamics and tracers |
|---|
| 20 | USE c1d ! 1d configuration |
|---|
| 21 | USE dom_oce ! ocean space and time domain |
|---|
| 22 | USE lib_mpp |
|---|
| 23 | USE ice_2 |
|---|
| 24 | USE par_ice_2 |
|---|
| 25 | USE iceini_2 |
|---|
| 26 | USE dom_ice_2 |
|---|
| 27 | |
|---|
| 28 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 29 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 30 | USE sbcblk_core ! Surface boundary condition: CORE bulk |
|---|
| 31 | USE sbcblk_clio ! Surface boundary condition: CLIO bulk |
|---|
| 32 | USE sbccpl ! Surface boundary condition: coupled interface |
|---|
| 33 | USE albedo |
|---|
| 34 | |
|---|
| 35 | USE phycst ! Define parameters for the routines |
|---|
| 36 | USE eosbn2 ! equation of state |
|---|
| 37 | USE limdyn_2 |
|---|
| 38 | USE limtrp_2 |
|---|
| 39 | USE limdmp_2 |
|---|
| 40 | USE limthd_2 |
|---|
| 41 | USE limsbc_2 ! sea surface boundary condition |
|---|
| 42 | USE limdia_2 |
|---|
| 43 | USE limwri_2 |
|---|
| 44 | USE limrst_2 |
|---|
| 45 | |
|---|
| 46 | USE lbclnk |
|---|
| 47 | USE iom ! I/O manager library |
|---|
| 48 | USE in_out_manager ! I/O manager |
|---|
| 49 | USE prtctl ! Print control |
|---|
| 50 | |
|---|
| 51 | IMPLICIT NONE |
|---|
| 52 | PRIVATE |
|---|
| 53 | |
|---|
| 54 | PUBLIC sbc_ice_lim_2 ! routine called by sbcmod.F90 |
|---|
| 55 | |
|---|
| 56 | !! * Substitutions |
|---|
| 57 | # include "domzgr_substitute.h90" |
|---|
| 58 | # include "vectopt_loop_substitute.h90" |
|---|
| 59 | !!---------------------------------------------------------------------- |
|---|
| 60 | !! NEMO/SBC 3.0 , LOCEAN-IPSL (2008) |
|---|
| 61 | !! $Id$ |
|---|
| 62 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | |
|---|
| 65 | CONTAINS |
|---|
| 66 | |
|---|
| 67 | SUBROUTINE sbc_ice_lim_2( kt, ksbc ) |
|---|
| 68 | !!--------------------------------------------------------------------- |
|---|
| 69 | !! *** ROUTINE sbc_ice_lim_2 *** |
|---|
| 70 | !! |
|---|
| 71 | !! ** Purpose : update the ocean surface boundary condition via the |
|---|
| 72 | !! Louvain la Neuve Sea Ice Model time stepping |
|---|
| 73 | !! |
|---|
| 74 | !! ** Method : ice model time stepping |
|---|
| 75 | !! - call the ice dynamics routine |
|---|
| 76 | !! - call the ice advection/diffusion routine |
|---|
| 77 | !! - call the ice thermodynamics routine |
|---|
| 78 | !! - call the routine that computes mass and |
|---|
| 79 | !! heat fluxes at the ice/ocean interface |
|---|
| 80 | !! - save the outputs |
|---|
| 81 | !! - save the outputs for restart when necessary |
|---|
| 82 | !! |
|---|
| 83 | !! ** Action : - time evolution of the LIM sea-ice model |
|---|
| 84 | !! - update all sbc variables below sea-ice: |
|---|
| 85 | !! utau, vtau, taum, wndm, qns , qsr, emp , emps |
|---|
| 86 | !!--------------------------------------------------------------------- |
|---|
| 87 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 88 | INTEGER, INTENT(in) :: ksbc ! type of sbc ( =3 CLIO bulk ; =4 CORE bulk ; =5 coupled ) |
|---|
| 89 | !! |
|---|
| 90 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 91 | REAL(wp), DIMENSION(jpi,jpj,1) :: zalb_ice_os ! albedo of the ice under overcast sky |
|---|
| 92 | REAL(wp), DIMENSION(jpi,jpj,1) :: zalb_ice_cs ! albedo of ice under clear sky |
|---|
| 93 | REAL(wp), DIMENSION(jpi,jpj,1) :: zsist ! surface ice temperature (K) |
|---|
| 94 | !!---------------------------------------------------------------------- |
|---|
| 95 | |
|---|
| 96 | IF( kt == nit000 ) THEN |
|---|
| 97 | IF(lwp) WRITE(numout,*) |
|---|
| 98 | IF(lwp) WRITE(numout,*) 'sbc_ice_lim_2 : update ocean surface boudary condition' |
|---|
| 99 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~ via Louvain la Neuve Ice Model (LIM) time stepping' |
|---|
| 100 | |
|---|
| 101 | CALL ice_init_2 |
|---|
| 102 | |
|---|
| 103 | ENDIF |
|---|
| 104 | |
|---|
| 105 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 106 | ! |
|---|
| 107 | ! ... mean surface ocean current at ice dynamics point |
|---|
| 108 | ! B-grid dynamics : I-point |
|---|
| 109 | DO jj = 2, jpj |
|---|
| 110 | DO ji = 2, jpi ! B grid : no vector opt. |
|---|
| 111 | u_oce(ji,jj) = 0.5 * ( ssu_m(ji-1,jj ) + ssu_m(ji-1,jj-1) ) * tmu(ji,jj) |
|---|
| 112 | v_oce(ji,jj) = 0.5 * ( ssv_m(ji ,jj-1) + ssv_m(ji-1,jj-1) ) * tmu(ji,jj) |
|---|
| 113 | END DO |
|---|
| 114 | END DO |
|---|
| 115 | CALL lbc_lnk( u_oce, 'I', -1. ) ! I-point (i.e. F-point with ice indices) |
|---|
| 116 | CALL lbc_lnk( v_oce, 'I', -1. ) ! I-point (i.e. F-point with ice indices) |
|---|
| 117 | |
|---|
| 118 | ! ... masked sea surface freezing temperature [Kelvin] (set to rt0 over land) |
|---|
| 119 | tfu(:,:) = tfreez( sss_m ) + rt0 |
|---|
| 120 | |
|---|
| 121 | zsist (:,:,1) = sist (:,:) + rt0 * ( 1. - tmask(:,:,1) ) |
|---|
| 122 | |
|---|
| 123 | ! ... ice albedo (clear sky and overcast sky) |
|---|
| 124 | CALL albedo_ice( zsist, reshape( hicif, (/jpi,jpj,1/) ), reshape( hsnif, (/jpi,jpj,1/) ), zalb_ice_cs, zalb_ice_os ) |
|---|
| 125 | |
|---|
| 126 | ! ... Sea-ice surface boundary conditions output from bulk formulae : |
|---|
| 127 | ! - utau_ice ! surface ice stress i-component (I-point) [N/m2] |
|---|
| 128 | ! - vtau_ice ! surface ice stress j-component (I-point) [N/m2] |
|---|
| 129 | ! - qns_ice ! non solar heat flux over ice (T-point) [W/m2] |
|---|
| 130 | ! - qsr_ice ! solar heat flux over ice (T-point) [W/m2] |
|---|
| 131 | ! - qla_ice ! latent heat flux over ice (T-point) [W/m2] |
|---|
| 132 | ! - dqns_ice ! non solar heat sensistivity (T-point) [W/m2] |
|---|
| 133 | ! - dqla_ice ! latent heat sensistivity (T-point) [W/m2] |
|---|
| 134 | ! - tprecip ! total precipitation (T-point) [Kg/m2/s] |
|---|
| 135 | ! - sprecip ! solid precipitation (T-point) [Kg/m2/s] |
|---|
| 136 | ! - fr1_i0 ! 1sr fraction of qsr penetration in ice [%] |
|---|
| 137 | ! - fr2_i0 ! 2nd fraction of qsr penetration in ice [%] |
|---|
| 138 | ! |
|---|
| 139 | SELECT CASE( ksbc ) |
|---|
| 140 | CASE( 3 ) ! CLIO bulk formulation |
|---|
| 141 | CALL blk_ice_clio( zsist, zalb_ice_cs, zalb_ice_os, & |
|---|
| 142 | & utau_ice , vtau_ice , qns_ice , qsr_ice, & |
|---|
| 143 | & qla_ice , dqns_ice , dqla_ice , & |
|---|
| 144 | & tprecip , sprecip , & |
|---|
| 145 | & fr1_i0 , fr2_i0 , cl_grid , jpl ) |
|---|
| 146 | |
|---|
| 147 | CASE( 4 ) ! CORE bulk formulation |
|---|
| 148 | CALL blk_ice_core( zsist, u_ice , v_ice , zalb_ice_cs, & |
|---|
| 149 | & utau_ice , vtau_ice , qns_ice , qsr_ice, & |
|---|
| 150 | & qla_ice , dqns_ice , dqla_ice , & |
|---|
| 151 | & tprecip , sprecip , & |
|---|
| 152 | & fr1_i0 , fr2_i0 , cl_grid , jpl ) |
|---|
| 153 | CASE( 5 ) ! Coupled formulation : atmosphere-ice stress only (fluxes provided after ice dynamics) |
|---|
| 154 | CALL sbc_cpl_ice_tau( utau_ice , vtau_ice ) |
|---|
| 155 | END SELECT |
|---|
| 156 | |
|---|
| 157 | CALL iom_put( 'utau_ice', utau_ice ) ! Wind stress over ice along i-axis at I-point |
|---|
| 158 | CALL iom_put( 'vtau_ice', vtau_ice ) ! Wind stress over ice along j-axis at I-point |
|---|
| 159 | |
|---|
| 160 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 161 | CALL prt_ctl_info( 'Ice Forcings ' ) |
|---|
| 162 | CALL prt_ctl( tab2d_1=tprecip ,clinfo1=' sbc_ice_lim: precip : ', tab2d_2=sprecip , clinfo2=' Snow : ' ) |
|---|
| 163 | CALL prt_ctl( tab2d_1=utau_ice,clinfo1=' sbc_ice_lim: utau_ice: ', tab2d_2=vtau_ice, clinfo2=' vtau_ice: ' ) |
|---|
| 164 | CALL prt_ctl( tab2d_1=sst_m ,clinfo1=' sbc_ice_lim: sst : ', tab2d_2=sss_m , clinfo2=' sss : ' ) |
|---|
| 165 | CALL prt_ctl( tab2d_1=u_oce ,clinfo1=' sbc_ice_lim: u_io : ', tab2d_2=v_oce , clinfo2=' v_io : ' ) |
|---|
| 166 | CALL prt_ctl( tab2d_1=hsnif ,clinfo1=' sbc_ice_lim: hsnif 1: ', tab2d_2=hicif , clinfo2=' hicif : ' ) |
|---|
| 167 | CALL prt_ctl( tab2d_1=frld ,clinfo1=' sbc_ice_lim: frld 1: ', tab2d_2=sist , clinfo2=' sist : ' ) |
|---|
| 168 | ENDIF |
|---|
| 169 | |
|---|
| 170 | ! ---------------- ! |
|---|
| 171 | ! Ice model step ! |
|---|
| 172 | ! ---------------- ! |
|---|
| 173 | numit = numit + nn_fsbc ! Ice model time step |
|---|
| 174 | |
|---|
| 175 | CALL lim_rst_opn_2 ( kt ) ! Open Ice restart file |
|---|
| 176 | IF( .NOT. lk_c1d ) THEN ! Ice dynamics & transport (not in 1D case) |
|---|
| 177 | CALL lim_dyn_2 ( kt ) ! Ice dynamics ( rheology/dynamics ) |
|---|
| 178 | CALL lim_trp_2 ( kt ) ! Ice transport ( Advection/diffusion ) |
|---|
| 179 | IF( ln_limdmp ) CALL lim_dmp_2 ( kt ) ! Ice damping |
|---|
| 180 | ENDIF |
|---|
| 181 | #if defined key_coupled |
|---|
| 182 | IF( ksbc == 5 ) CALL sbc_cpl_ice_flx( frld , & |
|---|
| 183 | & qns_tot, qns_ice, qsr_tot , qsr_ice, & |
|---|
| 184 | & emp_tot, emp_ice, dqns_ice, sprecip, & |
|---|
| 185 | ! optional arguments, used only in 'mixed oce-ice' case |
|---|
| 186 | & palbi = zalb_ice_cs, psst = sst_m, pist = sist ) |
|---|
| 187 | #endif |
|---|
| 188 | CALL lim_thd_2 ( kt ) ! Ice thermodynamics |
|---|
| 189 | CALL lim_sbc_2 ( kt ) ! Ice/Ocean Mass & Heat fluxes |
|---|
| 190 | |
|---|
| 191 | IF( ( MOD( kt+nn_fsbc-1, ninfo ) == 0 .OR. ntmoy == 1 ) .AND. .NOT. lk_mpp ) & |
|---|
| 192 | & CALL lim_dia_2 ( kt ) ! Ice Diagnostics |
|---|
| 193 | # if ! defined key_iomput |
|---|
| 194 | CALL lim_wri_2 ( kt ) ! Ice outputs |
|---|
| 195 | # endif |
|---|
| 196 | IF( lrst_ice ) CALL lim_rst_write_2( kt ) ! Ice restart file |
|---|
| 197 | ! |
|---|
| 198 | ENDIF |
|---|
| 199 | ! |
|---|
| 200 | END SUBROUTINE sbc_ice_lim_2 |
|---|
| 201 | |
|---|
| 202 | #else |
|---|
| 203 | !!---------------------------------------------------------------------- |
|---|
| 204 | !! Default option Dummy module NO LIM 2.0 sea-ice model |
|---|
| 205 | !!---------------------------------------------------------------------- |
|---|
| 206 | CONTAINS |
|---|
| 207 | SUBROUTINE sbc_ice_lim_2 ( kt, ksbc ) ! Dummy routine |
|---|
| 208 | WRITE(*,*) 'sbc_ice_lim_2: You should not have seen this print! error?', kt, ksbc |
|---|
| 209 | END SUBROUTINE sbc_ice_lim_2 |
|---|
| 210 | #endif |
|---|
| 211 | |
|---|
| 212 | !!====================================================================== |
|---|
| 213 | END MODULE sbcice_lim_2 |
|---|
