| 1 | MODULE sbcice_lim_2 |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcice_lim_2 *** |
|---|
| 4 | !! Surface module : update surface ocean boundary condition over ice covered area using LIM sea-ice model |
|---|
| 5 | !! Sea-Ice model : LIM-2 Sea ice model time-stepping |
|---|
| 6 | !!====================================================================== |
|---|
| 7 | !! History : 1.0 ! 06-2006 (G. Madec) from icestp_2.F90 |
|---|
| 8 | !! 3.0 ! 08-2008 (S. Masson, E. .... ) coupled interface |
|---|
| 9 | !! 3.3 ! 05-2009 (G.Garric) addition of the lim2_evp case |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | #if defined key_lim2 |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | !! 'key_lim2' : LIM-2 sea-ice model |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! sbc_ice_lim_2 : sea-ice model time-stepping and update ocean sbc over ice-covered area |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and tracers |
|---|
| 18 | USE dom_oce ! ocean space and time domain |
|---|
| 19 | USE ice_2 |
|---|
| 20 | USE par_ice_2 |
|---|
| 21 | USE iceini_2 |
|---|
| 22 | USE dom_ice_2 |
|---|
| 23 | |
|---|
| 24 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 25 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 26 | USE sbcblk_core ! Surface boundary condition: CORE bulk |
|---|
| 27 | USE sbcblk_clio ! Surface boundary condition: CLIO bulk |
|---|
| 28 | USE sbccpl ! Surface boundary condition: coupled interface |
|---|
| 29 | USE albedo |
|---|
| 30 | |
|---|
| 31 | USE phycst ! Define parameters for the routines |
|---|
| 32 | USE eosbn2 ! equation of state |
|---|
| 33 | USE limdyn_2 |
|---|
| 34 | USE limtrp_2 |
|---|
| 35 | USE limdmp_2 |
|---|
| 36 | USE limthd_2 |
|---|
| 37 | USE limsbc_2 ! sea surface boundary condition |
|---|
| 38 | USE limdia_2 |
|---|
| 39 | USE limwri_2 |
|---|
| 40 | USE limrst_2 |
|---|
| 41 | |
|---|
| 42 | USE lbclnk ! lateral boundary condition - MPP link |
|---|
| 43 | USE lib_mpp ! MPP library |
|---|
| 44 | USE iom ! I/O manager library |
|---|
| 45 | USE in_out_manager ! I/O manager |
|---|
| 46 | USE prtctl ! Print control |
|---|
| 47 | |
|---|
| 48 | IMPLICIT NONE |
|---|
| 49 | PRIVATE |
|---|
| 50 | |
|---|
| 51 | PUBLIC sbc_ice_lim_2 ! routine called by sbcmod.F90 |
|---|
| 52 | |
|---|
| 53 | !! * Substitutions |
|---|
| 54 | # include "domzgr_substitute.h90" |
|---|
| 55 | # include "vectopt_loop_substitute.h90" |
|---|
| 56 | !!---------------------------------------------------------------------- |
|---|
| 57 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 58 | !! $Id$ |
|---|
| 59 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 60 | !!---------------------------------------------------------------------- |
|---|
| 61 | CONTAINS |
|---|
| 62 | |
|---|
| 63 | SUBROUTINE sbc_ice_lim_2( kt, ksbc ) |
|---|
| 64 | !!--------------------------------------------------------------------- |
|---|
| 65 | !! *** ROUTINE sbc_ice_lim_2 *** |
|---|
| 66 | !! |
|---|
| 67 | !! ** Purpose : update the ocean surface boundary condition via the |
|---|
| 68 | !! Louvain la Neuve Sea Ice Model time stepping |
|---|
| 69 | !! |
|---|
| 70 | !! ** Method : ice model time stepping |
|---|
| 71 | !! - call the ice dynamics routine |
|---|
| 72 | !! - call the ice advection/diffusion routine |
|---|
| 73 | !! - call the ice thermodynamics routine |
|---|
| 74 | !! - call the routine that computes mass and |
|---|
| 75 | !! heat fluxes at the ice/ocean interface |
|---|
| 76 | !! - save the outputs |
|---|
| 77 | !! - save the outputs for restart when necessary |
|---|
| 78 | !! |
|---|
| 79 | !! ** Action : - time evolution of the LIM sea-ice model |
|---|
| 80 | !! - update all sbc variables below sea-ice: |
|---|
| 81 | !! utau, vtau, taum, wndm, qns , qsr, emp , emps |
|---|
| 82 | !!--------------------------------------------------------------------- |
|---|
| 83 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 84 | INTEGER, INTENT(in) :: ksbc ! type of sbc ( =3 CLIO bulk ; =4 CORE bulk ; =5 coupled ) |
|---|
| 85 | !! |
|---|
| 86 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 87 | REAL(wp), DIMENSION(jpi,jpj,1) :: zalb_ice_os ! albedo of the ice under overcast sky |
|---|
| 88 | REAL(wp), DIMENSION(jpi,jpj,1) :: zalb_ice_cs ! albedo of ice under clear sky |
|---|
| 89 | REAL(wp), DIMENSION(jpi,jpj,1) :: zsist ! surface ice temperature (K) |
|---|
| 90 | !!---------------------------------------------------------------------- |
|---|
| 91 | |
|---|
| 92 | IF( kt == nit000 ) THEN |
|---|
| 93 | IF(lwp) WRITE(numout,*) |
|---|
| 94 | IF(lwp) WRITE(numout,*) 'sbc_ice_lim_2 : update ocean surface boudary condition' |
|---|
| 95 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~ via Louvain la Neuve Ice Model (LIM) time stepping' |
|---|
| 96 | ! |
|---|
| 97 | CALL ice_init_2 |
|---|
| 98 | ENDIF |
|---|
| 99 | |
|---|
| 100 | ! !----------------------! |
|---|
| 101 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN ! Ice time-step only ! |
|---|
| 102 | ! !----------------------! |
|---|
| 103 | ! Bulk Formulea ! |
|---|
| 104 | !----------------! |
|---|
| 105 | ! ... mean surface ocean current at ice dynamics point |
|---|
| 106 | SELECT CASE( cp_ice_msh ) |
|---|
| 107 | CASE( 'I' ) !== B-grid ice dynamics : I-point (i.e. F-point with sea-ice indexation) |
|---|
| 108 | DO jj = 2, jpj |
|---|
| 109 | DO ji = 2, jpi ! NO vector opt. possible |
|---|
| 110 | u_oce(ji,jj) = 0.5_wp * ( ssu_m(ji-1,jj ) + ssu_m(ji-1,jj-1) ) * tmu(ji,jj) |
|---|
| 111 | v_oce(ji,jj) = 0.5_wp * ( ssv_m(ji ,jj-1) + ssv_m(ji-1,jj-1) ) * tmu(ji,jj) |
|---|
| 112 | END DO |
|---|
| 113 | END DO |
|---|
| 114 | CALL lbc_lnk( u_oce, 'I', -1. ) ! I-point (i.e. F-point with ice indices) |
|---|
| 115 | CALL lbc_lnk( v_oce, 'I', -1. ) ! I-point (i.e. F-point with ice indices) |
|---|
| 116 | ! |
|---|
| 117 | CASE( 'C' ) !== C-grid ice dynamics : U & V-points (same as ocean) |
|---|
| 118 | u_oce(:,:) = ssu_m(:,:) ! mean surface ocean current at ice velocity point |
|---|
| 119 | v_oce(:,:) = ssv_m(:,:) |
|---|
| 120 | ! |
|---|
| 121 | END SELECT |
|---|
| 122 | |
|---|
| 123 | ! ... masked sea surface freezing temperature [Kelvin] (set to rt0 over land) |
|---|
| 124 | tfu(:,:) = tfreez( sss_m ) + rt0 |
|---|
| 125 | |
|---|
| 126 | zsist (:,:,1) = sist (:,:) + rt0 * ( 1. - tmask(:,:,1) ) |
|---|
| 127 | |
|---|
| 128 | ! ... ice albedo (clear sky and overcast sky) |
|---|
| 129 | CALL albedo_ice( zsist, reshape( hicif, (/jpi,jpj,1/) ), reshape( hsnif, (/jpi,jpj,1/) ), zalb_ice_cs, zalb_ice_os ) |
|---|
| 130 | |
|---|
| 131 | ! ... Sea-ice surface boundary conditions output from bulk formulae : |
|---|
| 132 | ! - utau_ice ! surface ice stress i-component (I-point) [N/m2] |
|---|
| 133 | ! - vtau_ice ! surface ice stress j-component (I-point) [N/m2] |
|---|
| 134 | ! - qns_ice ! non solar heat flux over ice (T-point) [W/m2] |
|---|
| 135 | ! - qsr_ice ! solar heat flux over ice (T-point) [W/m2] |
|---|
| 136 | ! - qla_ice ! latent heat flux over ice (T-point) [W/m2] |
|---|
| 137 | ! - dqns_ice ! non solar heat sensistivity (T-point) [W/m2] |
|---|
| 138 | ! - dqla_ice ! latent heat sensistivity (T-point) [W/m2] |
|---|
| 139 | ! - tprecip ! total precipitation (T-point) [Kg/m2/s] |
|---|
| 140 | ! - sprecip ! solid precipitation (T-point) [Kg/m2/s] |
|---|
| 141 | ! - fr1_i0 ! 1sr fraction of qsr penetration in ice [%] |
|---|
| 142 | ! - fr2_i0 ! 2nd fraction of qsr penetration in ice [%] |
|---|
| 143 | ! |
|---|
| 144 | SELECT CASE( ksbc ) |
|---|
| 145 | CASE( 3 ) ! CLIO bulk formulation |
|---|
| 146 | CALL blk_ice_clio( zsist, zalb_ice_cs, zalb_ice_os, & |
|---|
| 147 | & utau_ice , vtau_ice , qns_ice , qsr_ice, & |
|---|
| 148 | & qla_ice , dqns_ice , dqla_ice , & |
|---|
| 149 | & tprecip , sprecip , & |
|---|
| 150 | & fr1_i0 , fr2_i0 , cp_ice_msh , jpl ) |
|---|
| 151 | |
|---|
| 152 | CASE( 4 ) ! CORE bulk formulation |
|---|
| 153 | CALL blk_ice_core( zsist, u_ice , v_ice , zalb_ice_cs, & |
|---|
| 154 | & utau_ice , vtau_ice , qns_ice , qsr_ice, & |
|---|
| 155 | & qla_ice , dqns_ice , dqla_ice , & |
|---|
| 156 | & tprecip , sprecip , & |
|---|
| 157 | & fr1_i0 , fr2_i0 , cp_ice_msh , jpl ) |
|---|
| 158 | CASE( 5 ) ! Coupled formulation : atmosphere-ice stress only (fluxes provided after ice dynamics) |
|---|
| 159 | CALL sbc_cpl_ice_tau( utau_ice , vtau_ice ) |
|---|
| 160 | END SELECT |
|---|
| 161 | |
|---|
| 162 | CALL iom_put( 'utau_ice', utau_ice ) ! Wind stress over ice along i-axis at I-point |
|---|
| 163 | CALL iom_put( 'vtau_ice', vtau_ice ) ! Wind stress over ice along j-axis at I-point |
|---|
| 164 | |
|---|
| 165 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 166 | CALL prt_ctl_info( 'Ice Forcings ' ) |
|---|
| 167 | CALL prt_ctl( tab2d_1=tprecip ,clinfo1=' sbc_ice_lim: precip : ', tab2d_2=sprecip , clinfo2=' Snow : ' ) |
|---|
| 168 | CALL prt_ctl( tab2d_1=utau_ice,clinfo1=' sbc_ice_lim: utau_ice: ', tab2d_2=vtau_ice, clinfo2=' vtau_ice: ' ) |
|---|
| 169 | CALL prt_ctl( tab2d_1=sst_m ,clinfo1=' sbc_ice_lim: sst : ', tab2d_2=sss_m , clinfo2=' sss : ' ) |
|---|
| 170 | CALL prt_ctl( tab2d_1=u_oce ,clinfo1=' sbc_ice_lim: u_io : ', tab2d_2=v_oce , clinfo2=' v_io : ' ) |
|---|
| 171 | CALL prt_ctl( tab2d_1=hsnif ,clinfo1=' sbc_ice_lim: hsnif 1: ', tab2d_2=hicif , clinfo2=' hicif : ' ) |
|---|
| 172 | CALL prt_ctl( tab2d_1=frld ,clinfo1=' sbc_ice_lim: frld 1: ', tab2d_2=sist , clinfo2=' sist : ' ) |
|---|
| 173 | ENDIF |
|---|
| 174 | |
|---|
| 175 | ! ---------------- ! |
|---|
| 176 | ! Ice model step ! |
|---|
| 177 | ! ---------------- ! |
|---|
| 178 | numit = numit + nn_fsbc ! Ice model time step |
|---|
| 179 | |
|---|
| 180 | CALL lim_rst_opn_2 ( kt ) ! Open Ice restart file |
|---|
| 181 | #if ! defined key_c1d |
|---|
| 182 | ! Ice dynamics & transport (except in 1D case) |
|---|
| 183 | CALL lim_dyn_2 ( kt ) ! Ice dynamics ( rheology/dynamics ) |
|---|
| 184 | CALL lim_trp_2 ( kt ) ! Ice transport ( Advection/diffusion ) |
|---|
| 185 | IF( ln_limdmp ) CALL lim_dmp_2 ( kt ) ! Ice damping |
|---|
| 186 | #endif |
|---|
| 187 | #if defined key_coupled |
|---|
| 188 | ! ! Ice surface fluxes in coupled mode |
|---|
| 189 | IF( ksbc == 5 ) CALL sbc_cpl_ice_flx( reshape( frld, (/jpi,jpj,1/) ), & |
|---|
| 190 | & qns_tot, qns_ice, qsr_tot , qsr_ice, & |
|---|
| 191 | & emp_tot, emp_ice, dqns_ice, sprecip, & |
|---|
| 192 | ! optional arguments, used only in 'mixed oce-ice' case |
|---|
| 193 | & palbi = zalb_ice_cs, psst = sst_m, pist = sist ) |
|---|
| 194 | #endif |
|---|
| 195 | CALL lim_thd_2 ( kt ) ! Ice thermodynamics |
|---|
| 196 | CALL lim_sbc_flx_2 ( kt ) ! update surface ocean mass, heat & salt fluxes |
|---|
| 197 | |
|---|
| 198 | IF( ( MOD( kt+nn_fsbc-1, ninfo ) == 0 .OR. ntmoy == 1 ) .AND. .NOT. lk_mpp ) & |
|---|
| 199 | & CALL lim_dia_2 ( kt ) ! Ice Diagnostics |
|---|
| 200 | # if ! defined key_iomput |
|---|
| 201 | CALL lim_wri_2 ( kt ) ! Ice outputs |
|---|
| 202 | # endif |
|---|
| 203 | IF( lrst_ice ) CALL lim_rst_write_2( kt ) ! Ice restart file |
|---|
| 204 | ! |
|---|
| 205 | ENDIF ! End sea-ice time step only |
|---|
| 206 | ! |
|---|
| 207 | ! !--------------------------! |
|---|
| 208 | ! ! at all ocean time step ! |
|---|
| 209 | ! !--------------------------! |
|---|
| 210 | ! |
|---|
| 211 | ! ! Update surface ocean stresses (only in ice-dynamic case) |
|---|
| 212 | ! ! otherwise the atm.-ocean stresses are used everywhere |
|---|
| 213 | IF( ln_limdyn ) CALL lim_sbc_tau_2( kt, ub(:,:,1), vb(:,:,1) ) ! using before instantaneous surf. currents |
|---|
| 214 | ! |
|---|
| 215 | END SUBROUTINE sbc_ice_lim_2 |
|---|
| 216 | |
|---|
| 217 | #else |
|---|
| 218 | !!---------------------------------------------------------------------- |
|---|
| 219 | !! Default option Dummy module NO LIM 2.0 sea-ice model |
|---|
| 220 | !!---------------------------------------------------------------------- |
|---|
| 221 | CONTAINS |
|---|
| 222 | SUBROUTINE sbc_ice_lim_2 ( kt, ksbc ) ! Dummy routine |
|---|
| 223 | WRITE(*,*) 'sbc_ice_lim_2: You should not have seen this print! error?', kt, ksbc |
|---|
| 224 | END SUBROUTINE sbc_ice_lim_2 |
|---|
| 225 | #endif |
|---|
| 226 | |
|---|
| 227 | !!====================================================================== |
|---|
| 228 | END MODULE sbcice_lim_2 |
|---|
