New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynadv_cen2.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/DYN/dynadv_cen2.F90 @ 2281

Last change on this file since 2281 was 2281, checked in by smasson, 14 years ago

set proper svn properties to all files...
  • Property svn:keywords set to Id
File size: 8.1 KB
Line 
1MODULE dynadv_cen2
2   !!======================================================================
3   !!                       ***  MODULE  dynadv  ***
4   !! Ocean dynamics: Update the momentum trend with the flux form advection
5   !!                 using a 2nd order centred scheme
6   !!======================================================================
7   !! History :  2.0  ! 2006-08  (G. Madec, S. Theetten)  Original code
8   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_adv_cen2       : flux form momentum advection (ln_dynadv_cen2=T)
13   !!                        trends using a 2nd order centred scheme 
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trdmod_oce     ! ocean variables trends
18   USE trdmod         ! ocean dynamics trends
19   USE in_out_manager ! I/O manager
20   USE prtctl         ! Print control
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   dyn_adv_cen2   ! routine called by step.F90
26
27   !! * Substitutions
28#  include "domzgr_substitute.h90"
29#  include "vectopt_loop_substitute.h90"
30   !!----------------------------------------------------------------------
31   !! NEMO/OPA 3.2 , LODYC-IPSL  (2009)
32   !! $Id$
33   !! Software governed by the CeCILL licence  (NEMOGCM/License_CeCILL.txt)
34   !!----------------------------------------------------------------------
35
36CONTAINS
37
38   SUBROUTINE dyn_adv_cen2( kt )
39      !!----------------------------------------------------------------------
40      !!                  ***  ROUTINE dyn_adv_cen2  ***
41      !!
42      !! ** Purpose :   Compute the now momentum advection trend in flux form
43      !!              and the general trend of the momentum equation.
44      !!
45      !! ** Method  :   Trend evaluated using now fields (centered in time)
46      !!
47      !! ** Action  :   (ua,va) updated with the now vorticity term trend
48      !!----------------------------------------------------------------------
49      USE oce, ONLY:   zfu => ta   ! use ta as 3D workspace
50      USE oce, ONLY:   zfv => sa   ! use sa as 3D workspace
51      !!
52      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
53      !!
54      INTEGER  ::   ji, jj, jk   ! dummy loop indices
55      REAL(wp) ::   zbu, zbv     ! temporary scalars
56      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zfu_t, zfu_f, zfu_uw   ! 3D workspace
57      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zfv_t, zfv_f, zfv_vw   !  -      -
58      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zfw                    !  -      -
59      !!----------------------------------------------------------------------
60
61      IF( kt == nit000 ) THEN
62         IF(lwp) WRITE(numout,*)
63         IF(lwp) WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection'
64         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
65      ENDIF
66
67      IF( l_trddyn ) THEN           ! Save ua and va trends
68         zfu_uw(:,:,:) = ua(:,:,:)
69         zfv_vw(:,:,:) = va(:,:,:)
70      ENDIF
71
72      !                                      ! ====================== !
73      !                                      !  Horizontal advection  !
74      DO jk = 1, jpkm1                       ! ====================== !
75         !                                         ! horizontal volume fluxes
76         zfu(:,:,jk) = 0.25 * e2u(:,:) * fse3u(:,:,jk) * un(:,:,jk)
77         zfv(:,:,jk) = 0.25 * e1v(:,:) * fse3v(:,:,jk) * vn(:,:,jk)
78         !
79         DO jj = 1, jpjm1                          ! horizontal momentum fluxes at T- and F-point
80            DO ji = 1, fs_jpim1   ! vector opt.
81               zfu_t(ji+1,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji+1,jj  ,jk) )
82               zfv_f(ji  ,jj  ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji  ,jj+1,jk) )
83               zfu_f(ji  ,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji+1,jj  ,jk) )
84               zfv_t(ji  ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji  ,jj+1,jk) )
85            END DO
86         END DO
87         DO jj = 2, jpjm1                          ! divergence of horizontal momentum fluxes
88            DO ji = fs_2, fs_jpim1   ! vector opt.
89               zbu = e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
90               zbv = e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
91               !
92               ua(ji,jj,jk) = ua(ji,jj,jk) - (  zfu_t(ji+1,jj  ,jk) - zfu_t(ji  ,jj  ,jk)    &
93                  &                           + zfv_f(ji  ,jj  ,jk) - zfv_f(ji  ,jj-1,jk)  ) / zbu
94               va(ji,jj,jk) = va(ji,jj,jk) - (  zfu_f(ji  ,jj  ,jk) - zfu_f(ji-1,jj  ,jk)    &
95                  &                           + zfv_t(ji  ,jj+1,jk) - zfv_t(ji  ,jj  ,jk)  ) / zbv
96            END DO
97         END DO
98      END DO
99      !
100      IF( l_trddyn ) THEN                          ! save the horizontal advection trend for diagnostic
101         zfu_uw(:,:,:) = ua(:,:,:) - zfu_uw(:,:,:)
102         zfv_vw(:,:,:) = va(:,:,:) - zfv_vw(:,:,:)
103         CALL trd_mod( zfu_uw, zfv_vw, jpdyn_trd_had, 'DYN', kt )
104         zfu_t(:,:,:) = ua(:,:,:)
105         zfv_t(:,:,:) = va(:,:,:)
106      ENDIF
107      !
108
109      !                                      ! ==================== !
110      !                                      !  Vertical advection  !
111      DO jk = 1, jpkm1                       ! ==================== !
112         !                                         ! Vertical volume fluxesÊ
113         zfw(:,:,jk) = 0.25 * e1t(:,:) * e2t(:,:) * wn(:,:,jk)
114         !
115         IF( jk == 1 ) THEN                        ! surface/bottom advective fluxes                   
116            zfu_uw(:,:,jpk) = 0.e0                      ! Bottom  value : flux set to zero
117            zfv_vw(:,:,jpk) = 0.e0
118            !                                           ! Surface value :
119            IF( lk_vvl ) THEN                                ! variable volume : flux set to zero
120               zfu_uw(:,:, 1 ) = 0.e0   
121               zfv_vw(:,:, 1 ) = 0.e0
122            ELSE                                             ! constant volume : advection through the surface
123               DO jj = 2, jpjm1
124                  DO ji = fs_2, fs_jpim1
125                     zfu_uw(ji,jj, 1 ) = 2.e0 * ( zfw(ji,jj,1) + zfw(ji+1,jj  ,1) ) * un(ji,jj,1)
126                     zfv_vw(ji,jj, 1 ) = 2.e0 * ( zfw(ji,jj,1) + zfw(ji  ,jj+1,1) ) * vn(ji,jj,1)
127                  END DO
128               END DO
129            ENDIF
130         ELSE                                      ! interior fluxes
131            DO jj = 2, jpjm1
132               DO ji = fs_2, fs_jpim1   ! vector opt.
133                  zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk)+ zfw(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji,jj,jk-1) )
134                  zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk)+ zfw(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji,jj,jk-1) )
135               END DO
136            END DO
137         ENDIF
138      END DO
139      DO jk = 1, jpkm1                             ! divergence of vertical momentum flux divergence
140         DO jj = 2, jpjm1 
141            DO ji = fs_2, fs_jpim1   ! vector opt.
142               ua(ji,jj,jk) =  ua(ji,jj,jk) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) )    &
143                  &  / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
144               va(ji,jj,jk) =  va(ji,jj,jk) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) )    &
145                  &  / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
146            END DO
147         END DO
148      END DO
149      !
150      IF( l_trddyn ) THEN                          ! save the vertical advection trend for diagnostic
151         zfu_t(:,:,:) = ua(:,:,:) - zfu_t(:,:,:)
152         zfv_t(:,:,:) = va(:,:,:) - zfv_t(:,:,:)
153         CALL trd_mod( zfu_t, zfv_t, jpdyn_trd_zad, 'DYN', kt )
154      ENDIF
155      !                                            ! Control print
156      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' cen2 adv - Ua: ', mask1=umask,   &
157         &                       tab3d_2=va, clinfo2=           ' Va: ', mask2=vmask, clinfo3='dyn' )
158      !
159   END SUBROUTINE dyn_adv_cen2
160
161   !!==============================================================================
162END MODULE dynadv_cen2
Note: See TracBrowser for help on using the repository browser.