New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zflx.F90 in tags/nemo_v3_3/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: tags/nemo_v3_3/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zflx.F90 @ 2581

Last change on this file since 2581 was 2528, checked in by rblod, 14 years ago

Update NEMOGCM from branch nemo_v3_3_beta
  • Property svn:keywords set to Id
File size: 10.7 KB
Line 
1MODULE p4zflx
2   !!======================================================================
3   !!                         ***  MODULE p4zflx  ***
4   !! TOP :   PISCES CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!----------------------------------------------------------------------
12#if defined key_pisces
13   !!----------------------------------------------------------------------
14   !!   'key_pisces'                                       PISCES bio-model
15   !!----------------------------------------------------------------------
16   !!   p4z_flx       :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
17   !!   p4z_flx_init  :   Read the namelist
18   !!----------------------------------------------------------------------
19   USE trc
20   USE oce_trc         !
21   USE trc
22   USE sms_pisces
23   USE prtctl_trc
24   USE p4zche
25   USE iom
26#if defined key_cpl_carbon_cycle
27   USE sbc_oce , ONLY :  atm_co2
28#endif
29   USE lib_mpp
30   USE lib_fortran
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   p4z_flx 
36   PUBLIC   p4z_flx_init 
37
38   REAL(wp), PUBLIC, DIMENSION(jpi,jpj) ::  oce_co2            !: ocean carbon flux
39   REAL(wp), PUBLIC, DIMENSION(jpi,jpj) ::  satmco2            !: atmospheric pco2
40   REAL(wp)                             ::  t_oce_co2_flx      !: Total ocean carbon flux
41   REAL(wp)                             ::  t_atm_co2_flx      !: global mean of atmospheric pco2
42   REAL(wp)                             ::  area               !: ocean surface
43   REAL(wp)                             ::  atcco2 = 278.      !: pre-industrial atmospheric [co2] (ppm)   
44   REAL(wp)                             ::  atcox  = 0.20946   !:
45   REAL(wp)                             ::  xconv  = 0.01/3600 !: coefficients for conversion
46
47   !!* Substitution
48#  include "top_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
51   !! $Id$
52   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
53   !!----------------------------------------------------------------------
54
55CONTAINS
56
57   SUBROUTINE p4z_flx ( kt )
58      !!---------------------------------------------------------------------
59      !!                     ***  ROUTINE p4z_flx  ***
60      !!
61      !! ** Purpose :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
62      !!
63      !! ** Method  : - ???
64      !!---------------------------------------------------------------------
65      INTEGER, INTENT(in) :: kt
66      INTEGER  ::   ji, jj, jrorr
67      REAL(wp) ::   ztc, ztc2, ztc3, zws, zkgwan
68      REAL(wp) ::   zfld, zflu, zfld16, zflu16, zfact
69      REAL(wp) ::   zph, zah2, zbot, zdic, zalk, zsch_o2, zalka, zsch_co2
70      REAL(wp), DIMENSION(jpi,jpj) ::   zkgco2, zkgo2, zh2co3
71#if defined key_diatrc && defined key_iomput
72      REAL(wp), DIMENSION(jpi,jpj) ::  zoflx, zkg, zdpco2, zdpo2
73#endif
74      CHARACTER (len=25) :: charout
75
76      !!---------------------------------------------------------------------
77
78      ! SURFACE CHEMISTRY (PCO2 AND [H+] IN
79      !     SURFACE LAYER); THE RESULT OF THIS CALCULATION
80      !     IS USED TO COMPUTE AIR-SEA FLUX OF CO2
81
82#if defined key_cpl_carbon_cycle
83      satmco2(:,:) = atm_co2(:,:)
84#endif
85
86      DO jrorr = 1, 10
87
88!CDIR NOVERRCHK
89         DO jj = 1, jpj
90!CDIR NOVERRCHK
91            DO ji = 1, jpi
92
93               ! DUMMY VARIABLES FOR DIC, H+, AND BORATE
94               zbot  = borat(ji,jj,1)
95               zfact = rhop(ji,jj,1) / 1000. + rtrn
96               zdic  = trn(ji,jj,1,jpdic) / zfact
97               zph   = MAX( hi(ji,jj,1), 1.e-10 ) / zfact
98               zalka = trn(ji,jj,1,jptal) / zfact
99
100               ! CALCULATE [ALK]([CO3--], [HCO3-])
101               zalk  = zalka - (  akw3(ji,jj,1) / zph - zph + zbot / ( 1.+ zph / akb3(ji,jj,1) )  )
102
103               ! CALCULATE [H+] AND [H2CO3]
104               zah2   = SQRT(  (zdic-zalk)**2 + 4.* ( zalk * ak23(ji,jj,1)   &
105                  &                                        / ak13(ji,jj,1) ) * ( 2.* zdic - zalk )  )
106               zah2   = 0.5 * ak13(ji,jj,1) / zalk * ( ( zdic - zalk ) + zah2 )
107               zh2co3(ji,jj) = ( 2.* zdic - zalk ) / ( 2.+ ak13(ji,jj,1) / zah2 ) * zfact
108               hi(ji,jj,1)   = zah2 * zfact
109            END DO
110         END DO
111      END DO
112
113
114      ! --------------
115      ! COMPUTE FLUXES
116      ! --------------
117
118      ! FIRST COMPUTE GAS EXCHANGE COEFFICIENTS
119      ! -------------------------------------------
120
121!CDIR NOVERRCHK
122      DO jj = 1, jpj
123!CDIR NOVERRCHK
124         DO ji = 1, jpi
125            ztc  = MIN( 35., tsn(ji,jj,1,jp_tem) )
126            ztc2 = ztc * ztc
127            ztc3 = ztc * ztc2 
128            ! Compute the schmidt Number both O2 and CO2
129            zsch_co2 = 2073.1 - 125.62 * ztc + 3.6276 * ztc2 - 0.043126 * ztc3
130            zsch_o2  = 1953.4 - 128.0  * ztc + 3.9918 * ztc2 - 0.050091 * ztc3
131            !  wind speed
132            zws  = wndm(ji,jj) * wndm(ji,jj)
133            ! Compute the piston velocity for O2 and CO2
134            zkgwan = 0.3 * zws  + 2.5 * ( 0.5246 + 0.016256 * ztc + 0.00049946  * ztc2 )
135# if defined key_degrad
136            zkgwan = zkgwan * xconv * ( 1.- fr_i(ji,jj) ) * tmask(ji,jj,1) * facvol(ji,jj,1)
137#else
138            zkgwan = zkgwan * xconv * ( 1.- fr_i(ji,jj) ) * tmask(ji,jj,1)
139#endif 
140            ! compute gas exchange for CO2 and O2
141            zkgco2(ji,jj) = zkgwan * SQRT( 660./ zsch_co2 )
142            zkgo2 (ji,jj) = zkgwan * SQRT( 660./ zsch_o2 )
143         END DO
144      END DO
145
146      DO jj = 1, jpj
147         DO ji = 1, jpi
148            ! Compute CO2 flux for the sea and air
149            zfld = satmco2(ji,jj) * tmask(ji,jj,1) * chemc(ji,jj,1) * zkgco2(ji,jj)
150            zflu = zh2co3(ji,jj) * tmask(ji,jj,1) * zkgco2(ji,jj)
151            oce_co2(ji,jj) = ( zfld - zflu ) * rfact &
152               &             * e1t(ji,jj) * e2t(ji,jj) * tmask(ji,jj,1) * 1000.
153            ! compute the trend
154            tra(ji,jj,1,jpdic) = tra(ji,jj,1,jpdic) + ( zfld - zflu ) / fse3t(ji,jj,1)
155
156            ! Compute O2 flux
157            zfld16 = atcox * chemc(ji,jj,2) * tmask(ji,jj,1) * zkgo2(ji,jj)
158            zflu16 = trn(ji,jj,1,jpoxy) * tmask(ji,jj,1) * zkgo2(ji,jj)
159            tra(ji,jj,1,jpoxy) = tra(ji,jj,1,jpoxy) + ( zfld16 - zflu16 ) / fse3t(ji,jj,1)
160
161#if defined key_diatrc 
162            ! Save diagnostics
163#  if ! defined key_iomput
164            zfact = 1. / ( e1t(ji,jj) * e2t(ji,jj) ) / rfact
165            trc2d(ji,jj,jp_pcs0_2d    ) = oce_co2(ji,jj) * zfact
166            trc2d(ji,jj,jp_pcs0_2d + 1) = ( zfld16 - zflu16 ) * 1000. * tmask(ji,jj,1)
167            trc2d(ji,jj,jp_pcs0_2d + 2) = zkgco2(ji,jj) * tmask(ji,jj,1)
168            trc2d(ji,jj,jp_pcs0_2d + 3) = ( satmco2(ji,jj) - zh2co3(ji,jj) / ( chemc(ji,jj,1) + rtrn ) ) &
169               &                            * tmask(ji,jj,1)
170#  else
171            zoflx(ji,jj) = ( zfld16 - zflu16 ) * 1000. * tmask(ji,jj,1)
172            zkg  (ji,jj) = zkgco2(ji,jj) * tmask(ji,jj,1)
173            zdpco2(ji,jj) = ( satmco2(ji,jj) - zh2co3(ji,jj) / ( chemc(ji,jj,1) + rtrn ) ) * tmask(ji,jj,1)
174            zdpo2 (ji,jj) = ( atcox  - trn(ji,jj,1,jpoxy) / ( chemc(ji,jj,2) + rtrn ) ) * tmask(ji,jj,1)
175#  endif
176#endif
177         END DO
178      END DO
179
180      t_oce_co2_flx = t_oce_co2_flx + glob_sum( oce_co2(:,:) )                     ! Cumulative Total Flux of Carbon
181      IF( kt == nitend ) THEN
182         t_atm_co2_flx = glob_sum( satmco2(:,:) * e1t(:,:) * e2t(:,:) )            ! Total atmospheric pCO2
183         !
184         t_oce_co2_flx = (-1.) * t_oce_co2_flx  * 12. / 1.e15                      ! Conversion in PgC ; negative for out of the ocean
185         t_atm_co2_flx = t_atm_co2_flx  / area                                     ! global mean of atmospheric pCO2
186         !
187         IF( lwp) THEN
188            WRITE(numout,*)
189            WRITE(numout,*) ' Global mean of atmospheric pCO2 (ppm) at it= ', kt, ' date= ', ndastp
190            WRITE(numout,*) '------------------------------------------------------- :  ',t_atm_co2_flx
191            WRITE(numout,*)
192            WRITE(numout,*) ' Cumulative total Flux of Carbon out of the ocean (PgC) :'
193            WRITE(numout,*) '-------------------------------------------------------  ',t_oce_co2_flx
194         ENDIF
195         !
196      ENDIF
197
198      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
199         WRITE(charout, FMT="('flx ')")
200         CALL prt_ctl_trc_info(charout)
201         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
202      ENDIF
203
204# if defined key_diatrc && defined key_iomput
205      CALL iom_put( "Cflx" , oce_co2(:,:) / ( e1t(:,:) * e2t(:,:) ) / rfact  )
206      CALL iom_put( "Oflx" , zoflx  )
207      CALL iom_put( "Kg"   , zkg    )
208      CALL iom_put( "Dpco2", zdpco2 )
209      CALL iom_put( "Dpo2" , zdpo2  )
210#endif
211
212   END SUBROUTINE p4z_flx
213
214   SUBROUTINE p4z_flx_init
215
216      !!----------------------------------------------------------------------
217      !!                  ***  ROUTINE p4z_flx_init  ***
218      !!
219      !! ** Purpose :   Initialization of atmospheric conditions
220      !!
221      !! ** Method  :   Read the nampisext namelist and check the parameters
222      !!      called at the first timestep (nit000)
223      !! ** input   :   Namelist nampisext
224      !!
225      !!----------------------------------------------------------------------
226
227      NAMELIST/nampisext/ atcco2
228
229      REWIND( numnat )                     ! read numnat
230      READ  ( numnat, nampisext )
231
232      IF(lwp) THEN                         ! control print
233         WRITE(numout,*) ' '
234         WRITE(numout,*) ' Namelist parameters for air-sea exchange, nampisext'
235         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
236         WRITE(numout,*) '    Atmospheric pCO2      atcco2      =', atcco2
237      ENDIF
238
239      ! interior global domain surface
240      area = glob_sum( e1t(:,:) * e2t(:,:) ) 
241
242      ! Initialization of Flux of Carbon
243      oce_co2(:,:)  = 0._wp
244      t_atm_co2_flx = 0._wp
245      ! Initialisation of atmospheric pco2
246      satmco2(:,:)  = atcco2
247      t_oce_co2_flx = 0._wp
248
249   END SUBROUTINE p4z_flx_init
250
251#else
252   !!======================================================================
253   !!  Dummy module :                                   No PISCES bio-model
254   !!======================================================================
255CONTAINS
256   SUBROUTINE p4z_flx( kt )                   ! Empty routine
257      INTEGER, INTENT( in ) ::   kt
258      WRITE(*,*) 'p4z_flx: You should not have seen this print! error?', kt
259   END SUBROUTINE p4z_flx
260#endif 
261
262   !!======================================================================
263END MODULE  p4zflx
Note: See TracBrowser for help on using the repository browser.