New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_eiv.F90 in tags/nemo_v3_2_beta/NEMO/OPA_SRC/TRA – NEMO

source: tags/nemo_v3_2_beta/NEMO/OPA_SRC/TRA/traadv_eiv.F90 @ 1784

Last change on this file since 1784 was 1482, checked in by smasson, 15 years ago

distribution of iom_put + cleaning of LIM2 outputs, see ticket:437
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 7.7 KB
Line 
1MODULE traadv_eiv
2   !!======================================================================
3   !!                    ***  MODULE  traadv_eiv  ***
4   !! Ocean active tracers:  advection trend - eddy induced velocity
5   !!======================================================================
6   !! History :  9.0  !  05-11  (G. Madec)  Original code, from traldf and zdf _iso
7   !!----------------------------------------------------------------------
8#if defined key_traldf_eiv   ||   defined key_esopa
9   !!----------------------------------------------------------------------
10   !!   'key_traldf_eiv'                  rotation of the lateral mixing tensor
11   !!----------------------------------------------------------------------
12   !!----------------------------------------------------------------------
13   !!   tra_ldf_iso : update the tracer trend with the horizontal component
14   !!                 of iso neutral laplacian operator or horizontal
15   !!                 laplacian operator in s-coordinate
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers variables
18   USE dom_oce         ! ocean space and time domain variables
19   USE ldftra_oce      ! ocean active tracers: lateral physics
20   USE ldfslp          ! iso-neutral slopes
21   USE in_out_manager  ! I/O manager
22   USE iom
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   tra_adv_eiv   ! routine called by step.F90
28
29   !! * Substitutions
30#  include "domzgr_substitute.h90"
31#  include "ldftra_substitute.h90"
32#  include "ldfeiv_substitute.h90"
33#  include "vectopt_loop_substitute.h90"
34   !!----------------------------------------------------------------------
35   !!  OPA 9.0 , LOCEAN-IPSL (2006)
36   !! $Id$
37   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
38   !!----------------------------------------------------------------------
39
40CONTAINS
41
42   SUBROUTINE tra_adv_eiv( kt, pun, pvn, pwn )
43      !!----------------------------------------------------------------------
44      !!                  ***  ROUTINE tra_adv_eiv  ***
45      !!
46      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
47      !!      trend and add it to the general trend of tracer equation.
48      !!
49      !! ** Method  :   The eddy induced advection is computed from the slope
50      !!      of iso-neutral surfaces computed in routine ldf_slp as follows:
51      !!         zu_eiv =  1/(e2u e3u)   dk[ aeiu e2u mi(wslpi) ]
52      !!         zv_eiv =  1/(e1v e3v)   dk[ aeiv e1v mj(wslpj)
53      !!         zw_eiv = -1/(e1t e2t) { di[ aeiu e2u mi(wslpi) ]
54      !!                               + dj[ aeiv e1v mj(wslpj) ] }
55      !!      add the eiv component to the model velocity:
56      !!         p.n = p.n + z._eiv
57      !!
58      !! ** Action  : - add to p.n the eiv component
59      !!----------------------------------------------------------------------
60      INTEGER , INTENT(in   )                         ::   kt    ! ocean time-step index
61      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   pun   ! in : 3 ocean velocity components
62      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   pvn   ! out: 3 ocean velocity components
63      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   pwn   !      increased by the eiv
64      !!
65      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
66      REAL(wp) ::   zuwk, zuwk1, zuwi, zuwi1   ! temporary scalar
67      REAL(wp) ::   zvwk, zvwk1, zvwj, zvwj1   !    "         "
68      REAL(wp) ::   zu_eiv, zv_eiv, zw_eiv     !    "         "
69      !!----------------------------------------------------------------------
70
71      IF( kt == nit000 ) THEN
72         IF(lwp) WRITE(numout,*)
73         IF(lwp) WRITE(numout,*) 'tra_adv_eiv : eddy induced advection :'
74         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   add to velocity fields the eiv component'
75# if defined key_diaeiv
76         u_eiv(:,:,:) = 0.e0
77         v_eiv(:,:,:) = 0.e0
78         w_eiv(:,:,:) = 0.e0
79# endif
80      ENDIF
81      !                                             ! =================
82      DO jk = 1, jpkm1                              !  Horizontal slab
83         !                                          ! =================
84         DO jj = 1, jpjm1
85            DO ji = 1, fs_jpim1   ! vector opt.
86               zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeiu(ji,jj,jk  ) * umask(ji,jj,jk  )
87               zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeiu(ji,jj,jk+1) * umask(ji,jj,jk+1)
88               zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeiv(ji,jj,jk  ) * vmask(ji,jj,jk  )
89               zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeiv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
90
91               zu_eiv = 0.5 * umask(ji,jj,jk) * ( zuwk - zuwk1 ) / fse3u(ji,jj,jk)
92               zv_eiv = 0.5 * vmask(ji,jj,jk) * ( zvwk - zvwk1 ) / fse3v(ji,jj,jk)
93   
94               pun(ji,jj,jk) = pun(ji,jj,jk) + zu_eiv
95               pvn(ji,jj,jk) = pvn(ji,jj,jk) + zv_eiv
96# if defined key_diaeiv
97               u_eiv(ji,jj,jk) = zu_eiv
98               v_eiv(ji,jj,jk) = zv_eiv
99# endif
100            END DO
101         END DO
102         IF( jk >=2 ) THEN                             ! jk=1 zw_eiv=0, not computed
103            DO jj = 2, jpjm1
104               DO ji = fs_2, fs_jpim1   ! vector opt.
105# if defined key_traldf_c2d || defined key_traldf_c3d
106                  zuwi  = ( wslpi(ji,jj,jk)+wslpi(ji-1,jj,jk) ) * fsaeiu(ji-1,jj,jk) * e2u(ji-1,jj) * umask(ji-1,jj,jk)
107                  zuwi1 = ( wslpi(ji,jj,jk)+wslpi(ji+1,jj,jk) ) * fsaeiu(ji  ,jj,jk) * e2u(ji  ,jj) * umask(ji  ,jj,jk)
108                  zvwj  = ( wslpj(ji,jj,jk)+wslpj(ji,jj-1,jk) ) * fsaeiv(ji,jj-1,jk) * e1v(ji,jj-1) * vmask(ji,jj-1,jk)
109                  zvwj1 = ( wslpj(ji,jj,jk)+wslpj(ji,jj+1,jk) ) * fsaeiv(ji,jj  ,jk) * e1v(ji  ,jj) * vmask(ji  ,jj,jk)
110 
111                  zw_eiv = - 0.5 * tmask(ji,jj,jk) * ( zuwi1 - zuwi + zvwj1 - zvwj ) / ( e1t(ji,jj)*e2t(ji,jj) )
112# else
113                  zuwi  = ( wslpi(ji,jj,jk) + wslpi(ji-1,jj,jk) ) * e2u(ji-1,jj) * umask(ji-1,jj,jk)
114                  zuwi1 = ( wslpi(ji,jj,jk) + wslpi(ji+1,jj,jk) ) * e2u(ji  ,jj) * umask(ji  ,jj,jk)
115                  zvwj  = ( wslpj(ji,jj,jk) + wslpj(ji,jj-1,jk) ) * e1v(ji,jj-1) * vmask(ji,jj-1,jk)
116                  zvwj1 = ( wslpj(ji,jj,jk) + wslpj(ji,jj+1,jk) ) * e1v(ji  ,jj) * vmask(ji  ,jj,jk)
117
118                  zw_eiv = - 0.5 * tmask(ji,jj,jk) * fsaeiw(ji,jj,jk) * ( zuwi1 - zuwi + zvwj1 - zvwj )  &
119                     &                                                / ( e1t(ji,jj)*e2t(ji,jj) )
120# endif
121                  pwn(ji,jj,jk) = pwn(ji,jj,jk) + zw_eiv
122
123# if defined key_diaeiv
124                  w_eiv(ji,jj,jk) = zw_eiv
125# endif
126               END DO
127            END DO
128         ENDIF
129         !                                          ! =================
130      END DO                                        !    End of slab 
131      !                                             ! =================
132
133# if defined key_diaeiv
134      CALL iom_put( "uoce_eiv", u_eiv )    ! i-eiv current
135      CALL iom_put( "voce_eiv", v_eiv )    ! j-eiv current
136      CALL iom_put( "woce_eiv", w_eiv )    ! vert. eiv current
137# endif 
138      !
139    END SUBROUTINE tra_adv_eiv
140
141#else
142   !!----------------------------------------------------------------------
143   !!   Dummy module :             No rotation of the lateral mixing tensor
144   !!----------------------------------------------------------------------
145CONTAINS
146   SUBROUTINE tra_adv_eiv( kt, pun, pvn, pwn )              ! Empty routine
147      REAL, DIMENSION(:,:,:) ::   pun, pvn, pwn
148      WRITE(*,*) 'tra_adv_eiv: You should not have seen this print! error?', kt, pun(1,1,1), pvn(1,1,1), pwn(1,1,1)
149   END SUBROUTINE tra_adv_eiv
150#endif
151
152   !!==============================================================================
153END MODULE traadv_eiv
Note: See TracBrowser for help on using the repository browser.