1 | MODULE traadv_eiv |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE traadv_eiv *** |
---|
4 | !! Ocean active tracers: advection trend - eddy induced velocity |
---|
5 | !!====================================================================== |
---|
6 | !! History : 9.0 ! 05-11 (G. Madec) Original code, from traldf and zdf _iso |
---|
7 | !!---------------------------------------------------------------------- |
---|
8 | #if defined key_traldf_eiv || defined key_esopa |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | !! 'key_traldf_eiv' rotation of the lateral mixing tensor |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! tra_ldf_iso : update the tracer trend with the horizontal component |
---|
14 | !! of iso neutral laplacian operator or horizontal |
---|
15 | !! laplacian operator in s-coordinate |
---|
16 | !!---------------------------------------------------------------------- |
---|
17 | USE oce ! ocean dynamics and tracers variables |
---|
18 | USE dom_oce ! ocean space and time domain variables |
---|
19 | USE ldftra_oce ! ocean active tracers: lateral physics |
---|
20 | USE ldfslp ! iso-neutral slopes |
---|
21 | USE in_out_manager ! I/O manager |
---|
22 | |
---|
23 | IMPLICIT NONE |
---|
24 | PRIVATE |
---|
25 | |
---|
26 | PUBLIC tra_adv_eiv ! routine called by step.F90 |
---|
27 | |
---|
28 | !! * Substitutions |
---|
29 | # include "domzgr_substitute.h90" |
---|
30 | # include "ldftra_substitute.h90" |
---|
31 | # include "ldfeiv_substitute.h90" |
---|
32 | # include "vectopt_loop_substitute.h90" |
---|
33 | !!---------------------------------------------------------------------- |
---|
34 | !! OPA 9.0 , LOCEAN-IPSL (2006) |
---|
35 | !! $Header$ |
---|
36 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
---|
37 | !!---------------------------------------------------------------------- |
---|
38 | |
---|
39 | CONTAINS |
---|
40 | |
---|
41 | SUBROUTINE tra_adv_eiv( kt, pun, pvn, pwn ) |
---|
42 | !!---------------------------------------------------------------------- |
---|
43 | !! *** ROUTINE tra_adv_eiv *** |
---|
44 | !! |
---|
45 | !! ** Purpose : Compute the before horizontal tracer (t & s) diffusive |
---|
46 | !! trend and add it to the general trend of tracer equation. |
---|
47 | !! |
---|
48 | !! ** Method : The eddy induced advection is computed from the slope |
---|
49 | !! of iso-neutral surfaces computed in routine ldf_slp as follows: |
---|
50 | !! zu_eiv = 1/(e2u e3u) dk[ aeiu e2u mi(wslpi) ] |
---|
51 | !! zv_eiv = 1/(e1v e3v) dk[ aeiv e1v mj(wslpj) |
---|
52 | !! zw_eiv = -1/(e1t e2t) { di[ aeiu e2u mi(wslpi) ] |
---|
53 | !! + dj[ aeiv e1v mj(wslpj) ] } |
---|
54 | !! add the eiv component to the model velocity: |
---|
55 | !! p.n = p.n + z._eiv |
---|
56 | !! |
---|
57 | !! ** Action : - add to p.n the eiv component |
---|
58 | !!---------------------------------------------------------------------- |
---|
59 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
---|
60 | REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) :: pun ! in : 3 ocean velocity components |
---|
61 | REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) :: pvn ! out: 3 ocean velocity components |
---|
62 | REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) :: pwn ! increased by the eiv |
---|
63 | !! |
---|
64 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
65 | REAL(wp) :: zuwk, zuwk1, zuwi, zuwi1 ! temporary scalar |
---|
66 | REAL(wp) :: zvwk, zvwk1, zvwj, zvwj1 ! " " |
---|
67 | REAL(wp) :: zu_eiv, zv_eiv, zw_eiv ! " " |
---|
68 | !!---------------------------------------------------------------------- |
---|
69 | |
---|
70 | IF( kt == nit000 ) THEN |
---|
71 | IF(lwp) WRITE(numout,*) |
---|
72 | IF(lwp) WRITE(numout,*) 'tra_adv_eiv : eddy induced advection :' |
---|
73 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ add to velocity fields the eiv component' |
---|
74 | # if defined key_diaeiv |
---|
75 | u_eiv(:,:,:) = 0.e0 |
---|
76 | v_eiv(:,:,:) = 0.e0 |
---|
77 | w_eiv(:,:,:) = 0.e0 |
---|
78 | # endif |
---|
79 | ENDIF |
---|
80 | ! ! ================= |
---|
81 | DO jk = 1, jpkm1 ! Horizontal slab |
---|
82 | ! ! ================= |
---|
83 | DO jj = 1, jpjm1 |
---|
84 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
85 | zuwk = ( wslpi(ji,jj,jk ) + wslpi(ji+1,jj,jk ) ) * fsaeiu(ji,jj,jk ) * umask(ji,jj,jk ) |
---|
86 | zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeiu(ji,jj,jk+1) * umask(ji,jj,jk+1) |
---|
87 | zvwk = ( wslpj(ji,jj,jk ) + wslpj(ji,jj+1,jk ) ) * fsaeiv(ji,jj,jk ) * vmask(ji,jj,jk ) |
---|
88 | zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeiv(ji,jj,jk+1) * vmask(ji,jj,jk+1) |
---|
89 | |
---|
90 | zu_eiv = 0.5 * umask(ji,jj,jk) * ( zuwk - zuwk1 ) / fse3u(ji,jj,jk) |
---|
91 | zv_eiv = 0.5 * vmask(ji,jj,jk) * ( zvwk - zvwk1 ) / fse3v(ji,jj,jk) |
---|
92 | |
---|
93 | pun(ji,jj,jk) = pun(ji,jj,jk) + zu_eiv |
---|
94 | pvn(ji,jj,jk) = pvn(ji,jj,jk) + zv_eiv |
---|
95 | # if defined key_diaeiv |
---|
96 | u_eiv(ji,jj,jk) = zu_eiv |
---|
97 | v_eiv(ji,jj,jk) = zv_eiv |
---|
98 | # endif |
---|
99 | END DO |
---|
100 | END DO |
---|
101 | IF( jk >=2 ) THEN ! jk=1 zw_eiv=0, not computed |
---|
102 | DO jj = 2, jpjm1 |
---|
103 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
104 | # if defined key_traldf_c2d || defined key_traldf_c3d |
---|
105 | zuwi = ( wslpi(ji,jj,jk)+wslpi(ji-1,jj,jk) ) * fsaeiu(ji-1,jj,jk) * e2u(ji-1,jj) * umask(ji-1,jj,jk) |
---|
106 | zuwi1 = ( wslpi(ji,jj,jk)+wslpi(ji+1,jj,jk) ) * fsaeiu(ji ,jj,jk) * e2u(ji ,jj) * umask(ji ,jj,jk) |
---|
107 | zvwj = ( wslpj(ji,jj,jk)+wslpj(ji,jj-1,jk) ) * fsaeiv(ji,jj-1,jk) * e1v(ji,jj-1) * vmask(ji,jj-1,jk) |
---|
108 | zvwj1 = ( wslpj(ji,jj,jk)+wslpj(ji,jj+1,jk) ) * fsaeiv(ji,jj ,jk) * e1v(ji ,jj) * vmask(ji ,jj,jk) |
---|
109 | |
---|
110 | zw_eiv = - 0.5 * tmask(ji,jj,jk) * ( zuwi1 - zuwi + zvwj1 - zvwj ) / ( e1t(ji,jj)*e2t(ji,jj) ) |
---|
111 | # else |
---|
112 | zuwi = ( wslpi(ji,jj,jk) + wslpi(ji-1,jj,jk) ) * e2u(ji-1,jj) * umask(ji-1,jj,jk) |
---|
113 | zuwi1 = ( wslpi(ji,jj,jk) + wslpi(ji+1,jj,jk) ) * e2u(ji ,jj) * umask(ji ,jj,jk) |
---|
114 | zvwj = ( wslpj(ji,jj,jk) + wslpj(ji,jj-1,jk) ) * e1v(ji,jj-1) * vmask(ji,jj-1,jk) |
---|
115 | zvwj1 = ( wslpj(ji,jj,jk) + wslpj(ji,jj+1,jk) ) * e1v(ji ,jj) * vmask(ji ,jj,jk) |
---|
116 | |
---|
117 | zw_eiv = - 0.5 * tmask(ji,jj,jk) * fsaeiw(ji,jj,jk) * ( zuwi1 - zuwi + zvwj1 - zvwj ) & |
---|
118 | & / ( e1t(ji,jj)*e2t(ji,jj) ) |
---|
119 | # endif |
---|
120 | pwn(ji,jj,jk) = pwn(ji,jj,jk) + zw_eiv |
---|
121 | |
---|
122 | # if defined key_diaeiv |
---|
123 | w_eiv(ji,jj,jk) = zw_eiv |
---|
124 | # endif |
---|
125 | END DO |
---|
126 | END DO |
---|
127 | ENDIF |
---|
128 | ! ! ================= |
---|
129 | END DO ! End of slab |
---|
130 | ! ! ================= |
---|
131 | END SUBROUTINE tra_adv_eiv |
---|
132 | |
---|
133 | #else |
---|
134 | !!---------------------------------------------------------------------- |
---|
135 | !! Dummy module : No rotation of the lateral mixing tensor |
---|
136 | !!---------------------------------------------------------------------- |
---|
137 | CONTAINS |
---|
138 | SUBROUTINE tra_adv_eiv( kt, pun, pvn, pwn ) ! Empty routine |
---|
139 | REAL, DIMENSION(:,:,:) :: pun, pvn, pwn |
---|
140 | WRITE(*,*) 'tra_adv_eiv: You should not have seen this print! error?', kt, pun(1,1,1), pvn(1,1,1), pwn(1,1,1) |
---|
141 | END SUBROUTINE tra_adv_eiv |
---|
142 | #endif |
---|
143 | |
---|
144 | !!============================================================================== |
---|
145 | END MODULE traadv_eiv |
---|