New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 2396

Last change on this file since 2396 was 2396, checked in by cbricaud, 13 years ago

add modifications for atmopheric pressure forcing
  • Property svn:keywords set to Id
File size: 9.5 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0   !  06-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssm        : calculate sea surface mean currents, temperature, 
12   !!                    and salinity over nn_fsbc time-step
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE sbc_oce         ! Surface boundary condition: ocean fields
17   USE sbc_oce         ! surface boundary condition: ocean fields
18   USE sbcapr          ! surface boundary condition: atmospheric pressure
19   USE prtctl          ! Print control                    (prt_ctl routine)
20   USE restart         ! ocean restart
21   USE iom
22   USE in_out_manager  ! I/O manager
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   sbc_ssm    ! routine called by step.F90
28   
29   !! * Substitutions
30#  include "domzgr_substitute.h90"
31   !!----------------------------------------------------------------------
32   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
33   !! $Id$
34   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
35   !!----------------------------------------------------------------------
36
37CONTAINS
38
39   SUBROUTINE sbc_ssm( kt )
40      !!---------------------------------------------------------------------
41      !!                     ***  ROUTINE sbc_oce  ***
42      !!                     
43      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
44      !!                condition computation
45      !!               
46      !! ** Method  :   compute mean surface velocity (2 components at U and
47      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
48      !!      the periode (kt - nn_fsbc) to kt
49      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
50      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
51      !!---------------------------------------------------------------------
52      INTEGER, INTENT(in) ::   kt        ! ocean time step
53      !
54      REAL(wp) ::   zcoef       ! temporary scalar
55      REAL(wp) ::   zf_sbc      ! read sbc frequency
56      !!---------------------------------------------------------------------
57      !                                                   ! ---------------------------------------- !
58      IF( nn_fsbc == 1 ) THEN                             !      Instantaneous surface fields        !
59         !                                                ! ---------------------------------------- !
60         IF( kt == nit000 ) THEN
61            IF(lwp) WRITE(numout,*)
62            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
63            IF(lwp) WRITE(numout,*) '~~~~~~~ '
64         ENDIF
65         !
66         ssu_m(:,:) = ub(:,:,1)
67         ssv_m(:,:) = vb(:,:,1)
68         sst_m(:,:) = tn(:,:,1)
69         sss_m(:,:) = sn(:,:,1)
70         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
71         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
72         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
73         ENDIF
74
75         !
76      ELSE
77         !                                                ! ---------------------------------------- !
78         IF( kt == nit000) THEN                           !       Initialisation: 1st time-step      !
79            !                                             ! ---------------------------------------- !
80            IF(lwp) WRITE(numout,*)
81            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
82            !
83            IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
84               CALL iom_get( numror               , 'nn_fsbc', zf_sbc )   ! sbc frequency of previous run
85               CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )   ! sea surface mean velocity    (T-point)
86               CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )   !   "         "    velocity    (V-point)
87               CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )   !   "         "    temperature (T-point)
88               CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )   !   "         "    salinity    (T-point)
89               CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )   !   "         "    height      (T-point)
90               !
91               IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
92                  IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
93                     &                    'from ', zf_sbc, ' to ', nn_fsbc
94                  zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc
95                  ssu_m(:,:) = zcoef * ssu_m(:,:)
96                  ssv_m(:,:) = zcoef * ssv_m(:,:)
97                  sst_m(:,:) = zcoef * sst_m(:,:)
98                  sss_m(:,:) = zcoef * sss_m(:,:)
99                  ssh_m(:,:) = zcoef * ssh_m(:,:)
100               ELSE
101                  IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
102               ENDIF
103            ELSE
104               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
105               zcoef = REAL( nn_fsbc - 1, wp )
106               ssu_m(:,:) = zcoef * ub(:,:,1)
107               ssv_m(:,:) = zcoef * vb(:,:,1)
108               sst_m(:,:) = zcoef * tn(:,:,1)
109               sss_m(:,:) = zcoef * sn(:,:,1)
110               !                          ! removed inverse barometer ssh when Patm forcing is used
111               IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
112               ELSE                    ;   ssh_m(:,:) = zcoef *   sshn(:,:)
113               ENDIF
114
115            ENDIF
116            !                                             ! ---------------------------------------- !
117         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
118            !                                             ! ---------------------------------------- !
119            ssu_m(:,:) = 0.e0      ! reset to zero ocean mean sbc fields
120            ssv_m(:,:) = 0.e0
121            sst_m(:,:) = 0.e0
122            sss_m(:,:) = 0.e0
123            ssh_m(:,:) = 0.e0
124         ENDIF
125         !                                                ! ---------------------------------------- !
126         !                                                !        Cumulate at each time step        !
127         !                                                ! ---------------------------------------- !
128         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
129         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
130         sst_m(:,:) = sst_m(:,:) + tn(:,:,1)
131         sss_m(:,:) = sss_m(:,:) + sn(:,:,1)
132         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
133         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 *  ( ssh_ib(:,:) + ssh_ibb(:,:) )
134         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
135         ENDIF
136
137         !                                                ! ---------------------------------------- !
138         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
139            !                                             ! ---------------------------------------- !
140            zcoef = 1. / REAL( nn_fsbc, wp )
141            sst_m(:,:) = sst_m(:,:) * zcoef           ! mean SST             [Celcius]
142            sss_m(:,:) = sss_m(:,:) * zcoef           ! mean SSS             [psu]
143            ssu_m(:,:) = ssu_m(:,:) * zcoef           ! mean suface current  [m/s]
144            ssv_m(:,:) = ssv_m(:,:) * zcoef           !
145            ssh_m(:,:) = ssh_m(:,:) * zcoef           ! mean SSH             [m]
146            !
147         ENDIF
148         !                                                ! ---------------------------------------- !
149         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
150            !                                             ! ---------------------------------------- !
151            IF(lwp) WRITE(numout,*)
152            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
153               &                    'at it= ', kt,' date= ', ndastp
154            IF(lwp) WRITE(numout,*) '~~~~~~~'
155            zf_sbc = REAL( nn_fsbc, wp )
156            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
157            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
158            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
159            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
160            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
161            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
162            !
163         ENDIF
164         !
165      ENDIF
166      !
167   END SUBROUTINE sbc_ssm
168
169   !!======================================================================
170END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.