New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 2446

Last change on this file since 2446 was 2383, checked in by gm, 14 years ago

v3.3beta: LIM-3 bug correction ticket #670
  • Property svn:keywords set to Id
File size: 44.4 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in rdmsnif
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!----------------------------------------------------------------------
13#if defined key_lim3
14   !!----------------------------------------------------------------------
15   !!   'key_lim3'                                      LIM3 sea-ice model
16   !!----------------------------------------------------------------------
17   !!   lim_thd        : thermodynamic of sea ice
18   !!   lim_thd_init   : initialisation of sea-ice thermodynamic
19   !!----------------------------------------------------------------------
20   USE phycst          ! physical constants
21   USE dom_oce         ! ocean space and time domain variables
22   USE ice             ! LIM: sea-ice variables
23   USE par_ice         ! LIM: sea-ice parameters
24   USE sbc_oce         ! Surface boundary condition: ocean fields
25   USE sbc_ice         ! Surface boundary condition: ice fields
26   USE thd_ice         ! LIM thermodynamic sea-ice variables
27   USE dom_ice         ! LIM sea-ice domain
28   USE domvvl          ! domain: variable volume level
29   USE iceini          ! LIM: sea-ice initialization
30   USE limthd_dif      ! LIM: thermodynamics, vertical diffusion
31   USE limthd_dh       ! LIM: thermodynamics, ice and snow thickness variation
32   USE limthd_sal      ! LIM: thermodynamics, ice salinity
33   USE limthd_ent      ! LIM: thermodynamics, ice enthalpy redistribution
34   USE limtab          ! LIM: 1D <==> 2D transformation
35   USE limvar          ! LIM: ???
36   USE lbclnk          ! lateral boundary condition - MPP links
37   USE lib_mpp         ! MPP library
38   USE in_out_manager  ! I/O manager
39   USE prtctl          ! Print control
40
41   IMPLICIT NONE
42   PRIVATE
43
44   PUBLIC   lim_thd    ! called by lim_step
45
46   REAL(wp) ::   epsi20 = 1e-20_wp   ! constant values
47   REAL(wp) ::   epsi16 = 1e-16_wp   !
48   REAL(wp) ::   epsi06 = 1e-06_wp   !
49   REAL(wp) ::   epsi04 = 1e-04_wp   !
50   REAL(wp) ::   zzero  = 0._wp      !
51   REAL(wp) ::   zone   = 1._wp      !
52
53   !! * Substitutions
54#  include "domzgr_substitute.h90"
55#  include "vectopt_loop_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
58   !! $Id$
59   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE lim_thd( kt )
64      !!-------------------------------------------------------------------
65      !!                ***  ROUTINE lim_thd  ***       
66      !! 
67      !! ** Purpose : This routine manages the ice thermodynamic.
68      !!         
69      !! ** Action : - Initialisation of some variables
70      !!             - Some preliminary computation (oceanic heat flux
71      !!               at the ice base, snow acc.,heat budget of the leads)
72      !!             - selection of the icy points and put them in an array
73      !!             - call lim_vert_ther for vert ice thermodynamic
74      !!             - back to the geographic grid
75      !!             - selection of points for lateral accretion
76      !!             - call lim_lat_acc  for the ice accretion
77      !!             - back to the geographic grid
78      !!     
79      !! ** References : H. Goosse et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90
80      !!---------------------------------------------------------------------
81      INTEGER, INTENT(in) ::   kt    ! number of iteration
82      !!
83      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
84      INTEGER  ::   nbpb             ! nb of icy pts for thermo. cal.
85      REAL(wp) ::   zfric_umin = 5e-03    ! lower bound for the friction velocity
86      REAL(wp) ::   zfric_umax = 2e-02    ! upper bound for the friction velocity
87      REAL(wp) ::   zinda, zindb, zthsnice, zfric_u    ! temporary scalar
88      REAL(wp) ::   zfntlat, zpareff   !    -         -
89      REAL(wp) ::   zeps, zareamin, zcoef
90      REAL(wp), DIMENSION(jpi,jpj) ::   zqlbsbq   ! link with lead energy budget qldif
91      !!-------------------------------------------------------------------
92
93      IF( numit == nstart )   CALL lim_thd_init      ! Initialization (first time-step only)
94
95      IF( numit == nstart )   CALL lim_thd_sal_init  ! Initialization (first time-step only)
96     
97      !------------------------------------------------------------------------------!
98      ! 1) Initialization of diagnostic variables                                    !
99      !------------------------------------------------------------------------------!
100      zeps = 1.e-10
101
102      !--------------------
103      ! 1.2) Heat content   
104      !--------------------
105      ! Change the units of heat content; from global units to J.m3
106      DO jl = 1, jpl
107         DO jk = 1, nlay_i
108            DO jj = 1, jpj
109               DO ji = 1, jpi
110                  !Energy of melting q(S,T) [J.m-3]
111                  e_i(ji,jj,jk,jl) = e_i(ji,jj,jk,jl) / ( area(ji,jj) * MAX( v_i(ji,jj,jl) , epsi06 ) ) * nlay_i
112                  !0 if no ice and 1 if yes
113                  zindb = 1.0 - MAX ( 0.0 , SIGN ( 1.0 , - ht_i(ji,jj,jl) ) ) 
114                  !convert units ! very important that this line is here
115                  e_i(ji,jj,jk,jl) = e_i(ji,jj,jk,jl) * unit_fac * zindb 
116               END DO
117            END DO
118         END DO
119         DO jk = 1, nlay_s
120            DO jj = 1, jpj
121               DO ji = 1, jpi
122                  !Energy of melting q(S,T) [J.m-3]
123                  e_s(ji,jj,jk,jl) = e_s(ji,jj,jk,jl) / ( area(ji,jj) * MAX( v_s(ji,jj,jl) , epsi06 ) ) * nlay_s
124                  !0 if no ice and 1 if yes
125                  zindb = 1.0 - MAX ( 0.0 , SIGN ( 1.0 , - ht_s(ji,jj,jl) ) ) 
126                  !convert units ! very important that this line is here
127                  e_s(ji,jj,jk,jl) = e_s(ji,jj,jk,jl) * unit_fac * zindb 
128               END DO
129            END DO
130         END DO
131      END DO
132
133      !-----------------------------
134      ! 1.3) Set some dummies to 0
135      !-----------------------------
136      rdvosif(:,:) = 0.e0   ! variation of ice volume at surface
137      rdvobif(:,:) = 0.e0   ! variation of ice volume at bottom
138      fdvolif(:,:) = 0.e0   ! total variation of ice volume
139      rdvonif(:,:) = 0.e0   ! lateral variation of ice volume
140      fstric (:,:) = 0.e0   ! part of solar radiation transmitted through the ice
141      ffltbif(:,:) = 0.e0   ! linked with fstric
142      qfvbq  (:,:) = 0.e0   ! linked with fstric
143      rdmsnif(:,:) = 0.e0   ! variation of snow mass per unit area
144      rdmicif(:,:) = 0.e0   ! variation of ice mass per unit area
145      hicifp (:,:) = 0.e0   ! daily thermodynamic ice production.
146      fsbri  (:,:) = 0.e0   ! brine flux contribution to salt flux to the ocean
147      fhbri  (:,:) = 0.e0   ! brine flux contribution to heat flux to the ocean
148      fseqv  (:,:) = 0.e0   ! equivalent salt flux to the ocean due to ice/growth decay
149
150      !-----------------------------------
151      ! 1.4) Compute global heat content
152      !-----------------------------------
153      qt_i_in  (:,:) = 0.e0
154      qt_s_in  (:,:) = 0.e0
155      qt_i_fin (:,:) = 0.e0
156      qt_s_fin (:,:) = 0.e0
157      sum_fluxq(:,:) = 0.e0
158      fatm     (:,:) = 0.e0
159
160      ! 2) Partial computation of forcing for the thermodynamic sea ice model.      !
161      !-----------------------------------------------------------------------------!
162
163!CDIR NOVERRCHK
164      DO jj = 1, jpj
165!CDIR NOVERRCHK
166         DO ji = 1, jpi
167            zthsnice       = SUM( ht_s(ji,jj,1:jpl) ) + SUM( ht_i(ji,jj,1:jpl) )
168            zindb          = tms(ji,jj) * ( 1.0 - MAX( zzero , SIGN( zone , - zthsnice ) ) ) 
169            phicif(ji,jj)  = vt_i(ji,jj)
170            pfrld(ji,jj)   = 1.0 - at_i(ji,jj)
171            zinda          = 1.0 - MAX( zzero , SIGN( zone , - ( 1.0 - pfrld(ji,jj) ) ) )
172            !
173            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
174            !           !  practically no "direct lateral ablation"
175            !           
176            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
177            !           !  temperature and turbulent mixing (McPhee, 1992)
178            ! friction velocity
179            zfric_u        = MAX ( MIN( SQRT( ust2s(ji,jj) ) , zfric_umax ) , zfric_umin ) 
180
181            ! here the drag will depend on ice thickness and type (0.006)
182            fdtcn(ji,jj)  = zindb * rau0 * rcp * 0.006  * zfric_u * ( (sst_m(ji,jj) + rt0) - t_bo(ji,jj) ) 
183            ! also category dependent
184            !           !-- Energy from the turbulent oceanic heat flux heat flux coming in the lead
185            qdtcn(ji,jj)  = zindb * fdtcn(ji,jj) * (1.0 - at_i(ji,jj)) * rdt_ice
186            !                       
187            !           !-- Lead heat budget, qldif (part 1, next one is in limthd_dh)
188            !           !   caution: exponent betas used as more snow can fallinto leads
189            qldif(ji,jj) =  tms(ji,jj) * rdt_ice  * (                             &
190               &   pfrld(ji,jj)        * (  qsr(ji,jj)                            &   ! solar heat
191               &                            + qns(ji,jj)                          &   ! non solar heat
192               &                            + fdtcn(ji,jj)                        &   ! turbulent ice-ocean heat
193               &                            + fsbbq(ji,jj) * ( 1.0 - zindb )  )   &   ! residual heat from previous step
194               & - pfrld(ji,jj)**betas * sprecip(ji,jj) * lfus                    )   ! latent heat of sprecip melting
195            !
196            ! Positive heat budget is used for bottom ablation
197            zfntlat        = 1.0 - MAX( zzero , SIGN( zone ,  - qldif(ji,jj) ) )
198            != 1 if positive heat budget
199            zpareff        = 1.0 - zinda * zfntlat
200            != 0 if ice and positive heat budget and 1 if one of those two is false
201            zqlbsbq(ji,jj) = qldif(ji,jj) * ( 1.0 - zpareff ) / MAX( at_i(ji,jj) * rdt_ice , epsi16 )
202            !
203            ! Heat budget of the lead, energy transferred from ice to ocean
204            qldif  (ji,jj) = zpareff * qldif(ji,jj)
205            qdtcn  (ji,jj) = zpareff * qdtcn(ji,jj)
206            !
207            ! Energy needed to bring ocean surface layer until its freezing (qcmif, limflx)
208            qcmif  (ji,jj) =  rau0 * rcp * fse3t(ji,jj,1) * ( t_bo(ji,jj) - (sst_m(ji,jj) + rt0) ) * ( 1. - zinda )
209            !
210            ! oceanic heat flux (limthd_dh)
211            fbif   (ji,jj) = zindb * (  fsbbq(ji,jj) / MAX( at_i(ji,jj) , epsi20 ) + fdtcn(ji,jj) )
212            !
213         END DO
214      END DO
215
216      !------------------------------------------------------------------------------!
217      ! 3) Select icy points and fulfill arrays for the vectorial grid.           
218      !------------------------------------------------------------------------------!
219
220      DO jl = 1, jpl      !loop over ice categories
221
222         IF( kt == nit000 .AND. lwp ) THEN
223            WRITE(numout,*) ' lim_thd : transfer to 1D vectors. Category no : ', jl 
224            WRITE(numout,*) ' ~~~~~~~~'
225         ENDIF
226
227         zareamin = 1.e-10
228         nbpb = 0
229         DO jj = 1, jpj
230            DO ji = 1, jpi
231               IF ( a_i(ji,jj,jl) .gt. zareamin ) THEN     
232                  nbpb      = nbpb  + 1
233                  npb(nbpb) = (jj - 1) * jpi + ji
234               ENDIF
235               ! debug point to follow
236               IF ( (ji.eq.jiindx).AND.(jj.eq.jjindx) ) THEN
237                  jiindex_1d = nbpb
238               ENDIF
239            END DO
240         END DO
241
242         !------------------------------------------------------------------------------!
243         ! 4) Thermodynamic computation
244         !------------------------------------------------------------------------------!
245
246         IF( lk_mpp )   CALL mpp_ini_ice( nbpb )
247
248         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
249
250            !-------------------------
251            ! 4.1 Move to 1D arrays
252            !-------------------------
253
254            CALL tab_2d_1d( nbpb, at_i_b     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
255            CALL tab_2d_1d( nbpb, a_i_b      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
256            CALL tab_2d_1d( nbpb, ht_i_b     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
257            CALL tab_2d_1d( nbpb, ht_s_b     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
258
259            CALL tab_2d_1d( nbpb, t_su_b     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
260            CALL tab_2d_1d( nbpb, sm_i_b     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
261            DO jk = 1, nlay_s
262               CALL tab_2d_1d( nbpb, t_s_b(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
263               CALL tab_2d_1d( nbpb, q_s_b(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
264            END DO
265            DO jk = 1, nlay_i
266               CALL tab_2d_1d( nbpb, t_i_b(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
267               CALL tab_2d_1d( nbpb, q_i_b(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
268               CALL tab_2d_1d( nbpb, s_i_b(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
269            END DO
270
271            CALL tab_2d_1d( nbpb, tatm_ice_1d(1:nbpb), tatm_ice(:,:)   , jpi, jpj, npb(1:nbpb) )
272            CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
273            CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
274            CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
275            CALL tab_2d_1d( nbpb, qnsr_ice_1d(1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
276
277#if ! defined key_coupled
278            CALL tab_2d_1d( nbpb, qla_ice_1d (1:nbpb), qla_ice(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
279            CALL tab_2d_1d( nbpb, dqla_ice_1d(1:nbpb), dqla_ice(:,:,jl)   , jpi, jpj, npb(1:nbpb) )
280#endif
281
282            CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl)   , jpi, jpj, npb(1:nbpb) )
283            CALL tab_2d_1d( nbpb, t_bo_b     (1:nbpb), t_bo       , jpi, jpj, npb(1:nbpb) )
284            CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip    , jpi, jpj, npb(1:nbpb) ) 
285            CALL tab_2d_1d( nbpb, fbif_1d    (1:nbpb), fbif       , jpi, jpj, npb(1:nbpb) )
286            CALL tab_2d_1d( nbpb, qldif_1d   (1:nbpb), qldif      , jpi, jpj, npb(1:nbpb) )
287            CALL tab_2d_1d( nbpb, rdmicif_1d (1:nbpb), rdmicif    , jpi, jpj, npb(1:nbpb) )
288            CALL tab_2d_1d( nbpb, rdmsnif_1d (1:nbpb), rdmsnif    , jpi, jpj, npb(1:nbpb) )
289            CALL tab_2d_1d( nbpb, dmgwi_1d   (1:nbpb), dmgwi      , jpi, jpj, npb(1:nbpb) )
290            CALL tab_2d_1d( nbpb, qlbbq_1d   (1:nbpb), zqlbsbq    , jpi, jpj, npb(1:nbpb) )
291
292            CALL tab_2d_1d( nbpb, fseqv_1d   (1:nbpb), fseqv      , jpi, jpj, npb(1:nbpb) )
293            CALL tab_2d_1d( nbpb, fsbri_1d   (1:nbpb), fsbri      , jpi, jpj, npb(1:nbpb) )
294            CALL tab_2d_1d( nbpb, fhbri_1d   (1:nbpb), fhbri      , jpi, jpj, npb(1:nbpb) )
295            CALL tab_2d_1d( nbpb, fstbif_1d  (1:nbpb), fstric     , jpi, jpj, npb(1:nbpb) )
296            CALL tab_2d_1d( nbpb, qfvbq_1d   (1:nbpb), qfvbq      , jpi, jpj, npb(1:nbpb) )
297
298            !--------------------------------
299            ! 4.3) Thermodynamic processes
300            !--------------------------------
301
302            IF( con_i )   CALL lim_thd_enmelt( 1, nbpb )   ! computes sea ice energy of melting
303            IF( con_i )   CALL lim_thd_glohec( qt_i_in, qt_s_in, q_i_layer_in, 1, nbpb, jl )
304
305            !                                 !---------------------------------!
306            CALL lim_thd_dif( 1, nbpb, jl )   ! Ice/Snow Temperature profile    !
307            !                                 !---------------------------------!
308
309            CALL lim_thd_enmelt( 1, nbpb )    ! computes sea ice energy of melting compulsory for limthd_dh
310
311            IF( con_i )   CALL lim_thd_glohec ( qt_i_fin, qt_s_fin, q_i_layer_fin, 1, nbpb, jl ) 
312            IF( con_i )   CALL lim_thd_con_dif( 1 , nbpb , jl )
313
314            !                                 !---------------------------------!
315            CALL lim_thd_dh( 1, nbpb, jl )    ! Ice/Snow thickness              !
316            !                                 !---------------------------------!
317
318            !                                 !---------------------------------!
319            CALL lim_thd_ent( 1, nbpb, jl )   ! Ice/Snow enthalpy remapping     !
320            !                                 !---------------------------------!
321
322            !                                 !---------------------------------!
323            CALL lim_thd_sal( 1, nbpb )       ! Ice salinity computation        !
324            !                                 !---------------------------------!
325
326            !           CALL lim_thd_enmelt(1,nbpb)   ! computes sea ice energy of melting
327            IF( con_i )   CALL lim_thd_glohec( qt_i_fin, qt_s_fin, q_i_layer_fin, 1, nbpb, jl ) 
328            IF( con_i )   CALL lim_thd_con_dh ( 1 , nbpb , jl )
329
330            !--------------------------------
331            ! 4.4) Move 1D to 2D vectors
332            !--------------------------------
333
334            CALL tab_1d_2d( nbpb, at_i        , npb, at_i_b(1:nbpb), jpi, jpj )
335            CALL tab_1d_2d( nbpb, ht_i(:,:,jl), npb, ht_i_b(1:nbpb), jpi, jpj )
336            CALL tab_1d_2d( nbpb, ht_s(:,:,jl), npb, ht_s_b(1:nbpb), jpi, jpj )
337            CALL tab_1d_2d( nbpb, a_i (:,:,jl), npb, a_i_b(1:nbpb) , jpi, jpj )
338            CALL tab_1d_2d( nbpb, t_su(:,:,jl), npb, t_su_b(1:nbpb), jpi, jpj )
339            CALL tab_1d_2d( nbpb, sm_i(:,:,jl), npb, sm_i_b(1:nbpb), jpi, jpj )
340
341            DO jk = 1, nlay_s
342               CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_b(1:nbpb,jk), jpi, jpj)
343               CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_b(1:nbpb,jk), jpi, jpj)
344            END DO
345
346            DO jk = 1, nlay_i
347               CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_b(1:nbpb,jk), jpi, jpj)
348               CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_b(1:nbpb,jk), jpi, jpj)
349               CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_b(1:nbpb,jk), jpi, jpj)
350            END DO
351
352            CALL tab_1d_2d( nbpb, fstric , npb, fstbif_1d (1:nbpb), jpi, jpj )
353            CALL tab_1d_2d( nbpb, qldif  , npb, qldif_1d  (1:nbpb), jpi, jpj )
354            CALL tab_1d_2d( nbpb, qfvbq  , npb, qfvbq_1d  (1:nbpb), jpi, jpj )
355            CALL tab_1d_2d( nbpb, rdmicif, npb, rdmicif_1d(1:nbpb), jpi, jpj )
356            CALL tab_1d_2d( nbpb, rdmsnif, npb, rdmsnif_1d(1:nbpb), jpi, jpj )
357            CALL tab_1d_2d( nbpb, dmgwi  , npb, dmgwi_1d  (1:nbpb), jpi, jpj )
358            CALL tab_1d_2d( nbpb, rdvosif, npb, dvsbq_1d  (1:nbpb), jpi, jpj )
359            CALL tab_1d_2d( nbpb, rdvobif, npb, dvbbq_1d  (1:nbpb), jpi, jpj )
360            CALL tab_1d_2d( nbpb, fdvolif, npb, dvlbq_1d  (1:nbpb), jpi, jpj )
361            CALL tab_1d_2d( nbpb, rdvonif, npb, dvnbq_1d  (1:nbpb), jpi, jpj ) 
362            CALL tab_1d_2d( nbpb, fseqv  , npb, fseqv_1d  (1:nbpb), jpi, jpj )
363            !
364            IF( num_sal == 2 ) THEN
365               CALL tab_1d_2d( nbpb, fsbri, npb, fsbri_1d(1:nbpb), jpi, jpj )
366               CALL tab_1d_2d( nbpb, fhbri, npb, fhbri_1d(1:nbpb), jpi, jpj )
367            ENDIF
368            !
369            !+++++
370            !temporary stuff for a dummy version
371            CALL tab_1d_2d( nbpb, dh_i_surf2D, npb, dh_i_surf(1:nbpb)      , jpi, jpj )
372            CALL tab_1d_2d( nbpb, dh_i_bott2D, npb, dh_i_bott(1:nbpb)      , jpi, jpj )
373            CALL tab_1d_2d( nbpb, fsup2D     , npb, fsup     (1:nbpb)      , jpi, jpj )
374            CALL tab_1d_2d( nbpb, focea2D    , npb, focea    (1:nbpb)      , jpi, jpj )
375            CALL tab_1d_2d( nbpb, s_i_newice , npb, s_i_new  (1:nbpb)      , jpi, jpj )
376            CALL tab_1d_2d( nbpb, izero(:,:,jl) , npb, i0    (1:nbpb)      , jpi, jpj )
377            CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qnsr_ice_1d(1:nbpb), jpi, jpj)
378            !+++++
379            !
380            IF( lk_mpp )   CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
381         ENDIF
382         !
383      END DO
384
385      !------------------------------------------------------------------------------!
386      ! 5) Global variables, diagnostics
387      !------------------------------------------------------------------------------!
388
389      !------------------------
390      ! 5.1) Ice heat content             
391      !------------------------
392      ! Enthalpies are global variables we have to readjust the units
393      zcoef = 1.e0 / ( unit_fac * REAL(nlay_i) )
394      DO jl = 1, jpl
395         DO jk = 1, nlay_i
396            ! Multiply by volume, divide by nlayers so that heat content in 10^9 Joules
397            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * area(:,:) * a_i(:,:,jl) * ht_i(:,:,jl) * zcoef
398         END DO
399      END DO
400
401      !------------------------
402      ! 5.2) Snow heat content             
403      !------------------------
404      ! Enthalpies are global variables we have to readjust the units
405      zcoef = 1.e0 / ( unit_fac * REAL(nlay_s) )
406      DO jl = 1, jpl
407         DO jk = 1, nlay_s
408            ! Multiply by volume, so that heat content in 10^9 Joules
409            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * area(:,:) * a_i(:,:,jl) * ht_s(:,:,jl) * zcoef
410         END DO
411      END DO
412
413      !----------------------------------
414      ! 5.3) Change thickness to volume
415      !----------------------------------
416      CALL lim_var_eqv2glo
417
418      !--------------------------------------------
419      ! 5.4) Diagnostic thermodynamic growth rates
420      !--------------------------------------------
421      d_v_i_thd(:,:,:) = v_i      (:,:,:) - old_v_i(:,:,:)    ! ice volumes
422      dv_dt_thd(:,:,:) = d_v_i_thd(:,:,:) / rdt_ice * 86400.0
423
424      IF( con_i )   fbif(:,:) = fbif(:,:) + zqlbsbq(:,:)
425
426      IF(ln_ctl) THEN            ! Control print
427         CALL prt_ctl_info(' ')
428         CALL prt_ctl_info(' - Cell values : ')
429         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
430         CALL prt_ctl(tab2d_1=area , clinfo1=' lim_thd  : cell area :')
431         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_thd  : at_i      :')
432         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_thd  : vt_i      :')
433         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_thd  : vt_s      :')
434         DO jl = 1, jpl
435            CALL prt_ctl_info(' ')
436            CALL prt_ctl_info(' - Category : ', ivar1=jl)
437            CALL prt_ctl_info('   ~~~~~~~~~~')
438            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_thd  : a_i      : ')
439            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_thd  : ht_i     : ')
440            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_thd  : ht_s     : ')
441            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_thd  : v_i      : ')
442            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_thd  : v_s      : ')
443            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_thd  : e_s      : ')
444            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_thd  : t_su     : ')
445            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_thd  : t_snow   : ')
446            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_thd  : sm_i     : ')
447            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_thd  : smv_i    : ')
448            DO jk = 1, nlay_i
449               CALL prt_ctl_info(' ')
450               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
451               CALL prt_ctl_info('   ~~~~~~~')
452               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_thd  : t_i      : ')
453               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_thd  : e_i      : ')
454            END DO
455         END DO
456      ENDIF
457      !
458   END SUBROUTINE lim_thd
459
460
461   SUBROUTINE lim_thd_glohec( eti, ets, etilayer, kideb, kiut, jl )
462      !!-----------------------------------------------------------------------
463      !!                   ***  ROUTINE lim_thd_glohec ***
464      !!                 
465      !! ** Purpose :  Compute total heat content for each category
466      !!               Works with 1d vectors only
467      !!-----------------------------------------------------------------------
468      INTEGER , INTENT(in   )                         ::   kideb, kiut   ! bounds for the spatial loop
469      INTEGER , INTENT(in   )                         ::   jl            ! category number
470      REAL(wp), INTENT(  out), DIMENSION (jpij,jpl  ) ::   eti, ets      ! vertically-summed heat content for ice & snow
471      REAL(wp), INTENT(  out), DIMENSION (jpij,jkmax) ::   etilayer      ! heat content for ice layers
472      !!
473      INTEGER  ::   ji,jk   ! loop indices
474      REAL(wp) ::   zeps    ! very small value (1.e-10)
475      !!-----------------------------------------------------------------------
476      eti(:,:) = 0.e0
477      ets(:,:) = 0.e0
478      zeps     = 1.e-10
479
480      DO jk = 1, nlay_i                ! total q over all layers, ice [J.m-2]
481         DO ji = kideb, kiut
482            etilayer(ji,jk) = q_i_b(ji,jk) * ht_i_b(ji) / nlay_i
483            eti     (ji,jl) = eti(ji,jl) + etilayer(ji,jk) 
484         END DO
485      END DO
486      DO ji = kideb, kiut              ! total q over all layers, snow [J.m-2]
487         ets(ji,jl) = ets(ji,jl) + q_s_b(ji,1) * ht_s_b(ji) / nlay_s
488      END DO
489
490      IF(lwp) WRITE(numout,*) ' lim_thd_glohec '
491      IF(lwp) WRITE(numout,*) ' qt_i_in : ', eti(jiindex_1d,jl) / rdt_ice
492      IF(lwp) WRITE(numout,*) ' qt_s_in : ', ets(jiindex_1d,jl) / rdt_ice
493      IF(lwp) WRITE(numout,*) ' qt_in   : ', ( eti(jiindex_1d,jl) + ets(jiindex_1d,jl) ) / rdt_ice
494      !
495   END SUBROUTINE lim_thd_glohec
496
497
498   SUBROUTINE lim_thd_con_dif( kideb, kiut, jl )
499      !!-----------------------------------------------------------------------
500      !!                   ***  ROUTINE lim_thd_con_dif ***
501      !!                 
502      !! ** Purpose :   Test energy conservation after heat diffusion
503      !!-------------------------------------------------------------------
504      INTEGER , INTENT(in   ) ::   kideb, kiut   ! bounds for the spatial loop
505      INTEGER , INTENT(in   ) ::   jl            ! category number
506
507      INTEGER  ::   ji, jk         ! loop indices
508      INTEGER  ::   zji, zjj
509      INTEGER  ::   numce          ! number of points for which conservation is violated
510      REAL(wp) ::   meance         ! mean conservation error
511      REAL(wp) ::   max_cons_err, max_surf_err
512      !!---------------------------------------------------------------------
513
514      max_cons_err =  1.0          ! maximum tolerated conservation error
515      max_surf_err =  0.001        ! maximum tolerated surface error
516
517      !--------------------------
518      ! Increment of energy
519      !--------------------------
520      ! global
521      DO ji = kideb, kiut
522         dq_i(ji,jl) = qt_i_fin(ji,jl) - qt_i_in(ji,jl) + qt_s_fin(ji,jl) - qt_s_in(ji,jl)
523      END DO
524      ! layer by layer
525      dq_i_layer(:,:) = q_i_layer_fin(:,:) - q_i_layer_in(:,:)
526
527      !----------------------------------------
528      ! Atmospheric heat flux, ice heat budget
529      !----------------------------------------
530      DO ji = kideb, kiut
531         zji = MOD( npb(ji) - 1 , jpi ) + 1
532         zjj =    ( npb(ji) - 1 ) / jpi + 1
533         fatm     (ji,jl) = qnsr_ice_1d(ji) + ( 1._wp - i0(ji) ) * qsr_ice_1d(ji)
534         sum_fluxq(ji,jl) = fc_su(ji) - fc_bo_i(ji) + qsr_ice_1d(ji) * i0(ji) - fstroc(zji,zjj,jl)
535      END DO
536
537      !--------------------
538      ! Conservation error
539      !--------------------
540      DO ji = kideb, kiut
541         cons_error(ji,jl) = ABS( dq_i(ji,jl) / rdt_ice + sum_fluxq(ji,jl) )
542      END DO
543
544      numce  = 0
545      meance = 0.0
546      DO ji = kideb, kiut
547         IF ( cons_error(ji,jl) .GT. max_cons_err ) THEN
548            numce = numce + 1
549            meance = meance + cons_error(ji,jl)
550         ENDIF
551      END DO
552      IF( numce .GT. 0 ) meance = meance / numce
553
554      WRITE(numout,*) ' Maximum tolerated conservation error : ', max_cons_err
555      WRITE(numout,*) ' After lim_thd_dif, category : ', jl
556      WRITE(numout,*) ' Mean conservation error on big error points ', meance, numit
557      WRITE(numout,*) ' Number of points where there is a cons err gt than c.e. : ', numce, numit
558
559      !-------------------------------------------------------
560      ! Surface error due to imbalance between Fatm and Fcsu
561      !-------------------------------------------------------
562      numce  = 0
563      meance = 0.0
564
565      DO ji = kideb, kiut
566         surf_error(ji,jl) = ABS ( fatm(ji,jl) - fc_su(ji) )
567         IF( ( t_su_b(ji) .LT. rtt ) .AND. ( surf_error(ji,jl) .GT. max_surf_err ) ) THEN
568            numce = numce + 1 
569            meance = meance + surf_error(ji,jl)
570         ENDIF
571      ENDDO
572      IF( numce .GT. 0 ) meance = meance / numce
573
574      WRITE(numout,*) ' Maximum tolerated surface error : ', max_surf_err
575      WRITE(numout,*) ' After lim_thd_dif, category : ', jl
576      WRITE(numout,*) ' Mean surface error on big error points ', meance, numit
577      WRITE(numout,*) ' Number of points where there is a surf err gt than surf_err : ', numce, numit
578
579      IF (jiindex_1D.GT.0) WRITE(numout,*) ' fc_su      : ', fc_su(jiindex_1d)
580      IF (jiindex_1D.GT.0) WRITE(numout,*) ' fatm       : ', fatm(jiindex_1d,jl)
581      IF (jiindex_1D.GT.0) WRITE(numout,*) ' t_su       : ', t_su_b(jiindex_1d)
582
583      !---------------------------------------
584      ! Write ice state in case of big errors
585      !---------------------------------------
586      DO ji = kideb, kiut
587         IF ( ( ( t_su_b(ji) .LT. rtt ) .AND. ( surf_error(ji,jl) .GT. max_surf_err ) ) .OR. &
588            ( cons_error(ji,jl) .GT. max_cons_err  ) ) THEN
589            zji                 = MOD( npb(ji) - 1, jpi ) + 1
590            zjj                 = ( npb(ji) - 1 ) / jpi + 1
591            !
592            WRITE(numout,*) ' alerte 1     '
593            WRITE(numout,*) ' Untolerated conservation / surface error after '
594            WRITE(numout,*) ' heat diffusion in the ice '
595            WRITE(numout,*) ' Category   : ', jl
596            WRITE(numout,*) ' zji , zjj  : ', zji, zjj
597            WRITE(numout,*) ' lat, lon   : ', gphit(zji,zjj), glamt(zji,zjj)
598            WRITE(numout,*) ' cons_error : ', cons_error(ji,jl)
599            WRITE(numout,*) ' surf_error : ', surf_error(ji,jl)
600            WRITE(numout,*) ' dq_i       : ', - dq_i(ji,jl) / rdt_ice
601            WRITE(numout,*) ' Fdt        : ', sum_fluxq(ji,jl)
602            WRITE(numout,*)
603            !        WRITE(numout,*) ' qt_i_in   : ', qt_i_in(ji,jl)
604            !        WRITE(numout,*) ' qt_s_in   : ', qt_s_in(ji,jl)
605            !        WRITE(numout,*) ' qt_i_fin  : ', qt_i_fin(ji,jl)
606            !        WRITE(numout,*) ' qt_s_fin  : ', qt_s_fin(ji,jl)
607            !        WRITE(numout,*) ' qt        : ', qt_i_fin(ji,jl) + qt_s_fin(ji,jl)
608            WRITE(numout,*) ' ht_i       : ', ht_i_b(ji)
609            WRITE(numout,*) ' ht_s       : ', ht_s_b(ji)
610            WRITE(numout,*) ' t_su       : ', t_su_b(ji)
611            WRITE(numout,*) ' t_s        : ', t_s_b(ji,1)
612            WRITE(numout,*) ' t_i        : ', t_i_b(ji,1:nlay_i)
613            WRITE(numout,*) ' t_bo       : ', t_bo_b(ji)
614            WRITE(numout,*) ' q_i        : ', q_i_b(ji,1:nlay_i)
615            WRITE(numout,*) ' s_i        : ', s_i_b(ji,1:nlay_i)
616            WRITE(numout,*) ' tmelts     : ', rtt - tmut*s_i_b(ji,1:nlay_i)
617            WRITE(numout,*)
618            WRITE(numout,*) ' Fluxes '
619            WRITE(numout,*) ' ~~~~~~ '
620            WRITE(numout,*) ' fatm       : ', fatm(ji,jl)
621            WRITE(numout,*) ' fc_su      : ', fc_su    (ji)
622            WRITE(numout,*) ' fstr_inice : ', qsr_ice_1d(ji)*i0(ji)
623            WRITE(numout,*) ' fc_bo      : ', - fc_bo_i  (ji)
624            WRITE(numout,*) ' foc        : ', fbif_1d(ji)
625            WRITE(numout,*) ' fstroc     : ', fstroc   (zji,zjj,jl)
626            WRITE(numout,*) ' i0         : ', i0(ji)
627            WRITE(numout,*) ' qsr_ice    : ', (1.0-i0(ji))*qsr_ice_1d(ji)
628            WRITE(numout,*) ' qns_ice    : ', qnsr_ice_1d(ji)
629            WRITE(numout,*) ' Conduction fluxes : '
630            WRITE(numout,*) ' fc_s      : ', fc_s(ji,0:nlay_s)
631            WRITE(numout,*) ' fc_i      : ', fc_i(ji,0:nlay_i)
632            WRITE(numout,*)
633            WRITE(numout,*) ' Layer by layer ... '
634            WRITE(numout,*) ' dq_snow : ', ( qt_s_fin(ji,jl) - qt_s_in(ji,jl) ) / rdt_ice
635            WRITE(numout,*) ' dfc_snow  : ', fc_s(ji,1) - fc_s(ji,0)
636            DO jk = 1, nlay_i
637               WRITE(numout,*) ' layer  : ', jk
638               WRITE(numout,*) ' dq_ice : ', dq_i_layer(ji,jk) / rdt_ice 
639               WRITE(numout,*) ' radab  : ', radab(ji,jk)
640               WRITE(numout,*) ' dfc_i  : ', fc_i(ji,jk) - fc_i(ji,jk-1)
641               WRITE(numout,*) ' tot f  : ', fc_i(ji,jk) - fc_i(ji,jk-1) - radab(ji,jk)
642            END DO
643
644         ENDIF
645
646      END DO
647      !
648   END SUBROUTINE lim_thd_con_dif
649
650
651   SUBROUTINE lim_thd_con_dh( kideb, kiut, jl )
652      !!-----------------------------------------------------------------------
653      !!                   ***  ROUTINE lim_thd_con_dh  ***
654      !!                 
655      !! ** Purpose :   Test energy conservation after enthalpy redistr.
656      !!-----------------------------------------------------------------------
657      INTEGER, INTENT(in) ::        &
658         kideb, kiut,               &  !: bounds for the spatial loop
659         jl                            !: category number
660
661      REAL(wp)                 ::   &  !: ! goes to trash
662         meance,                    &  !: mean conservation error
663         max_cons_err                  !: maximum tolerated conservation error
664
665      INTEGER ::                    &
666         numce                         !: number of points for which conservation
667      !  is violated
668      INTEGER  ::  ji, zji, zjj        ! loop indices
669      !!---------------------------------------------------------------------
670
671      max_cons_err = 1.0
672
673      !--------------------------
674      ! Increment of energy
675      !--------------------------
676      ! global
677      DO ji = kideb, kiut
678         dq_i(ji,jl) = qt_i_fin(ji,jl) - qt_i_in(ji,jl)  &
679            + qt_s_fin(ji,jl) - qt_s_in(ji,jl)
680      END DO
681      ! layer by layer
682      dq_i_layer(:,:)    = q_i_layer_fin(:,:) - q_i_layer_in(:,:)
683
684      !----------------------------------------
685      ! Atmospheric heat flux, ice heat budget
686      !----------------------------------------
687
688      DO ji = kideb, kiut
689         zji                 = MOD( npb(ji) - 1, jpi ) + 1
690         zjj                 = ( npb(ji) - 1 ) / jpi + 1
691
692         fatm(ji,jl) = &
693            qnsr_ice_1d(ji)                  + & ! atm non solar
694            !         (1.0-i0(ji))*qsr_ice_1d(ji)          ! atm solar
695            qsr_ice_1d(ji)                       ! atm solar
696
697         sum_fluxq(ji,jl)     = fatm(ji,jl) + fbif_1d(ji) - ftotal_fin(ji) & 
698            - fstroc(zji,zjj,jl) 
699         cons_error(ji,jl)   = ABS( dq_i(ji,jl) / rdt_ice + sum_fluxq(ji,jl) )
700      END DO
701
702      !--------------------
703      ! Conservation error
704      !--------------------
705
706      DO ji = kideb, kiut
707         cons_error(ji,jl) = ABS( dq_i(ji,jl) / rdt_ice + sum_fluxq(ji,jl) )
708      END DO
709
710      numce = 0
711      meance = 0.0
712      DO ji = kideb, kiut
713         IF ( cons_error(ji,jl) .GT. max_cons_err ) THEN
714            numce = numce + 1
715            meance = meance + cons_error(ji,jl)
716         ENDIF
717      ENDDO
718      IF (numce .GT. 0 ) meance = meance / numce
719
720      WRITE(numout,*) ' Error report - Category : ', jl
721      WRITE(numout,*) ' ~~~~~~~~~~~~ '
722      WRITE(numout,*) ' Maximum tolerated conservation error : ', max_cons_err
723      WRITE(numout,*) ' After lim_thd_ent, category : ', jl
724      WRITE(numout,*) ' Mean conservation error on big error points ', meance, &
725         numit
726      WRITE(numout,*) ' Number of points where there is a cons err gt than 0.1 W/m2 : ', numce, numit
727
728      !---------------------------------------
729      ! Write ice state in case of big errors
730      !---------------------------------------
731      DO ji = kideb, kiut
732         IF ( cons_error(ji,jl) .GT. max_cons_err  ) THEN
733            zji                 = MOD( npb(ji) - 1, jpi ) + 1
734            zjj                 = ( npb(ji) - 1 ) / jpi + 1
735            !
736            WRITE(numout,*) ' alerte 1 - category : ', jl
737            WRITE(numout,*) ' Untolerated conservation error after limthd_ent '
738            WRITE(numout,*) ' zji , zjj  : ', zji, zjj
739            WRITE(numout,*) ' lat, lon   : ', gphit(zji,zjj), glamt(zji,zjj)
740            WRITE(numout,*) ' * '
741            WRITE(numout,*) ' Ftotal     : ', sum_fluxq(ji,jl)
742            WRITE(numout,*) ' dq_t       : ', - dq_i(ji,jl) / rdt_ice
743            WRITE(numout,*) ' dq_i       : ', - ( qt_i_fin(ji,jl) - qt_i_in(ji,jl) ) / rdt_ice
744            WRITE(numout,*) ' dq_s       : ', - ( qt_s_fin(ji,jl) - qt_s_in(ji,jl) ) / rdt_ice
745            WRITE(numout,*) ' cons_error : ', cons_error(ji,jl)
746            WRITE(numout,*) ' * '
747            WRITE(numout,*) ' Fluxes        --- : '
748            WRITE(numout,*) ' fatm       : ', fatm(ji,jl)
749            WRITE(numout,*) ' foce       : ', fbif_1d(ji)
750            WRITE(numout,*) ' fres       : ', ftotal_fin(ji)
751            WRITE(numout,*) ' fhbri      : ', fhbricat(zji,zjj,jl)
752            WRITE(numout,*) ' * '
753            WRITE(numout,*) ' Heat contents --- : '
754            WRITE(numout,*) ' qt_s_in    : ', qt_s_in(ji,jl) / rdt_ice
755            WRITE(numout,*) ' qt_i_in    : ', qt_i_in(ji,jl) / rdt_ice
756            WRITE(numout,*) ' qt_in      : ', ( qt_i_in(ji,jl) + qt_s_in(ji,jl) ) / rdt_ice
757            WRITE(numout,*) ' qt_s_fin   : ', qt_s_fin(ji,jl) / rdt_ice
758            WRITE(numout,*) ' qt_i_fin   : ', qt_i_fin(ji,jl) / rdt_ice
759            WRITE(numout,*) ' qt_fin     : ', ( qt_i_fin(ji,jl) + qt_s_fin(ji,jl) ) / rdt_ice
760            WRITE(numout,*) ' * '
761            WRITE(numout,*) ' Ice variables --- : '
762            WRITE(numout,*) ' ht_i       : ', ht_i_b(ji)
763            WRITE(numout,*) ' ht_s       : ', ht_s_b(ji)
764            WRITE(numout,*) ' dh_s_tot  : ', dh_s_tot(ji)
765            WRITE(numout,*) ' dh_snowice: ', dh_snowice(ji)
766            WRITE(numout,*) ' dh_i_surf : ', dh_i_surf(ji)
767            WRITE(numout,*) ' dh_i_bott : ', dh_i_bott(ji)
768         ENDIF
769         !
770      END DO
771      !
772   END SUBROUTINE lim_thd_con_dh
773
774
775   SUBROUTINE lim_thd_enmelt( kideb, kiut )
776      !!-----------------------------------------------------------------------
777      !!                   ***  ROUTINE lim_thd_enmelt ***
778      !!                 
779      !! ** Purpose :   Computes sea ice energy of melting q_i (J.m-3)
780      !!
781      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
782      !!-------------------------------------------------------------------
783      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
784      !!
785      INTEGER  ::   ji, jk   !dummy loop indices
786      REAL(wp) ::   ztmelts, zeps   ! temporary scalar
787      !!-------------------------------------------------------------------
788      zeps = 1.e-10
789      !
790      DO jk = 1, nlay_i             ! Sea ice energy of melting
791         DO ji = kideb, kiut
792            ztmelts      =  - tmut  * s_i_b(ji,jk) + rtt 
793            q_i_b(ji,jk) =    rhoic * ( cpic * ( ztmelts - t_i_b(ji,jk) )                                 &
794               &                      + lfus * ( 1.0 - (ztmelts-rtt) / MIN( t_i_b(ji,jk)-rtt, -zeps ) )   &
795               &                      - rcp  * ( ztmelts-rtt  )  ) 
796         END DO
797      END DO
798      DO jk = 1, nlay_s             ! Snow energy of melting
799         DO ji = kideb,kiut
800            q_s_b(ji,jk) = rhosn * ( cpic * ( rtt - t_s_b(ji,jk) ) + lfus )
801         END DO
802      END DO
803      !
804   END SUBROUTINE lim_thd_enmelt
805
806
807   SUBROUTINE lim_thd_init
808      !!-----------------------------------------------------------------------
809      !!                   ***  ROUTINE lim_thd_init ***
810      !!                 
811      !! ** Purpose :   Physical constants and parameters linked to the ice
812      !!              thermodynamics
813      !!
814      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
815      !!              parameter values called at the first timestep (nit000)
816      !!
817      !! ** input   :   Namelist namicether
818      !!-------------------------------------------------------------------
819      NAMELIST/namicethd/ hmelt , hiccrit, fraz_swi, maxfrazb, vfrazb, Cfrazb,   &
820         &                hicmin, hiclim, amax  ,                                &
821         &                sbeta  , parlat, hakspl, hibspl, exld,                 &
822         &                hakdif, hnzst  , thth  , parsub, alphs, betas,         & 
823         &                kappa_i, nconv_i_thd, maxer_i_thd, thcon_i_swi
824      !!-------------------------------------------------------------------
825
826      IF(lwp) THEN
827         WRITE(numout,*)
828         WRITE(numout,*) 'lim_thd : Ice Thermodynamics'
829         WRITE(numout,*) '~~~~~~~'
830      ENDIF
831
832      REWIND( numnam_ice )                  ! read Namelist numnam_ice
833      READ  ( numnam_ice , namicethd )
834     
835      IF(lwp) THEN                          ! control print
836         WRITE(numout,*)
837         WRITE(numout,*)'   Namelist of ice parameters for ice thermodynamic computation '
838         WRITE(numout,*)'      maximum melting at the bottom                           hmelt        = ', hmelt
839         WRITE(numout,*)'      ice thick. for lateral accretion in NH (SH)             hiccrit(1/2) = ', hiccrit
840         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       fraz_swi     = ', fraz_swi
841         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   maxfrazb     = ', maxfrazb
842         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  vfrazb       = ', vfrazb
843         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          Cfrazb       = ', Cfrazb
844         WRITE(numout,*)'      ice thick. corr. to max. energy stored in brine pocket  hicmin       = ', hicmin 
845         WRITE(numout,*)'      minimum ice thickness                                   hiclim       = ', hiclim 
846         WRITE(numout,*)'      maximum lead fraction                                   amax         = ', amax
847         WRITE(numout,*)'      numerical carac. of the scheme for diffusion in ice '
848         WRITE(numout,*)'      Cranck-Nicholson (=0.5), implicit (=1), explicit (=0)   sbeta        = ', sbeta
849         WRITE(numout,*)'      percentage of energy used for lateral ablation          parlat       = ', parlat
850         WRITE(numout,*)'      slope of distr. for Hakkinen-Mellor lateral melting     hakspl       = ', hakspl 
851         WRITE(numout,*)'      slope of distribution for Hibler lateral melting        hibspl       = ', hibspl
852         WRITE(numout,*)'      exponent for leads-closure rate                         exld         = ', exld
853         WRITE(numout,*)'      coefficient for diffusions of ice and snow              hakdif       = ', hakdif
854         WRITE(numout,*)'      threshold thick. for comp. of eq. thermal conductivity  zhth         = ', thth 
855         WRITE(numout,*)'      thickness of the surf. layer in temp. computation       hnzst        = ', hnzst
856         WRITE(numout,*)'      switch for snow sublimation  (=1) or not (=0)           parsub       = ', parsub 
857         WRITE(numout,*)'      coefficient for snow density when snow ice formation    alphs        = ', alphs
858         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          betas        = ', betas
859         WRITE(numout,*)'      extinction radiation parameter in sea ice (1.0)         kappa_i      = ', kappa_i
860         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nconv_i_thd  = ', nconv_i_thd
861         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        maxer_i_thd  = ', maxer_i_thd
862         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     thcon_i_swi  = ', thcon_i_swi
863      ENDIF
864      !
865      rcdsn = hakdif * rcdsn 
866      rcdic = hakdif * rcdic
867      !
868   END SUBROUTINE lim_thd_init
869
870#else
871   !!----------------------------------------------------------------------
872   !!   Default option                               NO  LIM3 sea-ice model
873   !!----------------------------------------------------------------------
874CONTAINS
875   SUBROUTINE lim_thd         ! Empty routine
876   END SUBROUTINE lim_thd
877   SUBROUTINE lim_thd_con_dif
878   END SUBROUTINE lim_thd_con_dif
879#endif
880
881   !!======================================================================
882END MODULE limthd
Note: See TracBrowser for help on using the repository browser.