New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in tags/nemo_v3_2_beta/NEMO/TOP_SRC/PISCES – NEMO

source: tags/nemo_v3_2_beta/NEMO/TOP_SRC/PISCES/p4zprod.F90 @ 7039

Last change on this file since 7039 was 1562, checked in by cetlod, 15 years ago

rename some PISCES diag variables, see ticket:503
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 18.7 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9#if defined key_pisces
10   !!----------------------------------------------------------------------
11   !!   'key_pisces'                                       PISCES bio-model
12   !!----------------------------------------------------------------------
13   !!   p4z_prod       : 
14   !!----------------------------------------------------------------------
15   USE trc
16   USE oce_trc         !
17   USE sms_pisces      !
18   USE prtctl_trc
19   USE p4zopt
20   USE p4zint
21   USE p4zlim
22   USE iom
23
24   USE lib_mpp
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_prod    ! called in p4zbio.F90
30
31   !! * Shared module variables
32   REAL(wp), PUBLIC ::   &
33     pislope   = 3.0_wp          ,  &  !:
34     pislope2  = 3.0_wp          ,  &  !:
35     excret    = 10.e-5_wp       , &   !:
36     excret2   = 0.05_wp         , &   !:
37     chlcnm    = 0.033_wp        , &   !:
38     chlcdm    = 0.05_wp         , &   !:
39     fecnm     = 10.E-6_wp       , &   !:
40     fecdm     = 15.E-6_wp       , &   !:
41     grosip    = 0.151_wp
42
43   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk)  ::        &
44     &                   prmax
45   
46   REAL(wp) ::   &
47      texcret                    ,  &  !: 1 - excret
48      texcret2                   ,  &  !: 1 - excret2       
49      rpis180                    ,  &  !: rpi / 180
50      tpp                              !: Total primary production
51
52   !!* Substitution
53#  include "domzgr_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007)
56   !! $Id$
57   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59
60CONTAINS
61
62   SUBROUTINE p4z_prod( kt , jnt )
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p4z_prod  ***
65      !!
66      !! ** Purpose :   Compute the phytoplankton production depending on
67      !!              light, temperature and nutrient availability
68      !!
69      !! ** Method  : - ???
70      !!---------------------------------------------------------------------
71      INTEGER, INTENT(in) :: kt, jnt
72      INTEGER  ::   ji, jj, jk, nspyr
73      REAL(wp) ::   zsilfac, zfact
74      REAL(wp) ::   zprdiachl, zprbiochl, zsilim, ztn, zadap, zadap2
75      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zetot2, zmax, zproreg, zproreg2
76      REAL(wp) ::   zmxltst, zmxlday, zlim1
77      REAL(wp) ::   zpislopen  , zpislope2n
78      REAL(wp) ::   zrum, zcodel, zargu, zvol
79#if defined key_trc_diaadd && defined key_trc_dia3d
80      REAL(wp) ::   zrfact2
81#if  defined key_iomput
82      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zw3d
83#endif
84#endif
85      REAL(wp), DIMENSION(jpi,jpj)     ::   zmixnano   , zmixdiat, zstrn
86      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zpislopead , zpislopead2
87      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zprdia     , zprbio, zysopt
88      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zprorca    , zprorcad, zprofed
89      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zprofen   , zprochln, zprochld
90      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zpronew    , zpronewd
91      CHARACTER (len=25) :: charout
92      !!---------------------------------------------------------------------
93
94
95      IF( ( kt * jnt ) == nittrc000  )   CALL p4z_prod_init      ! Initialization (first time-step only)
96
97
98      zprorca (:,:,:) = 0.0
99      zprorcad(:,:,:) = 0.0
100      zprofed(:,:,:) = 0.0
101      zprofen(:,:,:) = 0.0
102      zprochln(:,:,:) = 0.0
103      zprochld(:,:,:) = 0.0
104      zpronew (:,:,:) = 0.0
105      zpronewd(:,:,:) = 0.0
106      zprdia  (:,:,:) = 0.0
107      zprbio  (:,:,:) = 0.0
108      zysopt  (:,:,:) = 0.0
109
110      nspyr  = INT( raass / rdt )
111
112
113      ! Computation of the optimal production
114
115# if defined key_off_degrad
116      prmax(:,:,:) = 0.6 / rjjss * tgfunc(:,:,:) * facvol(:,:,:)
117# else
118      prmax(:,:,:) = 0.6 / rjjss * tgfunc(:,:,:)
119# endif
120
121      ! compute the day length depending on latitude and the day
122      IF(lwp) write(numout,*)
123      IF(lwp) write(numout,*) 'p4zday : - Julian day ', nday_year
124      IF(lwp) write(numout,*) '~~~~~~'
125
126      IF( nleapy == 1 .AND. MOD( nyear, 4 ) == 0 ) THEN
127         zrum = FLOAT( nday_year - 80 ) / 366.
128      ELSE
129         zrum = FLOAT( nday_year - 80 ) / 365.
130      ENDIF
131      zcodel = ASIN(  SIN( zrum * rpi * 2. ) * SIN( rpis180 * 23.5 )  )
132
133      ! day length in hours
134      zstrn(:,:) = 0.
135      DO jj = 1, jpj
136         DO ji = 1, jpi
137            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rpis180 )
138            zargu = MAX( -1., MIN(  1., zargu ) )
139            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rpis180 / 15. )
140         END DO
141      END DO
142
143
144!CDIR NOVERRCHK
145      DO jk = 1, jpkm1
146!CDIR NOVERRCHK
147         DO jj = 1, jpj
148!CDIR NOVERRCHK
149            DO ji = 1, jpi
150
151               ! Computation of the P-I slope for nanos and diatoms
152               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
153                   ztn    = MAX( 0., tn(ji,jj,jk) - 15. )
154                   zadap  = 0.+ 1.* ztn / ( 2.+ ztn )
155                   zadap2 = 0.e0
156
157                   zfact  = EXP( -0.21 * emoy(ji,jj,jk) )
158
159                   zpislopead (ji,jj,jk) = pislope  * ( 1.+ zadap  * zfact )
160                   zpislopead2(ji,jj,jk) = pislope2 * ( 1.+ zadap2 * zfact )
161
162                   zpislopen = zpislopead(ji,jj,jk) * trn(ji,jj,jk,jpnch)                 &
163                     &         / ( trn(ji,jj,jk,jpphy) * 12.                   + rtrn )   &
164                     &         / ( prmax(ji,jj,jk) * rjjss * xlimphy(ji,jj,jk) + rtrn )
165
166                   zpislope2n = zpislopead2(ji,jj,jk) * trn(ji,jj,jk,jpdch)                &
167                     &          / ( trn(ji,jj,jk,jpdia) * 12.                   + rtrn )   &
168                     &          / ( prmax(ji,jj,jk) * rjjss * xlimdia(ji,jj,jk) + rtrn )
169
170                   ! Computation of production function
171                   zprbio(ji,jj,jk) = prmax(ji,jj,jk) * &
172                     &                (  1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
173                   zprdia(ji,jj,jk) = prmax(ji,jj,jk) * &
174                     &                (  1.- EXP( -zpislope2n * ediat(ji,jj,jk) )  )
175               ENDIF
176            END DO
177         END DO
178      END DO
179
180
181      DO jk = 1, jpkm1
182         DO jj = 1, jpj
183            DO ji = 1, jpi
184
185                IF( etot(ji,jj,jk) > 1.E-3 ) THEN
186                   !    Si/C of diatoms
187                   !    ------------------------
188                   !    Si/C increases with iron stress and silicate availability
189                   !    Si/C is arbitrariliy increased for very high Si concentrations
190                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
191
192                  zlim1  = trn(ji,jj,jk,jpsil) / ( trn(ji,jj,jk,jpsil) + xksi1 )
193                  zlim   = xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk)
194
195                  zsilim = MIN( zprdia(ji,jj,jk)    / ( rtrn + prmax(ji,jj,jk) ),                 &
196                  &          trn(ji,jj,jk,jpfer) / ( concdfe(ji,jj,jk) + trn(ji,jj,jk,jpfer) ),   &
197                  &          trn(ji,jj,jk,jppo4) / ( concdnh4 + trn(ji,jj,jk,jppo4) ),            &
198                  &          zlim )
199                  zsilfac = 5.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim1 - 0.5 ) )  ) + 1.e0
200                  zsiborn = MAX( 0.e0, ( trn(ji,jj,jk,jpsil) - 15.e-6 ) )
201                  zsilfac2 = 1.+ 3.* zsiborn / ( zsiborn + xksi2 )
202                  zsilfac = MIN( 6.4,zsilfac * zsilfac2)
203                  zysopt(ji,jj,jk) = grosip * zlim1 * zsilfac
204
205              ENDIF
206            END DO
207         END DO
208      END DO
209
210      !  Computation of the limitation term due to
211      !  A mixed layer deeper than the euphotic depth
212      DO jj = 1, jpj
213         DO ji = 1, jpi
214            zmxltst = MAX( 0.e0, hmld(ji,jj) - heup(ji,jj) )
215            zmxlday = zmxltst**2 / rjjss
216            zmixnano(ji,jj) = 1.- zmxlday / ( 1.+ zmxlday )
217            zmixdiat(ji,jj) = 1.- zmxlday / ( 3.+ zmxlday )
218         END DO
219      END DO
220 
221      !  Mixed-layer effect on production                                                                               
222      DO jk = 1, jpkm1
223         DO jj = 1, jpj
224            DO ji = 1, jpi
225               IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
226                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * zmixnano(ji,jj)
227                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * zmixdiat(ji,jj)
228               ENDIF
229            END DO
230         END DO
231      END DO
232
233
234      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
235      zstrn(:,:) = 24. / zstrn(:,:)
236
237!CDIR NOVERRCHK
238      DO jk = 1, jpkm1
239!CDIR NOVERRCHK
240         DO jj = 1, jpj
241!CDIR NOVERRCHK
242            DO ji = 1, jpi
243
244               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
245                  !     Computation of the various production terms for nanophyto.
246                  zetot2 = enano(ji,jj,jk) * zstrn(ji,jj)
247                  zmax = MAX( 0.1, xlimphy(ji,jj,jk) )
248                  zpislopen = zpislopead(ji,jj,jk)          &
249                  &         * trn(ji,jj,jk,jpnch) / ( rtrn + trn(ji,jj,jk,jpphy) * 12.)         &
250                  &         / ( prmax(ji,jj,jk) * rjjss * zmax + rtrn )
251
252                  zprbiochl = prmax(ji,jj,jk) * (  1.- EXP( -zpislopen * zetot2 )  )
253
254                  zprorca(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trn(ji,jj,jk,jpphy) * rfact2
255
256                  zpronew(ji,jj,jk) = zprorca(ji,jj,jk) * xnanono3(ji,jj,jk)    &
257                  &             / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
258                  zprod = rjjss * zprorca(ji,jj,jk) * zprbiochl * trn(ji,jj,jk,jpphy) *zmax
259
260                  zprofen(ji,jj,jk) = (fecnm)**2 * zprod / chlcnm            &
261                  &              / (  zpislopead(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpnfe) + rtrn  )
262
263                  zprochln(ji,jj,jk) = chlcnm * 144. * zprod                  &
264                  &              / (  zpislopead(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpnch) + rtrn  )
265               ENDIF
266            END DO
267         END DO
268      END DO
269
270!CDIR NOVERRCHK
271      DO jk = 1, jpkm1
272!CDIR NOVERRCHK
273         DO jj = 1, jpj
274!CDIR NOVERRCHK
275            DO ji = 1, jpi
276               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
277                  !  Computation of the various production terms for diatoms
278                  zetot2 = ediat(ji,jj,jk) * zstrn(ji,jj)
279                  zmax = MAX( 0.1, xlimdia(ji,jj,jk) )
280                  zpislope2n = zpislopead2(ji,jj,jk) * trn(ji,jj,jk,jpdch)        &
281                  &           / ( rtrn + trn(ji,jj,jk,jpdia) * 12.)        &
282                  &           / ( prmax(ji,jj,jk) * rjjss * zmax + rtrn )
283
284                  zprdiachl = prmax(ji,jj,jk) * (  1.- EXP( -zetot2 * zpislope2n )  )
285
286                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trn(ji,jj,jk,jpdia) * rfact2
287
288                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk)     &
289                  &              / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
290
291                  zprod = rjjss * zprorcad(ji,jj,jk) * zprdiachl * trn(ji,jj,jk,jpdia) * zmax
292
293                  zprofed(ji,jj,jk) = (fecdm)**2 * zprod / chlcdm                   &
294                  &              / ( zpislopead2(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpdfe) + rtrn )
295
296                  zprochld(ji,jj,jk) = chlcdm * 144. * zprod       &
297                  &              / ( zpislopead2(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpdch) + rtrn )
298
299               ENDIF
300            END DO
301         END DO
302      END DO
303      !
304
305      !   Update the arrays TRA which contain the biological sources and sinks
306      DO jk = 1, jpkm1
307         DO jj = 1, jpj
308           DO ji =1 ,jpi
309              zproreg  = zprorca(ji,jj,jk) - zpronew(ji,jj,jk)
310              zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
311              tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
312              tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronew(ji,jj,jk) - zpronewd(ji,jj,jk)
313              tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
314              tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorca(ji,jj,jk) * texcret
315              tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln(ji,jj,jk) * texcret
316              tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcret
317              tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcret2
318              tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld(ji,jj,jk) * texcret2
319              tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcret2
320              tra(ji,jj,jk,jpbsi) = tra(ji,jj,jk,jpbsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcret2
321              tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + &
322              &                     excret2 * zprorcad(ji,jj,jk) + excret * zprorca(ji,jj,jk)
323              tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
324              &                    + ( o2ut + o2nit ) * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) )
325              tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) &
326              &                     - texcret * zprofen(ji,jj,jk) - texcret2 * zprofed(ji,jj,jk)
327              tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) &
328              &                     - texcret2 * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
329              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
330              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) &
331              &                    + rno3 * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) )
332          END DO
333        END DO
334     END DO
335
336     ! Total primary production per year
337     DO jk = 1, jpkm1
338        DO jj = 1, jpj
339          DO ji = 1, jpi
340             zvol = cvol(ji,jj,jk)
341#if defined key_off_degrad
342             zvol = zvol * facvol(ji,jj,jk)
343#endif
344             tpp  = tpp + ( zprorca(ji,jj,jk) + zprorcad(ji,jj,jk) ) &
345                          * zvol * tmask(ji,jj,jk) * tmask_i(ji,jj)
346          END DO
347        END DO
348      END DO
349
350
351      IF( MOD( kt, nspyr ) == 0 .AND. jnt == nrdttrc ) THEN
352        IF( lk_mpp ) CALL mpp_sum( tpp )
353        WRITE(numout,*) 'Total PP :'
354        WRITE(numout,*) '-------------------- : ',tpp * 12. / 1.E12
355        WRITE(numout,*) '(GtC/an)'
356        tpp = 0.
357      ENDIF
358
359#if defined key_trc_diaadd && defined key_trc_dia3d
360      zrfact2 = 1.e3 * rfact2r
361      !   Supplementary diagnostics
362#  if ! defined key_iomput
363      trc3d(:,:,:,jp_pcs0_3d + 4)  = zprorca (:,:,:) * zrfact2 * tmask(:,:,:)
364      trc3d(:,:,:,jp_pcs0_3d + 5)  = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:)
365      trc3d(:,:,:,jp_pcs0_3d + 6)  = zpronew (:,:,:) * zrfact2 * tmask(:,:,:)
366      trc3d(:,:,:,jp_pcs0_3d + 7)  = zpronewd(:,:,:) * zrfact2 * tmask(:,:,:)
367      trc3d(:,:,:,jp_pcs0_3d + 8)  = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) * zysopt(:,:,:)
368      trc3d(:,:,:,jp_pcs0_3d + 9)  = zprofed (:,:,:) * zrfact2 * tmask(:,:,:)
369#if ! defined key_kriest
370      trc3d(:,:,:,jp_pcs0_3d + 10) = zprofen (:,:,:) * zrfact2 * tmask(:,:,:)
371#endif
372
373# else
374      zw3d(:,:,:) = zprorca (:,:,:) * zrfact2 * tmask(:,:,:)
375      IF( jnt == nrdttrc ) CALL iom_put( "PPPHY" , zw3d )
376      zw3d(:,:,:) = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:)
377      IF( jnt == nrdttrc ) CALL iom_put( "PPPHY2", zw3d )
378      zw3d(:,:,:) = zpronew (:,:,:) * zrfact2 * tmask(:,:,:)
379      IF( jnt == nrdttrc ) CALL iom_put( "PPNEWN" , zw3d )
380      zw3d(:,:,:) = zpronewd(:,:,:) * zrfact2 * tmask(:,:,:)
381      IF( jnt == nrdttrc ) CALL iom_put( "PPNEWD", zw3d )
382      zw3d(:,:,:) = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) * zysopt(:,:,:)
383      IF( jnt == nrdttrc ) CALL iom_put( "PBSi"  , zw3d )
384      zw3d(:,:,:) = zprofed (:,:,:) * zrfact2 * tmask(:,:,:)
385      IF( jnt == nrdttrc ) CALL iom_put( "PFeD"  , zw3d )
386      zw3d(:,:,:) = zprofen (:,:,:) * zrfact2 * tmask(:,:,:)
387      IF( jnt == nrdttrc ) CALL iom_put( "PFeN"  , zw3d )
388# endif
389#endif
390
391       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
392         WRITE(charout, FMT="('prod')")
393         CALL prt_ctl_trc_info(charout)
394         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
395       ENDIF
396
397   END SUBROUTINE p4z_prod
398
399   SUBROUTINE p4z_prod_init
400
401      !!----------------------------------------------------------------------
402      !!                  ***  ROUTINE p4z_prod_init  ***
403      !!
404      !! ** Purpose :   Initialization of phytoplankton production parameters
405      !!
406      !! ** Method  :   Read the nampisprod namelist and check the parameters
407      !!      called at the first timestep (nittrc000)
408      !!
409      !! ** input   :   Namelist nampisprod
410      !!
411      !!----------------------------------------------------------------------
412
413      NAMELIST/nampisprod/ pislope, pislope2, excret, excret2, chlcnm, chlcdm,   &
414         &              fecnm, fecdm, grosip
415
416      REWIND( numnat )                     ! read numnat
417      READ  ( numnat, nampisprod )
418
419      IF(lwp) THEN                         ! control print
420         WRITE(numout,*) ' '
421         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, nampisprod'
422         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
423         WRITE(numout,*) '    mean Si/C ratio                           grosip    =', grosip
424         WRITE(numout,*) '    P-I slope                                 pislope   =', pislope
425         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excret    =', excret
426         WRITE(numout,*) '    excretion ratio of diatoms                excret2   =', excret2
427         WRITE(numout,*) '    P-I slope  for diatoms                    pislope2  =', pislope2
428         WRITE(numout,*) '    Minimum Chl/C in nanophytoplankton        chlcnm    =', chlcnm
429         WRITE(numout,*) '    Minimum Chl/C in diatoms                  chlcdm    =', chlcdm
430         WRITE(numout,*) '    Maximum Fe/C in nanophytoplankton         fecnm     =', fecnm
431         WRITE(numout,*) '    Minimum Fe/C in diatoms                   fecdm     =', fecdm
432      ENDIF
433
434      rpis180   = rpi / 180.
435      texcret   = 1.0 - excret
436      texcret2  = 1.0 - excret2
437      tpp       = 0.
438
439   END SUBROUTINE p4z_prod_init
440
441
442
443#else
444   !!======================================================================
445   !!  Dummy module :                                   No PISCES bio-model
446   !!======================================================================
447CONTAINS
448   SUBROUTINE p4z_prod                    ! Empty routine
449   END SUBROUTINE p4z_prod
450#endif 
451
452   !!======================================================================
453END MODULE  p4zprod
Note: See TracBrowser for help on using the repository browser.