New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv_tvd.F90 in tags/nemo_v1_08/NEMO/TOP_SRC/TRP – NEMO

source: tags/nemo_v1_08/NEMO/TOP_SRC/TRP/trcadv_tvd.F90 @ 9353

Last change on this file since 9353 was 349, checked in by opalod, 19 years ago

nemo_v1_update_031 : CT : change header names
  • Property svn:eol-style set to native
  • Property svn:executable set to *
  • Property svn:keywords set to Author Date Id Revision
File size: 17.8 KB
Line 
1MODULE trcadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  trcadv_tvd  ***
4   !! Ocean passive tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6#if defined key_passivetrc
7   !!----------------------------------------------------------------------
8   !!   trc_adv_tvd  : update the passive tracer trend with the horizontal
9   !!                  and vertical advection trends using a TVD scheme
10   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
11   !!                  algorithm
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE oce_trc             ! ocean dynamics and active tracers variables
15   USE trc                 ! ocean passive tracers variables
16   USE lbclnk              ! ocean lateral boundary conditions (or mpp link)
17   USE trcbbl              ! advective passive tracers in the BBL
18   USE prtctl_trc      ! Print control for debbuging
19
20   IMPLICIT NONE
21   PRIVATE
22
23   !! * Accessibility
24   PUBLIC trc_adv_tvd    ! routine called by trcstp.F90
25
26   !! * Substitutions
27#  include "passivetrc_substitute.h90"
28   !!----------------------------------------------------------------------
29   !!   TOP 1.0 , LOCEAN-IPSL (2005)
30   !! $Header$
31   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
32   !!----------------------------------------------------------------------
33
34CONTAINS
35
36   SUBROUTINE trc_adv_tvd( kt )
37      !!----------------------------------------------------------------------
38      !!                  ***  ROUTINE trc_adv_tvd  ***
39      !!
40      !! **  Purpose :   Compute the now trend due to total advection of
41      !!       tracers and add it to the general trend of tracer equations
42      !!
43      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
44      !!       corrected flux (monotonic correction)
45      !!       note: - this advection scheme needs a leap-frog time scheme
46      !!
47      !! ** Action : - update tra with the now advective tracer trends
48      !!             - save the trends in trtrd ('key_trc_diatrd)
49      !!
50      !! History :
51      !!        !  95-12  (L. Mortier)  Original code
52      !!        !  00-01  (H. Loukos)  adapted to ORCA
53      !!        !  00-10  (MA Foujols E.Kestenare)  include file not routine
54      !!        !  00-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
55      !!        !  01-07  (E. Durand G. Madec)  adaptation to ORCA config
56      !!   9.0  !  02-06  (C. Ethe, G. Madec)  F90: Free form and module
57      !!----------------------------------------------------------------------
58      !! * Modules used
59#if defined key_trcbbl_adv
60      USE oce_trc            , zun => ua,  &  ! use ua as workspace
61         &                     zvn => va      ! use va as workspace
62      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwn
63#else
64      USE oce_trc            , zun => un,  &  ! When no bbl, zun == un
65                               zvn => vn,  &  !             zvn == vn
66                               zwn => wn      !             zwn == wn
67#endif
68      !! * Arguments
69      INTEGER, INTENT( in ) ::   kt         ! ocean time-step
70
71      !! * Local declarations
72      INTEGER  ::   ji, jj, jk,jn           ! dummy loop indices
73      REAL(wp) ::   ztra                    ! temporary scalar
74
75      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &
76         zti, ztu, ztv, ztw                ! temporary workspace
77
78      REAL(wp) ::   &
79         z2dtt, zbtr, zeu, zev, zew, z2, &  ! temporary scalar
80         zfp_ui, zfp_vj, zfp_wk,         &  !    "         "
81         zfm_ui, zfm_vj, zfm_wk             !    "         "
82
83      CHARACTER (len=22) :: charout
84      !!----------------------------------------------------------------------
85
86      IF( kt == nittrc000  .AND. lwp ) THEN
87         WRITE(numout,*)
88         WRITE(numout,*) 'trc_adv_tvd : TVD advection scheme'
89         WRITE(numout,*) '~~~~~~~~~~~'
90      ENDIF
91
92      IF( neuler == 0 .AND. kt == nittrc000 ) THEN
93         z2=1.
94      ELSE
95         z2=2.
96      ENDIF
97
98#if defined key_trcbbl_adv
99      ! Advective Bottom boundary layer: add the velocity
100      ! -------------------------------------------------
101      zun(:,:,:) = un (:,:,:) - u_trc_bbl(:,:,:)
102      zvn(:,:,:) = vn (:,:,:) - v_trc_bbl(:,:,:)
103      zwn(:,:,:) = wn (:,:,:) + w_trc_bbl(:,:,:)
104#endif
105
106      DO jn = 1, jptra
107
108         ! 1. Bottom value : flux set to zero
109         ! ---------------
110         ztu(:,:,jpk) = 0.e0
111         ztv(:,:,jpk) = 0.e0
112         ztw(:,:,jpk) = 0.e0
113         zti(:,:,jpk) = 0.e0
114
115
116         ! 2. upstream advection with initial mass fluxes & intermediate update
117         ! --------------------------------------------------------------------
118         ! upstream tracer flux in the i and j direction
119         DO jk = 1, jpkm1
120            DO jj = 1, jpjm1
121               DO ji = 1, fs_jpim1   ! vector opt.
122                  zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
123                  zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
124                  ! upstream scheme
125                  zfp_ui = zeu + ABS( zeu )
126                  zfm_ui = zeu - ABS( zeu )
127                  zfp_vj = zev + ABS( zev )
128                  zfm_vj = zev - ABS( zev )
129                  ztu(ji,jj,jk) = zfp_ui * trb(ji,jj,jk,jn) + zfm_ui * trb(ji+1,jj  ,jk,jn)
130                  ztv(ji,jj,jk) = zfp_vj * trb(ji,jj,jk,jn) + zfm_vj * trb(ji  ,jj+1,jk,jn)
131               END DO
132            END DO
133         END DO
134
135         ! upstream tracer flux in the k direction
136         ! Surface value
137         IF( lk_dynspg_fsc .OR. lk_dynspg_fsc_tsk ) THEN   ! free surface-constant volume
138            DO jj = 1, jpj
139               DO ji = 1, jpi
140                  zew = e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,1)
141                  ztw(ji,jj,1) = zew * trb(ji,jj,1,jn)
142               END DO
143            END DO
144         ELSE                                              ! rigid lid : flux set to zero
145            ztw(:,:,1) = 0.e0
146         ENDIF
147
148         ! Interior value
149         DO jk = 2, jpkm1
150            DO jj = 1, jpj
151               DO ji = 1, jpi
152                  zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk)
153                  zfp_wk = zew + ABS( zew )
154                  zfm_wk = zew - ABS( zew )
155                  ztw(ji,jj,jk) = zfp_wk * trb(ji,jj,jk,jn) + zfm_wk * trb(ji,jj,jk-1,jn)
156               END DO
157            END DO
158         END DO
159
160         ! total advective trend
161         DO jk = 1, jpkm1
162            DO jj = 2, jpjm1
163               DO ji = fs_2, fs_jpim1   ! vector opt.
164                  zbtr = 1./ ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
165                  zti(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk  )   &
166                     &              + ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  )   &
167                     &              + ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr
168               END DO
169            END DO
170         END DO
171
172
173         ! update and guess with monotonic sheme
174         DO jk = 1, jpkm1
175            z2dtt = z2 * rdttra(jk) * FLOAT(ndttrc)
176            DO jj = 2, jpjm1
177               DO ji = fs_2, fs_jpim1   ! vector opt.
178                  tra(ji,jj,jk,jn) =  tra(ji,jj,jk,jn) + zti(ji,jj,jk)
179                  zti (ji,jj,jk) = ( trb(ji,jj,jk,jn) + z2dtt * zti(ji,jj,jk) ) * tmask(ji,jj,jk)
180               END DO
181            END DO
182         END DO
183
184         ! Lateral boundary conditions on zti, zsi   (unchanged sign)
185         CALL lbc_lnk( zti, 'T', 1. )
186
187         ! 3. antidiffusive flux : high order minus low order
188         ! --------------------------------------------------
189         ! antidiffusive flux on i and j
190         DO jk = 1, jpkm1
191            DO jj = 1, jpjm1
192               DO ji = 1, fs_jpim1   ! vector opt.
193                  zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
194                  zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
195                  ztu(ji,jj,jk) = zeu * ( trn(ji,jj,jk,jn) + trn(ji+1,jj,jk,jn) ) - ztu(ji,jj,jk)
196                  ztv(ji,jj,jk) = zev * ( trn(ji,jj,jk,jn) + trn(ji,jj+1,jk,jn) ) - ztv(ji,jj,jk)
197               END DO
198            END DO
199         END DO
200
201         ! antidiffusive flux on k
202         ! Surface value
203         ztw(:,:,1) = 0.
204
205         ! Interior value
206         DO jk = 2, jpkm1
207            DO jj = 1, jpj
208               DO ji = 1, jpi
209                  zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk)
210                  ztw(ji,jj,jk) = zew * ( trn(ji,jj,jk,jn) + trn(ji,jj,jk-1,jn) ) - ztw(ji,jj,jk)
211               END DO
212            END DO
213         END DO
214
215         ! Lateral bondary conditions
216         CALL lbc_lnk( ztu, 'U', -1. )
217         CALL lbc_lnk( ztv, 'V', -1. )
218         CALL lbc_lnk( ztw, 'W',  1. )
219
220         ! 4. monotonicity algorithm
221         ! -------------------------
222         CALL nonosc( trb, ztu, ztv, ztw, zti, z2 )
223
224
225         ! 5. final trend with corrected fluxes
226         ! ------------------------------------
227         DO jk = 1, jpkm1
228            DO jj = 2, jpjm1
229               DO ji = fs_2, fs_jpim1   ! vector opt.
230                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
231                  tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn)   &
232                     &         - ( ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk  )   &
233                     &           + ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  )   &
234                     &           + ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr
235               END DO
236            END DO
237         END DO
238
239      END DO
240
241      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
242         WRITE(charout, FMT="('tvd - adv')")
243         CALL prt_ctl_trc_info(charout)
244         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
245      ENDIF
246
247   END SUBROUTINE trc_adv_tvd
248
249
250   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, prdt )
251      !!---------------------------------------------------------------------
252      !!                    ***  ROUTINE nonosc  ***
253      !!     
254      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
255      !!       scheme and the before field by a nonoscillatory algorithm
256      !!
257      !! **  Method  :   ... ???
258      !!       warning : pbef and paft must be masked, but the boundaries
259      !!       conditions on the fluxes are not necessary zalezak (1979)
260      !!       drange (1995) multi-dimensional forward-in-time and upstream-
261      !!       in-space based differencing for fluid
262      !!
263      !! History :
264      !!        !  97-04  (L. Mortier) Original code
265      !!        !  00-02  (H. Loukos)  rewritting for opa8
266      !!        !  00-10  (M.A Foujols, E. Kestenare)  lateral b.c.
267      !!        !  01-03  (E. Kestenare)  add key_passivetrc
268      !!        !  01-07  (E. Durand G. Madec)  adapted for T & S
269      !!   8.5  !  02-06  (G. Madec)  F90: Free form and module
270      !!----------------------------------------------------------------------
271      !! * Arguments
272      REAL(wp), INTENT( in ) ::   &
273         prdt                               ! ???
274      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT( inout ) ::   &
275         pbef,                            & ! before field
276         paft,                            & ! after field
277         paa,                             & ! monotonic flux in the i direction
278         pbb,                             & ! monotonic flux in the j direction
279         pcc                                ! monotonic flux in the k direction
280
281      !! * Local declarations
282      INTEGER ::   ji, jj, jk               ! dummy loop indices
283      INTEGER ::   ikm1
284      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zbetup, zbetdo
285      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt
286      !!----------------------------------------------------------------------
287
288      zbig = 1.e+40
289      zrtrn = 1.e-15
290
291      ! Search local extrema
292      ! --------------------
293      ! large negative value (-zbig) inside land
294      ! large negative value (-zbig) inside land
295      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) )
296      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) )
297      ! search maximum in neighbourhood
298      DO jk = 1, jpkm1
299         ikm1 = MAX(jk-1,1)
300         DO jj = 2, jpjm1
301            DO ji = fs_2, fs_jpim1   ! vector opt.
302               zbetup(ji,jj,jk) = MAX(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
303                  &                     pbef(ji-1,jj  ,jk  ), pbef(ji+1,jj  ,jk  ),   &
304                  &                     paft(ji-1,jj  ,jk  ), paft(ji+1,jj  ,jk  ),   &
305                  &                     pbef(ji  ,jj-1,jk  ), pbef(ji  ,jj+1,jk  ),   &
306                  &                     paft(ji  ,jj-1,jk  ), paft(ji  ,jj+1,jk  ),   &
307                  &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
308                  &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
309            END DO
310         END DO
311      END DO
312      ! large positive value (+zbig) inside land
313      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) )
314      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) )
315      ! search minimum in neighbourhood
316      DO jk = 1, jpkm1
317         ikm1 = MAX(jk-1,1)
318         DO jj = 2, jpjm1
319            DO ji = fs_2, fs_jpim1   ! vector opt.
320               zbetdo(ji,jj,jk) = MIN(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
321                  &                     pbef(ji-1,jj  ,jk  ), pbef(ji+1,jj  ,jk  ),   &
322                  &                     paft(ji-1,jj  ,jk  ), paft(ji+1,jj  ,jk  ),   &
323                  &                     pbef(ji  ,jj-1,jk  ), pbef(ji  ,jj+1,jk  ),   &
324                  &                     paft(ji  ,jj-1,jk  ), paft(ji  ,jj+1,jk  ),   &
325                  &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
326                  &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
327            END DO
328         END DO
329      END DO
330
331      ! restore masked values to zero
332      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:)
333      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:)
334 
335
336      ! 2. Positive and negative part of fluxes and beta terms
337      ! ------------------------------------------------------
338
339      DO jk = 1, jpkm1
340         z2dtt = prdt * rdttra(jk) * FLOAT(ndttrc)
341         DO jj = 2, jpjm1
342            DO ji = fs_2, fs_jpim1   ! vector opt.
343               ! positive & negative part of the flux
344               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
345                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
346                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
347               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
348                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
349                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
350               ! up & down beta terms
351               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
352               zbetup(ji,jj,jk) = ( zbetup(ji,jj,jk) - paft(ji,jj,jk) ) / (zpos+zrtrn) * zbt
353               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zbetdo(ji,jj,jk) ) / (zneg+zrtrn) * zbt
354            END DO
355         END DO
356      END DO
357
358      ! lateral boundary condition on zbetup & zbetdo   (unchanged sign)
359      CALL lbc_lnk( zbetup, 'T', 1. )
360      CALL lbc_lnk( zbetdo, 'T', 1. )
361
362
363      ! 3. monotonic flux in the i direction, i.e. paa
364      ! ----------------------------------------------
365      DO jk = 1, jpkm1
366         DO jj = 2, jpjm1
367            DO ji = fs_2, fs_jpim1   ! vector opt.
368               zc = paa(ji,jj,jk)
369               IF( zc >= 0. ) THEN
370                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
371                  paa(ji,jj,jk) = za * zc
372               ELSE
373                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
374                  paa(ji,jj,jk) = zb * zc
375               ENDIF
376            END DO
377         END DO
378      END DO
379
380      ! lateral boundary condition on paa   (changed sign)
381      CALL lbc_lnk( paa, 'U', -1. )
382
383
384      ! 4. monotonic flux in the j direction, i.e. pbb
385      ! ----------------------------------------------
386      DO jk = 1, jpkm1
387         DO jj = 2, jpjm1
388            DO ji = fs_2, fs_jpim1   ! vector opt.
389               zc = pbb(ji,jj,jk)
390               IF( zc >= 0. ) THEN
391                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
392                  pbb(ji,jj,jk) = za * zc
393               ELSE
394                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
395                  pbb(ji,jj,jk) = zb * zc
396               ENDIF
397            END DO
398         END DO
399      END DO
400
401      ! lateral boundary condition on pbb   (changed sign)
402      CALL lbc_lnk( pbb, 'V', -1. )
403
404
405      ! monotonic flux in the k direction, i.e. pcc
406      ! -------------------------------------------
407      DO jk = 2, jpkm1
408         DO jj = 2, jpjm1
409            DO ji = fs_2, fs_jpim1   ! vector opt.
410               zc = pcc(ji,jj,jk)
411               IF( zc >= 0. ) THEN
412                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj,jk-1) )
413                  pcc(ji,jj,jk) = za * zc
414               ELSE
415                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj,jk-1) )
416                  pcc(ji,jj,jk) = zb * zc
417               ENDIF
418            END DO
419         END DO
420      END DO
421
422      ! lateral boundary condition on pcc   (unchanged sign)
423      CALL lbc_lnk( pcc, 'W', 1. )
424
425   END SUBROUTINE nonosc
426
427#else
428   !!----------------------------------------------------------------------
429   !!   Default option                                         Empty module
430   !!----------------------------------------------------------------------
431CONTAINS
432   SUBROUTINE trc_adv_tvd( kt ) 
433      INTEGER, INTENT(in) :: kt
434      WRITE(*,*) 'trc_adv_tvd: You should not have seen this print! error?', kt
435   END SUBROUTINE trc_adv_tvd
436#endif
437
438   !!======================================================================
439END MODULE trcadv_tvd
Note: See TracBrowser for help on using the repository browser.