1 | MODULE trcnxt |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE trcnxt *** |
---|
4 | !! Ocean passive tracers: time stepping on passives tracers |
---|
5 | !!====================================================================== |
---|
6 | #if defined key_passivetrc |
---|
7 | !!---------------------------------------------------------------------- |
---|
8 | !! trc_nxt : time stepping on passive tracers |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | !! * Modules used |
---|
11 | USE oce_trc ! ocean dynamics and tracers variables |
---|
12 | USE trc ! ocean passive tracers variables |
---|
13 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
14 | USE trctrp_lec ! pasive tracers transport |
---|
15 | |
---|
16 | IMPLICIT NONE |
---|
17 | PRIVATE |
---|
18 | |
---|
19 | !! * Routine accessibility |
---|
20 | PUBLIC trc_nxt ! routine called by step.F90 |
---|
21 | !!---------------------------------------------------------------------- |
---|
22 | !! TOP 1.0, LOCEAN-IPSL (2005) |
---|
23 | !! $Header$ |
---|
24 | !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt |
---|
25 | !!---------------------------------------------------------------------- |
---|
26 | |
---|
27 | CONTAINS |
---|
28 | |
---|
29 | SUBROUTINE trc_nxt( kt ) |
---|
30 | !!---------------------------------------------------------------------- |
---|
31 | !! *** ROUTINE trcnxt *** |
---|
32 | !! |
---|
33 | !! ** Purpose : Compute the passive tracers fields at the |
---|
34 | !! next time-step from their temporal trends and swap the fields. |
---|
35 | !! |
---|
36 | !! ** Method : Apply lateral boundary conditions on (ua,va) through |
---|
37 | !! call to lbc_lnk routine |
---|
38 | !! default: |
---|
39 | !! arrays swap |
---|
40 | !! (trn) = (tra) ; (tra) = (0,0) |
---|
41 | !! (trb) = (trn) |
---|
42 | !! |
---|
43 | !! For Arakawa or TVD Scheme : |
---|
44 | !! A Asselin time filter applied on now tracers (trn) to avoid |
---|
45 | !! the divergence of two consecutive time-steps and tr arrays |
---|
46 | !! to prepare the next time_step: |
---|
47 | !! (trb) = (trn) + atfp [ (trb) + (tra) - 2 (trn) ] |
---|
48 | !! (trn) = (tra) ; (tra) = (0,0) |
---|
49 | !! |
---|
50 | !! |
---|
51 | !! ** Action : - update trb, trn |
---|
52 | !! |
---|
53 | !! History : |
---|
54 | !! 7.0 ! 91-11 (G. Madec) Original code |
---|
55 | !! ! 93-03 (M. Guyon) symetrical conditions |
---|
56 | !! ! 95-02 (M. Levy) passive tracers |
---|
57 | !! ! 96-02 (G. Madec & M. Imbard) opa release 8.0 |
---|
58 | !! 8.0 ! 96-04 (A. Weaver) Euler forward step |
---|
59 | !! 8.2 ! 99-02 (G. Madec, N. Grima) semi-implicit pressure grad. |
---|
60 | !! 8.5 ! 02-08 (G. Madec) F90: Free form and module |
---|
61 | !! ! 02-11 (C. Talandier, A-M Treguier) Open boundaries |
---|
62 | !! 9.0 ! 04-03 (C. Ethe) passive tracers |
---|
63 | !!---------------------------------------------------------------------- |
---|
64 | !! * Arguments |
---|
65 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
---|
66 | !! * Local declarations |
---|
67 | INTEGER :: ji, jj, jk,jn ! dummy loop indices |
---|
68 | REAL(wp) :: zfact, ztra ! temporary scalar |
---|
69 | !!---------------------------------------------------------------------- |
---|
70 | |
---|
71 | IF( kt == nittrc000 .AND. lwp ) THEN |
---|
72 | WRITE(numout,*) |
---|
73 | WRITE(numout,*) 'trc_nxt : time stepping on passive tracers' |
---|
74 | ENDIF |
---|
75 | |
---|
76 | |
---|
77 | DO jn = 1, jptra |
---|
78 | |
---|
79 | ! 0. Lateral boundary conditions on tra (T-point, unchanged sign) |
---|
80 | ! ---------------------------------============ |
---|
81 | CALL lbc_lnk( tra(:,:,:,jn), 'T', 1. ) |
---|
82 | |
---|
83 | ! ! =============== |
---|
84 | DO jk = 1, jpk ! Horizontal slab |
---|
85 | ! ! =============== |
---|
86 | ! 1. Leap-frog scheme (only in explicit case, otherwise the |
---|
87 | ! ------------------- time stepping is already done in trczdf) |
---|
88 | IF( l_trczdf_exp .AND. ( ln_trcadv_cen2 .OR. ln_trcadv_tvd) ) THEN |
---|
89 | zfact = 2. * rdttra(jk) * FLOAT(ndttrc) |
---|
90 | IF( neuler == 0 .AND. kt == nittrc000 ) zfact = rdttra(jk) * FLOAT(ndttrc) |
---|
91 | tra(:,:,jk,jn) = ( trb(:,:,jk,jn) + zfact * tra(:,:,jk,jn) ) * tmask(:,:,jk) |
---|
92 | ENDIF |
---|
93 | |
---|
94 | END DO |
---|
95 | |
---|
96 | #if defined key_obc |
---|
97 | IF(lwp) WRITE(numout,cform_err) |
---|
98 | IF(lwp) WRITE(numout,*) ' Passive tracers and Open Boundary condition can not be used together ' |
---|
99 | IF(lwp) WRITE(numout,*) ' Check in trc_nxt routine' |
---|
100 | nstop = nstop + 1 |
---|
101 | #endif |
---|
102 | |
---|
103 | DO jk = 1, jpk |
---|
104 | |
---|
105 | ! 2. Time filter and swap of arrays |
---|
106 | ! --------------------------------- |
---|
107 | IF ( ln_trcadv_cen2 .OR. ln_trcadv_tvd ) THEN |
---|
108 | |
---|
109 | IF( neuler == 0 .AND. kt == nittrc000 ) THEN |
---|
110 | DO jj = 1, jpj |
---|
111 | DO ji = 1, jpi |
---|
112 | trb(ji,jj,jk,jn) = trn(ji,jj,jk,jn) |
---|
113 | trn(ji,jj,jk,jn) = tra(ji,jj,jk,jn) |
---|
114 | tra(ji,jj,jk,jn) = 0. |
---|
115 | END DO |
---|
116 | END DO |
---|
117 | ELSE |
---|
118 | DO jj = 1, jpj |
---|
119 | DO ji = 1, jpi |
---|
120 | trb(ji,jj,jk,jn) = atfp * ( trb(ji,jj,jk,jn) + tra(ji,jj,jk,jn) ) + atfp1 * trn(ji,jj,jk,jn) |
---|
121 | trn(ji,jj,jk,jn) = tra(ji,jj,jk,jn) |
---|
122 | tra(ji,jj,jk,jn) = 0. |
---|
123 | END DO |
---|
124 | END DO |
---|
125 | ENDIF |
---|
126 | |
---|
127 | ELSE |
---|
128 | ! case of smolar scheme or muscl |
---|
129 | DO jj = 1, jpj |
---|
130 | DO ji = 1, jpi |
---|
131 | trb(ji,jj,jk,jn) = tra(ji,jj,jk,jn) |
---|
132 | trn(ji,jj,jk,jn) = tra(ji,jj,jk,jn) |
---|
133 | tra(ji,jj,jk,jn) = 0. |
---|
134 | END DO |
---|
135 | END DO |
---|
136 | |
---|
137 | ENDIF |
---|
138 | ! ! =============== |
---|
139 | END DO ! End of slab |
---|
140 | ! ! =============== |
---|
141 | IF(ln_ctl) THEN ! print mean field (used for debugging) |
---|
142 | ztra = SUM( trn(2:nictle,2:njctle,1:jpkm1,jn)*tmask(2:nictle,2:njctle,1:jpkm1) ) |
---|
143 | WRITE(numout,*) ' trc/nxt - ',ctrcnm(jn),' : ', ztra |
---|
144 | ENDIF |
---|
145 | |
---|
146 | END DO |
---|
147 | |
---|
148 | END SUBROUTINE trc_nxt |
---|
149 | |
---|
150 | #else |
---|
151 | !!---------------------------------------------------------------------- |
---|
152 | !! Default option Empty module |
---|
153 | !!---------------------------------------------------------------------- |
---|
154 | CONTAINS |
---|
155 | SUBROUTINE trc_nxt( kt ) |
---|
156 | INTEGER, INTENT(in) :: kt |
---|
157 | WRITE(*,*) 'trc_nxt: You should not have seen this print! error?', kt |
---|
158 | END SUBROUTINE trc_nxt |
---|
159 | #endif |
---|
160 | !!====================================================================== |
---|
161 | END MODULE trcnxt |
---|