| 1 | MODULE daymod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE daymod *** |
|---|
| 4 | !! Ocean : calendar |
|---|
| 5 | !!===================================================================== |
|---|
| 6 | !! History : OPA ! 1994-09 (M. Pontaud M. Imbard) Original code |
|---|
| 7 | !! ! 1997-03 (O. Marti) |
|---|
| 8 | !! ! 1997-05 (G. Madec) |
|---|
| 9 | !! ! 1997-08 (M. Imbard) |
|---|
| 10 | !! NEMO 1.0 ! 2003-09 (G. Madec) F90 + nyear, nmonth, nday |
|---|
| 11 | !! ! 2004-01 (A.M. Treguier) new calculation based on adatrj |
|---|
| 12 | !! ! 2006-08 (G. Madec) surface module major update |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! day : calendar |
|---|
| 17 | !! |
|---|
| 18 | !! ------------------------------- |
|---|
| 19 | !! ----------- WARNING ----------- |
|---|
| 20 | !! |
|---|
| 21 | !! we suppose that the time step is deviding the number of second of in a day |
|---|
| 22 | !! ---> MOD( rday, rdttra(1) ) == 0 |
|---|
| 23 | !! |
|---|
| 24 | !! ----------- WARNING ----------- |
|---|
| 25 | !! ------------------------------- |
|---|
| 26 | !! |
|---|
| 27 | !!---------------------------------------------------------------------- |
|---|
| 28 | USE dom_oce ! ocean space and time domain |
|---|
| 29 | USE phycst ! physical constants |
|---|
| 30 | USE in_out_manager ! I/O manager |
|---|
| 31 | USE iom ! |
|---|
| 32 | USE ioipsl, ONLY : ymds2ju ! for calendar |
|---|
| 33 | USE prtctl ! Print control |
|---|
| 34 | USE restart ! |
|---|
| 35 | |
|---|
| 36 | IMPLICIT NONE |
|---|
| 37 | PRIVATE |
|---|
| 38 | |
|---|
| 39 | PUBLIC day ! called by step.F90 |
|---|
| 40 | PUBLIC day_init ! called by istate.F90 |
|---|
| 41 | |
|---|
| 42 | INTEGER :: nsecd, nsecd05, ndt, ndt05 |
|---|
| 43 | |
|---|
| 44 | !!---------------------------------------------------------------------- |
|---|
| 45 | !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009) |
|---|
| 46 | !! $Id: daymod.F90 1730 2009-11-16 14:34:19Z smasson $ |
|---|
| 47 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
|---|
| 48 | !!---------------------------------------------------------------------- |
|---|
| 49 | |
|---|
| 50 | CONTAINS |
|---|
| 51 | |
|---|
| 52 | SUBROUTINE day_init |
|---|
| 53 | !!---------------------------------------------------------------------- |
|---|
| 54 | !! *** ROUTINE day_init *** |
|---|
| 55 | !! |
|---|
| 56 | !! ** Purpose : Initialization of the calendar values to their values 1 time step before nit000 |
|---|
| 57 | !! because day will be called at the beginning of step |
|---|
| 58 | !! |
|---|
| 59 | !! ** Action : - nyear : current year |
|---|
| 60 | !! - nmonth : current month of the year nyear |
|---|
| 61 | !! - nday : current day of the month nmonth |
|---|
| 62 | !! - nday_year : current day of the year nyear |
|---|
| 63 | !! - nsec_year : current time step counted in second since 00h jan 1st of the current year |
|---|
| 64 | !! - nsec_month : current time step counted in second since 00h 1st day of the current month |
|---|
| 65 | !! - nsec_day : current time step counted in second since 00h of the current day |
|---|
| 66 | !! - nsec1jan000 : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year |
|---|
| 67 | !! - nmonth_len, nyear_len, nmonth_half, nmonth_end through day_mth |
|---|
| 68 | !!---------------------------------------------------------------------- |
|---|
| 69 | |
|---|
| 70 | ! all calendar staff is based on the fact that MOD( rday, rdttra(1) ) == 0 |
|---|
| 71 | IF( MOD( rday , rdttra(1) ) /= 0. ) CALL ctl_stop( 'the time step must devide the number of second of in a day' ) |
|---|
| 72 | IF( MOD( rday , 2. ) /= 0. ) CALL ctl_stop( 'the number of second of in a day must be an even number' ) |
|---|
| 73 | IF( MOD( rdttra(1), 2. ) /= 0. ) CALL ctl_stop( 'the time step (in second) must be an even number' ) |
|---|
| 74 | nsecd = NINT(rday ) |
|---|
| 75 | nsecd05 = NINT(0.5 * rday ) |
|---|
| 76 | ndt = NINT( rdttra(1)) |
|---|
| 77 | ndt05 = NINT(0.5 * rdttra(1)) |
|---|
| 78 | |
|---|
| 79 | CALL day_rst( nit000, 'READ' ) |
|---|
| 80 | |
|---|
| 81 | ! set the calandar from ndastp (read in restart file and namelist) |
|---|
| 82 | |
|---|
| 83 | nyear = ndastp / 10000 |
|---|
| 84 | nmonth = ( ndastp - (nyear * 10000) ) / 100 |
|---|
| 85 | nday = ndastp - (nyear * 10000) - ( nmonth * 100 ) |
|---|
| 86 | |
|---|
| 87 | CALL ymds2ju( nyear, nmonth, nday, 0.0, fjulday ) ! we assume that we start run at 00:00 |
|---|
| 88 | IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < 0.1 / rday ) fjulday = REAL(NINT(fjulday),wp) ! avoid truncation error |
|---|
| 89 | fjulday = fjulday + 1. ! move back to the day at nit000 (and not at nit000 - 1) |
|---|
| 90 | |
|---|
| 91 | nsec1jan000 = 0 |
|---|
| 92 | CALL day_mth |
|---|
| 93 | |
|---|
| 94 | IF ( nday == 0 ) THEN ! for ex if ndastp = ndate0 - 1 |
|---|
| 95 | nmonth = nmonth - 1 |
|---|
| 96 | nday = nmonth_len(nmonth) |
|---|
| 97 | ENDIF |
|---|
| 98 | IF ( nmonth == 0 ) THEN ! go at the end of previous year |
|---|
| 99 | nmonth = 12 |
|---|
| 100 | nyear = nyear - 1 |
|---|
| 101 | nsec1jan000 = nsec1jan000 - nsecd * nyear_len(0) |
|---|
| 102 | IF( nleapy == 1 ) CALL day_mth |
|---|
| 103 | ENDIF |
|---|
| 104 | |
|---|
| 105 | ! day since january 1st |
|---|
| 106 | nday_year = nday + SUM( nmonth_len(1:nmonth - 1) ) |
|---|
| 107 | |
|---|
| 108 | ! number of seconds since the beginning of current year/month at the middle of the time-step |
|---|
| 109 | nsec_year = nday_year * nsecd - ndt05 ! 1 time step before the middle of the first time step |
|---|
| 110 | nsec_month = nday * nsecd - ndt05 ! because day will be called at the beginning of step |
|---|
| 111 | nsec_day = nsecd - ndt05 |
|---|
| 112 | |
|---|
| 113 | ! control print |
|---|
| 114 | IF(lwp) WRITE(numout,'(a,i6,a,i2,a,i2,a,i6)')' ==============>> 1/2 time step before the start of the run DATE Y/M/D = ', & |
|---|
| 115 | & nyear, '/', nmonth, '/', nday, ' nsec_day:', nsec_day |
|---|
| 116 | |
|---|
| 117 | ! Up to now, calendar parameters are related to the end of previous run (nit000-1) |
|---|
| 118 | ! call day to set the calendar parameters at the begining of the current simulaton. needed by iom_init |
|---|
| 119 | CALL day( nit000 ) |
|---|
| 120 | |
|---|
| 121 | |
|---|
| 122 | END SUBROUTINE day_init |
|---|
| 123 | |
|---|
| 124 | |
|---|
| 125 | SUBROUTINE day_mth |
|---|
| 126 | !!---------------------------------------------------------------------- |
|---|
| 127 | !! *** ROUTINE day_init *** |
|---|
| 128 | !! |
|---|
| 129 | !! ** Purpose : calendar values related to the months |
|---|
| 130 | !! |
|---|
| 131 | !! ** Action : - nmonth_len : length in days of the months of the current year |
|---|
| 132 | !! - nyear_len : length in days of the previous/current year |
|---|
| 133 | !! - nmonth_half : second since the beginning of the year and the halft of the months |
|---|
| 134 | !! - nmonth_end : second since the beginning of the year and the end of the months |
|---|
| 135 | !!---------------------------------------------------------------------- |
|---|
| 136 | INTEGER :: jm ! dummy loop indice |
|---|
| 137 | !!---------------------------------------------------------------------- |
|---|
| 138 | |
|---|
| 139 | ! length of the month of the current year (from nleapy, read in namelist) |
|---|
| 140 | IF ( nleapy < 2 ) THEN |
|---|
| 141 | nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /) |
|---|
| 142 | nyear_len(:) = 365 |
|---|
| 143 | IF ( nleapy == 1 ) THEN ! we are using calandar with leap years |
|---|
| 144 | IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN |
|---|
| 145 | nyear_len(0) = 366 |
|---|
| 146 | ENDIF |
|---|
| 147 | IF ( MOD(nyear, 4) == 0 .AND. ( MOD(nyear, 400) == 0 .OR. MOD(nyear, 100) /= 0 ) ) THEN |
|---|
| 148 | nmonth_len(2) = 29 |
|---|
| 149 | nyear_len(1) = 366 |
|---|
| 150 | ENDIF |
|---|
| 151 | ENDIF |
|---|
| 152 | ELSE |
|---|
| 153 | nmonth_len(:) = nleapy ! all months with nleapy days per year |
|---|
| 154 | nyear_len(:) = 12 * nleapy |
|---|
| 155 | ENDIF |
|---|
| 156 | |
|---|
| 157 | ! half month in second since the begining of the year: |
|---|
| 158 | ! time since Jan 1st 0 1 2 ... 11 12 13 |
|---|
| 159 | ! ---------*--|--*--|--*--| ... |--*--|--*--|--*--|-------------------------------------- |
|---|
| 160 | ! <---> <---> <---> ... <---> <---> <---> |
|---|
| 161 | ! month number 0 1 2 ... 11 12 13 |
|---|
| 162 | ! |
|---|
| 163 | ! nmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) ) |
|---|
| 164 | nmonth_half(0) = - nsecd05 * nmonth_len(0) |
|---|
| 165 | DO jm = 1, 13 |
|---|
| 166 | nmonth_half(jm) = nmonth_half(jm-1) + nsecd05 * ( nmonth_len(jm-1) + nmonth_len(jm) ) |
|---|
| 167 | END DO |
|---|
| 168 | |
|---|
| 169 | nmonth_end(0) = 0 |
|---|
| 170 | DO jm = 1, 13 |
|---|
| 171 | nmonth_end(jm) = nmonth_end(jm-1) + nsecd * nmonth_len(jm) |
|---|
| 172 | END DO |
|---|
| 173 | ! |
|---|
| 174 | END SUBROUTINE |
|---|
| 175 | |
|---|
| 176 | |
|---|
| 177 | SUBROUTINE day( kt ) |
|---|
| 178 | !!---------------------------------------------------------------------- |
|---|
| 179 | !! *** ROUTINE day *** |
|---|
| 180 | !! |
|---|
| 181 | !! ** Purpose : Compute the date with a day iteration IF necessary. |
|---|
| 182 | !! |
|---|
| 183 | !! ** Method : - ??? |
|---|
| 184 | !! |
|---|
| 185 | !! ** Action : - nyear : current year |
|---|
| 186 | !! - nmonth : current month of the year nyear |
|---|
| 187 | !! - nday : current day of the month nmonth |
|---|
| 188 | !! - nday_year : current day of the year nyear |
|---|
| 189 | !! - ndastp : = nyear*10000 + nmonth*100 + nday |
|---|
| 190 | !! - adatrj : date in days since the beginning of the run |
|---|
| 191 | !! - nsec_year : current time of the year (in second since 00h, jan 1st) |
|---|
| 192 | !!---------------------------------------------------------------------- |
|---|
| 193 | INTEGER, INTENT(in) :: kt ! ocean time-step indices |
|---|
| 194 | ! |
|---|
| 195 | CHARACTER (len=25) :: charout |
|---|
| 196 | REAL(wp) :: zprec ! fraction of day corresponding to 0.1 second |
|---|
| 197 | !!---------------------------------------------------------------------- |
|---|
| 198 | zprec = 0.1 / rday |
|---|
| 199 | ! ! New time-step |
|---|
| 200 | nsec_year = nsec_year + ndt |
|---|
| 201 | nsec_month = nsec_month + ndt |
|---|
| 202 | nsec_day = nsec_day + ndt |
|---|
| 203 | adatrj = adatrj + rdttra(1) / rday |
|---|
| 204 | fjulday = fjulday + rdttra(1) / rday |
|---|
| 205 | IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < zprec ) fjulday = REAL(NINT(fjulday),wp) ! avoid truncation error |
|---|
| 206 | IF( ABS(adatrj - REAL(NINT(adatrj ),wp)) < zprec ) adatrj = REAL(NINT(adatrj ),wp) ! avoid truncation error |
|---|
| 207 | |
|---|
| 208 | IF( nsec_day > nsecd ) THEN ! NEW day |
|---|
| 209 | ! |
|---|
| 210 | nday = nday + 1 |
|---|
| 211 | nday_year = nday_year + 1 |
|---|
| 212 | nsec_day = ndt05 |
|---|
| 213 | ! |
|---|
| 214 | IF( nday == nmonth_len(nmonth) + 1 ) THEN ! NEW month |
|---|
| 215 | nday = 1 |
|---|
| 216 | nmonth = nmonth + 1 |
|---|
| 217 | nsec_month = ndt05 |
|---|
| 218 | IF( nmonth == 13 ) THEN ! NEW year |
|---|
| 219 | nyear = nyear + 1 |
|---|
| 220 | nmonth = 1 |
|---|
| 221 | nday_year = 1 |
|---|
| 222 | nsec_year = ndt05 |
|---|
| 223 | nsec1jan000 = nsec1jan000 + nsecd * nyear_len(1) |
|---|
| 224 | IF( nleapy == 1 ) CALL day_mth |
|---|
| 225 | ENDIF |
|---|
| 226 | ENDIF |
|---|
| 227 | ! |
|---|
| 228 | ndastp = nyear * 10000 + nmonth * 100 + nday ! NEW date |
|---|
| 229 | ! |
|---|
| 230 | IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt, & |
|---|
| 231 | & ' New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, ' nday_year = ', nday_year |
|---|
| 232 | IF(lwp) WRITE(numout,'(a,i8,a,i7,a,i5)') ' nsec_year = ', nsec_year, & |
|---|
| 233 | & ' nsec_month = ', nsec_month, ' nsec_day = ', nsec_day |
|---|
| 234 | ENDIF |
|---|
| 235 | |
|---|
| 236 | IF(ln_ctl) THEN |
|---|
| 237 | WRITE(charout,FMT="('kt =', I4,' d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear |
|---|
| 238 | CALL prt_ctl_info(charout) |
|---|
| 239 | ENDIF |
|---|
| 240 | |
|---|
| 241 | IF( lrst_oce ) CALL day_rst( kt, 'WRITE' ) |
|---|
| 242 | ! |
|---|
| 243 | END SUBROUTINE day |
|---|
| 244 | |
|---|
| 245 | |
|---|
| 246 | SUBROUTINE day_rst( kt, cdrw ) |
|---|
| 247 | !!--------------------------------------------------------------------- |
|---|
| 248 | !! *** ROUTINE ts_rst *** |
|---|
| 249 | !! |
|---|
| 250 | !! ** Purpose : Read or write calendar in restart file: |
|---|
| 251 | !! |
|---|
| 252 | !! WRITE(READ) mode: |
|---|
| 253 | !! kt : number of time step since the begining of the experiment at the |
|---|
| 254 | !! end of the current(previous) run |
|---|
| 255 | !! adatrj(0) : number of elapsed days since the begining of the experiment at the |
|---|
| 256 | !! end of the current(previous) run (REAL -> keep fractions of day) |
|---|
| 257 | !! ndastp : date at the end of the current(previous) run (coded as yyyymmdd integer) |
|---|
| 258 | !! |
|---|
| 259 | !! According to namelist parameter nrstdt, |
|---|
| 260 | !! nrstdt = 0 no control on the date (nit000 is arbitrary). |
|---|
| 261 | !! nrstdt = 1 we verify that nit000 is equal to the last |
|---|
| 262 | !! time step of previous run + 1. |
|---|
| 263 | !! In both those options, the exact duration of the experiment |
|---|
| 264 | !! since the beginning (cumulated duration of all previous restart runs) |
|---|
| 265 | !! is not stored in the restart and is assumed to be (nit000-1)*rdt. |
|---|
| 266 | !! This is valid is the time step has remained constant. |
|---|
| 267 | !! |
|---|
| 268 | !! nrstdt = 2 the duration of the experiment in days (adatrj) |
|---|
| 269 | !! has been stored in the restart file. |
|---|
| 270 | !!---------------------------------------------------------------------- |
|---|
| 271 | INTEGER , INTENT(in) :: kt ! ocean time-step |
|---|
| 272 | CHARACTER(len=*), INTENT(in) :: cdrw ! "READ"/"WRITE" flag |
|---|
| 273 | ! |
|---|
| 274 | REAL(wp) :: zkt, zndastp |
|---|
| 275 | !!---------------------------------------------------------------------- |
|---|
| 276 | |
|---|
| 277 | IF( TRIM(cdrw) == 'READ' ) THEN |
|---|
| 278 | |
|---|
| 279 | IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 280 | ! Get Calendar informations |
|---|
| 281 | CALL iom_get( numror, 'kt', zkt ) ! last time-step of previous run |
|---|
| 282 | IF(lwp) THEN |
|---|
| 283 | WRITE(numout,*) ' *** Info read in restart : ' |
|---|
| 284 | WRITE(numout,*) ' previous time-step : ', NINT( zkt ) |
|---|
| 285 | WRITE(numout,*) ' *** restart option' |
|---|
| 286 | SELECT CASE ( nrstdt ) |
|---|
| 287 | CASE ( 0 ) ; WRITE(numout,*) ' nrstdt = 0 : no control of nit000' |
|---|
| 288 | CASE ( 1 ) ; WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)' |
|---|
| 289 | CASE ( 2 ) ; WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart' |
|---|
| 290 | END SELECT |
|---|
| 291 | WRITE(numout,*) |
|---|
| 292 | ENDIF |
|---|
| 293 | ! Control of date |
|---|
| 294 | IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 ) & |
|---|
| 295 | & CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart', & |
|---|
| 296 | & ' verify the restart file or rerun with nrstdt = 0 (namelist)' ) |
|---|
| 297 | ! define ndastp and adatrj |
|---|
| 298 | IF ( nrstdt == 2 ) THEN |
|---|
| 299 | ! read the parameters correspondting to nit000 - 1 (last time step of previous run) |
|---|
| 300 | CALL iom_get( numror, 'ndastp', zndastp ) |
|---|
| 301 | ndastp = NINT( zndastp ) |
|---|
| 302 | CALL iom_get( numror, 'adatrj', adatrj ) |
|---|
| 303 | ELSE |
|---|
| 304 | ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day) |
|---|
| 305 | ndastp = ndate0 - 1 ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00 |
|---|
| 306 | adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday |
|---|
| 307 | ! note this is wrong if time step has changed during run |
|---|
| 308 | ENDIF |
|---|
| 309 | ELSE |
|---|
| 310 | ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day) |
|---|
| 311 | ndastp = ndate0 - 1 ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00 |
|---|
| 312 | adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday |
|---|
| 313 | ENDIF |
|---|
| 314 | IF( ABS(adatrj - REAL(NINT(adatrj),wp)) < 0.1 / rday ) adatrj = REAL(NINT(adatrj),wp) ! avoid truncation error |
|---|
| 315 | ! |
|---|
| 316 | IF(lwp) THEN |
|---|
| 317 | WRITE(numout,*) ' *** Info used values : ' |
|---|
| 318 | WRITE(numout,*) ' date ndastp : ', ndastp |
|---|
| 319 | WRITE(numout,*) ' number of elapsed days since the begining of run : ', adatrj |
|---|
| 320 | WRITE(numout,*) |
|---|
| 321 | ENDIF |
|---|
| 322 | ! |
|---|
| 323 | ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN |
|---|
| 324 | ! |
|---|
| 325 | IF( kt == nitrst ) THEN |
|---|
| 326 | IF(lwp) WRITE(numout,*) |
|---|
| 327 | IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file kt =', kt |
|---|
| 328 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
|---|
| 329 | ENDIF |
|---|
| 330 | ! calendar control |
|---|
| 331 | CALL iom_rstput( kt, nitrst, numrow, 'kt' , REAL( kt , wp) ) ! time-step |
|---|
| 332 | CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) ) ! date |
|---|
| 333 | CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj ) ! number of elapsed days since |
|---|
| 334 | ! ! the begining of the run [s] |
|---|
| 335 | ENDIF |
|---|
| 336 | ! |
|---|
| 337 | END SUBROUTINE day_rst |
|---|
| 338 | |
|---|
| 339 | !!====================================================================== |
|---|
| 340 | END MODULE daymod |
|---|
