New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcmod.F90 in branches/devukmo2010/NEMO/OPA_SRC/SBC – NEMO

source: branches/devukmo2010/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 2128

Last change on this file since 2128 was 2128, checked in by rfurner, 14 years ago

merged branches OBS, ASM, Rivers, BDY & mixed_dynldf ready for vn3.3 merge
  • Property svn:keywords set to Id
File size: 15.3 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0   !  07-2006  (G. Madec)  Original code
7   !!             -    !  08-2008  (S. Masson, E. .... ) coupled interface
8   !!            3.3   !  09-2010  (D. Storkey) add ice boundary conditions (BDY)
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_init       : read namsbc namelist
13   !!   sbc            : surface ocean momentum, heat and freshwater boundary conditions
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and tracers
16   USE dom_oce         ! ocean space and time domain
17   USE phycst          ! physical constants
18
19   USE sbc_oce         ! Surface boundary condition: ocean fields
20   USE sbc_ice         ! Surface boundary condition: ice fields
21   USE sbcssm          ! surface boundary condition: sea-surface mean variables
22   USE sbcana          ! surface boundary condition: analytical formulation
23   USE sbcflx          ! surface boundary condition: flux formulation
24   USE sbcblk_clio     ! surface boundary condition: bulk formulation : CLIO
25   USE sbcblk_core     ! surface boundary condition: bulk formulation : CORE
26   USE sbcice_if       ! surface boundary condition: ice-if sea-ice model
27   USE sbcice_lim      ! surface boundary condition: LIM 3.0 sea-ice model
28   USE sbcice_lim_2    ! surface boundary condition: LIM 2.0 sea-ice model
29   USE sbccpl          ! surface boundary condition: coupled florulation
30   USE cpl_oasis3, ONLY:lk_cpl      ! are we in coupled mode?
31   USE sbcssr          ! surface boundary condition: sea surface restoring
32   USE sbcrnf          ! surface boundary condition: runoffs
33   USE sbcfwb          ! surface boundary condition: freshwater budget
34   USE closea          ! closed sea
35   USE bdy_par         ! unstructured open boundary data variables
36   USE bdyice          ! unstructured open boundary data  (bdy_ice routine)
37
38   USE prtctl          ! Print control                    (prt_ctl routine)
39   USE restart         ! ocean restart
40   USE iom
41   USE in_out_manager  ! I/O manager
42
43   IMPLICIT NONE
44   PRIVATE
45
46   PUBLIC   sbc        ! routine called by step.F90
47   PUBLIC   sbc_init   ! routine called by opa.F90
48   
49   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
50     
51   !! * Substitutions
52#  include "domzgr_substitute.h90"
53   !!----------------------------------------------------------------------
54   !! NEMO/OPA 3.0 , LOCEAN-IPSL (2008)
55   !! $Id$
56   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
57   !!----------------------------------------------------------------------
58
59CONTAINS
60
61   SUBROUTINE sbc_init
62      !!---------------------------------------------------------------------
63      !!                    ***  ROUTINE sbc_init ***
64      !!
65      !! ** Purpose :   Initialisation of the ocean surface boundary computation
66      !!
67      !! ** Method  :   Read the namsbc namelist and set derived parameters
68      !!
69      !! ** Action  : - read namsbc parameters
70      !!              - nsbc: type of sbc
71      !!----------------------------------------------------------------------
72      INTEGER ::   icpt      ! temporary integer
73      !!
74      NAMELIST/namsbc/ nn_fsbc, ln_ana, ln_flx, ln_blk_clio, ln_blk_core, ln_cpl,   &
75         &             nn_ice , ln_dm2dc, ln_rnf, ln_ssr, nn_fwb, nn_ico_cpl
76      !!----------------------------------------------------------------------
77
78      IF(lwp) THEN
79         WRITE(numout,*)
80         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
81         WRITE(numout,*) '~~~~~~~~ '
82      ENDIF
83
84      REWIND( numnam )                   ! Read Namelist namsbc
85      READ  ( numnam, namsbc )
86
87      ! overwrite namelist parameter using CPP key information
88!!gm here no overwrite, test all option via namelist change: require more incore memory
89!!gm  IF( lk_sbc_cpl       ) THEN   ;   ln_cpl      = .TRUE.   ;   ELSE   ;   ln_cpl      = .FALSE.   ;   ENDIF
90
91      IF ( Agrif_Root() ) THEN
92        IF( lk_lim2 )            nn_ice      = 2
93        IF( lk_lim3 )            nn_ice      = 3
94      ENDIF
95      !
96      IF( cp_cfg == 'gyre' ) THEN
97          ln_ana      = .TRUE.   
98          nn_ice      =   0
99      ENDIF
100     
101      ! Control print
102      IF(lwp) THEN
103         WRITE(numout,*) '        Namelist namsbc (partly overwritten with CPP key setting)'
104         WRITE(numout,*) '           frequency update of sbc (and ice)             nn_fsbc     = ', nn_fsbc
105         WRITE(numout,*) '           Type of sbc : '
106         WRITE(numout,*) '              analytical formulation                     ln_ana      = ', ln_ana
107         WRITE(numout,*) '              flux       formulation                     ln_flx      = ', ln_flx
108         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_clio = ', ln_blk_clio
109         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_core = ', ln_blk_core
110         WRITE(numout,*) '              coupled    formulation (T if key_sbc_cpl)  ln_cpl      = ', ln_cpl
111         WRITE(numout,*) '           Misc. options of sbc : '
112         WRITE(numout,*) '              ice management in the sbc (=0/1/2/3)       nn_ice      = ', nn_ice 
113         WRITE(numout,*) '              ice-ocean stress computation (=0/1/2)      nn_ico_cpl  = ', nn_ico_cpl
114         WRITE(numout,*) '              daily mean to diurnal cycle qsr            ln_dm2dc    = ', ln_dm2dc 
115         WRITE(numout,*) '              runoff / runoff mouths                     ln_rnf      = ', ln_rnf
116         WRITE(numout,*) '              Sea Surface Restoring on SST and/or SSS    ln_ssr      = ', ln_ssr
117         WRITE(numout,*) '              FreshWater Budget control  (=0/1/2)        nn_fwb      = ', nn_fwb
118         WRITE(numout,*) '              closed sea (=0/1) (set in namdom)          nn_closea   = ', nn_closea
119      ENDIF
120
121      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
122         ln_rnf_mouth  = .false.                     
123         nkrnf         = 0
124         rnfmsk  (:,:) = 0.e0
125         rnfmsk_z(:)   = 0.e0
126      ENDIF
127      IF( nn_ice == 0  )   fr_i(:,:) = 0.e0        ! no ice in the domain, ice fraction is always zero
128
129      !                                            ! restartability   
130      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
131          MOD( nstock             , nn_fsbc) /= 0 ) THEN
132         WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
133            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
134         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
135      ENDIF
136      !
137      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
138         &  CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
139      !
140      IF( nn_ice == 2 .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) )   &
141         &   CALL ctl_stop( 'sea-ice model requires a bulk formulation or coupled configuration' )
142     
143      ! Choice of the Surface Boudary Condition (set nsbc)
144      icpt = 0
145      IF( ln_ana          ) THEN   ;   nsbc =  1   ; icpt = icpt + 1   ;   ENDIF       ! analytical      formulation
146      IF( ln_flx          ) THEN   ;   nsbc =  2   ; icpt = icpt + 1   ;   ENDIF       ! flux            formulation
147      IF( ln_blk_clio     ) THEN   ;   nsbc =  3   ; icpt = icpt + 1   ;   ENDIF       ! CLIO bulk       formulation
148      IF( ln_blk_core     ) THEN   ;   nsbc =  4   ; icpt = icpt + 1   ;   ENDIF       ! CORE bulk       formulation
149      IF( ln_cpl          ) THEN   ;   nsbc =  5   ; icpt = icpt + 1   ;   ENDIF       ! Coupled         formulation
150      IF( cp_cfg == 'gyre') THEN   ;   nsbc =  0                       ;   ENDIF       ! GYRE analytical formulation
151      IF( lk_esopa        )            nsbc = -1                                       ! esopa test, ALL formulations
152
153      IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
154         WRITE(numout,*)
155         WRITE(numout,*) '           E R R O R in setting the sbc, one and only one namelist/CPP key option '
156         WRITE(numout,*) '                     must be choosen. You choose ', icpt, ' option(s)'
157         WRITE(numout,*) '                     We stop'
158         nstop = nstop + 1
159      ENDIF
160      IF(lwp) THEN
161         WRITE(numout,*)
162         IF( nsbc == -1 )   WRITE(numout,*) '              ESOPA test All surface boundary conditions'
163         IF( nsbc ==  0 )   WRITE(numout,*) '              GYRE analytical formulation'
164         IF( nsbc ==  1 )   WRITE(numout,*) '              analytical formulation'
165         IF( nsbc ==  2 )   WRITE(numout,*) '              flux formulation'
166         IF( nsbc ==  3 )   WRITE(numout,*) '              CLIO bulk formulation'
167         IF( nsbc ==  4 )   WRITE(numout,*) '              CORE bulk formulation'
168         IF( nsbc ==  5 )   WRITE(numout,*) '              coupled formulation'
169      ENDIF
170      !
171   END SUBROUTINE sbc_init
172
173
174   SUBROUTINE sbc( kt )
175      !!---------------------------------------------------------------------
176      !!                    ***  ROUTINE sbc  ***
177      !!             
178      !! ** Purpose :   provide at each time-step the ocean surface boundary
179      !!                condition (momentum, heat and freshwater fluxes)
180      !!
181      !! ** Method  :   blah blah  to be written ?????????
182      !!                CAUTION : never mask the surface stress field (tke sbc)
183      !!
184      !! ** Action  : - set the ocean surface boundary condition, i.e. 
185      !!                utau, vtau, qns, qsr, emp, emps, qrp, erp
186      !!              - updte the ice fraction : fr_i
187      !!----------------------------------------------------------------------
188      INTEGER, INTENT(in) ::   kt       ! ocean time step
189      !!---------------------------------------------------------------------
190
191      CALL iom_setkt( kt + nn_fsbc - 1 )         !  in sbc, iom_put is called every nn_fsbc time step
192      !
193      ! ocean to sbc mean sea surface variables (ss._m)
194      ! ---------------------------------------
195      CALL sbc_ssm( kt )                         ! sea surface mean currents (at U- and V-points),
196      !                                          ! temperature and salinity (at T-point) over nf_sbc time-step
197      !                                          ! (i.e. sst_m, sss_m, ssu_m, ssv_m)
198
199      ! sbc formulation
200      ! ---------------
201         
202      SELECT CASE( nsbc )                        ! Compute ocean surface boundary condition
203      !                                          ! (i.e. utau,vtau, qns, qsr, emp, emps)
204      CASE(  0 )   ;   CALL sbc_gyre    ( kt )                    ! analytical formulation : GYRE configuration
205      CASE(  1 )   ;   CALL sbc_ana     ( kt )                    ! analytical formulation : uniform sbc
206      CASE(  2 )   ;   CALL sbc_flx     ( kt )                    ! flux formulation
207      CASE(  3 )   ;   CALL sbc_blk_clio( kt )                    ! bulk formulation : CLIO for the ocean
208      CASE(  4 )   ;   CALL sbc_blk_core( kt )                    ! bulk formulation : CORE for the ocean
209      CASE(  5 )   ;   CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! coupled formulation
210      CASE( -1 )                               
211                       CALL sbc_ana     ( kt )                    ! ESOPA, test ALL the formulations
212                       CALL sbc_gyre    ( kt )                    !
213                       CALL sbc_flx     ( kt )                    !
214                       CALL sbc_blk_clio( kt )                    !
215                       CALL sbc_blk_core( kt )                    !
216                       CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   !
217      END SELECT
218
219      ! Misc. Options
220      ! -------------
221
222!!gm  IF( ln_dm2dc       )   CALL sbc_dcy( kt )                 ! Daily mean qsr distributed over the Diurnal Cycle
223     
224      SELECT CASE( nn_ice )                                     ! Update heat and freshwater fluxes over sea-ice areas
225      CASE(  1 )   ;       CALL sbc_ice_if   ( kt )                   ! Ice-cover climatology ("Ice-if" model)
226         !                                                     
227      CASE(  2 )   ;       CALL sbc_ice_lim_2( kt, nsbc )             ! LIM 2.0 ice model
228                           IF( lk_bdy ) CALL bdy_ice( kt )
229         !                                                     
230      CASE(  3 )   ;       CALL sbc_ice_lim  ( kt, nsbc, nn_ico_cpl)  ! LIM 3.0 ice model
231      END SELECT                                             
232
233      IF( ln_rnf       )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
234 
235      IF( ln_ssr       )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
236
237      IF( nn_fwb  /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
238
239      IF( nclosea == 1 )   CALL sbc_clo( kt )                   ! treatment of closed sea in the model domain
240      !                                                         ! (update freshwater fluxes)
241      !
242      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
243         CALL iom_put( "emp-rnf"  , (emp-rnf)  )                ! upward water flux
244         CALL iom_put( "emps-rnf" , (emps-rnf) )                ! c/d water flux
245         CALL iom_put( "qns+qsr"  , qns + qsr  )                ! total heat flux   (caution if ln_dm2dc=true, to be
246         CALL iom_put( "qns"      , qns        )                ! solar heat flux    moved after the call to iom_setkt)
247         CALL iom_put( "qsr"      ,       qsr  )                ! solar heat flux    moved after the call to iom_setkt)
248         IF(  nn_ice > 0 )   CALL iom_put( "ice_cover", fr_i )  ! ice fraction
249      ENDIF
250      !
251      CALL iom_setkt( kt )           ! iom_put outside of sbc is called at every time step
252      !
253      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at
254      CALL iom_put( "vtau", vtau )   ! j-wind stress    each time step in sea-ice)
255      CALL iom_put( "taum", taum )   ! wind stress module
256      CALL iom_put( "wspd", wndm )   ! wind speed  module
257      !
258      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
259         CALL prt_ctl(tab2d_1=fr_i   , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 )
260         CALL prt_ctl(tab2d_1=(emp-rnf) , clinfo1=' emp-rnf  - : ', mask1=tmask, ovlap=1 ) 
261         CALL prt_ctl(tab2d_1=(emps-rnf), clinfo1=' emps-rnf - : ', mask1=tmask, ovlap=1 ) 
262         CALL prt_ctl(tab2d_1=qns    , clinfo1=' qns  - : ', mask1=tmask, ovlap=1 )
263         CALL prt_ctl(tab2d_1=qsr    , clinfo1=' qsr  - : ', mask1=tmask, ovlap=1 )
264         CALL prt_ctl(tab3d_1=tmask  , clinfo1=' tmask  : ', mask1=tmask, ovlap=1, kdim=jpk )
265         CALL prt_ctl(tab3d_1=tn     , clinfo1=' sst  - : ', mask1=tmask, ovlap=1, kdim=1   )
266         CALL prt_ctl(tab3d_1=sn     , clinfo1=' sss  - : ', mask1=tmask, ovlap=1, kdim=1   )
267         CALL prt_ctl(tab2d_1=utau   , clinfo1=' utau - : ', mask1=umask,                      &
268            &         tab2d_2=vtau   , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 )
269      ENDIF
270      !
271   END SUBROUTINE sbc
272
273   !!======================================================================
274END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.