New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limrhg_2.F90 in trunk/NEMO/LIM_SRC_2 – NEMO

source: trunk/NEMO/LIM_SRC_2/limrhg_2.F90 @ 1510

Last change on this file since 1510 was 1470, checked in by smasson, 15 years ago

[uv]i_ice and [uv]i_oce renamed [uv]_ice and [uv]_oce, see ticket:453
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 32.6 KB
Line 
1MODULE limrhg_2
2   !!======================================================================
3   !!                     ***  MODULE  limrhg_2  ***
4   !!   Ice rheology :  performs sea ice rheology
5   !!======================================================================
6   !! History :  0.0  !  93-12  (M.A. Morales Maqueda.)  Original code
7   !!            1.0  !  94-12  (H. Goosse)
8   !!            2.0  !  03-12  (C. Ethe, G. Madec)  F90, mpp
9   !!            " "  !  06-08  (G. Madec)  surface module, ice-stress at I-point
10   !!            " "  !  09-09  (G. Madec)  Huge verctor optimisation
11   !!----------------------------------------------------------------------
12#if defined key_lim2
13   !!----------------------------------------------------------------------
14   !!   'key_lim2'                                    LIM 2.0 sea-ice model
15   !!----------------------------------------------------------------------
16   !!----------------------------------------------------------------------
17   !!   lim_rhg_2   : computes ice velocities
18   !!----------------------------------------------------------------------
19   USE par_oce        ! ocean parameter
20   USE sbc_ice        ! surface boundary condition: ice variables
21   USE dom_ice_2      ! domaine: ice variables
22   USE phycst         ! physical constant
23   USE ice_2          ! ice variables
24   USE lbclnk         ! lateral boundary condition
25   USE lib_mpp        ! MPP library
26   USE in_out_manager ! I/O manager
27   USE prtctl         ! Print control
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   lim_rhg_2 ! routine called by lim_dyn
33
34   REAL(wp) ::   rzero   = 0.e0   ! constant value: zero
35   REAL(wp) ::   rone    = 1.e0   !            and  one
36
37   !! * Substitutions
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !!   LIM 2.0,  UCL-LOCEAN-IPSL (2006)
41   !! $Id$
42   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44
45CONTAINS
46
47   SUBROUTINE lim_rhg_2( k_j1, k_jpj )
48      !!-------------------------------------------------------------------
49      !!                 ***  SUBROUTINR lim_rhg_2  ***
50      !!
51      !! ** purpose :   determines the velocity field of sea ice by using
52      !!  atmospheric (wind stress) and oceanic (water stress and surface
53      !!  tilt) forcings. Ice-ice interaction is described by a non-linear
54      !!  viscous-plastic law including shear strength and a bulk rheology.
55      !!
56      !! ** Action  : - compute u_ice, v_ice the sea-ice velocity defined
57      !!              at I-point
58      !!-------------------------------------------------------------------
59      INTEGER, INTENT(in) ::   k_j1    ! southern j-index for ice computation
60      INTEGER, INTENT(in) ::   k_jpj   ! northern j-index for ice computation
61      !!
62      INTEGER ::   ji, jj              ! dummy loop indices
63      INTEGER ::   iter, jter          ! temporary integers
64      CHARACTER (len=50) ::   charout
65      REAL(wp) ::   ze11  , ze12  , ze22  , ze21       ! temporary scalars
66      REAL(wp) ::   zt11  , zt12  , zt21  , zt22       !    "         "
67      REAL(wp) ::   zvis11, zvis21, zvis12, zvis22     !    "         "
68      REAL(wp) ::   zgphsx, ztagnx, zunw, zur, zusw    !    "         "
69      REAL(wp) ::   zgphsy, ztagny, zvnw, zvr          !    "         "
70      REAL(wp) ::   zresm,  za, zac, zmod
71      REAL(wp) ::   zmpzas, zstms, zindu, zusdtp, zmassdt, zcorlal
72      REAL(wp) ::   ztrace2, zdeter, zdelta, zmask, zdgp, zdgi, zdiag
73      REAL(wp) ::   za1, zb1, zc1, zd1
74      REAL(wp) ::   za2, zb2, zc2, zd2, zden
75      REAL(wp) ::   zs11_11, zs11_12, zs11_21, zs11_22
76      REAL(wp) ::   zs12_11, zs12_12, zs12_21, zs12_22
77      REAL(wp) ::   zs21_11, zs21_12, zs21_21, zs21_22
78      REAL(wp) ::   zs22_11, zs22_12, zs22_21, zs22_22
79      REAL(wp), DIMENSION(jpi,  jpj  ) ::   zfrld, zmass, zcorl
80      REAL(wp), DIMENSION(jpi,  jpj  ) ::   za1ct, za2ct, zresr
81      REAL(wp), DIMENSION(jpi,  jpj  ) ::   zc1u, zc1v, zc2u, zc2v
82      REAL(wp), DIMENSION(jpi,  jpj  ) ::   zsang
83      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zu0, zv0
84      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zu_n, zv_n
85      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zu_a, zv_a
86      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zviszeta, zviseta
87      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zzfrld, zztms
88      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zi1, zi2, zmasst, zpresh
89
90      !!-------------------------------------------------------------------
91
92!!bug
93!!    u_oce(:,:) = 0.e0
94!!    v_oce(:,:) = 0.e0
95!!    write(*,*) 'rhg min, max u & v', maxval(u_oce), minval(u_oce), maxval(v_oce), minval(v_oce)
96!!bug
97     
98      !  Store initial velocities
99      !  ----------------
100      zztms(:,0    ) = 0.e0       ;    zzfrld(:,0    ) = 0.e0
101      zztms(:,jpj+1) = 0.e0       ;    zzfrld(:,jpj+1) = 0.e0
102      zu0(:,0    ) = 0.e0         ;    zv0(:,0    ) = 0.e0
103      zu0(:,jpj+1) = 0.e0         ;    zv0(:,jpj+1) = 0.e0
104      zztms(:,1:jpj) = tms(:,:)   ;    zzfrld(:,1:jpj) = frld(:,:)
105      zu0(:,1:jpj) = u_ice(:,:)   ;    zv0(:,1:jpj) = v_ice(:,:)
106
107      zu_a(:,:)    = zu0(:,:)     ;   zv_a(:,:) = zv0(:,:)
108      zu_n(:,:)    = zu0(:,:)     ;   zv_n(:,:) = zv0(:,:)
109
110!i
111      zi1   (:,:) = 0.e0
112      zi2   (:,:) = 0.e0
113      zpresh(:,:) = 0.e0
114      zmasst(:,:) = 0.e0
115!i
116!!gm violant
117      zfrld(:,:) =0.e0
118      zcorl(:,:) =0.e0
119      zmass(:,:) =0.e0
120      za1ct(:,:) =0.e0
121      za2ct(:,:) =0.e0
122!!gm end
123
124      zviszeta(:,:) = 0.e0
125      zviseta (:,:) = 0.e0
126
127!i    zviszeta(:,0    ) = 0.e0    ;    zviseta(:,0    ) = 0.e0
128!i    zviszeta(:,jpj  ) = 0.e0    ;    zviseta(:,jpj  ) = 0.e0
129!i    zviszeta(:,jpj+1) = 0.e0    ;    zviseta(:,jpj+1) = 0.e0
130
131
132      ! Ice mass, ice strength, and wind stress at the center            |
133      ! of the grid squares.                                             |
134      !-------------------------------------------------------------------
135
136!CDIR NOVERRCHK
137      DO jj = k_j1 , k_jpj-1
138!CDIR NOVERRCHK
139         DO ji = 1 , jpi
140            ! only the sinus changes its sign with the hemisphere
141            zsang(ji,jj)  = SIGN( 1.e0, fcor(ji,jj) ) * sangvg   ! only the sinus changes its sign with the hemisphere
142            !
143            zmasst(ji,jj) = tms(ji,jj) * ( rhosn * hsnm(ji,jj) + rhoic * hicm(ji,jj) )
144            zpresh(ji,jj) = tms(ji,jj) *  pstarh * hicm(ji,jj) * EXP( -c_rhg * frld(ji,jj) )
145!!gm  :: stress given at I-point (F-point for the ocean) only compute the ponderation with the ice fraction (1-frld)
146            zi1(ji,jj)    = tms(ji,jj) * ( 1.0 - frld(ji,jj) )
147            zi2(ji,jj)    = tms(ji,jj) * ( 1.0 - frld(ji,jj) )
148         END DO
149      END DO
150
151
152      !---------------------------------------------------------------------------
153      !  Wind stress, coriolis and mass terms at the corners of the grid squares |
154      !  Gradient of ice strenght.                                               |
155      !---------------------------------------------------------------------------
156         
157      DO jj = k_j1+1, k_jpj-1
158         DO ji = fs_2, jpi
159            zstms = zztms(ji,jj  ) * wght(ji,jj,2,2) + zztms(ji-1,jj  ) * wght(ji,jj,1,2)   &
160               &  + zztms(ji,jj-1) * wght(ji,jj,2,1) + zztms(ji-1,jj-1) * wght(ji,jj,1,1)
161            zusw  = 1.0 / MAX( zstms, epsd )
162
163            zt11 = zztms(ji  ,jj  ) * zzfrld(ji  ,jj  ) 
164            zt12 = zztms(ji-1,jj  ) * zzfrld(ji-1,jj  ) 
165            zt21 = zztms(ji  ,jj-1) * zzfrld(ji  ,jj-1) 
166            zt22 = zztms(ji-1,jj-1) * zzfrld(ji-1,jj-1)
167
168            ! Leads area.
169            zfrld(ji,jj) =  (  zt11 * wght(ji,jj,2,2) + zt12 * wght(ji,jj,1,2)   &
170               &             + zt21 * wght(ji,jj,2,1) + zt22 * wght(ji,jj,1,1) ) * zusw
171
172            ! Mass and coriolis coeff. at I-point
173            zmass(ji,jj) = ( zmasst(ji,jj  ) * wght(ji,jj,2,2) + zmasst(ji-1,jj  ) * wght(ji,jj,1,2)   &
174               &           + zmasst(ji,jj-1) * wght(ji,jj,2,1) + zmasst(ji-1,jj-1) * wght(ji,jj,1,1) ) * zusw
175            zcorl(ji,jj) = zmass(ji,jj) * fcor(ji,jj)
176
177            ! Wind stress.
178            ! always provide stress at I-point
179            ztagnx = ( zi1(ji,jj  ) * wght(ji,jj,2,2) + zi1(ji-1,jj  ) * wght(ji,jj,1,2)   &
180               &     + zi1(ji,jj-1) * wght(ji,jj,2,1) + zi1(ji-1,jj-1) * wght(ji,jj,1,1) ) * zusw * utau_ice(ji,jj)
181            ztagny = ( zi2(ji,jj  ) * wght(ji,jj,2,2) + zi2(ji-1,jj  ) * wght(ji,jj,1,2)   &
182               &     + zi2(ji,jj-1) * wght(ji,jj,2,1) + zi2(ji-1,jj-1) * wght(ji,jj,1,1) ) * zusw * vtau_ice(ji,jj)
183
184            ! Gradient of ice strength
185            zgphsx =   ( alambd(ji,jj,2,2,2,1) - alambd(ji,jj,2,1,2,1) ) * zpresh(ji  ,jj-1)   &
186               &     + ( alambd(ji,jj,2,2,2,2) - alambd(ji,jj,2,1,2,2) ) * zpresh(ji  ,jj  )   &
187               &     - ( alambd(ji,jj,2,2,1,1) + alambd(ji,jj,2,1,1,1) ) * zpresh(ji-1,jj-1)   &
188               &     - ( alambd(ji,jj,2,2,1,2) + alambd(ji,jj,2,1,1,2) ) * zpresh(ji-1,jj  )
189
190            zgphsy = - ( alambd(ji,jj,1,1,2,1) + alambd(ji,jj,1,2,2,1) ) * zpresh(ji  ,jj-1)   &
191               &     - ( alambd(ji,jj,1,1,1,1) + alambd(ji,jj,1,2,1,1) ) * zpresh(ji-1,jj-1)   &
192               &     + ( alambd(ji,jj,1,1,2,2) - alambd(ji,jj,1,2,2,2) ) * zpresh(ji  ,jj  )   &
193               &     + ( alambd(ji,jj,1,1,1,2) - alambd(ji,jj,1,2,1,2) ) * zpresh(ji-1,jj  )
194
195            ! Computation of the velocity field taking into account the ice-ice interaction.                                 
196            ! Terms that are independent of the ice velocity field.
197            za1ct(ji,jj) = ztagnx - zcorl(ji,jj) * v_oce(ji,jj) - zgphsx
198            za2ct(ji,jj) = ztagny + zcorl(ji,jj) * u_oce(ji,jj) - zgphsy
199         END DO
200      END DO
201
202
203      ! SOLUTION OF THE MOMENTUM EQUATION.
204      !------------------------------------------
205      !                                                   ! ==================== !
206      DO iter = 1 , 2 * nbiter                            !    loop over iter    !
207         !                                                ! ==================== !       
208         zindu = MOD( iter , 2 )
209         zusdtp = ( zindu * 2.0 + ( 1.0 - zindu ) * 1.0 )  * REAL( nbiter ) / rdt_ice
210
211         ! Computation of free drift field for free slip boundary conditions.
212
213!CDIR NOVERRCHK
214         DO jj = k_j1, k_jpj-1
215!CDIR NOVERRCHK
216            DO ji = 1, fs_jpim1
217               !- Rate of strain tensor.
218               zt11 =   akappa(ji,jj,1,1) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) - zu_a(ji,jj  ) - zu_a(ji  ,jj+1) )  &
219                  &   + akappa(ji,jj,1,2) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) + zv_a(ji,jj  ) + zv_a(ji  ,jj+1) )
220               zt12 = - akappa(ji,jj,2,2) * ( zu_a(ji  ,jj) + zu_a(ji+1,jj  ) - zu_a(ji,jj+1) - zu_a(ji+1,jj+1) )  &
221                  &   - akappa(ji,jj,2,1) * ( zv_a(ji  ,jj) + zv_a(ji+1,jj  ) + zv_a(ji,jj+1) + zv_a(ji+1,jj+1) )
222               zt22 = - akappa(ji,jj,2,2) * ( zv_a(ji  ,jj) + zv_a(ji+1,jj  ) - zv_a(ji,jj+1) - zv_a(ji+1,jj+1) )  &
223                  &   + akappa(ji,jj,2,1) * ( zu_a(ji  ,jj) + zu_a(ji+1,jj  ) + zu_a(ji,jj+1) + zu_a(ji+1,jj+1) )
224               zt21 =   akappa(ji,jj,1,1) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) - zv_a(ji,jj  ) - zv_a(ji  ,jj+1) )  &
225                  &   - akappa(ji,jj,1,2) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) + zu_a(ji,jj  ) + zu_a(ji  ,jj+1) )
226
227               !- Rate of strain tensor.
228               zdgp = zt11 + zt22
229               zdgi = zt12 + zt21
230               ztrace2 = zdgp * zdgp 
231               zdeter  = zt11 * zt22 - 0.25 * zdgi * zdgi
232
233               !  Creep limit depends on the size of the grid.
234               zdelta = MAX( SQRT( ztrace2 + ( ztrace2 - 4.0 * zdeter ) * usecc2 ),  creepl)
235
236               !-  Computation of viscosities.
237               zviszeta(ji,jj) = MAX( zpresh(ji,jj) / zdelta, etamn )
238               zviseta (ji,jj) = zviszeta(ji,jj) * usecc2
239            END DO
240         END DO
241
242         !-  Determination of zc1u, zc2u, zc1v and zc2v.
243         DO jj = k_j1+1, k_jpj-1
244            DO ji = 2, fs_jpim1   ! NO vector opt.
245               !* zc1u , zc2v
246               zvis11 = 2.0 * zviseta (ji-1,jj-1) + dm
247               zvis12 =       zviseta (ji-1,jj-1) + dm
248               zvis21 =       zviseta (ji-1,jj-1)
249               zvis22 =       zviszeta(ji-1,jj-1) - zviseta(ji-1,jj-1)
250               zdiag  = zvis22 * ( akappa(ji-1,jj-1,1,1) + akappa(ji-1,jj-1,2,1) )
251               zs11_11 =  zvis11 * akappa(ji-1,jj-1,1,1) + zdiag
252               zs12_11 =  zvis12 * akappa(ji-1,jj-1,2,2) - zvis21 * akappa(ji-1,jj-1,1,2)
253               zs21_11 = -zvis12 * akappa(ji-1,jj-1,1,2) + zvis21 * akappa(ji-1,jj-1,2,2)
254               zs22_11 =  zvis11 * akappa(ji-1,jj-1,2,1) + zdiag
255
256               zvis11 = 2.0 * zviseta (ji,jj-1) + dm
257               zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
258               zvis12 =       zviseta (ji,jj-1) + dm
259               zvis21 =       zviseta (ji,jj-1)
260               zdiag = zvis22 * ( -akappa(ji,jj-1,1,1) + akappa(ji,jj-1,2,1) )
261               zs11_21 = -zvis11 * akappa(ji,jj-1,1,1) + zdiag
262               zs12_21 =  zvis12 * akappa(ji,jj-1,2,2) - zvis21 * akappa(ji,jj-1,1,2)
263               zs22_21 =  zvis11 * akappa(ji,jj-1,2,1) + zdiag
264               zs21_21 = -zvis12 * akappa(ji,jj-1,1,2) + zvis21 * akappa(ji,jj-1,2,2)
265
266               zvis11 = 2.0 * zviseta (ji-1,jj) + dm
267               zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
268               zvis12 =       zviseta (ji-1,jj) + dm
269               zvis21 =       zviseta (ji-1,jj)
270               zdiag = zvis22 * ( akappa(ji-1,jj,1,1) + akappa(ji-1,jj,2,1) )
271               zs11_12 =  zvis11 * akappa(ji-1,jj,1,1) + zdiag
272               zs12_12 = -zvis12 * akappa(ji-1,jj,2,2) - zvis21 * akappa(ji-1,jj,1,2)
273               zs22_12 =  zvis11 * akappa(ji-1,jj,2,1) + zdiag
274               zs21_12 = -zvis12 * akappa(ji-1,jj,1,2) - zvis21 * akappa(ji-1,jj,2,2)
275
276               zvis11 = 2.0 * zviseta (ji,jj) + dm
277               zvis22 =       zviszeta(ji,jj) - zviseta(ji,jj)
278               zvis12 =       zviseta (ji,jj) + dm
279               zvis21 =       zviseta (ji,jj)
280               zdiag = zvis22 * ( -akappa(ji,jj,1,1) + akappa(ji,jj,2,1) )
281               zs11_22 = -zvis11 * akappa(ji,jj,1,1) + zdiag
282               zs12_22 = -zvis12 * akappa(ji,jj,2,2) - zvis21 * akappa(ji,jj,1,2)
283               zs22_22 =  zvis11 * akappa(ji,jj,2,1) + zdiag
284               zs21_22 = -zvis12 * akappa(ji,jj,1,2) - zvis21 * akappa(ji,jj,2,2)
285
286               zc1u(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs11_21 + alambd(ji,jj,2,2,2,2) * zs11_22   &
287                  &          - alambd(ji,jj,2,2,1,1) * zs11_11 - alambd(ji,jj,2,2,1,2) * zs11_12   &
288                  &          - alambd(ji,jj,1,1,2,1) * zs12_21 - alambd(ji,jj,1,1,1,1) * zs12_11   &
289                  &          + alambd(ji,jj,1,1,2,2) * zs12_22 + alambd(ji,jj,1,1,1,2) * zs12_12   &
290                  &          + alambd(ji,jj,1,2,1,1) * zs21_11 + alambd(ji,jj,1,2,2,1) * zs21_21   &
291                  &          + alambd(ji,jj,1,2,1,2) * zs21_12 + alambd(ji,jj,1,2,2,2) * zs21_22   &
292                  &          - alambd(ji,jj,2,1,1,1) * zs22_11 - alambd(ji,jj,2,1,2,1) * zs22_21   &
293                  &          - alambd(ji,jj,2,1,1,2) * zs22_12 - alambd(ji,jj,2,1,2,2) * zs22_22
294
295               zc2u(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs21_21 + alambd(ji,jj,2,2,2,2) * zs21_22   &
296                  &          - alambd(ji,jj,2,2,1,1) * zs21_11 - alambd(ji,jj,2,2,1,2) * zs21_12   &
297                  &          - alambd(ji,jj,1,1,2,1) * zs22_21 - alambd(ji,jj,1,1,1,1) * zs22_11   &
298                  &          + alambd(ji,jj,1,1,2,2) * zs22_22 + alambd(ji,jj,1,1,1,2) * zs22_12   &
299                  &          - alambd(ji,jj,1,2,1,1) * zs11_11 - alambd(ji,jj,1,2,2,1) * zs11_21   &
300                  &          - alambd(ji,jj,1,2,1,2) * zs11_12 - alambd(ji,jj,1,2,2,2) * zs11_22   &
301                  &          + alambd(ji,jj,2,1,1,1) * zs12_11 + alambd(ji,jj,2,1,2,1) * zs12_21   &
302                  &          + alambd(ji,jj,2,1,1,2) * zs12_12 + alambd(ji,jj,2,1,2,2) * zs12_22
303
304               !* zc1v , zc2v.
305               zvis11 = 2.0 * zviseta (ji-1,jj-1) + dm
306               zvis22 =       zviszeta(ji-1,jj-1) - zviseta(ji-1,jj-1)
307               zvis12 =       zviseta (ji-1,jj-1) + dm
308               zvis21 =       zviseta (ji-1,jj-1)
309               zdiag = zvis22 * ( akappa(ji-1,jj-1,1,2) + akappa(ji-1,jj-1,2,2) )
310               zs11_11 =  zvis11 * akappa(ji-1,jj-1,1,2) + zdiag
311               zs12_11 = -zvis12 * akappa(ji-1,jj-1,2,1) + zvis21 * akappa(ji-1,jj-1,1,1)
312               zs22_11 =  zvis11 * akappa(ji-1,jj-1,2,2) + zdiag
313               zs21_11 =  zvis12 * akappa(ji-1,jj-1,1,1) - zvis21 * akappa(ji-1,jj-1,2,1)
314 
315               zvis11 = 2.0 * zviseta (ji,jj-1) + dm
316               zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
317               zvis12 =       zviseta (ji,jj-1) + dm
318               zvis21 =       zviseta (ji,jj-1)
319               zdiag = zvis22 * ( akappa(ji,jj-1,1,2) + akappa(ji,jj-1,2,2) )
320               zs11_21 =  zvis11 * akappa(ji,jj-1,1,2) + zdiag
321               zs12_21 = -zvis12 * akappa(ji,jj-1,2,1) - zvis21 * akappa(ji,jj-1,1,1)
322               zs22_21 =  zvis11 * akappa(ji,jj-1,2,2) + zdiag
323               zs21_21 = -zvis12 * akappa(ji,jj-1,1,1) - zvis21 * akappa(ji,jj-1,2,1)
324
325               zvis11 = 2.0 * zviseta (ji-1,jj) + dm
326               zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
327               zvis12 =       zviseta (ji-1,jj) + dm
328               zvis21 =       zviseta (ji-1,jj)
329               zdiag = zvis22 * ( akappa(ji-1,jj,1,2) - akappa(ji-1,jj,2,2) )
330               zs11_12 =  zvis11 * akappa(ji-1,jj,1,2) + zdiag
331               zs12_12 = -zvis12 * akappa(ji-1,jj,2,1) + zvis21 * akappa(ji-1,jj,1,1)
332               zs22_12 = -zvis11 * akappa(ji-1,jj,2,2) + zdiag
333               zs21_12 =  zvis12 * akappa(ji-1,jj,1,1) - zvis21 * akappa(ji-1,jj,2,1)
334
335               zvis11 = 2.0 * zviseta (ji,jj) + dm
336               zvis22 =       zviszeta(ji,jj) - zviseta(ji,jj)
337               zvis12 =       zviseta (ji,jj) + dm
338               zvis21 =       zviseta (ji,jj)
339               zdiag = zvis22 * ( akappa(ji,jj,1,2) - akappa(ji,jj,2,2) )
340               zs11_22 =  zvis11 * akappa(ji,jj,1,2) + zdiag
341               zs12_22 = -zvis12 * akappa(ji,jj,2,1) - zvis21 * akappa(ji,jj,1,1)
342               zs22_22 = -zvis11 * akappa(ji,jj,2,2) + zdiag
343               zs21_22 = -zvis12 * akappa(ji,jj,1,1) - zvis21 * akappa(ji,jj,2,1)
344
345               zc1v(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs11_21 + alambd(ji,jj,2,2,2,2) * zs11_22   &
346                  &          - alambd(ji,jj,2,2,1,1) * zs11_11 - alambd(ji,jj,2,2,1,2) * zs11_12   &
347                  &          - alambd(ji,jj,1,1,2,1) * zs12_21 - alambd(ji,jj,1,1,1,1) * zs12_11   &
348                  &          + alambd(ji,jj,1,1,2,2) * zs12_22 + alambd(ji,jj,1,1,1,2) * zs12_12   &
349                  &          + alambd(ji,jj,1,2,1,1) * zs21_11 + alambd(ji,jj,1,2,2,1) * zs21_21   &
350                  &          + alambd(ji,jj,1,2,1,2) * zs21_12 + alambd(ji,jj,1,2,2,2) * zs21_22   &
351                  &          - alambd(ji,jj,2,1,1,1) * zs22_11 - alambd(ji,jj,2,1,2,1) * zs22_21   &
352                  &          - alambd(ji,jj,2,1,1,2) * zs22_12 - alambd(ji,jj,2,1,2,2) * zs22_22
353
354               zc2v(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs21_21 + alambd(ji,jj,2,2,2,2) * zs21_22   &
355                  &          - alambd(ji,jj,2,2,1,1) * zs21_11 - alambd(ji,jj,2,2,1,2) * zs21_12   &
356                  &          - alambd(ji,jj,1,1,2,1) * zs22_21 - alambd(ji,jj,1,1,1,1) * zs22_11   &
357                  &          + alambd(ji,jj,1,1,2,2) * zs22_22 + alambd(ji,jj,1,1,1,2) * zs22_12   &
358                  &          - alambd(ji,jj,1,2,1,1) * zs11_11 - alambd(ji,jj,1,2,2,1) * zs11_21   &
359                  &          - alambd(ji,jj,1,2,1,2) * zs11_12 - alambd(ji,jj,1,2,2,2) * zs11_22   &
360                  &          + alambd(ji,jj,2,1,1,1) * zs12_11 + alambd(ji,jj,2,1,2,1) * zs12_21   &
361                  &          + alambd(ji,jj,2,1,1,2) * zs12_12 + alambd(ji,jj,2,1,2,2) * zs12_22
362            END DO
363         END DO
364
365         ! GAUSS-SEIDEL method
366         !                                                      ! ================ !
367iflag:   DO jter = 1 , nbitdr                                   !    Relaxation    !
368            !                                                   ! ================ !
369!CDIR NOVERRCHK
370            DO jj = k_j1+1, k_jpj-1
371!CDIR NOVERRCHK
372               DO ji = 2, fs_jpim1   ! NO vector opt.
373                  !
374                  ze11 =   akappa(ji,jj-1,1,1) * zu_a(ji+1,jj) + akappa(ji,jj-1,1,2) * zv_a(ji+1,jj)
375                  ze12 = + akappa(ji,jj-1,2,2) * zu_a(ji+1,jj) - akappa(ji,jj-1,2,1) * zv_a(ji+1,jj)
376                  ze22 = + akappa(ji,jj-1,2,2) * zv_a(ji+1,jj) + akappa(ji,jj-1,2,1) * zu_a(ji+1,jj)
377                  ze21 =   akappa(ji,jj-1,1,1) * zv_a(ji+1,jj) - akappa(ji,jj-1,1,2) * zu_a(ji+1,jj)
378                  zvis11 = 2.0 * zviseta (ji,jj-1) + dm
379                  zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
380                  zvis12 =       zviseta (ji,jj-1) + dm
381                  zvis21 =       zviseta (ji,jj-1)
382                  zdiag = zvis22 * ( ze11 + ze22 )
383                  zs11_21 =  zvis11 * ze11 + zdiag
384                  zs12_21 =  zvis12 * ze12 + zvis21 * ze21
385                  zs22_21 =  zvis11 * ze22 + zdiag
386                  zs21_21 =  zvis12 * ze21 + zvis21 * ze12
387
388                  ze11 =   akappa(ji-1,jj,1,1) * ( zu_a(ji  ,jj+1) - zu_a(ji-1,jj+1) )   &
389                     &   + akappa(ji-1,jj,1,2) * ( zv_a(ji  ,jj+1) + zv_a(ji-1,jj+1) )
390                  ze12 = + akappa(ji-1,jj,2,2) * ( zu_a(ji-1,jj+1) + zu_a(ji  ,jj+1) )   &
391                     &   - akappa(ji-1,jj,2,1) * ( zv_a(ji-1,jj+1) + zv_a(ji  ,jj+1) )
392                  ze22 = + akappa(ji-1,jj,2,2) * ( zv_a(ji-1,jj+1) + zv_a(ji  ,jj+1) )   &
393                     &   + akappa(ji-1,jj,2,1) * ( zu_a(ji-1,jj+1) + zu_a(ji  ,jj+1) )
394                  ze21 =   akappa(ji-1,jj,1,1) * ( zv_a(ji  ,jj+1) - zv_a(ji-1,jj+1) )   &
395                     &   - akappa(ji-1,jj,1,2) * ( zu_a(ji  ,jj+1) + zu_a(ji-1,jj+1) )
396                  zvis11 = 2.0 * zviseta (ji-1,jj) + dm
397                  zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
398                  zvis12 =       zviseta (ji-1,jj) + dm
399                  zvis21 =       zviseta (ji-1,jj)
400                  zdiag = zvis22 * ( ze11 + ze22 )
401                  zs11_12 =  zvis11 * ze11 + zdiag
402                  zs12_12 =  zvis12 * ze12 + zvis21 * ze21
403                  zs22_12 =  zvis11 * ze22 + zdiag
404                  zs21_12 =  zvis12 * ze21 + zvis21 * ze12
405
406                  ze11 =   akappa(ji,jj,1,1) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) - zu_a(ji  ,jj+1) )   &
407                     &   + akappa(ji,jj,1,2) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) + zv_a(ji  ,jj+1) )
408                  ze12 = - akappa(ji,jj,2,2) * ( zu_a(ji+1,jj) - zu_a(ji  ,jj+1) - zu_a(ji+1,jj+1) )   &
409                     &   - akappa(ji,jj,2,1) * ( zv_a(ji+1,jj) + zv_a(ji  ,jj+1) + zv_a(ji+1,jj+1) )
410                  ze22 = - akappa(ji,jj,2,2) * ( zv_a(ji+1,jj) - zv_a(ji  ,jj+1) - zv_a(ji+1,jj+1) )   &
411                     &   + akappa(ji,jj,2,1) * ( zu_a(ji+1,jj) + zu_a(ji  ,jj+1) + zu_a(ji+1,jj+1) )
412                  ze21 =   akappa(ji,jj,1,1) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) - zv_a(ji  ,jj+1) )   &
413                     &   - akappa(ji,jj,1,2) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) + zu_a(ji  ,jj+1) )
414                  zvis11 = 2.0 * zviseta (ji,jj) + dm
415                  zvis22 =       zviszeta(ji,jj) - zviseta(ji,jj)
416                  zvis12 =       zviseta (ji,jj) + dm
417                  zvis21 =       zviseta (ji,jj)
418                  zdiag = zvis22 * ( ze11 + ze22 )
419                  zs11_22 =  zvis11 * ze11 + zdiag
420                  zs12_22 =  zvis12 * ze12 + zvis21 * ze21
421                  zs22_22 =  zvis11 * ze22 + zdiag
422                  zs21_22 =  zvis12 * ze21 + zvis21 * ze12
423
424            ! 2nd part
425                  ze11 =   akappa(ji-1,jj-1,1,1) * ( zu_a(ji  ,jj-1) - zu_a(ji-1,jj-1) - zu_a(ji-1,jj) )   &
426                     &   + akappa(ji-1,jj-1,1,2) * ( zv_a(ji  ,jj-1) + zv_a(ji-1,jj-1) + zv_a(ji-1,jj) )
427                  ze12 = - akappa(ji-1,jj-1,2,2) * ( zu_a(ji-1,jj-1) + zu_a(ji  ,jj-1) - zu_a(ji-1,jj) )   &
428                     &   - akappa(ji-1,jj-1,2,1) * ( zv_a(ji-1,jj-1) + zv_a(ji  ,jj-1) + zv_a(ji-1,jj) )
429                  ze22 = - akappa(ji-1,jj-1,2,2) * ( zv_a(ji-1,jj-1) + zv_a(ji  ,jj-1) - zv_a(ji-1,jj) )   &
430                     &   + akappa(ji-1,jj-1,2,1) * ( zu_a(ji-1,jj-1) + zu_a(ji  ,jj-1) + zu_a(ji-1,jj) )
431                  ze21 =   akappa(ji-1,jj-1,1,1) * ( zv_a(ji  ,jj-1) - zv_a(ji-1,jj-1) - zv_a(ji-1,jj) )   &
432                     &  -  akappa(ji-1,jj-1,1,2) * ( zu_a(ji  ,jj-1) + zu_a(ji-1,jj-1) + zu_a(ji-1,jj) )
433                  zvis11 = 2.0 * zviseta (ji-1,jj-1) + dm
434                  zvis22 =       zviszeta(ji-1,jj-1) - zviseta(ji-1,jj-1)
435                  zvis12 =       zviseta (ji-1,jj-1) + dm
436                  zvis21 =       zviseta (ji-1,jj-1)
437                  zdiag = zvis22 * ( ze11 + ze22 )
438                  zs11_11 =  zvis11 * ze11 + zdiag
439                  zs12_11 =  zvis12 * ze12 + zvis21 * ze21
440                  zs22_11 =  zvis11 * ze22 + zdiag
441                  zs21_11 =  zvis12 * ze21 + zvis21 * ze12
442
443                  ze11 =   akappa(ji,jj-1,1,1) * ( zu_a(ji+1,jj-1) - zu_a(ji  ,jj-1) )   &
444                     &   + akappa(ji,jj-1,1,2) * ( zv_a(ji+1,jj-1) + zv_a(ji  ,jj-1) )
445                  ze12 = - akappa(ji,jj-1,2,2) * ( zu_a(ji  ,jj-1) + zu_a(ji+1,jj-1) )   &
446                     &   - akappa(ji,jj-1,2,1) * ( zv_a(ji  ,jj-1) + zv_a(ji+1,jj-1) )
447                  ze22 = - akappa(ji,jj-1,2,2) * ( zv_a(ji  ,jj-1) + zv_a(ji+1,jj-1) )   &
448                     &   + akappa(ji,jj-1,2,1) * ( zu_a(ji  ,jj-1) + zu_a(ji+1,jj-1) )
449                  ze21 =   akappa(ji,jj-1,1,1) * ( zv_a(ji+1,jj-1) - zv_a(ji  ,jj-1) )   &
450                     &   - akappa(ji,jj-1,1,2) * ( zu_a(ji+1,jj-1) + zu_a(ji  ,jj-1) )
451                  zvis11 = 2.0 * zviseta (ji,jj-1) + dm
452                  zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
453                  zvis12 =       zviseta (ji,jj-1) + dm
454                  zvis21 =       zviseta (ji,jj-1)
455                  zdiag = zvis22 * ( ze11 + ze22 )
456                  zs11_21 =  zs11_21 + zvis11 * ze11 + zdiag
457                  zs12_21 =  zs12_21 + zvis12 * ze12 + zvis21 * ze21
458                  zs22_21 =  zs22_21 + zvis11 * ze22 + zdiag
459                  zs21_21 =  zs21_21 + zvis12 * ze21 + zvis21 * ze12
460
461                  ze11 = - akappa(ji-1,jj,1,1) * zu_a(ji-1,jj) + akappa(ji-1,jj,1,2) * zv_a(ji-1,jj)
462                  ze12 = - akappa(ji-1,jj,2,2) * zu_a(ji-1,jj) - akappa(ji-1,jj,2,1) * zv_a(ji-1,jj)
463                  ze22 = - akappa(ji-1,jj,2,2) * zv_a(ji-1,jj) + akappa(ji-1,jj,2,1) * zu_a(ji-1,jj)
464                  ze21 = - akappa(ji-1,jj,1,1) * zv_a(ji-1,jj) - akappa(ji-1,jj,1,2) * zu_a(ji-1,jj)
465                  zvis11 = 2.0 * zviseta (ji-1,jj) + dm
466                  zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
467                  zvis12 =       zviseta (ji-1,jj) + dm
468                  zvis21 =       zviseta (ji-1,jj)
469                  zdiag = zvis22 * ( ze11 + ze22 )
470                  zs11_12 =  zs11_12 + zvis11 * ze11 + zdiag
471                  zs12_12 =  zs12_12 + zvis12 * ze12 + zvis21 * ze21
472                  zs22_12 =  zs22_12 + zvis11 * ze22 + zdiag
473                  zs21_12 =  zs21_12 + zvis12 * ze21 + zvis21 * ze12
474
475                  zd1 = + alambd(ji,jj,2,2,2,1) * zs11_21 + alambd(ji,jj,2,2,2,2) * zs11_22  &
476                     &  - alambd(ji,jj,2,2,1,1) * zs11_11 - alambd(ji,jj,2,2,1,2) * zs11_12  &
477                     &  - alambd(ji,jj,1,1,2,1) * zs12_21 - alambd(ji,jj,1,1,1,1) * zs12_11  &
478                     &  + alambd(ji,jj,1,1,2,2) * zs12_22 + alambd(ji,jj,1,1,1,2) * zs12_12  &
479                     &  + alambd(ji,jj,1,2,1,1) * zs21_11 + alambd(ji,jj,1,2,2,1) * zs21_21  &
480                     &  + alambd(ji,jj,1,2,1,2) * zs21_12 + alambd(ji,jj,1,2,2,2) * zs21_22  &
481                     &  - alambd(ji,jj,2,1,1,1) * zs22_11 - alambd(ji,jj,2,1,2,1) * zs22_21  &
482                     &  - alambd(ji,jj,2,1,1,2) * zs22_12 - alambd(ji,jj,2,1,2,2) * zs22_22
483
484                  zd2 = + alambd(ji,jj,2,2,2,1) * zs21_21 + alambd(ji,jj,2,2,2,2) * zs21_22  &
485                     &  - alambd(ji,jj,2,2,1,1) * zs21_11 - alambd(ji,jj,2,2,1,2) * zs21_12  &
486                     &  - alambd(ji,jj,1,1,2,1) * zs22_21 - alambd(ji,jj,1,1,1,1) * zs22_11  &
487                     &  + alambd(ji,jj,1,1,2,2) * zs22_22 + alambd(ji,jj,1,1,1,2) * zs22_12  &
488                     &  - alambd(ji,jj,1,2,1,1) * zs11_11 - alambd(ji,jj,1,2,2,1) * zs11_21  &
489                     &  - alambd(ji,jj,1,2,1,2) * zs11_12 - alambd(ji,jj,1,2,2,2) * zs11_22  &
490                     &  + alambd(ji,jj,2,1,1,1) * zs12_11 + alambd(ji,jj,2,1,2,1) * zs12_21  &
491                     &  + alambd(ji,jj,2,1,1,2) * zs12_12 + alambd(ji,jj,2,1,2,2) * zs12_22
492
493                  zur     = zu_a(ji,jj) - u_oce(ji,jj)
494                  zvr     = zv_a(ji,jj) - v_oce(ji,jj)
495!!!!
496                  zmod    = SQRT( zur*zur + zvr*zvr ) * ( 1.0 - zfrld(ji,jj) )
497                  za      = rhoco * zmod
498!!!!
499!!gm chg resul    za      = rhoco * SQRT( zur*zur + zvr*zvr ) * ( 1.0 - zfrld(ji,jj) )
500                  zac     = za * cangvg
501                  zmpzas  = alpha * zcorl(ji,jj) + za * zsang(ji,jj)
502                  zmassdt = zusdtp * zmass(ji,jj)
503                  zcorlal = ( 1.0 - alpha ) * zcorl(ji,jj)
504
505                  za1 =  zmassdt * zu0(ji,jj) + zcorlal * zv0(ji,jj) + za1ct(ji,jj)   &
506                     &        + za * ( cangvg * u_oce(ji,jj) - zsang(ji,jj) * v_oce(ji,jj) )
507                  za2 =  zmassdt * zv0(ji,jj) - zcorlal * zu0(ji,jj) + za2ct(ji,jj)   &
508                     &        + za * ( cangvg * v_oce(ji,jj) + zsang(ji,jj) * u_oce(ji,jj) )
509                  zb1    = zmassdt + zac - zc1u(ji,jj)
510                  zb2    = zmpzas        - zc2u(ji,jj)
511                  zc1    = zmpzas        + zc1v(ji,jj)
512                  zc2    = zmassdt + zac - zc2v(ji,jj)
513                  zdeter = zc1 * zb2 + zc2 * zb1
514                  zden   = SIGN( rone, zdeter) / MAX( epsd , ABS( zdeter ) )
515                  zunw   = (  ( za1 + zd1 ) * zc2 + ( za2 + zd2 ) * zc1 ) * zden
516                  zvnw   = (  ( za2 + zd2 ) * zb1 - ( za1 + zd1 ) * zb2 ) * zden
517                  zmask  = ( 1.0 - MAX( rzero, SIGN( rone , 1.0 - zmass(ji,jj) ) ) ) * tmu(ji,jj)
518
519                  zu_n(ji,jj) = ( zu_a(ji,jj) + om * ( zunw - zu_a(ji,jj) ) * tmu(ji,jj) ) * zmask
520                  zv_n(ji,jj) = ( zv_a(ji,jj) + om * ( zvnw - zv_a(ji,jj) ) * tmu(ji,jj) ) * zmask
521               END DO
522            END DO
523
524            CALL lbc_lnk( zu_n(:,1:jpj), 'I', -1. )
525            CALL lbc_lnk( zv_n(:,1:jpj), 'I', -1. )
526
527            ! Test of Convergence
528            DO jj = k_j1+1 , k_jpj-1
529               zresr(:,jj) = MAX( ABS( zu_a(:,jj) - zu_n(:,jj) ) , ABS( zv_a(:,jj) - zv_n(:,jj) ) )
530            END DO
531            zresm = MAXVAL( zresr(1:jpi,k_j1+1:k_jpj-1) )
532!!!! this should be faster on scalar processor
533!           zresm = MAXVAL(  MAX( ABS( zu_a(1:jpi,k_j1+1:k_jpj-1) - zu_n(1:jpi,k_j1+1:k_jpj-1) ),   &
534!              &                  ABS( zv_a(1:jpi,k_j1+1:k_jpj-1) - zv_n(1:jpi,k_j1+1:k_jpj-1) ) )  )
535!!!!
536            IF( lk_mpp )   CALL mpp_max( zresm )   ! max over the global domain
537
538            DO jj = k_j1, k_jpj
539               zu_a(:,jj) = zu_n(:,jj)
540               zv_a(:,jj) = zv_n(:,jj)
541            END DO
542
543            IF( zresm <= resl )   EXIT   iflag
544
545            !                                                   ! ================ !
546         END DO    iflag                                        !  end Relaxation  !
547         !                                                      ! ================ !
548
549         IF( zindu == 0 ) THEN      ! even iteration
550            DO jj = k_j1 , k_jpj-1
551               zu0(:,jj) = zu_a(:,jj)
552               zv0(:,jj) = zv_a(:,jj)
553            END DO
554         ENDIF
555         !                                                ! ==================== !
556      END DO                                              !  end loop over iter  !
557      !                                                   ! ==================== !
558
559      u_ice(:,:) = zu_a(:,1:jpj)
560      v_ice(:,:) = zv_a(:,1:jpj)
561
562      IF(ln_ctl) THEN
563         WRITE(charout,FMT="('lim_rhg  : res =',D23.16, ' iter =',I4)") zresm, jter
564         CALL prt_ctl_info(charout)
565         CALL prt_ctl(tab2d_1=u_ice, clinfo1=' lim_rhg  : u_ice :', tab2d_2=v_ice, clinfo2=' v_ice :')
566      ENDIF
567
568   END SUBROUTINE lim_rhg_2
569
570#else
571   !!----------------------------------------------------------------------
572   !!   Default option          Dummy module       NO 2.0 LIM sea-ice model
573   !!----------------------------------------------------------------------
574CONTAINS
575   SUBROUTINE lim_rhg_2( k1 , k2 )       ! Dummy routine
576      WRITE(*,*) 'lim_rhg_2: You should not have seen this print! error?', k1, k2
577   END SUBROUTINE lim_rhg_2
578#endif
579
580   !!==============================================================================
581END MODULE limrhg_2
Note: See TracBrowser for help on using the repository browser.