New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynnxt1d.F90 in trunk/NEMO/C1D_SRC – NEMO

source: trunk/NEMO/C1D_SRC/dynnxt1d.F90 @ 304

Last change on this file since 304 was 257, checked in by opalod, 19 years ago

nemo_v1_update_003 : CT : Add the missing header
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 6.9 KB
Line 
1MODULE dynnxt1d
2   !!======================================================================
3   !!                       ***  MODULE  dynnxt1d  ***
4   !! Ocean dynamics: time stepping in 1D configuration
5   !!======================================================================
6#if defined key_cfg_1d
7   !!----------------------------------------------------------------------
8   !!   'key_cfg_1d'               1D Configuration
9   !!---------------------------------------------------------------------- 
10   !!----------------------------------------------------------------------
11   !!   dyn_nxt_1d   : update the horizontal velocity from the momentum trend
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE in_out_manager  ! I/O manager
17   USE lbclnk          ! lateral boundary condition (or mpp link)
18
19   IMPLICIT NONE
20   PRIVATE
21
22   !! * Accessibility
23   PUBLIC dyn_nxt_1d                ! routine called by step.F90
24   !!----------------------------------------------------------------------
25
26CONTAINS
27
28   SUBROUTINE dyn_nxt_1d ( kt )
29      !!----------------------------------------------------------------------
30      !!                  ***  ROUTINE dyn_nxt_1d  ***
31      !!                   
32      !! ** Purpose :   Compute the after horizontal velocity from the
33      !!      momentum trend.
34      !!
35      !! ** Method  :   Apply lateral boundary conditions on the trends (ua,va)
36      !!      through calls to routine lbc_lnk.
37      !!      After velocity is compute using a leap-frog scheme environment:
38      !!         (ua,va) = (ub,vb) + 2 rdt (ua,va)
39      !!      Time filter applied on now horizontal velocity to avoid the
40      !!      divergence of two consecutive time-steps and swap of dynamics
41      !!      arrays to start the next time step:
42      !!         (ub,vb) = (un,vn) + atfp [ (ub,vb) + (ua,va) - 2 (un,vn) ]
43      !!         (un,vn) = (ua,va)
44      !!
45      !! ** Action : - Update ub,vb arrays, the before horizontal velocity
46      !!             - Update un,vn arrays, the now horizontal velocity
47      !!
48      !! History :
49      !!        !  87-02  (P. Andrich, D. L Hostis)  Original code
50      !!        !  90-10  (C. Levy, G. Madec)
51      !!        !  93-03  (M. Guyon)  symetrical conditions
52      !!        !  97-02  (G. Madec & M. Imbard)  opa, release 8.0
53      !!        !  97-04  (A. Weaver)  Euler forward step
54      !!        !  97-06  (G. Madec)  lateral boudary cond., lbc routine
55      !!   8.5  !  02-08  (G. Madec)  F90: Free form and module
56      !!        !  04-10  (C. Ethe) 1D configuration
57      !!----------------------------------------------------------------------
58      !! * Arguments
59      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index
60
61      !! * Local declarations
62      INTEGER  ::   ji, jj, jk   ! dummy loop indices
63      REAL(wp) ::   z2dt         ! temporary scalar
64      !!----------------------------------------------------------------------
65      !!   OPA 9.0 , LOCEAN-IPSL (2005)
66      !! $Header$
67      !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
68      !!----------------------------------------------------------------------
69
70      IF( kt == nit000 ) THEN
71         IF(lwp) WRITE(numout,*)
72         IF(lwp) WRITE(numout,*) 'dyn_nxt_1d : time stepping on 1D configuation'
73         IF(lwp) WRITE(numout,*) '~~~~~~~'
74      ENDIF
75
76      ! Local constant initialization
77      z2dt = 2. * rdt
78      IF( neuler == 0 .AND. kt == nit000 )  z2dt = rdt
79
80      ! Lateral boundary conditions on ( ua, va )
81      CALL lbc_lnk( ua, 'U', -1. )
82      CALL lbc_lnk( va, 'V', -1. )
83
84      !                                                ! ===============
85      DO jk = 1, jpkm1                                 ! Horizontal slab
86         !                                             ! ===============
87         ! Next velocity
88         ! -------------
89         DO jj = 1, jpj                      ! caution: don't use (:,:) for this loop
90            DO ji = 1, jpi                   ! it causes optimization problems on NEC in auto-tasking
91               ! Leap-frog time stepping
92               ua(ji,jj,jk) = ( ub(ji,jj,jk) + z2dt * ua(ji,jj,jk) ) * umask(ji,jj,jk)
93               va(ji,jj,jk) = ( vb(ji,jj,jk) + z2dt * va(ji,jj,jk) ) * vmask(ji,jj,jk)
94            END DO
95         END DO
96         !                                             ! ===============
97      END DO                                           !   End of slab
98      !                                                ! ===============
99 
100     !                                                ! ===============
101      DO jk = 1, jpkm1                                 ! Horizontal slab
102         !                                             ! ===============
103         ! Time filter and swap of dynamics arrays
104         ! ------------------------------------------
105         IF( neuler == 0 .AND. kt == nit000 ) THEN
106            DO jj = 1, jpj                      ! caution: don't use (:,:) for this loop
107               DO ji = 1, jpi                   ! it causes optimization problems on NEC in auto-tasking
108                  ! Euler (forward) time stepping
109                  ub(ji,jj,jk) = un(ji,jj,jk)
110                  vb(ji,jj,jk) = vn(ji,jj,jk)
111                  un(ji,jj,jk) = ua(ji,jj,jk)
112                  vn(ji,jj,jk) = va(ji,jj,jk)
113               END DO
114            END DO
115         ELSE
116            DO jj = 1, jpj                      ! caution: don't use (:,:) for this loop
117               DO ji = 1, jpi                   ! it causes optimization problems on NEC in auto-tasking
118                  ! Leap-frog time stepping
119                  ub(ji,jj,jk) = atfp * ( ub(ji,jj,jk) + ua(ji,jj,jk) ) + atfp1 * un(ji,jj,jk)
120                  vb(ji,jj,jk) = atfp * ( vb(ji,jj,jk) + va(ji,jj,jk) ) + atfp1 * vn(ji,jj,jk)
121                  un(ji,jj,jk) = ua(ji,jj,jk)
122                  vn(ji,jj,jk) = va(ji,jj,jk)
123               END DO
124            END DO
125         ENDIF
126         !                                             ! ===============
127      END DO                                           !   End of slab
128      !                                                ! ===============
129
130      IF(l_ctl)   WRITE(numout,*) ' nxt  - Un: ', SUM(un(2:nictl,2:njctl,1:jpkm1)*umask(2:nictl,2:njctl,1:jpkm1)), &
131      &                                  ' Vn: ', SUM(vn(2:nictl,2:njctl,1:jpkm1)*vmask(2:nictl,2:njctl,1:jpkm1))
132
133   END SUBROUTINE dyn_nxt_1d
134#else
135   !!----------------------------------------------------------------------
136   !!   Default key                                     NO 1D Config
137   !!----------------------------------------------------------------------
138CONTAINS
139   SUBROUTINE dyn_nxt_1d ( kt )
140      WRITE(*,*) 'dyn_nxt_1d: You should not have seen this print! error?', kt
141   END SUBROUTINE dyn_nxt_1d
142#endif
143   !!======================================================================
144END MODULE dynnxt1d
Note: See TracBrowser for help on using the repository browser.