New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_lap.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_lap.F90 @ 2330

Last change on this file since 2330 was 2287, checked in by smasson, 14 years ago

update licence of all NEMO files...
  • Property svn:keywords set to Id
File size: 7.6 KB
Line 
1MODULE traldf_lap
2   !!==============================================================================
3   !!                       ***  MODULE  traldf_lap  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6   !! History :  OPA  !  87-06  (P. Andrich, D. L Hostis)  Original code
7   !!                 !  91-11  (G. Madec)
8   !!                 !  95-11  (G. Madec)  suppress volumetric scale factors
9   !!                 !  96-01  (G. Madec)  statement function for e3
10   !!            NEMO !  02-06  (G. Madec)  F90: Free form and module
11   !!            1.0  !  04-08  (C. Talandier) New trends organization
12   !!                 !  05-11  (G. Madec)  add zps case
13   !!            3.0  !  10-06  (C. Ethe, G. Madec) Merge TRA-TRC
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   tra_ldf_lap  : update the tracer trend with the horizontal diffusion
18   !!                 using a iso-level harmonic (laplacien) operator.
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and active tracers
21   USE dom_oce         ! ocean space and time domain
22   USE ldftra_oce      ! ocean active tracers: lateral physics
23   USE in_out_manager  ! I/O manager
24   USE diaptr          ! poleward transport diagnostics
25   USE trc_oce         ! share passive tracers/Ocean variables
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   tra_ldf_lap   ! routine called by step.F90
31
32   REAL(wp), DIMENSION(jpi,jpj) ::   e1ur, e2vr   ! scale factor coefficients
33
34   !! * Substitutions
35#  include "domzgr_substitute.h90"
36#  include "ldftra_substitute.h90"
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
40   !! $Id$
41   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43   
44CONTAINS
45
46   SUBROUTINE tra_ldf_lap( kt, cdtype, pgu, pgv,   &
47      &                                ptb, pta, kjpt ) 
48      !!----------------------------------------------------------------------
49      !!                  ***  ROUTINE tra_ldf_lap  ***
50      !!                   
51      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
52      !!      trend and add it to the general trend of tracer equation.
53      !!
54      !! ** Method  :   Second order diffusive operator evaluated using before
55      !!      fields (forward time scheme). The horizontal diffusive trends of
56      !!      the tracer is given by:
57      !!          difft = 1/(e1t*e2t*e3t) {  di-1[ aht e2u*e3u/e1u di(tb) ]
58      !!                                   + dj-1[ aht e1v*e3v/e2v dj(tb) ] }
59      !!      Add this trend to the general tracer trend pta :
60      !!          pta = pta + difft
61      !!
62      !! ** Action  : - Update pta arrays with the before iso-level
63      !!                harmonic mixing trend.
64      !!----------------------------------------------------------------------
65      USE oce         , ztu => ua   ! use ua as workspace
66      USE oce         , ztv => va   ! use va as workspace
67      !!
68      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
69      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
70      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
71      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
72      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
73      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
74      !!
75      INTEGER  ::   ji, jj, jk, jn       ! dummy loop indices
76      INTEGER  ::   iku, ikv             ! local integers
77      REAL(wp) ::   zabe1, zabe2, zbtr   ! local scalars
78      !!----------------------------------------------------------------------
79     
80      IF( kt == nit000 )  THEN
81         IF(lwp) WRITE(numout,*)
82         IF(lwp) WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion on ', cdtype
83         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
84         e1ur(:,:) = e2u(:,:) / e1u(:,:)
85         e2vr(:,:) = e1v(:,:) / e2v(:,:)
86      ENDIF
87
88      !                                                          ! =========== !
89      DO jn = 1, kjpt                                            ! tracer loop !
90         !                                                       ! =========== !   
91         DO jk = 1, jpkm1                                            ! slab loop
92            !                                           
93            ! 1. First derivative (gradient)
94            ! -------------------
95            DO jj = 1, jpjm1
96               DO ji = 1, fs_jpim1   ! vector opt.
97                  zabe1 = fsahtu(ji,jj,jk) * umask(ji,jj,jk) * e1ur(ji,jj) * fse3u(ji,jj,jk)
98                  zabe2 = fsahtv(ji,jj,jk) * vmask(ji,jj,jk) * e2vr(ji,jj) * fse3v(ji,jj,jk)
99                  ztu(ji,jj,jk) = zabe1 * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
100                  ztv(ji,jj,jk) = zabe2 * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
101               END DO
102            END DO
103            IF( ln_zps ) THEN      ! set gradient at partial step level
104               DO jj = 1, jpjm1
105                  DO ji = 1, fs_jpim1   ! vector opt.
106                     ! last level
107                     iku = MIN ( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
108                     ikv = MIN ( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
109                     IF( iku == jk ) THEN
110                        zabe1 = fsahtu(ji,jj,iku) * umask(ji,jj,iku) * e1ur(ji,jj) * fse3u(ji,jj,iku)
111                        ztu(ji,jj,jk) = zabe1 * pgu(ji,jj,jn)
112                     ENDIF
113                     IF( ikv == jk ) THEN
114                        zabe2 = fsahtv(ji,jj,ikv) * vmask(ji,jj,ikv) * e2vr(ji,jj) * fse3v(ji,jj,ikv)
115                        ztv(ji,jj,jk) = zabe2 * pgv(ji,jj,jn)
116                     ENDIF
117                  END DO
118               END DO
119            ENDIF
120         
121         
122            ! 2. Second derivative (divergence) added to the general tracer trends
123            ! ---------------------------------------------------------------------
124            DO jj = 2, jpjm1
125               DO ji = fs_2, fs_jpim1   ! vector opt.
126                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
127                  ! horizontal diffusive trends added to the general tracer trends
128                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk)   &
129                     &                                          + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
130               END DO
131            END DO
132            !
133         END DO                                             !  End of slab 
134         !
135         ! "Poleward" diffusive heat or salt transports
136         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
137            IF( jn  == jp_tem)   pht_ldf(:) = ptr_vj( ztv(:,:,:) )
138            IF( jn  == jp_sal)   pst_ldf(:) = ptr_vj( ztv(:,:,:) )
139         ENDIF
140         !                                                  ! ==================
141      END DO                                                ! end of tracer loop
142      !                                                     ! ==================
143   END SUBROUTINE tra_ldf_lap
144
145   !!==============================================================================
146END MODULE traldf_lap
Note: See TracBrowser for help on using the repository browser.