| 1 | MODULE step |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE step *** |
|---|
| 4 | !! Time-stepping : manager of the ocean, tracer and ice time stepping |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1991-03 (G. Madec) Original code |
|---|
| 7 | !! - ! 1991-11 (G. Madec) |
|---|
| 8 | !! - ! 1992-06 (M. Imbard) add a first output record |
|---|
| 9 | !! - ! 1996-04 (G. Madec) introduction of dynspg |
|---|
| 10 | !! - ! 1996-04 (M.A. Foujols) introduction of passive tracer |
|---|
| 11 | !! 8.0 ! 1997-06 (G. Madec) new architecture of call |
|---|
| 12 | !! 8.2 ! 1997-06 (G. Madec, M. Imbard, G. Roullet) free surface |
|---|
| 13 | !! - ! 1999-02 (G. Madec, N. Grima) hpg implicit |
|---|
| 14 | !! - ! 2000-07 (J-M Molines, M. Imbard) Open Bondary Conditions |
|---|
| 15 | !! NEMO 1.0 ! 2002-06 (G. Madec) free form, suppress macro-tasking |
|---|
| 16 | !! - ! 2004-08 (C. Talandier) New trends organization |
|---|
| 17 | !! - ! 2005-01 (C. Ethe) Add the KPP closure scheme |
|---|
| 18 | !! - ! 2005-11 (G. Madec) Reorganisation of tra and dyn calls |
|---|
| 19 | !! - ! 2006-01 (L. Debreu, C. Mazauric) Agrif implementation |
|---|
| 20 | !! - ! 2006-07 (S. Masson) restart using iom |
|---|
| 21 | !! 3.2 ! 2009-02 (G. Madec, R. Benshila) reintroduicing z*-coordinate |
|---|
| 22 | !! - ! 2009-06 (S. Masson, G. Madec) TKE restart compatible with key_cpl |
|---|
| 23 | !! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
|---|
| 24 | !!---------------------------------------------------------------------- |
|---|
| 25 | |
|---|
| 26 | !!---------------------------------------------------------------------- |
|---|
| 27 | !! stp : OPA system time-stepping |
|---|
| 28 | !!---------------------------------------------------------------------- |
|---|
| 29 | USE oce ! ocean dynamics and tracers variables |
|---|
| 30 | USE dom_oce ! ocean space and time domain variables |
|---|
| 31 | USE zdf_oce ! ocean vertical physics variables |
|---|
| 32 | USE ldftra_oce ! ocean tracer - trends |
|---|
| 33 | USE ldfdyn_oce ! ocean dynamics - trends |
|---|
| 34 | USE in_out_manager ! I/O manager |
|---|
| 35 | USE iom ! |
|---|
| 36 | USE lbclnk |
|---|
| 37 | |
|---|
| 38 | USE daymod ! calendar (day routine) |
|---|
| 39 | |
|---|
| 40 | USE dtatem ! ocean temperature data (dta_tem routine) |
|---|
| 41 | USE dtasal ! ocean salinity data (dta_sal routine) |
|---|
| 42 | USE sbcmod ! surface boundary condition (sbc routine) |
|---|
| 43 | USE sbcrnf ! surface boundary condition: runoff variables |
|---|
| 44 | USE sbccpl ! surface boundary condition: coupled formulation (call send at end of step) |
|---|
| 45 | USE cpl_oasis3, ONLY : lk_cpl |
|---|
| 46 | |
|---|
| 47 | #if defined key_top |
|---|
| 48 | USE trcstp ! passive tracer time-stepping (trc_stp routine) |
|---|
| 49 | #endif |
|---|
| 50 | |
|---|
| 51 | USE traqsr ! solar radiation penetration (tra_qsr routine) |
|---|
| 52 | USE trasbc ! surface boundary condition (tra_sbc routine) |
|---|
| 53 | USE trabbc ! bottom boundary condition (tra_bbc routine) |
|---|
| 54 | USE trabbl ! bottom boundary layer (tra_bbl routine) |
|---|
| 55 | USE tradmp ! internal damping (tra_dmp routine) |
|---|
| 56 | USE traadv ! advection scheme control (tra_adv_ctl routine) |
|---|
| 57 | USE traldf ! lateral mixing (tra_ldf routine) |
|---|
| 58 | USE cla ! cross land advection (tra_cla routine) |
|---|
| 59 | ! zdfkpp ! KPP non-local tracer fluxes (tra_kpp routine) |
|---|
| 60 | USE trazdf ! vertical mixing (tra_zdf routine) |
|---|
| 61 | USE tranxt ! time-stepping (tra_nxt routine) |
|---|
| 62 | USE tranpc ! non-penetrative convection (tra_npc routine) |
|---|
| 63 | |
|---|
| 64 | USE eosbn2 ! equation of state (eos_bn2 routine) |
|---|
| 65 | |
|---|
| 66 | USE dynadv ! advection (dyn_adv routine) |
|---|
| 67 | USE dynbfr ! Bottom friction terms (dyn_bfr routine) |
|---|
| 68 | USE dynvor ! vorticity term (dyn_vor routine) |
|---|
| 69 | USE dynhpg ! hydrostatic pressure grad. (dyn_hpg routine) |
|---|
| 70 | USE dynldf ! lateral momentum diffusion (dyn_ldf routine) |
|---|
| 71 | USE dynzdf ! vertical diffusion (dyn_zdf routine) |
|---|
| 72 | USE dynspg_oce ! surface pressure gradient (dyn_spg routine) |
|---|
| 73 | USE dynspg ! surface pressure gradient (dyn_spg routine) |
|---|
| 74 | USE dynnxt ! time-stepping (dyn_nxt routine) |
|---|
| 75 | |
|---|
| 76 | USE obc_par ! open boundary condition variables |
|---|
| 77 | USE obcdta ! open boundary condition data (obc_dta routine) |
|---|
| 78 | USE obcrst ! open boundary cond. restart (obc_rst routine) |
|---|
| 79 | USE obcrad ! open boundary cond. radiation (obc_rad routine) |
|---|
| 80 | |
|---|
| 81 | USE bdy_par ! unstructured open boundary data variables |
|---|
| 82 | USE bdydta ! unstructured open boundary data (bdy_dta routine) |
|---|
| 83 | |
|---|
| 84 | USE sshwzv ! vertical velocity and ssh (ssh_wzv routine) |
|---|
| 85 | |
|---|
| 86 | USE ldfslp ! iso-neutral slopes (ldf_slp routine) |
|---|
| 87 | USE ldfeiv ! eddy induced velocity coef. (ldf_eiv routine) |
|---|
| 88 | |
|---|
| 89 | USE zdftmx ! tide-induced vertical mixing (zdf_tmx routine) |
|---|
| 90 | USE zdfbfr ! bottom friction (zdf_bfr routine) |
|---|
| 91 | USE zdftke_old ! old TKE vertical mixing (zdf_tke_old routine) |
|---|
| 92 | USE zdftke ! TKE vertical mixing (zdf_tke routine) |
|---|
| 93 | USE zdfkpp ! KPP vertical mixing (zdf_kpp routine) |
|---|
| 94 | USE zdfddm ! double diffusion mixing (zdf_ddm routine) |
|---|
| 95 | USE zdfevd ! enhanced vertical diffusion (zdf_evd routine) |
|---|
| 96 | USE zdfric ! Richardson vertical mixing (zdf_ric routine) |
|---|
| 97 | USE zdfmxl ! Mixed-layer depth (zdf_mxl routine) |
|---|
| 98 | |
|---|
| 99 | USE zpshde ! partial step: hor. derivative (zps_hde routine) |
|---|
| 100 | |
|---|
| 101 | USE diawri ! Standard run outputs (dia_wri routine) |
|---|
| 102 | USE trdicp ! Ocean momentum/tracers trends (trd_wri routine) |
|---|
| 103 | USE trdmld ! mixed-layer trends (trd_mld routine) |
|---|
| 104 | USE trdmld_rst ! restart for mixed-layer trends |
|---|
| 105 | USE trdmod_oce ! ocean momentum/tracers trends |
|---|
| 106 | USE trdvor ! vorticity budget (trd_vor routine) |
|---|
| 107 | USE diagap ! hor. mean model-data gap (dia_gap routine) |
|---|
| 108 | USE diahdy ! dynamic height (dia_hdy routine) |
|---|
| 109 | USE diaptr ! poleward transports (dia_ptr routine) |
|---|
| 110 | USE diaar5 ! AR5 diagnosics (dia_ar5 routine) |
|---|
| 111 | USE diahth ! thermocline depth (dia_hth routine) |
|---|
| 112 | USE diafwb ! freshwater budget (dia_fwb routine) |
|---|
| 113 | USE diaobs ! obs-minus-model (assimilation) (dia_obs routine) |
|---|
| 114 | USE flo_oce ! floats variables |
|---|
| 115 | USE floats ! floats computation (flo_stp routine) |
|---|
| 116 | |
|---|
| 117 | USE asminc ! assimilation increments (tra_asm_inc, dyn_asm_inc routines) |
|---|
| 118 | USE stpctl ! time stepping control (stp_ctl routine) |
|---|
| 119 | USE restart ! ocean restart (rst_wri routine) |
|---|
| 120 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 121 | |
|---|
| 122 | #if defined key_agrif |
|---|
| 123 | USE agrif_opa_sponge ! Momemtum and tracers sponges |
|---|
| 124 | #endif |
|---|
| 125 | |
|---|
| 126 | IMPLICIT NONE |
|---|
| 127 | PRIVATE |
|---|
| 128 | |
|---|
| 129 | PUBLIC stp ! called by opa.F90 |
|---|
| 130 | |
|---|
| 131 | !! * Substitutions |
|---|
| 132 | # include "domzgr_substitute.h90" |
|---|
| 133 | # include "zdfddm_substitute.h90" |
|---|
| 134 | !!---------------------------------------------------------------------- |
|---|
| 135 | !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009) |
|---|
| 136 | !! $Id$ |
|---|
| 137 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
|---|
| 138 | !!---------------------------------------------------------------------- |
|---|
| 139 | |
|---|
| 140 | CONTAINS |
|---|
| 141 | |
|---|
| 142 | #if defined key_agrif |
|---|
| 143 | SUBROUTINE stp( ) |
|---|
| 144 | INTEGER :: kstp ! ocean time-step index |
|---|
| 145 | #else |
|---|
| 146 | SUBROUTINE stp( kstp ) |
|---|
| 147 | INTEGER, INTENT(in) :: kstp ! ocean time-step index |
|---|
| 148 | #endif |
|---|
| 149 | !!---------------------------------------------------------------------- |
|---|
| 150 | !! *** ROUTINE stp *** |
|---|
| 151 | !! |
|---|
| 152 | !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.) |
|---|
| 153 | !! - Time stepping of LIM (dynamic and thermodynamic eqs.) |
|---|
| 154 | !! - Tme stepping of TRC (passive tracer eqs.) |
|---|
| 155 | !! |
|---|
| 156 | !! ** Method : -1- Update forcings and data |
|---|
| 157 | !! -2- Update ocean physics |
|---|
| 158 | !! -3- Compute the t and s trends |
|---|
| 159 | !! -4- Update t and s |
|---|
| 160 | !! -5- Compute the momentum trends |
|---|
| 161 | !! -6- Update the horizontal velocity |
|---|
| 162 | !! -7- Compute the diagnostics variables (rd,N2, div,cur,w) |
|---|
| 163 | !! -8- Outputs and diagnostics |
|---|
| 164 | !!---------------------------------------------------------------------- |
|---|
| 165 | INTEGER :: jk ! dummy loop indice |
|---|
| 166 | INTEGER :: indic ! error indicator if < 0 |
|---|
| 167 | !! --------------------------------------------------------------------- |
|---|
| 168 | |
|---|
| 169 | #if defined key_agrif |
|---|
| 170 | kstp = nit000 + Agrif_Nb_Step() |
|---|
| 171 | ! IF( Agrif_Root() .and. lwp) Write(*,*) '---' |
|---|
| 172 | ! IF(lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp |
|---|
| 173 | # if defined key_iomput |
|---|
| 174 | IF( Agrif_Nbstepint() == 0) CALL iom_swap |
|---|
| 175 | # endif |
|---|
| 176 | #endif |
|---|
| 177 | indic = 1 ! reset to no error condition |
|---|
| 178 | |
|---|
| 179 | IF( kstp /= nit000 ) CALL day( kstp ) ! Calendar (day was already called at nit000 in day_init) |
|---|
| 180 | |
|---|
| 181 | CALL iom_setkt( kstp ) ! say to iom that we are at time step kstp |
|---|
| 182 | |
|---|
| 183 | CALL rst_opn( kstp ) ! Open the restart file |
|---|
| 184 | |
|---|
| 185 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 186 | ! Update data, open boundaries, surface boundary condition (including sea-ice) |
|---|
| 187 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 188 | IF( lk_dtatem ) CALL dta_tem( kstp ) ! update 3D temperature data |
|---|
| 189 | IF( lk_dtasal ) CALL dta_sal( kstp ) ! update 3D salinity data |
|---|
| 190 | CALL sbc ( kstp ) ! Sea Boundary Condition (including sea-ice) |
|---|
| 191 | IF( lk_obc ) CALL obc_dta( kstp ) ! update dynamic and tracer data at open boundaries |
|---|
| 192 | IF( lk_obc ) CALL obc_rad( kstp ) ! compute phase velocities at open boundaries |
|---|
| 193 | IF( lk_bdy ) CALL bdy_dta( kstp ) ! update dynamic and tracer data at unstructured open boundary |
|---|
| 194 | |
|---|
| 195 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 196 | ! Ocean dynamics : ssh, wn, hdiv, rot ! |
|---|
| 197 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 198 | CALL ssh_wzv( kstp ) ! after ssh & vertical velocity |
|---|
| 199 | |
|---|
| 200 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 201 | ! Ocean physics update (ua, va, ta, sa used as workspace) |
|---|
| 202 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 203 | CALL bn2( tb, sb, rn2b ) ! before Brunt-Vaisala frequency |
|---|
| 204 | CALL bn2( tn, sn, rn2 ) ! now Brunt-Vaisala frequency |
|---|
| 205 | ! |
|---|
| 206 | ! VERTICAL PHYSICS |
|---|
| 207 | CALL zdf_bfr( kstp ) ! bottom friction |
|---|
| 208 | ! ! Vertical eddy viscosity and diffusivity coefficients |
|---|
| 209 | IF( lk_zdfric ) CALL zdf_ric ( kstp ) ! Richardson number dependent Kz |
|---|
| 210 | IF( lk_zdftke_old ) CALL zdf_tke_old( kstp ) ! TKE closure scheme for Kz (old scheme) |
|---|
| 211 | IF( lk_zdftke ) CALL zdf_tke ( kstp ) ! TKE closure scheme for Kz |
|---|
| 212 | IF( lk_zdfkpp ) CALL zdf_kpp ( kstp ) ! KPP closure scheme for Kz |
|---|
| 213 | IF( lk_zdfcst ) THEN ! Constant Kz (reset avt, avm[uv] to the background value) |
|---|
| 214 | avt (:,:,:) = rn_avt0 * tmask(:,:,:) |
|---|
| 215 | avmu(:,:,:) = rn_avm0 * umask(:,:,:) |
|---|
| 216 | avmv(:,:,:) = rn_avm0 * vmask(:,:,:) |
|---|
| 217 | ENDIF |
|---|
| 218 | IF( ln_rnf_mouth ) THEN ! increase diffusivity at rivers mouths |
|---|
| 219 | DO jk = 2, nkrnf ; avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk) ; END DO |
|---|
| 220 | ENDIF |
|---|
| 221 | IF( ln_zdfevd ) CALL zdf_evd( kstp ) ! enhanced vertical eddy diffusivity |
|---|
| 222 | |
|---|
| 223 | IF( lk_zdftmx ) CALL zdf_tmx( kstp ) ! tidal vertical mixing |
|---|
| 224 | |
|---|
| 225 | IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) & |
|---|
| 226 | & CALL zdf_ddm( kstp ) ! double diffusive mixing |
|---|
| 227 | CALL zdf_mxl( kstp ) ! mixed layer depth |
|---|
| 228 | |
|---|
| 229 | ! write tke information in the restart file |
|---|
| 230 | IF( lrst_oce .AND. lk_zdftke ) CALL tke_rst( kstp, 'WRITE' ) |
|---|
| 231 | ! |
|---|
| 232 | ! LATERAL PHYSICS |
|---|
| 233 | ! |
|---|
| 234 | IF( lk_ldfslp ) THEN ! slope of lateral mixing |
|---|
| 235 | CALL eos( tb, sb, rhd ) ! before in situ density |
|---|
| 236 | IF( ln_zps ) CALL zps_hde( kstp, tb, sb, rhd, & ! Partial steps: before horizontal gradient |
|---|
| 237 | & gtu, gsu, gru, & ! of t, s, rd at the last ocean level |
|---|
| 238 | & gtv, gsv, grv ) |
|---|
| 239 | CALL ldf_slp( kstp, rhd, rn2b ) ! before slope of the lateral mixing |
|---|
| 240 | ENDIF |
|---|
| 241 | #if defined key_traldf_c2d |
|---|
| 242 | IF( lk_traldf_eiv ) CALL ldf_eiv( kstp ) ! eddy induced velocity coefficient |
|---|
| 243 | # endif |
|---|
| 244 | |
|---|
| 245 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 246 | ! diagnostics and outputs (ua, va, ta, sa used as workspace) |
|---|
| 247 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 248 | IF( lk_floats ) CALL flo_stp( kstp ) ! drifting Floats |
|---|
| 249 | IF( lk_diahth ) CALL dia_hth( kstp ) ! Thermocline depth (20 degres isotherm depth) |
|---|
| 250 | IF( lk_diagap ) CALL dia_gap( kstp ) ! basin averaged diagnostics |
|---|
| 251 | IF( lk_diahdy ) CALL dia_hdy( kstp ) ! dynamical heigh diagnostics |
|---|
| 252 | IF( lk_diafwb ) CALL dia_fwb( kstp ) ! Fresh water budget diagnostics |
|---|
| 253 | IF( lk_diaobs ) CALL dia_obs( kstp ) ! obs-minus-model (assimilation) diagnostics |
|---|
| 254 | IF( ln_diaptr ) CALL dia_ptr( kstp ) ! Poleward TRansports diagnostics |
|---|
| 255 | IF( lk_diaar5 ) CALL dia_ar5( kstp ) ! ar5 diag |
|---|
| 256 | CALL dia_wri( kstp ) ! ocean model: outputs |
|---|
| 257 | |
|---|
| 258 | #if defined key_top |
|---|
| 259 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 260 | ! Passive Tracer Model |
|---|
| 261 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 262 | CALL trc_stp( kstp ) ! time-stepping |
|---|
| 263 | #endif |
|---|
| 264 | |
|---|
| 265 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 266 | ! Active tracers (ua, va used as workspace) |
|---|
| 267 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 268 | ta(:,:,:) = 0.e0 ! set tracer trends to zero |
|---|
| 269 | sa(:,:,:) = 0.e0 |
|---|
| 270 | |
|---|
| 271 | IF( ln_asmiau .AND. & |
|---|
| 272 | & ln_trainc ) CALL tra_asm_inc( kstp ) ! apply tracer assimilation increment |
|---|
| 273 | CALL tra_sbc ( kstp ) ! surface boundary condition |
|---|
| 274 | IF( ln_traqsr ) CALL tra_qsr ( kstp ) ! penetrative solar radiation qsr |
|---|
| 275 | IF( lk_trabbc ) CALL tra_bbc ( kstp ) ! bottom heat flux |
|---|
| 276 | IF( lk_trabbl_dif ) CALL tra_bbl_dif( kstp ) ! diffusive bottom boundary layer scheme |
|---|
| 277 | IF( lk_trabbl_adv ) CALL tra_bbl_adv( kstp ) ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 278 | IF( lk_tradmp ) CALL tra_dmp ( kstp ) ! internal damping trends |
|---|
| 279 | CALL tra_adv ( kstp ) ! horizontal & vertical advection |
|---|
| 280 | IF( n_cla == 1 ) CALL tra_cla ( kstp ) ! Cross Land Advection (Update Hor. advection) |
|---|
| 281 | IF( lk_zdfkpp ) CALL tra_kpp ( kstp ) ! KPP non-local tracer fluxes |
|---|
| 282 | CALL tra_ldf ( kstp ) ! lateral mixing |
|---|
| 283 | #if defined key_agrif |
|---|
| 284 | IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra ! tracers sponge |
|---|
| 285 | #endif |
|---|
| 286 | CALL tra_zdf ( kstp ) ! vertical mixing and after tracer fields |
|---|
| 287 | |
|---|
| 288 | IF( ln_dynhpg_imp ) THEN ! semi-implicit hpg (time stepping then eos) |
|---|
| 289 | IF( ln_zdfnpc ) CALL tra_npc ( kstp ) ! update after fields by non-penetrative convection |
|---|
| 290 | CALL tra_nxt ( kstp ) ! tracer fields at next time step |
|---|
| 291 | CALL eos( ta, sa, rhd, rhop ) ! Time-filtered in situ density for hpg computation |
|---|
| 292 | IF( ln_zps ) CALL zps_hde( kstp, ta, sa, rhd, & ! Partial steps: time filtered hor. derivative |
|---|
| 293 | & gtu, gsu, gru, & ! of t, s, rd at the bottom ocean level |
|---|
| 294 | & gtv, gsv, grv ) |
|---|
| 295 | |
|---|
| 296 | ELSE ! centered hpg (eos then time stepping) |
|---|
| 297 | CALL eos( tn, sn, rhd, rhop ) ! now in situ density for hpg computation |
|---|
| 298 | IF( ln_zps ) CALL zps_hde( kstp, tn, sn, rhd, & ! Partial steps: now horizontal derivative |
|---|
| 299 | & gtu, gsu, gru, & ! of t, s, rd at the bottom ocean level |
|---|
| 300 | & gtv, gsv, grv ) |
|---|
| 301 | IF( ln_zdfnpc ) CALL tra_npc ( kstp ) ! update after fields by non-penetrative convection |
|---|
| 302 | CALL tra_nxt ( kstp ) ! tracer fields at next time step |
|---|
| 303 | ENDIF |
|---|
| 304 | |
|---|
| 305 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 306 | ! Dynamics (ta, sa used as workspace) |
|---|
| 307 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 308 | ua(:,:,:) = 0.e0 ! set dynamics trends to zero |
|---|
| 309 | va(:,:,:) = 0.e0 |
|---|
| 310 | |
|---|
| 311 | IF( ln_asmiau .AND. & |
|---|
| 312 | & ln_dyninc ) CALL dyn_asm_inc( kstp ) ! apply dynamics assimilation increment |
|---|
| 313 | CALL dyn_adv( kstp ) ! advection (vector or flux form) |
|---|
| 314 | CALL dyn_vor( kstp ) ! vorticity term including Coriolis |
|---|
| 315 | CALL dyn_ldf( kstp ) ! lateral mixing |
|---|
| 316 | #if defined key_agrif |
|---|
| 317 | IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_dyn ! momemtum sponge |
|---|
| 318 | #endif |
|---|
| 319 | CALL dyn_hpg( kstp ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 320 | CALL dyn_bfr( kstp ) ! bottom friction |
|---|
| 321 | CALL dyn_zdf( kstp ) ! vertical diffusion |
|---|
| 322 | indic=0 |
|---|
| 323 | CALL dyn_spg( kstp, indic ) ! surface pressure gradient |
|---|
| 324 | CALL dyn_nxt( kstp ) ! lateral velocity at next time step |
|---|
| 325 | |
|---|
| 326 | CALL ssh_nxt( kstp ) ! sea surface height at next time step |
|---|
| 327 | |
|---|
| 328 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 329 | ! Control and restarts |
|---|
| 330 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 331 | CALL stp_ctl( kstp, indic ) |
|---|
| 332 | IF( indic < 0 ) THEN |
|---|
| 333 | CALL ctl_stop( 'step: indic < 0' ) |
|---|
| 334 | CALL dia_wri_state( 'output.abort', kstp ) |
|---|
| 335 | ENDIF |
|---|
| 336 | IF( kstp == nit000 ) CALL iom_close( numror ) ! close input ocean restart file |
|---|
| 337 | IF( lrst_oce ) CALL rst_write ( kstp ) ! write output ocean restart file |
|---|
| 338 | IF( lk_obc ) CALL obc_rst_write( kstp ) ! write open boundary restart file |
|---|
| 339 | |
|---|
| 340 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 341 | ! Trends (ua, va, ta, sa used as workspace) |
|---|
| 342 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 343 | IF( nstop == 0 ) THEN |
|---|
| 344 | IF( lk_trddyn ) CALL trd_dwr( kstp ) ! trends: dynamics |
|---|
| 345 | IF( lk_trdtra ) CALL trd_twr( kstp ) ! trends: active tracers |
|---|
| 346 | IF( lk_trdmld ) CALL trd_mld( kstp ) ! trends: Mixed-layer |
|---|
| 347 | IF( lk_trdvor ) CALL trd_vor( kstp ) ! trends: vorticity budget |
|---|
| 348 | ENDIF |
|---|
| 349 | |
|---|
| 350 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 351 | ! Coupled mode |
|---|
| 352 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 353 | IF( lk_cpl ) CALL sbc_cpl_snd( kstp ) ! coupled mode : field exchanges |
|---|
| 354 | ! |
|---|
| 355 | ! |
|---|
| 356 | END SUBROUTINE stp |
|---|
| 357 | |
|---|
| 358 | !!====================================================================== |
|---|
| 359 | END MODULE step |
|---|
