New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iom_nf90.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/IOM/iom_nf90.F90 @ 2351

Last change on this file since 2351 was 2351, checked in by sga, 13 years ago

NEMO branch nemo_v3_3_beta
modify interpolation on the fly scheme within fldread.F90.
Instead of attempting to decide on cyclicity of input non-model grid by inspecting a longitude variable,
fld_read now expects to find an attribute in the input weights file to tell it how many columns overlap
at the east-west edges of the grid.
iom and iom_nf90.F90 have new routines to expose netcdf attributes to the model.
  • Property svn:keywords set to Id
File size: 30.8 KB
Line 
1MODULE iom_nf90
2   !!=====================================================================
3   !!                    ***  MODULE  iom_nf90 ***
4   !! Input/Output manager :  Library to read input files with NF90 (only fliocom module)
5   !!====================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!             "   ! 07 07  (D. Storkey) Changes to iom_nf90_gettime
9   !!--------------------------------------------------------------------
10   !!gm  caution add !DIR nec: improved performance to be checked as well as no result changes
11
12   !!--------------------------------------------------------------------
13   !!   iom_open       : open a file read only
14   !!   iom_close      : close a file or all files opened by iom
15   !!   iom_get        : read a field (interfaced to several routines)
16   !!   iom_gettime    : read the time axis kvid in the file
17   !!   iom_varid      : get the id of a variable in a file
18   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
19   !!--------------------------------------------------------------------
20   USE in_out_manager  ! I/O manager
21   USE dom_oce         ! ocean space and time domain
22   USE lbclnk          ! lateal boundary condition / mpp exchanges
23   USE iom_def         ! iom variables definitions
24   USE netcdf          ! NetCDF library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC iom_nf90_open, iom_nf90_close, iom_nf90_varid, iom_nf90_get, iom_nf90_gettime, iom_nf90_rstput
30   PUBLIC iom_nf90_getatt
31
32   INTERFACE iom_nf90_get
33      MODULE PROCEDURE iom_nf90_g0d, iom_nf90_g123d
34   END INTERFACE
35   INTERFACE iom_nf90_getatt
36      MODULE PROCEDURE iom_nf90_intatt
37   END INTERFACE
38   INTERFACE iom_nf90_rstput
39      MODULE PROCEDURE iom_nf90_rp0123d
40   END INTERFACE
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
43   !! $Id$
44   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46
47CONTAINS
48
49   SUBROUTINE iom_nf90_open( cdname, kiomid, ldwrt, ldok, kdompar )
50      !!---------------------------------------------------------------------
51      !!                   ***  SUBROUTINE  iom_open  ***
52      !!
53      !! ** Purpose : open an input file with NF90
54      !!---------------------------------------------------------------------
55      CHARACTER(len=*)       , INTENT(inout)           ::   cdname      ! File name
56      INTEGER                , INTENT(  out)           ::   kiomid      ! nf90 identifier of the opened file
57      LOGICAL                , INTENT(in   )           ::   ldwrt       ! read or write the file?
58      LOGICAL                , INTENT(in   )           ::   ldok        ! check the existence
59      INTEGER, DIMENSION(2,5), INTENT(in   ), OPTIONAL ::   kdompar     ! domain parameters:
60
61      CHARACTER(LEN=100) ::   clinfo           ! info character
62      CHARACTER(LEN=100) ::   cltmp            ! temporary character
63      INTEGER            ::   iln              ! lengths of character
64      INTEGER            ::   istop            ! temporary storage of nstop
65      INTEGER            ::   if90id           ! nf90 identifier of the opened file
66      INTEGER            ::   idmy             ! dummy variable
67      INTEGER            ::   jl               ! loop variable
68      INTEGER            ::   ichunk           ! temporary storage of nn_chunksz
69      INTEGER            ::   imode            ! creation mode flag: NF90_CLOBBER or NF90_NOCLOBBER
70      LOGICAL            ::   llclobber        ! local definition of ln_clobber
71      !---------------------------------------------------------------------
72
73      clinfo = '                    iom_nf90_open ~~~  '
74      istop = nstop   ! store the actual value of nstop
75      IF( nn_chunksz > 0 ) THEN   ;   ichunk = nn_chunksz
76      ELSE                        ;   ichunk = NF90_SIZEHINT_DEFAULT
77      ENDIF
78      !
79      llclobber = ldwrt .AND. ln_clobber
80      IF( ldok .AND. .NOT. llclobber ) THEN      ! Open existing file...
81         !                 ! =============
82         IF( ldwrt ) THEN  ! ... in write mode
83            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
84            CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id, chunksize = ichunk ), clinfo)
85            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                          ), clinfo)
86         ELSE              ! ... in read mode
87            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
88            CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_NOWRITE, if90id, chunksize = ichunk ), clinfo)
89         ENDIF
90      ELSE                                       ! the file does not exist (or we overwrite it)
91         !                 ! =============
92         iln = INDEX( cdname, '.nc' )
93         IF( ldwrt ) THEN  ! the file should be open in write mode so we create it...
94            IF( jpnij > 1 ) THEN
95               WRITE(cltmp,'(a,a,i4.4,a)') cdname(1:iln-1), '_', narea-1, '.nc'
96               cdname = TRIM(cltmp)
97            ENDIF
98            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in WRITE mode'
99
100            IF( llclobber ) THEN   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_CLOBBER   )
101            ELSE                   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_NOCLOBBER ) 
102            ENDIF
103            CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id, chunksize = ichunk ), clinfo)
104            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                     ), clinfo)
105            ! define dimensions
106            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'x', kdompar(1,1)  , idmy ), clinfo)
107            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'y', kdompar(2,1)  , idmy ), clinfo)
108            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'z', jpk           , idmy ), clinfo)
109            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 't', NF90_UNLIMITED, idmy ), clinfo)
110            ! global attributes
111            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij              ), clinfo)
112            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number'         , narea-1            ), clinfo)
113            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/1     , 2     /) ), clinfo)
114            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_global'    , (/jpiglo, jpjglo/) ), clinfo)
115            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_local'     , kdompar(:,1)       ), clinfo)
116            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_first' , kdompar(:,2)       ), clinfo)
117            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_last'  , kdompar(:,3)       ), clinfo)
118            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_start', kdompar(:,4)       ), clinfo)
119            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , kdompar(:,5)       ), clinfo)
120            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'              ), clinfo)
121         ELSE              ! the file should be open for read mode so it must exist...
122            CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
123         ENDIF
124      ENDIF
125      ! start to fill file informations
126      ! =============
127      IF( istop == nstop ) THEN   ! no error within this routine
128!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
129         kiomid = 0
130         DO jl = jpmax_files, 1, -1
131            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
132         ENDDO
133         iom_file(kiomid)%name   = TRIM(cdname)
134         iom_file(kiomid)%nfid   = if90id
135         iom_file(kiomid)%iolib  = jpnf90
136         iom_file(kiomid)%nvars  = 0
137         iom_file(kiomid)%irec   = -1   ! useless for NetCDF files, used to know if the file is in define mode
138         CALL iom_nf90_check(NF90_Inquire(if90id, unlimitedDimId = iom_file(kiomid)%iduld), clinfo)
139         IF ( iom_file(kiomid)%iduld .GE. 0 ) THEN
140           CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, iom_file(kiomid)%iduld,   &
141        &                                               name = iom_file(kiomid)%uldname), clinfo)
142         ENDIF
143         IF(lwp) WRITE(numout,*) '                   ---> '//TRIM(cdname)//' OK'
144      ELSE
145         kiomid = 0               ! return error flag
146      ENDIF
147      !
148   END SUBROUTINE iom_nf90_open
149
150
151   SUBROUTINE iom_nf90_close( kiomid )
152      !!--------------------------------------------------------------------
153      !!                   ***  SUBROUTINE  iom_nf90_close  ***
154      !!
155      !! ** Purpose : close an input file with NF90
156      !!--------------------------------------------------------------------
157      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
158      CHARACTER(LEN=100)  ::   clinfo   ! info character
159      !---------------------------------------------------------------------
160      !
161      clinfo = '      iom_nf90_close    , file: '//TRIM(iom_file(kiomid)%name)
162      CALL iom_nf90_check(NF90_CLOSE(iom_file(kiomid)%nfid), clinfo)
163      !   
164   END SUBROUTINE iom_nf90_close
165
166
167   FUNCTION iom_nf90_varid ( kiomid, cdvar, kiv, kdimsz ) 
168      !!-----------------------------------------------------------------------
169      !!                  ***  FUNCTION  iom_varid  ***
170      !!
171      !! ** Purpose : get the id of a variable in a file with NF90
172      !!-----------------------------------------------------------------------
173      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
174      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
175      INTEGER              , INTENT(in   )           ::   kiv   !
176      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of the dimensions
177      !
178      INTEGER                        ::   iom_nf90_varid   ! iom variable Id
179      INTEGER                        ::   if90id           ! nf90 file identifier
180      INTEGER                        ::   ji               ! dummy loop index
181      INTEGER                        ::   ivarid           ! NetCDF  variable Id
182      INTEGER                        ::   i_nvd            ! number of dimension of the variable
183      INTEGER, DIMENSION(jpmax_dims) ::   idimid           ! dimension ids of the variable
184      LOGICAL                        ::   llok             ! ok  test
185      CHARACTER(LEN=100)             ::   clinfo           ! info character
186      !!-----------------------------------------------------------------------
187      clinfo = '          iom_nf90_varid, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
188      iom_nf90_varid = 0                    ! default definition
189      IF( PRESENT(kdimsz) ) kdimsz(:) = 0   ! default definition
190      if90id = iom_file(kiomid)%nfid        ! get back NetCDF file id
191      !
192      llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! does the variable exist in the file
193      IF( llok ) THEN
194         iom_nf90_varid = kiv
195         iom_file(kiomid)%nvars       = kiv
196         iom_file(kiomid)%nvid(kiv)   = ivarid
197         iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
198         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, ndims = i_nvd), clinfo)   ! number of dimensions
199         iom_file(kiomid)%ndims(kiv)  = i_nvd
200         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, dimids = idimid(1:i_nvd)), clinfo)   ! dimensions ids
201         iom_file(kiomid)%luld(kiv) = .FALSE.   ! default value
202         DO ji = 1, i_nvd                       ! dimensions size
203            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, idimid(ji), len = iom_file(kiomid)%dimsz(ji,kiv)), clinfo)   
204            IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.   ! unlimited dimension?
205         END DO
206         !---------- Deal with scale_factor and add_offset
207         llok = NF90_Inquire_attribute(if90id, ivarid, 'scale_factor') == nf90_noerr
208         IF( llok) THEN
209            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'scale_factor', iom_file(kiomid)%scf(kiv)), clinfo)
210         ELSE
211            iom_file(kiomid)%scf(kiv) = 1.
212         END IF
213         llok = NF90_Inquire_attribute(if90id, ivarid, 'add_offset') == nf90_noerr
214         IF( llok ) THEN
215            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'add_offset', iom_file(kiomid)%ofs(kiv)), clinfo)
216         ELSE
217            iom_file(kiomid)%ofs(kiv) = 0.
218         END IF
219         ! return the simension size
220         IF( PRESENT(kdimsz) ) THEN
221            IF( i_nvd == SIZE(kdimsz) ) THEN
222               kdimsz(:) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
223            ELSE
224               WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
225               CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
226            ENDIF
227         ENDIF
228      ELSE 
229         iom_nf90_varid = -1   !   variable not found, return error code: -1
230      ENDIF
231      !
232   END FUNCTION iom_nf90_varid
233
234
235   SUBROUTINE iom_nf90_g0d( kiomid, kvid, pvar )
236      !!-----------------------------------------------------------------------
237      !!                  ***  ROUTINE  iom_nf90_g0d  ***
238      !!
239      !! ** Purpose : read a scalar with NF90
240      !!-----------------------------------------------------------------------
241      INTEGER , INTENT(in   ) ::   kiomid   ! Identifier of the file
242      INTEGER , INTENT(in   ) ::   kvid     ! variable id
243      REAL(wp), INTENT(  out) ::   pvar     ! read field
244      !
245      CHARACTER(LEN=100)      ::   clinfo   ! info character
246      !---------------------------------------------------------------------
247      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
248      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar), clinfo )
249      !
250   END SUBROUTINE iom_nf90_g0d
251
252
253   SUBROUTINE iom_nf90_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2,   &
254         &                    pv_r1d, pv_r2d, pv_r3d )
255      !!-----------------------------------------------------------------------
256      !!                  ***  ROUTINE  iom_nf90_g123d  ***
257      !!
258      !! ** Purpose : read a 1D/2D/3D variable with NF90
259      !!
260      !! ** Method : read ONE record at each CALL
261      !!-----------------------------------------------------------------------
262      INTEGER                    , INTENT(in   )           ::   kiomid    ! iom identifier of the file
263      INTEGER                    , INTENT(in   )           ::   kvid      ! Name of the variable
264      INTEGER                    , INTENT(in   )           ::   knbdim    ! number of dimensions of the variable
265      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart    ! start position of the reading in each axis
266      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount    ! number of points to be read in each axis
267      INTEGER ,                    INTENT(in   )           ::   kx1, kx2, ky1, ky2   ! subdomain indexes
268      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d    ! read field (1D case)
269      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d    ! read field (2D case)
270      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d    ! read field (3D case)
271      !
272      CHARACTER(LEN=100) ::   clinfo               ! info character
273      INTEGER            ::   if90id               ! nf90 identifier of the opened file
274      INTEGER            ::   ivid                 ! nf90 variable id
275      !---------------------------------------------------------------------
276      clinfo = 'iom_nf90_g123d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
277      if90id = iom_file(kiomid)%nfid         ! get back NetCDF file id
278      ivid   = iom_file(kiomid)%nvid(kvid)   ! get back NetCDF var id
279      !
280      IF(     PRESENT(pv_r1d) ) THEN
281         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r1d(:                ), start = kstart(1:knbdim),   &
282            &                                                                       count = kcount(1:knbdim)), clinfo )
283      ELSEIF( PRESENT(pv_r2d) ) THEN
284         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r2d(kx1:kx2,ky1:ky2  ), start = kstart(1:knbdim),   &
285            &                                                                       count = kcount(1:knbdim)), clinfo )
286      ELSEIF( PRESENT(pv_r3d) ) THEN
287         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim),   &
288            &                                                                       count = kcount(1:knbdim)), clinfo )
289      ENDIF
290      !
291   END SUBROUTINE iom_nf90_g123d
292
293
294   SUBROUTINE iom_nf90_intatt( kiomid, cdatt, pvar )
295      !!-----------------------------------------------------------------------
296      !!                  ***  ROUTINE  iom_nf90_intatt  ***
297      !!
298      !! ** Purpose : read an integer attribute with NF90
299      !!-----------------------------------------------------------------------
300      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
301      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
302      INTEGER         , INTENT(  out) ::   pvar     ! read field
303      !
304      INTEGER                         ::   if90id   ! temporary integer
305      LOGICAL                         ::   llok     ! temporary logical
306      CHARACTER(LEN=100)              ::   clinfo   ! info character
307      !---------------------------------------------------------------------
308      !
309      if90id = iom_file(kiomid)%nfid
310      llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
311      IF( llok) THEN
312         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', att: '//TRIM(cdatt)
313         CALL iom_nf90_check(NF90_GET_ATT(if90id, NF90_GLOBAL, cdatt, values=pvar), clinfo)
314      ELSE
315         CALL ctl_warn('iom_nf90_getatt: no attribute '//cdatt//' found')
316         pvar = -999
317      ENDIF
318      !
319   END SUBROUTINE iom_nf90_intatt
320
321
322   SUBROUTINE iom_nf90_gettime( kiomid, kvid, ptime, cdunits, cdcalendar )
323      !!--------------------------------------------------------------------
324      !!                   ***  SUBROUTINE iom_gettime  ***
325      !!
326      !! ** Purpose : read the time axis kvid in the file with NF90
327      !!--------------------------------------------------------------------
328      INTEGER                   , INTENT(in   ) ::   kiomid     ! file Identifier
329      INTEGER                   , INTENT(in   ) ::   kvid       ! variable id
330      REAL(wp), DIMENSION(:)    , INTENT(  out) ::   ptime      ! the time axis
331      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdunits    ! units attribute
332      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdcalendar ! calendar attribute
333      !
334      CHARACTER(LEN=100) ::   clinfo     ! info character
335      !---------------------------------------------------------------------
336      clinfo = 'iom_nf90_gettime, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
337      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), ptime(:),   &
338            &                           start=(/ 1 /), count=(/ iom_file(kiomid)%dimsz(1, kvid) /)), clinfo)
339      IF ( PRESENT(cdunits) ) THEN
340         CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "units", &
341            &                           values=cdunits), clinfo)
342      ENDIF
343      IF ( PRESENT(cdcalendar) ) THEN
344         CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "calendar", &
345            &                           values=cdcalendar), clinfo)
346      ENDIF
347      !
348   END SUBROUTINE iom_nf90_gettime
349
350
351   SUBROUTINE iom_nf90_rp0123d( kt, kwrite, kiomid, cdvar , kvid  , ktype,   &
352         &                               pv_r0d, pv_r1d, pv_r2d, pv_r3d )
353      !!--------------------------------------------------------------------
354      !!                   ***  SUBROUTINE  iom_nf90_rstput  ***
355      !!
356      !! ** Purpose : read the time axis cdvar in the file
357      !!--------------------------------------------------------------------
358      INTEGER                     , INTENT(in)           ::   kt       ! ocean time-step
359      INTEGER                     , INTENT(in)           ::   kwrite   ! writing time-step
360      INTEGER                     , INTENT(in)           ::   kiomid   ! Identifier of the file
361      CHARACTER(len=*)            , INTENT(in)           ::   cdvar    ! variable name
362      INTEGER                     , INTENT(in)           ::   kvid     ! variable id
363      INTEGER                     , INTENT(in), OPTIONAL ::   ktype    ! variable type (default R8)
364      REAL(wp)                    , INTENT(in), OPTIONAL ::   pv_r0d   ! written Od field
365      REAL(wp), DIMENSION(      :), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
366      REAL(wp), DIMENSION(:, :   ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
367      REAL(wp), DIMENSION(:, :, :), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
368      !
369      INTEGER               :: idims                ! number of dimension
370      INTEGER               :: idvar                ! variable id
371      INTEGER               :: jd                   ! dimension loop counter   
372      INTEGER               :: ix1, ix2, iy1, iy2   ! subdomain indexes   
373      INTEGER, DIMENSION(4) :: idimsz               ! dimensions size 
374      INTEGER, DIMENSION(4) :: idimid               ! dimensions id
375      CHARACTER(LEN=100)    :: clinfo               ! info character
376      CHARACTER(LEN= 12), DIMENSION(4) :: cltmp     ! temporary character
377      INTEGER               :: if90id               ! nf90 file identifier
378      INTEGER               :: idmy                 ! dummy variable
379      INTEGER               :: itype                ! variable type
380      !---------------------------------------------------------------------
381      !
382      clinfo = '          iom_nf90_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
383      if90id = iom_file(kiomid)%nfid
384      !
385      ! define dimension variables if it is not already done
386      ! ==========================
387      IF( iom_file(kiomid)%nvars == 0 ) THEN
388         ! are we in define mode?
389         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
390            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
391         ENDIF
392         ! define the dimension variables if it is not already done
393         cltmp = (/ 'nav_lon     ', 'nav_lat     ', 'nav_lev     ', 'time_counter' /)
394         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(1)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(1) ), clinfo)
395         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(2)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(2) ), clinfo)
396         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(3)), NF90_FLOAT , (/ 3    /), iom_file(kiomid)%nvid(3) ), clinfo)
397         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(4)), NF90_DOUBLE, (/ 4    /), iom_file(kiomid)%nvid(4) ), clinfo)
398         ! update informations structure related the dimension variable we just added...
399         iom_file(kiomid)%nvars       = 4
400         iom_file(kiomid)%luld(1:4)   = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
401         iom_file(kiomid)%cn_var(1:4) = cltmp
402         iom_file(kiomid)%ndims(1:4)  = (/ 2, 2, 1, 1 /) 
403         ! trick: defined to 0 to say that dimension variables are defined but not yet written
404         iom_file(kiomid)%dimsz(1, 1)  = 0   
405         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
406      ENDIF
407      ! define the data if it is not already done
408      ! ===============
409      IF( kvid <= 0 ) THEN
410         idvar = iom_file(kiomid)%nvars + 1
411         ! are we in define mode?
412         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
413            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
414         ENDIF
415         ! variable definition
416         IF(     PRESENT(pv_r0d) ) THEN   ;   idims = 0
417         ELSEIF( PRESENT(pv_r1d) ) THEN   ;   idims = 2   ;   idimid(1:idims) = (/    3,4/)
418         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   idims = 3   ;   idimid(1:idims) = (/1,2  ,4/)
419         ELSEIF( PRESENT(pv_r3d) ) THEN   ;   idims = 4   ;   idimid(1:idims) = (/1,2,3,4/)
420         ENDIF
421         IF( PRESENT(ktype) ) THEN   ! variable external type
422            SELECT CASE (ktype)
423            CASE (jp_r8)  ;   itype = NF90_DOUBLE
424            CASE (jp_r4)  ;   itype = NF90_FLOAT
425            CASE (jp_i4)  ;   itype = NF90_INT
426            CASE (jp_i2)  ;   itype = NF90_SHORT
427            CASE (jp_i1)  ;   itype = NF90_BYTE
428            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
429            END SELECT
430         ELSE
431            itype = NF90_DOUBLE
432         ENDIF
433         IF( PRESENT(pv_r0d) ) THEN
434            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype,                    &
435                 &                            iom_file(kiomid)%nvid(idvar) ), clinfo)
436         ELSE
437            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype, idimid(1:idims),   &
438                 &                            iom_file(kiomid)%nvid(idvar) ), clinfo)
439         ENDIF
440         ! update informations structure related the new variable we want to add...
441         iom_file(kiomid)%nvars         = idvar
442         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
443         iom_file(kiomid)%scf(idvar)    = 1.
444         iom_file(kiomid)%ofs(idvar)    = 0.
445         iom_file(kiomid)%ndims(idvar)  = idims
446         IF( .NOT. PRESENT(pv_r0d) ) THEN   ;   iom_file(kiomid)%luld(idvar) = .TRUE.
447         ELSE                               ;   iom_file(kiomid)%luld(idvar) = .FALSE.
448         ENDIF
449         DO jd = 1, idims
450            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, idimid(jd), len = iom_file(kiomid)%dimsz(jd,idvar) ), clinfo)
451         END DO
452         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
453      ELSE
454         idvar = kvid
455      ENDIF
456
457      ! time step kwrite : write the variable
458      IF( kt == kwrite ) THEN
459         ! are we in write mode?
460         IF( iom_file(kiomid)%irec == -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
461            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = 0
462         ENDIF
463         ! on what kind of domain must the data be written?
464         IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
465            idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
466            IF(     idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN
467               ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
468            ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN
469               ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
470            ELSEIF( idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN
471               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
472            ELSE
473               CALL ctl_stop( 'iom_nf90_rp0123d: should have been an impossible case...' )
474            ENDIF
475
476            ! write dimension variables if it is not already done
477            ! =============
478            ! trick: is defined to 0 => dimension variable are defined but not yet written
479            IF( iom_file(kiomid)%dimsz(1, 1) == 0 ) THEN
480               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lon'     , idmy ), clinfo)
481               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, glamt(ix1:ix2, iy1:iy2) ), clinfo)
482               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lat'     , idmy ), clinfo)
483               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, gphit(ix1:ix2, iy1:iy2) ), clinfo)
484               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lev'     , idmy ), clinfo)
485               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, gdept_0                 ), clinfo)
486               ! +++ WRONG VALUE: to be improved but not really useful...
487               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'time_counter', idmy ), clinfo)
488               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, kt                      ), clinfo)   
489               ! update the values of the variables dimensions size
490               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 1, len = iom_file(kiomid)%dimsz(1,1) ), clinfo)
491               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 2, len = iom_file(kiomid)%dimsz(2,1) ), clinfo)
492               iom_file(kiomid)%dimsz(1:2, 2) = iom_file(kiomid)%dimsz(1:2, 1)
493               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 3, len = iom_file(kiomid)%dimsz(1,3) ), clinfo)
494               iom_file(kiomid)%dimsz(1  , 4) = 1   ! unlimited dimension
495               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
496            ENDIF
497         ENDIF
498
499         ! write the data
500         ! =============
501         IF(     PRESENT(pv_r0d) ) THEN
502            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r0d                      ), clinfo)
503         ELSEIF( PRESENT(pv_r1d) ) THEN
504            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r1d(                  :) ), clinfo)
505         ELSEIF( PRESENT(pv_r2d) ) THEN
506            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r2d(ix1:ix2, iy1:iy2   ) ), clinfo)
507         ELSEIF( PRESENT(pv_r3d) ) THEN
508            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r3d(ix1:ix2, iy1:iy2, :) ), clinfo)
509         ENDIF
510         ! add 1 to the size of the temporal dimension (not really useful...)
511         IF( iom_file(kiomid)%luld(idvar) )   iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar)    &
512               &                            = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
513         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
514      ENDIF
515      !     
516   END SUBROUTINE iom_nf90_rp0123d
517
518
519   SUBROUTINE iom_nf90_check( kstatus, cdinfo )
520      !!--------------------------------------------------------------------
521      !!                   ***  SUBROUTINE iom_nf90_check  ***
522      !!
523      !! ** Purpose :   check nf90 errors
524      !!--------------------------------------------------------------------
525      INTEGER,          INTENT(in) :: kstatus
526      CHARACTER(LEN=*), INTENT(in) :: cdinfo
527      !---------------------------------------------------------------------
528      IF(kstatus /= nf90_noerr)   CALL ctl_stop( 'iom_nf90_check : '//TRIM(nf90_strerror(kstatus)), TRIM(cdinfo) )
529   END SUBROUTINE iom_nf90_check
530
531
532   !!======================================================================
533END MODULE iom_nf90
Note: See TracBrowser for help on using the repository browser.