New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limtrp.F90 in trunk/NEMO/LIM_SRC – NEMO

source: trunk/NEMO/LIM_SRC/limtrp.F90 @ 115

Last change on this file since 115 was 115, checked in by opalod, 20 years ago

CT : UPDATE074 : Mpp addition with a call to mpp_max(zcfl) so that the CFL test is done on a the global domain and not only for each processor
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 15.1 KB
Line 
1MODULE limtrp
2   !!======================================================================
3   !!                       ***  MODULE limtrp   ***
4   !! LIM transport ice model : sea-ice advection/diffusion
5   !!======================================================================
6#if defined key_ice_lim
7   !!----------------------------------------------------------------------
8   !!   'key_ice_lim' :                                   LIM sea-ice model
9   !!----------------------------------------------------------------------
10   !!   lim_trp      : advection/diffusion process of sea ice
11   !!   lim_trp_init : initialization and namelist read
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE phycst
15   USE dom_oce
16   USE daymod
17   USE in_out_manager  ! I/O manager
18   USE ice_oce         ! ice variables
19   USE dom_ice
20   USE ice
21   USE iceini
22   USE limistate
23   USE limadv
24   USE limhdf
25   USE lbclnk
26   USE lib_mpp
27
28   IMPLICIT NONE
29   PRIVATE
30
31   !! * Routine accessibility
32   PUBLIC lim_trp       ! called by ice_step
33
34   !! * Shared module variables
35   REAL(wp), PUBLIC  ::   &  !:
36      bound  = 0.e0          !: boundary condit. (0.0 no-slip, 1.0 free-slip)
37
38   !! * Module variables
39   REAL(wp)  ::           &  ! constant values
40      epsi06 = 1.e-06  ,  &
41      epsi03 = 1.e-03  ,  &
42      epsi16 = 1.e-16  ,  &
43      rzero  = 0.e0    ,  &
44      rone   = 1.e0
45
46   !! * Substitution
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !!   LIM 2.0 , UCL-LODYC-IPSL  (2003)
50   !!----------------------------------------------------------------------
51
52CONTAINS
53
54   SUBROUTINE lim_trp
55      !!-------------------------------------------------------------------
56      !!                   ***  ROUTINE lim_trp ***
57      !!                   
58      !! ** purpose : advection/diffusion process of sea ice
59      !!
60      !! ** method  : variables included in the process are scalar,   
61      !!     other values are considered as second order.
62      !!     For advection, a second order Prather scheme is used. 
63      !!
64      !! ** action :
65      !!
66      !! History :
67      !!   1.0  !  00-01 (LIM)  Original code
68      !!        !  01-05 (G. Madec, R. Hordoir) opa norm
69      !!   2.0  !  04-01 (G. Madec, C. Ethe)  F90, mpp
70      !!---------------------------------------------------------------------
71      !! * Local Variables
72      INTEGER  ::   ji, jj, jk,   &  ! dummy loop indices
73         &          initad           ! number of sub-timestep for the advection
74
75      REAL(wp) ::  &                             
76         zindb  ,  &
77         zacrith, &
78         zindsn , &
79         zindic , &
80         zusvosn, &
81         zusvoic, &
82         zignm  , &
83         zindhe , &
84         zvbord , &
85         zcfl   , &
86         zusnit , &
87         zrtt, ztsn, ztic1, ztic2
88
89      REAL(wp), DIMENSION(jpi,jpj)  ::   &  ! temporary workspace
90         zui_u , zvi_v , zsm   ,         &
91         zs0ice, zs0sn , zs0a  ,         &
92         zs0c0 , zs0c1 , zs0c2 ,         &
93         zs0st
94      !---------------------------------------------------------------------
95
96      IF( numit == nstart  )   CALL lim_trp_init      ! Initialization (first time-step only)
97
98      zsm(:,:) = area(:,:)
99     
100      IF( ln_limdyn ) THEN
101         !-------------------------------------!
102         !   Advection of sea ice properties   !
103         !-------------------------------------!
104
105         ! ice velocities at ocean U- and V-points (zui_u,zvi_v)
106         ! ---------------------------------------
107         ! zvbord factor between 1 and 2 to take into account slip or no-slip boundary conditions.       
108         zvbord = 1.0 + ( 1.0 - bound )
109         DO jj = 1, jpjm1
110            DO ji = 1, jpim1
111               zui_u(ji,jj) = ( u_ice(ji+1,jj  ) + u_ice(ji+1,jj+1) ) / ( MAX( tmu(ji+1,jj  ) + tmu(ji+1,jj+1), zvbord ) )
112               zvi_v(ji,jj) = ( v_ice(ji  ,jj+1) + v_ice(ji+1,jj+1) ) / ( MAX( tmu(ji  ,jj+1) + tmu(ji+1,jj+1), zvbord ) )
113            END DO
114         END DO
115         ! Lateral boundary conditions on zui_u, zvi_v
116         CALL lbc_lnk( zui_u, 'U', -1. )
117         CALL lbc_lnk( zvi_v, 'V', -1. )
118
119         ! CFL test for stability
120         ! ----------------------
121         zcfl  = 0.e0
122         zcfl  = MAX( zcfl, MAXVAL( ABS( zui_u(1:jpim1, :     ) ) * rdt_ice / e1u(1:jpim1, :     ) ) )
123         zcfl  = MAX( zcfl, MAXVAL( ABS( zvi_v( :     ,1:jpjm1) ) * rdt_ice / e2v( :     ,1:jpjm1) ) )
124
125         IF (lk_mpp ) CALL mpp_max(zcfl)
126
127         IF ( zcfl > 0.5 .AND. lwp )   WRITE(numout,*) 'lim_trp : violation of cfl criterion the ',nday,'th day, cfl = ',zcfl
128
129         ! content of properties
130         ! ---------------------
131         zs0sn (:,:) =  hsnm(:,:) * area(:,:)                 ! Snow volume.
132         zs0ice(:,:) =  hicm (:,:) * area(:,:)                ! Ice volume.
133         zs0a  (:,:) =  ( 1.0 - frld(:,:) ) * area(:,:)       ! Surface covered by ice.
134         zs0c0 (:,:) =  tbif(:,:,1) / rt0_snow * zs0sn(:,:)   ! Heat content of the snow layer.
135         zs0c1 (:,:) =  tbif(:,:,2) / rt0_ice  * zs0ice(:,:)  ! Heat content of the first ice layer.
136         zs0c2 (:,:) =  tbif(:,:,3) / rt0_ice  * zs0ice(:,:)  ! Heat content of the second ice layer.
137         zs0st (:,:) =  qstoif(:,:) / xlic     * zs0a(:,:)    ! Heat reservoir for brine pockets.
138         
139 
140         ! Advection
141         ! ---------
142         ! If ice drift field is too fast, use an appropriate time step for advection.         
143         initad = 1 + INT( MAX( rzero, SIGN( rone, zcfl-0.5 ) ) )
144         zusnit = 1.0 / REAL( initad ) 
145         
146         IF ( MOD( nday , 2 ) == 0) THEN
147            DO jk = 1,initad
148               CALL lim_adv_x( zusnit, zui_u, rone , zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
149               CALL lim_adv_y( zusnit, zvi_v, rzero, zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
150               CALL lim_adv_x( zusnit, zui_u, rone , zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
151               CALL lim_adv_y( zusnit, zvi_v, rzero, zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
152               CALL lim_adv_x( zusnit, zui_u, rone , zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
153               CALL lim_adv_y( zusnit, zvi_v, rzero, zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
154               CALL lim_adv_x( zusnit, zui_u, rone , zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
155               CALL lim_adv_y( zusnit, zvi_v, rzero, zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
156               CALL lim_adv_x( zusnit, zui_u, rone , zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
157               CALL lim_adv_y( zusnit, zvi_v, rzero, zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
158               CALL lim_adv_x( zusnit, zui_u, rone , zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
159               CALL lim_adv_y( zusnit, zvi_v, rzero, zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
160               CALL lim_adv_x( zusnit, zui_u, rone , zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
161               CALL lim_adv_y( zusnit, zvi_v, rzero, zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
162            END DO
163         ELSE
164            DO jk = 1, initad
165               CALL lim_adv_y( zusnit, zvi_v, rone , zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
166               CALL lim_adv_x( zusnit, zui_u, rzero, zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
167               CALL lim_adv_y( zusnit, zvi_v, rone , zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
168               CALL lim_adv_x( zusnit, zui_u, rzero, zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
169               CALL lim_adv_y( zusnit, zvi_v, rone , zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
170               CALL lim_adv_x( zusnit, zui_u, rzero, zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
171               CALL lim_adv_y( zusnit, zvi_v, rone , zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
172               CALL lim_adv_x( zusnit, zui_u, rzero, zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
173               CALL lim_adv_y( zusnit, zvi_v, rone , zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
174               CALL lim_adv_x( zusnit, zui_u, rzero, zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
175               CALL lim_adv_y( zusnit, zvi_v, rone , zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
176               CALL lim_adv_x( zusnit, zui_u, rzero, zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
177               CALL lim_adv_y( zusnit, zvi_v, rone , zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
178               CALL lim_adv_x( zusnit, zui_u, rzero, zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
179            END DO
180         ENDIF
181                       
182         ! recover the properties from their contents
183         ! ------------------------------------------
184         zs0ice(:,:) = zs0ice(:,:) / area(:,:)
185         zs0sn (:,:) = zs0sn (:,:) / area(:,:)
186         zs0a  (:,:) = zs0a  (:,:) / area(:,:)
187         zs0c0 (:,:) = zs0c0 (:,:) / area(:,:)
188         zs0c1 (:,:) = zs0c1 (:,:) / area(:,:)
189         zs0c2 (:,:) = zs0c2 (:,:) / area(:,:)
190         zs0st (:,:) = zs0st (:,:) / area(:,:)
191
192
193         !-------------------------------------!
194         !   Diffusion of sea ice properties   !
195         !-------------------------------------!
196
197         ! Masked eddy diffusivity coefficient at ocean U- and V-points
198         ! ------------------------------------------------------------
199         DO jj = 1, jpjm1          ! NB: has not to be defined on jpj line and jpi row
200            DO ji = 1 , fs_jpim1   ! vector opt.
201               pahu(ji,jj) = ( 1.0 - MAX( rzero, SIGN( rone, -zs0a(ji  ,jj) ) ) )   &
202                  &        * ( 1.0 - MAX( rzero, SIGN( rone, -zs0a(ji+1,jj) ) ) ) * ahiu(ji,jj)
203               pahv(ji,jj) = ( 1.0 - MAX( rzero, SIGN( rone, -zs0a(ji,jj  ) ) ) )   &
204                  &        * ( 1.0 - MAX( rzero, SIGN( rone,- zs0a(ji,jj+1) ) ) ) * ahiv(ji,jj)
205            END DO
206         END DO
207
208         ! diffusion
209         ! ---------
210         CALL lim_hdf( zs0ice )
211         CALL lim_hdf( zs0sn  )
212         CALL lim_hdf( zs0a   )
213         CALL lim_hdf( zs0c0  )
214         CALL lim_hdf( zs0c1  )
215         CALL lim_hdf( zs0c2  )
216         CALL lim_hdf( zs0st  )
217
218         zs0ice(:,:) = MAX( rzero, zs0ice(:,:) * area(:,:) )    !!bug:  est-ce utile
219         zs0sn (:,:) = MAX( rzero, zs0sn (:,:) * area(:,:) )    !!bug:  cf /area  juste apres
220         zs0a  (:,:) = MAX( rzero, zs0a  (:,:) * area(:,:) )    !! suppression des 2 change le resultat...
221         zs0c0 (:,:) = MAX( rzero, zs0c0 (:,:) * area(:,:) )
222         zs0c1 (:,:) = MAX( rzero, zs0c1 (:,:) * area(:,:) )
223         zs0c2 (:,:) = MAX( rzero, zs0c2 (:,:) * area(:,:) )
224         zs0st (:,:) = MAX( rzero, zs0st (:,:) * area(:,:) )
225
226
227         ! -------------------------------------------------------------------!
228         !   Up-dating and limitation of sea ice properties after transport   !
229         ! -------------------------------------------------------------------!
230
231         ! Up-dating and limitation of sea ice properties after transport.
232         DO jj = 1, jpj
233!!!iii      zindhe = REAL( MAX( 0, isign(1, jj - njeq ) ) )              !ibug mpp  !!bugmpp  njeq!
234            zindhe = MAX( 0.e0, SIGN( 1.e0, fcor(1,jj) ) )              ! = 0 for SH, =1 for NH
235            DO ji = 1, jpi
236
237               ! Recover mean values over the grid squares.
238               zs0sn (ji,jj) = MAX( rzero, zs0sn (ji,jj)/area(ji,jj) )
239               zs0ice(ji,jj) = MAX( rzero, zs0ice(ji,jj)/area(ji,jj) )
240               zs0a  (ji,jj) = MAX( rzero, zs0a  (ji,jj)/area(ji,jj) )
241               zs0c0 (ji,jj) = MAX( rzero, zs0c0 (ji,jj)/area(ji,jj) )
242               zs0c1 (ji,jj) = MAX( rzero, zs0c1 (ji,jj)/area(ji,jj) )
243               zs0c2 (ji,jj) = MAX( rzero, zs0c2 (ji,jj)/area(ji,jj) )
244               zs0st (ji,jj) = MAX( rzero, zs0st (ji,jj)/area(ji,jj) )
245
246               ! Recover in situ values.
247               zindb         = MAX( rzero, SIGN( rone, zs0a(ji,jj) - epsi06 ) )
248               zacrith       = 1.0 - ( zindhe * acrit(1) + ( 1.0 - zindhe ) * acrit(2) )
249               zs0a (ji,jj)  = zindb * MIN( zs0a(ji,jj), zacrith )
250               hsnif(ji,jj)  = zindb * ( zs0sn(ji,jj) /MAX( zs0a(ji,jj), epsi16 ) )
251               hicif(ji,jj)  = zindb * ( zs0ice(ji,jj)/MAX( zs0a(ji,jj), epsi16 ) )
252               zindsn        = MAX( rzero, SIGN( rone, hsnif(ji,jj) - epsi06 ) )
253               zindic        = MAX( rzero, SIGN( rone, hicif(ji,jj) - epsi03 ) )
254               zindb         = MAX( zindsn, zindic )
255               zs0a (ji,jj)  = zindb * zs0a(ji,jj)
256               frld (ji,jj)  = 1.0 - zs0a(ji,jj)
257               hsnif(ji,jj)  = zindsn * hsnif(ji,jj)
258               hicif(ji,jj)  = zindic * hicif(ji,jj)
259               zusvosn       = 1.0/MAX( hsnif(ji,jj) * zs0a(ji,jj), epsi16 )
260               zusvoic       = 1.0/MAX( hicif(ji,jj) * zs0a(ji,jj), epsi16 )
261               zignm         = MAX( rzero,  SIGN( rone, hsndif - hsnif(ji,jj) ) )
262               zrtt          = 173.15 * rone 
263               ztsn          =          zignm   * tbif(ji,jj,1)  &
264                              + ( 1.0 - zignm ) * MIN( MAX( zrtt, rt0_snow * zusvosn * zs0c0(ji,jj)) , tfu(ji,jj) ) 
265               ztic1          = MIN( MAX( zrtt, rt0_ice * zusvoic * zs0c1(ji,jj) ) , tfu(ji,jj) )
266               ztic2          = MIN( MAX( zrtt, rt0_ice * zusvoic * zs0c2(ji,jj) ) , tfu(ji,jj) )
267 
268               tbif(ji,jj,1) = zindsn * ztsn  + ( 1.0 - zindsn ) * tfu(ji,jj)               
269               tbif(ji,jj,2) = zindic * ztic1 + ( 1.0 - zindic ) * tfu(ji,jj)
270               tbif(ji,jj,3) = zindic * ztic2 + ( 1.0 - zindic ) * tfu(ji,jj)
271               qstoif(ji,jj) = zindb  * xlic * zs0st(ji,jj) /  MAX( zs0a(ji,jj), epsi16 )
272            END DO
273         END DO
274         
275      ENDIF
276     
277   END SUBROUTINE lim_trp
278
279
280   SUBROUTINE lim_trp_init
281      !!-------------------------------------------------------------------
282      !!                  ***  ROUTINE lim_trp_init  ***
283      !!
284      !! ** Purpose :   initialization of ice advection parameters
285      !!
286      !! ** Method  : Read the namicetrp namelist and check the parameter
287      !!       values called at the first timestep (nit000)
288      !!
289      !! ** input   :   Namelist namicetrp
290      !!
291      !! history :
292      !!   2.0  !  03-08 (C. Ethe)  Original code
293      !!-------------------------------------------------------------------
294      NAMELIST/namicetrp/ bound
295      !!-------------------------------------------------------------------
296
297      ! Read Namelist namicetrp
298      REWIND ( numnam_ice )
299      READ   ( numnam_ice  , namicetrp )
300      IF(lwp) THEN
301         WRITE(numout,*)
302         WRITE(numout,*) 'lim_trp_init : Ice parameters for advection '
303         WRITE(numout,*) '~~~~~~~~~~~~'
304         WRITE(numout,*) '   boundary conditions (0. no-slip, 1. free-slip) bound  = ', bound
305      ENDIF
306           
307   END SUBROUTINE lim_trp_init
308
309#else
310   !!----------------------------------------------------------------------
311   !!   Default option         Empty Module                No sea-ice model
312   !!----------------------------------------------------------------------
313CONTAINS
314   SUBROUTINE lim_trp        ! Empty routine
315   END SUBROUTINE lim_trp
316#endif
317
318   !!======================================================================
319END MODULE limtrp
Note: See TracBrowser for help on using the repository browser.