1 | MODULE nemogcm |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE nemogcm *** |
---|
4 | !! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice) |
---|
5 | !!====================================================================== |
---|
6 | !! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code |
---|
7 | !! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec) |
---|
8 | !! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar, |
---|
9 | !! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1 |
---|
10 | !! - ! 1992-06 (L.Terray) coupling implementation |
---|
11 | !! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice |
---|
12 | !! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar, |
---|
13 | !! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0 |
---|
14 | !! 8.1 ! 1997-06 (M. Imbard, G. Madec) |
---|
15 | !! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model |
---|
16 | !! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP |
---|
17 | !! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER) |
---|
18 | !! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules |
---|
19 | !! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces |
---|
20 | !! - ! 2004-08 (C. Talandier) New trends organization |
---|
21 | !! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility |
---|
22 | !! - ! 2005-11 (V. Garnier) Surface pressure gradient organization |
---|
23 | !! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation |
---|
24 | !! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization |
---|
25 | !! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY) |
---|
26 | !! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp |
---|
27 | !! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
---|
28 | !! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
---|
29 | !!---------------------------------------------------------------------- |
---|
30 | |
---|
31 | !!---------------------------------------------------------------------- |
---|
32 | !! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice |
---|
33 | !! nemo_init : initialization of the NEMO system |
---|
34 | !! nemo_ctl : initialisation of the contol print |
---|
35 | !! nemo_closefile : close remaining open files |
---|
36 | !!---------------------------------------------------------------------- |
---|
37 | USE step_oce ! module used in the ocean time stepping module |
---|
38 | USE sbc_oce ! surface boundary condition: ocean |
---|
39 | USE cla ! cross land advection (tra_cla routine) |
---|
40 | USE domcfg ! domain configuration (dom_cfg routine) |
---|
41 | USE mppini ! shared/distributed memory setting (mpp_init routine) |
---|
42 | USE domain ! domain initialization (dom_init routine) |
---|
43 | USE obcini ! open boundary cond. initialization (obc_ini routine) |
---|
44 | USE bdyini ! unstructured open boundary cond. initialization (bdy_init routine) |
---|
45 | USE istate ! initial state setting (istate_init routine) |
---|
46 | USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine) |
---|
47 | USE ldftra ! lateral diffusivity setting (ldftra_init routine) |
---|
48 | USE zdfini ! vertical physics setting (zdf_init routine) |
---|
49 | USE phycst ! physical constant (par_cst routine) |
---|
50 | USE trdmod ! momentum/tracers trends (trd_mod_init routine) |
---|
51 | USE asminc ! assimilation increments (asm_inc_init routine) |
---|
52 | USE asmtrj ! writing out state trajectory |
---|
53 | USE sshwzv ! vertical velocity used in asm |
---|
54 | USE diaptr ! poleward transports (dia_ptr_init routine) |
---|
55 | USE diaobs ! Observation diagnostics (dia_obs_init routine) |
---|
56 | USE step ! NEMO time-stepping (stp routine) |
---|
57 | #if defined key_oasis3 |
---|
58 | USE cpl_oasis3 ! OASIS3 coupling |
---|
59 | #elif defined key_oasis4 |
---|
60 | USE cpl_oasis4 ! OASIS4 coupling (not working) |
---|
61 | #endif |
---|
62 | USE c1d ! 1D configuration |
---|
63 | USE step_c1d ! Time stepping loop for the 1D configuration |
---|
64 | #if defined key_top |
---|
65 | USE trcini ! passive tracer initialisation |
---|
66 | #endif |
---|
67 | USE lib_mpp ! distributed memory computing |
---|
68 | #if defined key_iomput |
---|
69 | USE mod_ioclient |
---|
70 | #endif |
---|
71 | |
---|
72 | PRIVATE |
---|
73 | |
---|
74 | PUBLIC nemo_gcm ! called by model.F90 |
---|
75 | PUBLIC nemo_init ! needed by AGRIF |
---|
76 | |
---|
77 | CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing |
---|
78 | |
---|
79 | !!---------------------------------------------------------------------- |
---|
80 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
---|
81 | !! $Id$ |
---|
82 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
83 | !!---------------------------------------------------------------------- |
---|
84 | CONTAINS |
---|
85 | |
---|
86 | SUBROUTINE nemo_gcm |
---|
87 | !!---------------------------------------------------------------------- |
---|
88 | !! *** ROUTINE nemo_gcm *** |
---|
89 | !! |
---|
90 | !! ** Purpose : NEMO solves the primitive equations on an orthogonal |
---|
91 | !! curvilinear mesh on the sphere. |
---|
92 | !! |
---|
93 | !! ** Method : - model general initialization |
---|
94 | !! - launch the time-stepping (stp routine) |
---|
95 | !! - finalize the run by closing files and communications |
---|
96 | !! |
---|
97 | !! References : Madec, Delecluse,Imbard, and Levy, 1997: internal report, IPSL. |
---|
98 | !! Madec, 2008, internal report, IPSL. |
---|
99 | !!---------------------------------------------------------------------- |
---|
100 | INTEGER :: istp ! time step index |
---|
101 | !!---------------------------------------------------------------------- |
---|
102 | ! |
---|
103 | #if defined key_agrif |
---|
104 | CALL Agrif_Init_Grids() ! AGRIF: set the meshes |
---|
105 | #endif |
---|
106 | |
---|
107 | ! !-----------------------! |
---|
108 | CALL nemo_init !== Initialisations ==! |
---|
109 | ! !-----------------------! |
---|
110 | |
---|
111 | ! check that all process are still there... If some process have an error, |
---|
112 | ! they will never enter in step and other processes will wait until the end of the cpu time! |
---|
113 | IF( lk_mpp ) CALL mpp_max( nstop ) |
---|
114 | |
---|
115 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
---|
116 | |
---|
117 | ! !-----------------------! |
---|
118 | ! !== time stepping ==! |
---|
119 | ! !-----------------------! |
---|
120 | istp = nit000 |
---|
121 | #if defined key_c1d |
---|
122 | DO WHILE ( istp <= nitend .AND. nstop == 0 ) |
---|
123 | CALL stp_c1d( istp ) |
---|
124 | istp = istp + 1 |
---|
125 | END DO |
---|
126 | #else |
---|
127 | IF( lk_asminc ) THEN |
---|
128 | IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields |
---|
129 | IF( ln_trjwri ) CALL asm_trj_wri( nit000 - 1 ) ! Output trajectory fields |
---|
130 | IF( ln_asmdin ) THEN ! Direct initialization |
---|
131 | IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers |
---|
132 | IF( ln_dyninc ) THEN |
---|
133 | CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics |
---|
134 | IF ( ln_asmdin ) CALL ssh_wzv ( nit000 - 1 ) ! update vertical velocity |
---|
135 | ENDIF |
---|
136 | IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH |
---|
137 | ENDIF |
---|
138 | ENDIF |
---|
139 | |
---|
140 | DO WHILE ( istp <= nitend .AND. nstop == 0 ) |
---|
141 | #if defined key_agrif |
---|
142 | CALL Agrif_Step( stp ) ! AGRIF: time stepping |
---|
143 | #else |
---|
144 | CALL stp( istp ) ! standard time stepping |
---|
145 | #endif |
---|
146 | istp = istp + 1 |
---|
147 | IF( lk_mpp ) CALL mpp_max( nstop ) |
---|
148 | END DO |
---|
149 | #endif |
---|
150 | |
---|
151 | IF( lk_diaobs ) CALL dia_obs_wri |
---|
152 | |
---|
153 | ! !------------------------! |
---|
154 | ! !== finalize the run ==! |
---|
155 | ! !------------------------! |
---|
156 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
---|
157 | ! |
---|
158 | IF( nstop /= 0 .AND. lwp ) THEN ! error print |
---|
159 | WRITE(numout,cform_err) |
---|
160 | WRITE(numout,*) nstop, ' error have been found' |
---|
161 | ENDIF |
---|
162 | ! |
---|
163 | CALL nemo_closefile |
---|
164 | #if defined key_oasis3 || defined key_oasis4 |
---|
165 | CALL cpl_prism_finalize ! end coupling and mpp communications with OASIS |
---|
166 | #else |
---|
167 | IF( lk_mpp ) CALL mppstop ! end mpp communications |
---|
168 | #endif |
---|
169 | ! |
---|
170 | END SUBROUTINE nemo_gcm |
---|
171 | |
---|
172 | |
---|
173 | SUBROUTINE nemo_init |
---|
174 | !!---------------------------------------------------------------------- |
---|
175 | !! *** ROUTINE nemo_init *** |
---|
176 | !! |
---|
177 | !! ** Purpose : initialization of the NEMO GCM |
---|
178 | !!---------------------------------------------------------------------- |
---|
179 | INTEGER :: ji ! dummy loop indices |
---|
180 | INTEGER :: ilocal_comm ! local integer |
---|
181 | CHARACTER(len=80), DIMENSION(10) :: cltxt |
---|
182 | !! |
---|
183 | NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, & |
---|
184 | & nn_isplt, nn_jsplt, nn_jctls, nn_jctle, nn_bench |
---|
185 | !!---------------------------------------------------------------------- |
---|
186 | ! |
---|
187 | cltxt = '' |
---|
188 | ! |
---|
189 | ! ! open Namelist file |
---|
190 | CALL ctl_opn( numnam, 'namelist', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. ) |
---|
191 | ! |
---|
192 | READ( numnam, namctl ) ! Namelist namctl : Control prints & Benchmark |
---|
193 | ! |
---|
194 | ! !--------------------------------------------! |
---|
195 | ! ! set communicator & select the local node ! |
---|
196 | ! !--------------------------------------------! |
---|
197 | #if defined key_iomput |
---|
198 | IF( Agrif_Root() ) THEN |
---|
199 | # if defined key_oasis3 || defined key_oasis4 |
---|
200 | CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis |
---|
201 | # endif |
---|
202 | CALL init_ioclient( ilocal_comm ) ! exchange io_server nemo local communicator with the io_server |
---|
203 | ENDIF |
---|
204 | narea = mynode( cltxt, ilocal_comm ) ! Nodes selection |
---|
205 | #else |
---|
206 | # if defined key_oasis3 || defined key_oasis4 |
---|
207 | IF( Agrif_Root() ) THEN |
---|
208 | CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis |
---|
209 | ENDIF |
---|
210 | narea = mynode( cltxt, ilocal_comm ) ! Nodes selection (control print return in cltxt) |
---|
211 | # else |
---|
212 | ilocal_comm = 0 |
---|
213 | narea = mynode( cltxt ) ! Nodes selection (control print return in cltxt) |
---|
214 | # endif |
---|
215 | #endif |
---|
216 | narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 ) |
---|
217 | |
---|
218 | lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print |
---|
219 | |
---|
220 | IF(lwp) THEN ! open listing units |
---|
221 | ! |
---|
222 | CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea ) |
---|
223 | ! |
---|
224 | WRITE(numout,*) |
---|
225 | WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean' |
---|
226 | WRITE(numout,*) ' NEMO team' |
---|
227 | WRITE(numout,*) ' Ocean General Circulation Model' |
---|
228 | WRITE(numout,*) ' version 3.3 (2010) ' |
---|
229 | WRITE(numout,*) |
---|
230 | WRITE(numout,*) |
---|
231 | DO ji = 1, SIZE(cltxt) |
---|
232 | IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode |
---|
233 | END DO |
---|
234 | WRITE(numout,cform_aaa) ! Flag AAAAAAA |
---|
235 | ! |
---|
236 | ENDIF |
---|
237 | ! !-------------------------------! |
---|
238 | ! ! NEMO general initialization ! |
---|
239 | ! !-------------------------------! |
---|
240 | |
---|
241 | CALL nemo_ctl ! Control prints & Benchmark |
---|
242 | |
---|
243 | ! ! Domain decomposition |
---|
244 | IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out |
---|
245 | ELSE ; CALL mpp_init2 ! eliminate land processors |
---|
246 | ENDIF |
---|
247 | ! |
---|
248 | ! ! General initialization |
---|
249 | CALL phy_cst ! Physical constants |
---|
250 | CALL eos_init ! Equation of state |
---|
251 | CALL dom_cfg ! Domain configuration |
---|
252 | CALL dom_init ! Domain |
---|
253 | |
---|
254 | IF( ln_ctl ) CALL prt_ctl_init ! Print control |
---|
255 | |
---|
256 | IF( lk_obc ) CALL obc_init ! Open boundaries |
---|
257 | IF( lk_bdy ) CALL bdy_init ! Unstructured open boundaries |
---|
258 | |
---|
259 | CALL istate_init ! ocean initial state (Dynamics and tracers) |
---|
260 | |
---|
261 | ! ! Ocean physics |
---|
262 | CALL sbc_init ! Forcings : surface module |
---|
263 | ! ! Vertical physics |
---|
264 | CALL zdf_init ! namelist read |
---|
265 | CALL zdf_bfr_init ! bottom friction |
---|
266 | IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz |
---|
267 | IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme |
---|
268 | IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme |
---|
269 | IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme |
---|
270 | IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing |
---|
271 | IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) & |
---|
272 | & CALL zdf_ddm_init ! double diffusive mixing |
---|
273 | ! ! Lateral physics |
---|
274 | CALL ldf_tra_init ! Lateral ocean tracer physics |
---|
275 | CALL ldf_dyn_init ! Lateral ocean momentum physics |
---|
276 | IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing |
---|
277 | |
---|
278 | ! ! Active tracers |
---|
279 | CALL tra_qsr_init ! penetrative solar radiation qsr |
---|
280 | CALL tra_bbc_init ! bottom heat flux |
---|
281 | IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme |
---|
282 | IF( lk_tradmp ) CALL tra_dmp_init ! internal damping trends |
---|
283 | CALL tra_adv_init ! horizontal & vertical advection |
---|
284 | CALL tra_ldf_init ! lateral mixing |
---|
285 | CALL tra_zdf_init ! vertical mixing and after tracer fields |
---|
286 | |
---|
287 | ! ! Dynamics |
---|
288 | CALL dyn_adv_init ! advection (vector or flux form) |
---|
289 | CALL dyn_vor_init ! vorticity term including Coriolis |
---|
290 | CALL dyn_ldf_init ! lateral mixing |
---|
291 | CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure |
---|
292 | CALL dyn_zdf_init ! vertical diffusion |
---|
293 | CALL dyn_spg_init ! surface pressure gradient |
---|
294 | |
---|
295 | ! ! Misc. options |
---|
296 | IF( nn_cla == 1 ) CALL cla_init ! Cross Land Advection |
---|
297 | |
---|
298 | #if defined key_top |
---|
299 | ! ! Passive tracers |
---|
300 | CALL trc_init |
---|
301 | #endif |
---|
302 | ! ! Diagnostics |
---|
303 | CALL iom_init ! iom_put initialization |
---|
304 | IF( lk_floats ) CALL flo_init ! drifting Floats |
---|
305 | IF( lk_diaar5 ) CALL dia_ar5_init ! ar5 diag |
---|
306 | CALL dia_ptr_init ! Poleward TRansports initialization |
---|
307 | CALL dia_hsb_init ! heat content, salt content and volume budgets |
---|
308 | CALL trd_mod_init ! Mixed-layer/Vorticity/Integral constraints trends |
---|
309 | IF( lk_diaobs ) THEN ! Observation & model comparison |
---|
310 | CALL dia_obs_init ! Initialize observational data |
---|
311 | CALL dia_obs( nit000 - 1 ) ! Observation operator for restart |
---|
312 | ENDIF |
---|
313 | ! ! Assimilation increments |
---|
314 | IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments |
---|
315 | IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler |
---|
316 | ! |
---|
317 | END SUBROUTINE nemo_init |
---|
318 | |
---|
319 | |
---|
320 | SUBROUTINE nemo_ctl |
---|
321 | !!---------------------------------------------------------------------- |
---|
322 | !! *** ROUTINE nemo_ctl *** |
---|
323 | !! |
---|
324 | !! ** Purpose : control print setting |
---|
325 | !! |
---|
326 | !! ** Method : - print namctl information and check some consistencies |
---|
327 | !!---------------------------------------------------------------------- |
---|
328 | ! |
---|
329 | IF(lwp) THEN ! control print |
---|
330 | WRITE(numout,*) |
---|
331 | WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark' |
---|
332 | WRITE(numout,*) '~~~~~~~ ' |
---|
333 | WRITE(numout,*) ' Namelist namctl' |
---|
334 | WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl |
---|
335 | WRITE(numout,*) ' level of print nn_print = ', nn_print |
---|
336 | WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls |
---|
337 | WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle |
---|
338 | WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls |
---|
339 | WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle |
---|
340 | WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt |
---|
341 | WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt |
---|
342 | WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench |
---|
343 | ENDIF |
---|
344 | ! |
---|
345 | nprint = nn_print ! convert DOCTOR namelist names into OLD names |
---|
346 | nictls = nn_ictls |
---|
347 | nictle = nn_ictle |
---|
348 | njctls = nn_jctls |
---|
349 | njctle = nn_jctle |
---|
350 | isplt = nn_isplt |
---|
351 | jsplt = nn_jsplt |
---|
352 | nbench = nn_bench |
---|
353 | ! ! Parameter control |
---|
354 | ! |
---|
355 | IF( ln_ctl ) THEN ! sub-domain area indices for the control prints |
---|
356 | IF( lk_mpp ) THEN |
---|
357 | isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain |
---|
358 | ELSE |
---|
359 | IF( isplt == 1 .AND. jsplt == 1 ) THEN |
---|
360 | CALL ctl_warn( ' - isplt & jsplt are equal to 1', & |
---|
361 | & ' - the print control will be done over the whole domain' ) |
---|
362 | ENDIF |
---|
363 | ijsplt = isplt * jsplt ! total number of processors ijsplt |
---|
364 | ENDIF |
---|
365 | IF(lwp) WRITE(numout,*)' - The total number of processors over which the' |
---|
366 | IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt |
---|
367 | ! |
---|
368 | ! ! indices used for the SUM control |
---|
369 | IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area |
---|
370 | lsp_area = .FALSE. |
---|
371 | ELSE ! print control done over a specific area |
---|
372 | lsp_area = .TRUE. |
---|
373 | IF( nictls < 1 .OR. nictls > jpiglo ) THEN |
---|
374 | CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' ) |
---|
375 | nictls = 1 |
---|
376 | ENDIF |
---|
377 | IF( nictle < 1 .OR. nictle > jpiglo ) THEN |
---|
378 | CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' ) |
---|
379 | nictle = jpiglo |
---|
380 | ENDIF |
---|
381 | IF( njctls < 1 .OR. njctls > jpjglo ) THEN |
---|
382 | CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' ) |
---|
383 | njctls = 1 |
---|
384 | ENDIF |
---|
385 | IF( njctle < 1 .OR. njctle > jpjglo ) THEN |
---|
386 | CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' ) |
---|
387 | njctle = jpjglo |
---|
388 | ENDIF |
---|
389 | ENDIF |
---|
390 | ENDIF |
---|
391 | ! |
---|
392 | IF( nbench == 1 ) THEN ! Benchmark |
---|
393 | SELECT CASE ( cp_cfg ) |
---|
394 | CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' ) |
---|
395 | CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', & |
---|
396 | & ' key_gyre must be used or set nbench = 0' ) |
---|
397 | END SELECT |
---|
398 | ENDIF |
---|
399 | ! |
---|
400 | IF( lk_c1d .AND. .NOT.lk_iomput ) CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ', & |
---|
401 | & 'with the IOM Input/Output manager. ' , & |
---|
402 | & 'Compile with key_iomput enabled' ) |
---|
403 | ! |
---|
404 | END SUBROUTINE nemo_ctl |
---|
405 | |
---|
406 | |
---|
407 | SUBROUTINE nemo_closefile |
---|
408 | !!---------------------------------------------------------------------- |
---|
409 | !! *** ROUTINE nemo_closefile *** |
---|
410 | !! |
---|
411 | !! ** Purpose : Close the files |
---|
412 | !!---------------------------------------------------------------------- |
---|
413 | ! |
---|
414 | IF( lk_mpp ) CALL mppsync |
---|
415 | ! |
---|
416 | CALL iom_close ! close all input/output files managed by iom_* |
---|
417 | ! |
---|
418 | IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file |
---|
419 | IF( numsol /= -1 ) CLOSE( numsol ) ! solver file |
---|
420 | IF( numnam /= -1 ) CLOSE( numnam ) ! oce namelist |
---|
421 | IF( numnam_ice /= -1 ) CLOSE( numnam_ice ) ! ice namelist |
---|
422 | IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution) |
---|
423 | IF( numout /= 6 ) CLOSE( numout ) ! standard model output file |
---|
424 | ! |
---|
425 | numout = 6 ! redefine numout in case it is used after this point... |
---|
426 | ! |
---|
427 | END SUBROUTINE nemo_closefile |
---|
428 | |
---|
429 | !!====================================================================== |
---|
430 | END MODULE nemogcm |
---|