1 | MODULE dynldf_bilap |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE dynldf_bilap *** |
---|
4 | !! Ocean dynamics: lateral viscosity trend |
---|
5 | !!====================================================================== |
---|
6 | |
---|
7 | !!---------------------------------------------------------------------- |
---|
8 | !! dyn_ldf_bilap : update the momentum trend with the lateral diffusion |
---|
9 | !! using an iso-level bilaplacian operator |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | !! * Modules used |
---|
12 | USE oce ! ocean dynamics and tracers |
---|
13 | USE dom_oce ! ocean space and time domain |
---|
14 | USE ldfdyn_oce ! ocean dynamics: lateral physics |
---|
15 | USE in_out_manager ! I/O manager |
---|
16 | USE trddyn_oce ! dynamics trends diagnostics variables |
---|
17 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
18 | |
---|
19 | IMPLICIT NONE |
---|
20 | PRIVATE |
---|
21 | |
---|
22 | !! * Routine accessibility |
---|
23 | PUBLIC dyn_ldf_bilap ! called by step.F90 |
---|
24 | |
---|
25 | !! * Substitutions |
---|
26 | # include "domzgr_substitute.h90" |
---|
27 | # include "ldfdyn_substitute.h90" |
---|
28 | # include "vectopt_loop_substitute.h90" |
---|
29 | !!---------------------------------------------------------------------- |
---|
30 | !! OPA 9.0 , LODYC-IPSL (2003) |
---|
31 | !!---------------------------------------------------------------------- |
---|
32 | |
---|
33 | CONTAINS |
---|
34 | |
---|
35 | SUBROUTINE dyn_ldf_bilap( kt ) |
---|
36 | !!---------------------------------------------------------------------- |
---|
37 | !! *** ROUTINE dyn_ldf_bilap *** |
---|
38 | !! |
---|
39 | !! ** Purpose : Compute the before trend of the lateral momentum |
---|
40 | !! diffusion and add it to the general trend of momentum equation. |
---|
41 | !! |
---|
42 | !! ** Method : The before horizontal momentum diffusion trend is a |
---|
43 | !! bi-harmonic operator (bilaplacian type) which separates the |
---|
44 | !! divergent and rotational parts of the flow. |
---|
45 | !! Its horizontal components are computed as follow: |
---|
46 | !! laplacian: |
---|
47 | !! zlu = 1/e1u di[ hdivb ] - 1/(e2u*e3u) dj-1[ e3f rotb ] |
---|
48 | !! zlv = 1/e2v dj[ hdivb ] + 1/(e1v*e3v) di-1[ e3f rotb ] |
---|
49 | !! third derivative: |
---|
50 | !! * multiply by the eddy viscosity coef. at u-, v-point, resp. |
---|
51 | !! zlu = ahmu * zlu |
---|
52 | !! zlv = ahmv * zlv |
---|
53 | !! * curl and divergence of the laplacian |
---|
54 | !! zuf = 1/(e1f*e2f) ( di[e2v zlv] - dj[e1u zlu] ) |
---|
55 | !! zut = 1/(e1t*e2t*e3t) ( di[e2u*e3u zlu] + dj[e1v*e3v zlv] ) |
---|
56 | !! bilaplacian: |
---|
57 | !! diffu = 1/e1u di[ zut ] - 1/(e2u*e3u) dj-1[ e3f zuf ] |
---|
58 | !! diffv = 1/e2v dj[ zut ] + 1/(e1v*e3v) di-1[ e3f zuf ] |
---|
59 | !! If lk_sco=F and lk_zps=F, the vertical scale factors in the |
---|
60 | !! rotational part of the diffusion are simplified |
---|
61 | !! Add this before trend to the general trend (ua,va): |
---|
62 | !! (ua,va) = (ua,va) + (diffu,diffv) |
---|
63 | !! 'key_trddyn' defined: the two components of the horizontal |
---|
64 | !! diffusion trend are saved. |
---|
65 | !! |
---|
66 | !! ** Action : - Update (ua,va) with the before iso-level biharmonic |
---|
67 | !! mixing trend. |
---|
68 | !! - Save in (utrd,vtrd) the trends ('key_diatrends') |
---|
69 | !! |
---|
70 | !! History : |
---|
71 | !! ! 90-09 (G. Madec) Original code |
---|
72 | !! ! 91-11 (G. Madec) |
---|
73 | !! ! 93-03 (M. Guyon) symetrical conditions (M. Guyon) |
---|
74 | !! ! 96-01 (G. Madec) statement function for e3 |
---|
75 | !! ! 97-07 (G. Madec) lbc calls |
---|
76 | !! 8.5 ! 02-08 (G. Madec) F90: Free form and module |
---|
77 | !!---------------------------------------------------------------------- |
---|
78 | !! * Arguments |
---|
79 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
---|
80 | |
---|
81 | !! * Local declarations |
---|
82 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
83 | REAL(wp) :: zua, zva, zbt, ze2u, ze2v ! temporary scalar |
---|
84 | REAL(wp), DIMENSION(jpi,jpj) :: & |
---|
85 | zuf, zut, zlu, zlv, zcu, zcv ! temporary workspace |
---|
86 | !!---------------------------------------------------------------------- |
---|
87 | !! OPA 8.5, LODYC-IPSL (2002) |
---|
88 | !!---------------------------------------------------------------------- |
---|
89 | |
---|
90 | IF( kt == nit000 ) THEN |
---|
91 | IF(lwp) WRITE(numout,*) |
---|
92 | IF(lwp) WRITE(numout,*) 'dyn_ldf_bilap : iso-level bilaplacian operator' |
---|
93 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~' |
---|
94 | ENDIF |
---|
95 | zuf(:,:) = 0.e0 |
---|
96 | zut(:,:) = 0.e0 |
---|
97 | zlu(:,:) = 0.e0 |
---|
98 | zlv(:,:) = 0.e0 |
---|
99 | ! ! =============== |
---|
100 | DO jk = 1, jpkm1 ! Horizontal slab |
---|
101 | ! ! =============== |
---|
102 | ! Laplacian |
---|
103 | ! --------- |
---|
104 | |
---|
105 | IF( lk_sco .OR. lk_zps ) THEN ! s-coordinate or z-coordinate with partial steps |
---|
106 | zuf(:,:) = rotb(:,:,jk) * fse3f(:,:,jk) |
---|
107 | DO jj = 2, jpjm1 |
---|
108 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
109 | zlu(ji,jj) = - ( zuf(ji,jj) - zuf(ji,jj-1) ) / ( e2u(ji,jj) * fse3u(ji,jj,jk) ) & |
---|
110 | & + ( hdivb(ji+1,jj,jk) - hdivb(ji,jj,jk) ) / e1u(ji,jj) |
---|
111 | |
---|
112 | zlv(ji,jj) = + ( zuf(ji,jj) - zuf(ji-1,jj) ) / ( e1v(ji,jj) * fse3v(ji,jj,jk) ) & |
---|
113 | & + ( hdivb(ji,jj+1,jk) - hdivb(ji,jj,jk) ) / e2v(ji,jj) |
---|
114 | END DO |
---|
115 | END DO |
---|
116 | ELSE ! z-coordinate |
---|
117 | DO jj = 2, jpjm1 |
---|
118 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
119 | zlu(ji,jj) = - ( rotb (ji ,jj,jk) - rotb (ji,jj-1,jk) ) / e2u(ji,jj) & |
---|
120 | & + ( hdivb(ji+1,jj,jk) - hdivb(ji,jj ,jk) ) / e1u(ji,jj) |
---|
121 | |
---|
122 | zlv(ji,jj) = + ( rotb (ji,jj ,jk) - rotb (ji-1,jj,jk) ) / e1v(ji,jj) & |
---|
123 | & + ( hdivb(ji,jj+1,jk) - hdivb(ji ,jj,jk) ) / e2v(ji,jj) |
---|
124 | END DO |
---|
125 | END DO |
---|
126 | ENDIF |
---|
127 | |
---|
128 | ! Boundary conditions on the laplacian (zlu,zlv) |
---|
129 | CALL lbc_lnk( zlu, 'U', -1. ) |
---|
130 | CALL lbc_lnk( zlv, 'V', -1. ) |
---|
131 | |
---|
132 | |
---|
133 | ! Third derivative |
---|
134 | ! ---------------- |
---|
135 | |
---|
136 | ! Multiply by the eddy viscosity coef. (at u- and v-points) |
---|
137 | zlu(:,:) = zlu(:,:) * fsahmu(:,:,jk) |
---|
138 | zlv(:,:) = zlv(:,:) * fsahmv(:,:,jk) |
---|
139 | |
---|
140 | ! Contravariant "laplacian" |
---|
141 | zcu(:,:) = e1u(:,:) * zlu(:,:) |
---|
142 | zcv(:,:) = e2v(:,:) * zlv(:,:) |
---|
143 | |
---|
144 | ! Laplacian curl ( * e3f if s-coordinates or z-coordinate with partial steps) |
---|
145 | DO jj = 1, jpjm1 |
---|
146 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
147 | zuf(ji,jj) = fmask(ji,jj,jk) * ( zcv(ji+1,jj ) - zcv(ji,jj) & |
---|
148 | & - zcu(ji ,jj+1) + zcu(ji,jj) ) & |
---|
149 | #if defined key_s_coord || defined key_partial_steps |
---|
150 | & * fse3f(ji,jj,jk) / ( e1f(ji,jj)*e2f(ji,jj) ) |
---|
151 | #else |
---|
152 | & / ( e1f(ji,jj)*e2f(ji,jj) ) |
---|
153 | #endif |
---|
154 | END DO |
---|
155 | END DO |
---|
156 | |
---|
157 | ! Laplacian Horizontal fluxes |
---|
158 | DO jj = 1, jpjm1 |
---|
159 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
160 | #if defined key_s_coord || defined key_partial_steps |
---|
161 | zlu(ji,jj) = e2u(ji,jj) * fse3u(ji,jj,jk) * zlu(ji,jj) |
---|
162 | zlv(ji,jj) = e1v(ji,jj) * fse3v(ji,jj,jk) * zlv(ji,jj) |
---|
163 | #else |
---|
164 | zlu(ji,jj) = e2u(ji,jj) * zlu(ji,jj) |
---|
165 | zlv(ji,jj) = e1v(ji,jj) * zlv(ji,jj) |
---|
166 | #endif |
---|
167 | END DO |
---|
168 | END DO |
---|
169 | |
---|
170 | ! Laplacian divergence |
---|
171 | DO jj = 2, jpj |
---|
172 | DO ji = fs_2, jpi ! vector opt. |
---|
173 | #if defined key_s_coord || defined key_partial_steps |
---|
174 | zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) |
---|
175 | #else |
---|
176 | zbt = e1t(ji,jj) * e2t(ji,jj) |
---|
177 | #endif |
---|
178 | zut(ji,jj) = ( zlu(ji,jj) - zlu(ji-1,jj ) & |
---|
179 | & + zlv(ji,jj) - zlv(ji ,jj-1) ) / zbt |
---|
180 | END DO |
---|
181 | END DO |
---|
182 | |
---|
183 | |
---|
184 | ! boundary conditions on the laplacian curl and div (zuf,zut) |
---|
185 | CALL lbc_lnk( zuf, 'F', -1. ) |
---|
186 | CALL lbc_lnk( zut, 'T', -1. ) |
---|
187 | |
---|
188 | |
---|
189 | ! Bilaplacian |
---|
190 | ! ----------- |
---|
191 | |
---|
192 | DO jj = 2, jpjm1 |
---|
193 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
194 | #if defined key_s_coord || defined key_partial_steps |
---|
195 | ze2u = e2u(ji,jj) * fse3u(ji,jj,jk) |
---|
196 | ze2v = e1v(ji,jj) * fse3v(ji,jj,jk) |
---|
197 | #else |
---|
198 | ze2u = e2u(ji,jj) |
---|
199 | ze2v = e1v(ji,jj) |
---|
200 | #endif |
---|
201 | ! horizontal biharmonic diffusive trends |
---|
202 | zua = - ( zuf(ji ,jj) - zuf(ji,jj-1) ) / ze2u & |
---|
203 | & + ( zut(ji+1,jj) - zut(ji,jj ) ) / e1u(ji,jj) |
---|
204 | |
---|
205 | zva = + ( zuf(ji,jj ) - zuf(ji-1,jj) ) / ze2v & |
---|
206 | & + ( zut(ji,jj+1) - zut(ji ,jj) ) / e2v(ji,jj) |
---|
207 | ! add it to the general momentum trends |
---|
208 | ua(ji,jj,jk) = ua(ji,jj,jk) + zua |
---|
209 | va(ji,jj,jk) = va(ji,jj,jk) + zva |
---|
210 | #if defined key_trddyn || defined key_trd_vor |
---|
211 | ! save the horizontal biharmonic diffusive trends |
---|
212 | utrd(ji,jj,jk,5) = zua |
---|
213 | vtrd(ji,jj,jk,5) = zva |
---|
214 | #endif |
---|
215 | END DO |
---|
216 | END DO |
---|
217 | |
---|
218 | ! ! =============== |
---|
219 | END DO ! End of slab |
---|
220 | ! ! =============== |
---|
221 | |
---|
222 | IF(l_ctl) THEN ! print sum trends (used for debugging) |
---|
223 | zua = SUM( ua(2:nictl,2:njctl,1:jpkm1) * umask(2:nictl,2:njctl,1:jpkm1) ) |
---|
224 | zva = SUM( va(2:nictl,2:njctl,1:jpkm1) * vmask(2:nictl,2:njctl,1:jpkm1) ) |
---|
225 | WRITE(numout,*) ' ldf - Ua: ', zua-u_ctl, ' Va: ', zva-v_ctl |
---|
226 | u_ctl = zua ; v_ctl = zva |
---|
227 | ENDIF |
---|
228 | |
---|
229 | END SUBROUTINE dyn_ldf_bilap |
---|
230 | |
---|
231 | !!====================================================================== |
---|
232 | END MODULE dynldf_bilap |
---|