New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dyncor1d.F90 in tags/nemo_v1_01/NEMO/C1D_SRC – NEMO

source: tags/nemo_v1_01/NEMO/C1D_SRC/dyncor1d.F90 @ 4294

Last change on this file since 4294 was 253, checked in by opalod, 19 years ago

nemo_v1_update_001 : Add the 1D configuration possibility
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 6.3 KB
Line 
1MODULE dyncor1d
2   !!======================================================================
3   !!                     ***  MODULE  ini1D  ***
4   !! Ocean state   :  1D initialization
5   !!=====================================================================
6#if defined key_cfg_1d
7   !!----------------------------------------------------------------------
8   !!   'key_cfg_1d'               1D Configuration
9   !!----------------------------------------------------------------------
10   !!----------------------------------------------------------------------
11   !!   fcorio_1d   : Coriolis factor at T-point
12   !!   dyn_cor_1d  : vorticity trend due to Coriolis
13   !!----------------------------------------------------------------------
14   !! * Modules used
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE phycst          ! physical constants
18   USE in_out_manager ! I/O manager
19
20   IMPLICIT NONE
21   PRIVATE
22
23   !! * Routine accessibility
24   PUBLIC fcorio_1d   ! routine called by OPA.F90
25   PUBLIC dyn_cor_1d  ! routine called by step1d.F90
26
27   !! * Substitutions
28#  include "vectopt_loop_substitute.h90"
29   !!----------------------------------------------------------------------
30   !!   OPA 9.0 , LODYC-IPSL  (2003)
31   !!----------------------------------------------------------------------
32
33CONTAINS
34
35   SUBROUTINE fcorio_1d
36      !!----------------------------------------------------------------------
37      !!                   ***  ROUTINE fcorio_1d  ***
38      !!
39      !! ** Purpose : Compute the Coriolis factor at T-point
40      !!
41      !! ** Method  :
42      !!
43      !! History :
44      !!   9.0  !  04-09  (C. Ethe) 1D configuration
45      !!----------------------------------------------------------------------
46      !! * Local declarations
47      !!----------------------------------------------------------------------
48      REAL(wp) ::   &
49         zphi0, zbeta, zf0         !  temporary scalars
50 
51
52      !!----------------------------------------------------------------------
53
54      ! ================= !
55      !  Coriolis factor  !
56      ! ================= !
57      IF(lwp) WRITE(numout,*)
58      IF(lwp) WRITE(numout,*) 'fcorio_1d : Coriolis factor at T-point'
59      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
60
61      SELECT CASE( jphgr_msh )   ! type of horizontal mesh
62
63      CASE ( 0, 1, 4 )               ! mesh on the sphere
64
65         ff(:,:) = 2. * omega * SIN( rad * gphit(:,:) ) 
66
67      CASE ( 2 )                     ! f-plane at ppgphi0
68
69         ff(:,:) = 2. * omega * SIN( rad * ppgphi0 )
70
71         IF(lwp) WRITE(numout,*) '          f-plane: Coriolis parameter = constant = ', ff(1,1)
72
73      CASE ( 3 )                     ! beta-plane
74
75         zbeta   = 2. * omega * COS( rad * ppgphi0 ) / ra                     ! beta at latitude ppgphi0
76         zphi0   = ppgphi0 - FLOAT( jpjglo/2) * ppe2_m *1.e-3  / ( ra * rad ) ! latitude of the first row F-points
77         zf0     = 2. * omega * SIN( rad * zphi0 )                            ! compute f0 1st point south
78
79         ff(:,:) = ( zf0  + zbeta * gphit(:,:) * 1.e+3 )                      ! f = f0 +beta* y ( y=0 at south)
80
81         IF(lwp) WRITE(numout,*) '          Beta-plane: Beta parameter = constant = ', ff(1,1)
82         IF(lwp) WRITE(numout,*) '                      Coriolis parameter varies from ', ff(1,1),' to ', ff(1,jpj)
83
84      CASE ( 5 )                     ! beta-plane and rotated domain
85
86         zbeta = 2. * omega * COS( rad * ppgphi0 ) / ra                     ! beta at latitude ppgphi0
87         zphi0 = 15.e0                                                      ! latitude of the first row F-points
88         zf0   = 2. * omega * SIN( rad * zphi0 )                            ! compute f0 1st point south
89
90         ff(:,:) = ( zf0 + zbeta * ABS( gphit(:,:) - zphi0 ) * rad * ra )   ! f = f0 +beta* y ( y=0 at south)
91
92         IF(lwp) WRITE(numout,*) '          Beta-plane: Beta parameter = constant = ', ff(1,1)
93         IF(lwp) WRITE(numout,*) '                      Coriolis parameter varies from ', ff(1,1),' to ', ff(1,jpj)
94
95      END SELECT
96
97   END SUBROUTINE fcorio_1d
98
99
100   SUBROUTINE dyn_cor_1d( kt )
101      !!----------------------------------------------------------------------
102      !!                   ***  ROUTINE dyn_cor_1d  ***
103      !!
104      !! ** Purpose :   Compute the now total vorticity trend and add it to
105      !!               the general trend of the momentum equation
106      !!
107      !! ** Method  :
108      !!
109      !! History :
110      !!   9.0  !  04-09  (C. Ethe) 1D configuration
111      !!----------------------------------------------------------------------
112      !! * Arguments
113      INTEGER, INTENT( in ) ::   kt        ! ocean time-step index
114
115      !! * Local declarations
116      INTEGER ::   ji, jj, jk              ! dummy loop indices
117      REAL(wp) ::   &
118         zua, zva                          ! temporary scalars
119
120      !!----------------------------------------------------------------------
121
122      IF( kt == nit000 ) THEN
123         IF(lwp) WRITE(numout,*)
124         IF(lwp) WRITE(numout,*) 'dyn_cor_1d : total vorticity trend in 1D'
125         IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
126      ENDIF
127
128      DO jk = 1, jpkm1
129         DO jj = 2, jpjm1
130            DO ji = fs_2, fs_jpim1   ! vector opt.
131               zua =    ff(ji,jj) * vn(ji,jj,jk)
132               zva =  - ff(ji,jj) * un(ji,jj,jk)
133               ua(ji,jj,jk) = ua(ji,jj,jk) + zua
134               va(ji,jj,jk) = va(ji,jj,jk) + zva
135            END DO
136         END DO
137      END DO   
138      IF(l_ctl) THEN         ! print sum trends (used for debugging)
139         zua = SUM( ua(2:nictl,2:njctl,1:jpkm1) * umask(2:nictl,2:njctl,1:jpkm1) )
140         zva = SUM( va(2:nictl,2:njctl,1:jpkm1) * vmask(2:nictl,2:njctl,1:jpkm1) )
141         WRITE(numout,*) ' cor  - Ua: ', zua-u_ctl, ' Va: ', zva-v_ctl
142         u_ctl = zua   ;   v_ctl = zva
143      ENDIF
144   END SUBROUTINE dyn_cor_1d
145
146#else
147   !!----------------------------------------------------------------------
148   !!   Default key                                     NO 1D Config
149   !!----------------------------------------------------------------------
150CONTAINS
151   SUBROUTINE fcorio_1d      ! Empty routine
152   END SUBROUTINE fcorio_1d   
153   SUBROUTINE dyn_cor_1d ( kt )
154      WRITE(*,*) 'dyn_cor_1d: You should not have seen this print! error?', kt
155   END SUBROUTINE dyn_cor_1d
156#endif
157
158   !!=====================================================================
159END MODULE dyncor1d
Note: See TracBrowser for help on using the repository browser.