New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limrhg_2.F90 in trunk/NEMO/LIM_SRC_2 – NEMO

source: trunk/NEMO/LIM_SRC_2/limrhg_2.F90 @ 1605

Last change on this file since 1605 was 1569, checked in by ctlod, 15 years ago

correction of a bug in the Coriolis term in the rheology of LIM2, see ticket: #504
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 32.8 KB
Line 
1MODULE limrhg_2
2   !!======================================================================
3   !!                     ***  MODULE  limrhg_2  ***
4   !!   Ice rheology :  performs sea ice rheology
5   !!======================================================================
6   !! History :  0.0  !  93-12  (M.A. Morales Maqueda.)  Original code
7   !!            1.0  !  94-12  (H. Goosse)
8   !!            2.0  !  03-12  (C. Ethe, G. Madec)  F90, mpp
9   !!            " "  !  06-08  (G. Madec)  surface module, ice-stress at I-point
10   !!            " "  !  09-09  (G. Madec)  Huge verctor optimisation
11   !!----------------------------------------------------------------------
12#if defined key_lim2
13   !!----------------------------------------------------------------------
14   !!   'key_lim2'                                    LIM 2.0 sea-ice model
15   !!----------------------------------------------------------------------
16   !!----------------------------------------------------------------------
17   !!   lim_rhg_2   : computes ice velocities
18   !!----------------------------------------------------------------------
19   USE par_oce        ! ocean parameter
20   USE sbc_ice        ! surface boundary condition: ice variables
21   USE dom_ice_2      ! domaine: ice variables
22   USE phycst         ! physical constant
23   USE ice_2          ! ice variables
24   USE lbclnk         ! lateral boundary condition
25   USE lib_mpp        ! MPP library
26   USE in_out_manager ! I/O manager
27   USE prtctl         ! Print control
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   lim_rhg_2 ! routine called by lim_dyn
33
34   REAL(wp) ::   rzero   = 0.e0   ! constant value: zero
35   REAL(wp) ::   rone    = 1.e0   !            and  one
36
37   !! * Substitutions
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !!   LIM 2.0,  UCL-LOCEAN-IPSL (2006)
41   !! $Id$
42   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44
45CONTAINS
46
47   SUBROUTINE lim_rhg_2( k_j1, k_jpj )
48      !!-------------------------------------------------------------------
49      !!                 ***  SUBROUTINR lim_rhg_2  ***
50      !!
51      !! ** purpose :   determines the velocity field of sea ice by using
52      !!  atmospheric (wind stress) and oceanic (water stress and surface
53      !!  tilt) forcings. Ice-ice interaction is described by a non-linear
54      !!  viscous-plastic law including shear strength and a bulk rheology.
55      !!
56      !! ** Action  : - compute u_ice, v_ice the sea-ice velocity defined
57      !!              at I-point
58      !!-------------------------------------------------------------------
59      INTEGER, INTENT(in) ::   k_j1    ! southern j-index for ice computation
60      INTEGER, INTENT(in) ::   k_jpj   ! northern j-index for ice computation
61      !!
62      INTEGER ::   ji, jj              ! dummy loop indices
63      INTEGER ::   iter, jter          ! temporary integers
64      CHARACTER (len=50) ::   charout
65      REAL(wp) ::   ze11  , ze12  , ze22  , ze21       ! temporary scalars
66      REAL(wp) ::   zt11  , zt12  , zt21  , zt22       !    "         "
67      REAL(wp) ::   zvis11, zvis21, zvis12, zvis22     !    "         "
68      REAL(wp) ::   zgphsx, ztagnx, zunw, zur, zusw    !    "         "
69      REAL(wp) ::   zgphsy, ztagny, zvnw, zvr          !    "         "
70      REAL(wp) ::   zresm,  za, zac, zmod
71      REAL(wp) ::   zmpzas, zstms, zindu, zusdtp, zmassdt, zcorlal
72      REAL(wp) ::   ztrace2, zdeter, zdelta, zmask, zdgp, zdgi, zdiag
73      REAL(wp) ::   za1, zb1, zc1, zd1
74      REAL(wp) ::   za2, zb2, zc2, zd2, zden
75      REAL(wp) ::   zs11_11, zs11_12, zs11_21, zs11_22
76      REAL(wp) ::   zs12_11, zs12_12, zs12_21, zs12_22
77      REAL(wp) ::   zs21_11, zs21_12, zs21_21, zs21_22
78      REAL(wp) ::   zs22_11, zs22_12, zs22_21, zs22_22
79      REAL(wp), DIMENSION(jpi,  jpj  ) ::   zfrld, zmass, zcorl
80      REAL(wp), DIMENSION(jpi,  jpj  ) ::   za1ct, za2ct, zresr
81      REAL(wp), DIMENSION(jpi,  jpj  ) ::   zc1u, zc1v, zc2u, zc2v
82      REAL(wp), DIMENSION(jpi,  jpj  ) ::   zsang
83      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zu0, zv0
84      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zu_n, zv_n
85      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zu_a, zv_a
86      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zviszeta, zviseta
87      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zzfrld, zztms
88      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zi1, zi2, zmasst, zpresh
89
90      !!-------------------------------------------------------------------
91
92!!bug
93!!    u_oce(:,:) = 0.e0
94!!    v_oce(:,:) = 0.e0
95!!    write(*,*) 'rhg min, max u & v', maxval(u_oce), minval(u_oce), maxval(v_oce), minval(v_oce)
96!!bug
97     
98      !  Store initial velocities
99      !  ----------------
100      zztms(:,0    ) = 0.e0       ;    zzfrld(:,0    ) = 0.e0
101      zztms(:,jpj+1) = 0.e0       ;    zzfrld(:,jpj+1) = 0.e0
102      zu0(:,0    ) = 0.e0         ;    zv0(:,0    ) = 0.e0
103      zu0(:,jpj+1) = 0.e0         ;    zv0(:,jpj+1) = 0.e0
104      zztms(:,1:jpj) = tms(:,:)   ;    zzfrld(:,1:jpj) = frld(:,:)
105      zu0(:,1:jpj) = u_ice(:,:)   ;    zv0(:,1:jpj) = v_ice(:,:)
106
107      zu_a(:,:)    = zu0(:,:)     ;   zv_a(:,:) = zv0(:,:)
108      zu_n(:,:)    = zu0(:,:)     ;   zv_n(:,:) = zv0(:,:)
109
110!i
111      zi1   (:,:) = 0.e0
112      zi2   (:,:) = 0.e0
113      zpresh(:,:) = 0.e0
114      zmasst(:,:) = 0.e0
115!i
116!!gm violant
117      zfrld(:,:) =0.e0
118      zcorl(:,:) =0.e0
119      zmass(:,:) =0.e0
120      za1ct(:,:) =0.e0
121      za2ct(:,:) =0.e0
122!!gm end
123
124      zviszeta(:,:) = 0.e0
125      zviseta (:,:) = 0.e0
126
127!i    zviszeta(:,0    ) = 0.e0    ;    zviseta(:,0    ) = 0.e0
128!i    zviszeta(:,jpj  ) = 0.e0    ;    zviseta(:,jpj  ) = 0.e0
129!i    zviszeta(:,jpj+1) = 0.e0    ;    zviseta(:,jpj+1) = 0.e0
130
131
132      ! Ice mass, ice strength, and wind stress at the center            |
133      ! of the grid squares.                                             |
134      !-------------------------------------------------------------------
135
136!CDIR NOVERRCHK
137      DO jj = k_j1 , k_jpj-1
138!CDIR NOVERRCHK
139         DO ji = 1 , jpi
140            ! only the sinus changes its sign with the hemisphere
141            zsang(ji,jj)  = SIGN( 1.e0, fcor(ji,jj) ) * sangvg   ! only the sinus changes its sign with the hemisphere
142            !
143            zmasst(ji,jj) = tms(ji,jj) * ( rhosn * hsnm(ji,jj) + rhoic * hicm(ji,jj) )
144            zpresh(ji,jj) = tms(ji,jj) *  pstarh * hicm(ji,jj) * EXP( -c_rhg * frld(ji,jj) )
145!!gm  :: stress given at I-point (F-point for the ocean) only compute the ponderation with the ice fraction (1-frld)
146            zi1(ji,jj)    = tms(ji,jj) * ( 1.0 - frld(ji,jj) )
147            zi2(ji,jj)    = tms(ji,jj) * ( 1.0 - frld(ji,jj) )
148         END DO
149      END DO
150
151
152      !---------------------------------------------------------------------------
153      !  Wind stress, coriolis and mass terms at the corners of the grid squares |
154      !  Gradient of ice strenght.                                               |
155      !---------------------------------------------------------------------------
156         
157      DO jj = k_j1+1, k_jpj-1
158         DO ji = fs_2, jpi
159            zstms = zztms(ji,jj  ) * wght(ji,jj,2,2) + zztms(ji-1,jj  ) * wght(ji,jj,1,2)   &
160               &  + zztms(ji,jj-1) * wght(ji,jj,2,1) + zztms(ji-1,jj-1) * wght(ji,jj,1,1)
161            zusw  = 1.0 / MAX( zstms, epsd )
162
163            zt11 = zztms(ji  ,jj  ) * zzfrld(ji  ,jj  ) 
164            zt12 = zztms(ji-1,jj  ) * zzfrld(ji-1,jj  ) 
165            zt21 = zztms(ji  ,jj-1) * zzfrld(ji  ,jj-1) 
166            zt22 = zztms(ji-1,jj-1) * zzfrld(ji-1,jj-1)
167
168            ! Leads area.
169            zfrld(ji,jj) =  (  zt11 * wght(ji,jj,2,2) + zt12 * wght(ji,jj,1,2)   &
170               &             + zt21 * wght(ji,jj,2,1) + zt22 * wght(ji,jj,1,1) ) * zusw
171
172            ! Mass and coriolis coeff. at I-point
173            zmass(ji,jj) = ( zmasst(ji,jj  ) * wght(ji,jj,2,2) + zmasst(ji-1,jj  ) * wght(ji,jj,1,2)   &
174               &           + zmasst(ji,jj-1) * wght(ji,jj,2,1) + zmasst(ji-1,jj-1) * wght(ji,jj,1,1) ) * zusw
175            zcorl(ji,jj) = zmass(ji,jj) &
176               &           *( fcor(ji,jj  ) * wght(ji,jj,2,2) + fcor(ji-1,jj  )*wght(ji,jj,1,2)   &
177               &            + fcor(ji,jj-1) * wght(ji,jj,2,1) + fcor(ji-1,jj-1)*wght(ji,jj,1,1) ) * zusw
178
179            ! Wind stress.
180            ! always provide stress at I-point
181            ztagnx = ( zi1(ji,jj  ) * wght(ji,jj,2,2) + zi1(ji-1,jj  ) * wght(ji,jj,1,2)   &
182               &     + zi1(ji,jj-1) * wght(ji,jj,2,1) + zi1(ji-1,jj-1) * wght(ji,jj,1,1) ) * zusw * utau_ice(ji,jj)
183            ztagny = ( zi2(ji,jj  ) * wght(ji,jj,2,2) + zi2(ji-1,jj  ) * wght(ji,jj,1,2)   &
184               &     + zi2(ji,jj-1) * wght(ji,jj,2,1) + zi2(ji-1,jj-1) * wght(ji,jj,1,1) ) * zusw * vtau_ice(ji,jj)
185
186            ! Gradient of ice strength
187            zgphsx =   ( alambd(ji,jj,2,2,2,1) - alambd(ji,jj,2,1,2,1) ) * zpresh(ji  ,jj-1)   &
188               &     + ( alambd(ji,jj,2,2,2,2) - alambd(ji,jj,2,1,2,2) ) * zpresh(ji  ,jj  )   &
189               &     - ( alambd(ji,jj,2,2,1,1) + alambd(ji,jj,2,1,1,1) ) * zpresh(ji-1,jj-1)   &
190               &     - ( alambd(ji,jj,2,2,1,2) + alambd(ji,jj,2,1,1,2) ) * zpresh(ji-1,jj  )
191
192            zgphsy = - ( alambd(ji,jj,1,1,2,1) + alambd(ji,jj,1,2,2,1) ) * zpresh(ji  ,jj-1)   &
193               &     - ( alambd(ji,jj,1,1,1,1) + alambd(ji,jj,1,2,1,1) ) * zpresh(ji-1,jj-1)   &
194               &     + ( alambd(ji,jj,1,1,2,2) - alambd(ji,jj,1,2,2,2) ) * zpresh(ji  ,jj  )   &
195               &     + ( alambd(ji,jj,1,1,1,2) - alambd(ji,jj,1,2,1,2) ) * zpresh(ji-1,jj  )
196
197            ! Computation of the velocity field taking into account the ice-ice interaction.                                 
198            ! Terms that are independent of the ice velocity field.
199            za1ct(ji,jj) = ztagnx - zcorl(ji,jj) * v_oce(ji,jj) - zgphsx
200            za2ct(ji,jj) = ztagny + zcorl(ji,jj) * u_oce(ji,jj) - zgphsy
201         END DO
202      END DO
203
204
205      ! SOLUTION OF THE MOMENTUM EQUATION.
206      !------------------------------------------
207      !                                                   ! ==================== !
208      DO iter = 1 , 2 * nbiter                            !    loop over iter    !
209         !                                                ! ==================== !       
210         zindu = MOD( iter , 2 )
211         zusdtp = ( zindu * 2.0 + ( 1.0 - zindu ) * 1.0 )  * REAL( nbiter ) / rdt_ice
212
213         ! Computation of free drift field for free slip boundary conditions.
214
215!CDIR NOVERRCHK
216         DO jj = k_j1, k_jpj-1
217!CDIR NOVERRCHK
218            DO ji = 1, fs_jpim1
219               !- Rate of strain tensor.
220               zt11 =   akappa(ji,jj,1,1) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) - zu_a(ji,jj  ) - zu_a(ji  ,jj+1) )  &
221                  &   + akappa(ji,jj,1,2) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) + zv_a(ji,jj  ) + zv_a(ji  ,jj+1) )
222               zt12 = - akappa(ji,jj,2,2) * ( zu_a(ji  ,jj) + zu_a(ji+1,jj  ) - zu_a(ji,jj+1) - zu_a(ji+1,jj+1) )  &
223                  &   - akappa(ji,jj,2,1) * ( zv_a(ji  ,jj) + zv_a(ji+1,jj  ) + zv_a(ji,jj+1) + zv_a(ji+1,jj+1) )
224               zt22 = - akappa(ji,jj,2,2) * ( zv_a(ji  ,jj) + zv_a(ji+1,jj  ) - zv_a(ji,jj+1) - zv_a(ji+1,jj+1) )  &
225                  &   + akappa(ji,jj,2,1) * ( zu_a(ji  ,jj) + zu_a(ji+1,jj  ) + zu_a(ji,jj+1) + zu_a(ji+1,jj+1) )
226               zt21 =   akappa(ji,jj,1,1) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) - zv_a(ji,jj  ) - zv_a(ji  ,jj+1) )  &
227                  &   - akappa(ji,jj,1,2) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) + zu_a(ji,jj  ) + zu_a(ji  ,jj+1) )
228
229               !- Rate of strain tensor.
230               zdgp = zt11 + zt22
231               zdgi = zt12 + zt21
232               ztrace2 = zdgp * zdgp 
233               zdeter  = zt11 * zt22 - 0.25 * zdgi * zdgi
234
235               !  Creep limit depends on the size of the grid.
236               zdelta = MAX( SQRT( ztrace2 + ( ztrace2 - 4.0 * zdeter ) * usecc2 ),  creepl)
237
238               !-  Computation of viscosities.
239               zviszeta(ji,jj) = MAX( zpresh(ji,jj) / zdelta, etamn )
240               zviseta (ji,jj) = zviszeta(ji,jj) * usecc2
241            END DO
242         END DO
243
244         !-  Determination of zc1u, zc2u, zc1v and zc2v.
245         DO jj = k_j1+1, k_jpj-1
246            DO ji = 2, fs_jpim1   ! NO vector opt.
247               !* zc1u , zc2v
248               zvis11 = 2.0 * zviseta (ji-1,jj-1) + dm
249               zvis12 =       zviseta (ji-1,jj-1) + dm
250               zvis21 =       zviseta (ji-1,jj-1)
251               zvis22 =       zviszeta(ji-1,jj-1) - zviseta(ji-1,jj-1)
252               zdiag  = zvis22 * ( akappa(ji-1,jj-1,1,1) + akappa(ji-1,jj-1,2,1) )
253               zs11_11 =  zvis11 * akappa(ji-1,jj-1,1,1) + zdiag
254               zs12_11 =  zvis12 * akappa(ji-1,jj-1,2,2) - zvis21 * akappa(ji-1,jj-1,1,2)
255               zs21_11 = -zvis12 * akappa(ji-1,jj-1,1,2) + zvis21 * akappa(ji-1,jj-1,2,2)
256               zs22_11 =  zvis11 * akappa(ji-1,jj-1,2,1) + zdiag
257
258               zvis11 = 2.0 * zviseta (ji,jj-1) + dm
259               zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
260               zvis12 =       zviseta (ji,jj-1) + dm
261               zvis21 =       zviseta (ji,jj-1)
262               zdiag = zvis22 * ( -akappa(ji,jj-1,1,1) + akappa(ji,jj-1,2,1) )
263               zs11_21 = -zvis11 * akappa(ji,jj-1,1,1) + zdiag
264               zs12_21 =  zvis12 * akappa(ji,jj-1,2,2) - zvis21 * akappa(ji,jj-1,1,2)
265               zs22_21 =  zvis11 * akappa(ji,jj-1,2,1) + zdiag
266               zs21_21 = -zvis12 * akappa(ji,jj-1,1,2) + zvis21 * akappa(ji,jj-1,2,2)
267
268               zvis11 = 2.0 * zviseta (ji-1,jj) + dm
269               zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
270               zvis12 =       zviseta (ji-1,jj) + dm
271               zvis21 =       zviseta (ji-1,jj)
272               zdiag = zvis22 * ( akappa(ji-1,jj,1,1) + akappa(ji-1,jj,2,1) )
273               zs11_12 =  zvis11 * akappa(ji-1,jj,1,1) + zdiag
274               zs12_12 = -zvis12 * akappa(ji-1,jj,2,2) - zvis21 * akappa(ji-1,jj,1,2)
275               zs22_12 =  zvis11 * akappa(ji-1,jj,2,1) + zdiag
276               zs21_12 = -zvis12 * akappa(ji-1,jj,1,2) - zvis21 * akappa(ji-1,jj,2,2)
277
278               zvis11 = 2.0 * zviseta (ji,jj) + dm
279               zvis22 =       zviszeta(ji,jj) - zviseta(ji,jj)
280               zvis12 =       zviseta (ji,jj) + dm
281               zvis21 =       zviseta (ji,jj)
282               zdiag = zvis22 * ( -akappa(ji,jj,1,1) + akappa(ji,jj,2,1) )
283               zs11_22 = -zvis11 * akappa(ji,jj,1,1) + zdiag
284               zs12_22 = -zvis12 * akappa(ji,jj,2,2) - zvis21 * akappa(ji,jj,1,2)
285               zs22_22 =  zvis11 * akappa(ji,jj,2,1) + zdiag
286               zs21_22 = -zvis12 * akappa(ji,jj,1,2) - zvis21 * akappa(ji,jj,2,2)
287
288               zc1u(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs11_21 + alambd(ji,jj,2,2,2,2) * zs11_22   &
289                  &          - alambd(ji,jj,2,2,1,1) * zs11_11 - alambd(ji,jj,2,2,1,2) * zs11_12   &
290                  &          - alambd(ji,jj,1,1,2,1) * zs12_21 - alambd(ji,jj,1,1,1,1) * zs12_11   &
291                  &          + alambd(ji,jj,1,1,2,2) * zs12_22 + alambd(ji,jj,1,1,1,2) * zs12_12   &
292                  &          + alambd(ji,jj,1,2,1,1) * zs21_11 + alambd(ji,jj,1,2,2,1) * zs21_21   &
293                  &          + alambd(ji,jj,1,2,1,2) * zs21_12 + alambd(ji,jj,1,2,2,2) * zs21_22   &
294                  &          - alambd(ji,jj,2,1,1,1) * zs22_11 - alambd(ji,jj,2,1,2,1) * zs22_21   &
295                  &          - alambd(ji,jj,2,1,1,2) * zs22_12 - alambd(ji,jj,2,1,2,2) * zs22_22
296
297               zc2u(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs21_21 + alambd(ji,jj,2,2,2,2) * zs21_22   &
298                  &          - alambd(ji,jj,2,2,1,1) * zs21_11 - alambd(ji,jj,2,2,1,2) * zs21_12   &
299                  &          - alambd(ji,jj,1,1,2,1) * zs22_21 - alambd(ji,jj,1,1,1,1) * zs22_11   &
300                  &          + alambd(ji,jj,1,1,2,2) * zs22_22 + alambd(ji,jj,1,1,1,2) * zs22_12   &
301                  &          - alambd(ji,jj,1,2,1,1) * zs11_11 - alambd(ji,jj,1,2,2,1) * zs11_21   &
302                  &          - alambd(ji,jj,1,2,1,2) * zs11_12 - alambd(ji,jj,1,2,2,2) * zs11_22   &
303                  &          + alambd(ji,jj,2,1,1,1) * zs12_11 + alambd(ji,jj,2,1,2,1) * zs12_21   &
304                  &          + alambd(ji,jj,2,1,1,2) * zs12_12 + alambd(ji,jj,2,1,2,2) * zs12_22
305
306               !* zc1v , zc2v.
307               zvis11 = 2.0 * zviseta (ji-1,jj-1) + dm
308               zvis22 =       zviszeta(ji-1,jj-1) - zviseta(ji-1,jj-1)
309               zvis12 =       zviseta (ji-1,jj-1) + dm
310               zvis21 =       zviseta (ji-1,jj-1)
311               zdiag = zvis22 * ( akappa(ji-1,jj-1,1,2) + akappa(ji-1,jj-1,2,2) )
312               zs11_11 =  zvis11 * akappa(ji-1,jj-1,1,2) + zdiag
313               zs12_11 = -zvis12 * akappa(ji-1,jj-1,2,1) + zvis21 * akappa(ji-1,jj-1,1,1)
314               zs22_11 =  zvis11 * akappa(ji-1,jj-1,2,2) + zdiag
315               zs21_11 =  zvis12 * akappa(ji-1,jj-1,1,1) - zvis21 * akappa(ji-1,jj-1,2,1)
316 
317               zvis11 = 2.0 * zviseta (ji,jj-1) + dm
318               zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
319               zvis12 =       zviseta (ji,jj-1) + dm
320               zvis21 =       zviseta (ji,jj-1)
321               zdiag = zvis22 * ( akappa(ji,jj-1,1,2) + akappa(ji,jj-1,2,2) )
322               zs11_21 =  zvis11 * akappa(ji,jj-1,1,2) + zdiag
323               zs12_21 = -zvis12 * akappa(ji,jj-1,2,1) - zvis21 * akappa(ji,jj-1,1,1)
324               zs22_21 =  zvis11 * akappa(ji,jj-1,2,2) + zdiag
325               zs21_21 = -zvis12 * akappa(ji,jj-1,1,1) - zvis21 * akappa(ji,jj-1,2,1)
326
327               zvis11 = 2.0 * zviseta (ji-1,jj) + dm
328               zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
329               zvis12 =       zviseta (ji-1,jj) + dm
330               zvis21 =       zviseta (ji-1,jj)
331               zdiag = zvis22 * ( akappa(ji-1,jj,1,2) - akappa(ji-1,jj,2,2) )
332               zs11_12 =  zvis11 * akappa(ji-1,jj,1,2) + zdiag
333               zs12_12 = -zvis12 * akappa(ji-1,jj,2,1) + zvis21 * akappa(ji-1,jj,1,1)
334               zs22_12 = -zvis11 * akappa(ji-1,jj,2,2) + zdiag
335               zs21_12 =  zvis12 * akappa(ji-1,jj,1,1) - zvis21 * akappa(ji-1,jj,2,1)
336
337               zvis11 = 2.0 * zviseta (ji,jj) + dm
338               zvis22 =       zviszeta(ji,jj) - zviseta(ji,jj)
339               zvis12 =       zviseta (ji,jj) + dm
340               zvis21 =       zviseta (ji,jj)
341               zdiag = zvis22 * ( akappa(ji,jj,1,2) - akappa(ji,jj,2,2) )
342               zs11_22 =  zvis11 * akappa(ji,jj,1,2) + zdiag
343               zs12_22 = -zvis12 * akappa(ji,jj,2,1) - zvis21 * akappa(ji,jj,1,1)
344               zs22_22 = -zvis11 * akappa(ji,jj,2,2) + zdiag
345               zs21_22 = -zvis12 * akappa(ji,jj,1,1) - zvis21 * akappa(ji,jj,2,1)
346
347               zc1v(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs11_21 + alambd(ji,jj,2,2,2,2) * zs11_22   &
348                  &          - alambd(ji,jj,2,2,1,1) * zs11_11 - alambd(ji,jj,2,2,1,2) * zs11_12   &
349                  &          - alambd(ji,jj,1,1,2,1) * zs12_21 - alambd(ji,jj,1,1,1,1) * zs12_11   &
350                  &          + alambd(ji,jj,1,1,2,2) * zs12_22 + alambd(ji,jj,1,1,1,2) * zs12_12   &
351                  &          + alambd(ji,jj,1,2,1,1) * zs21_11 + alambd(ji,jj,1,2,2,1) * zs21_21   &
352                  &          + alambd(ji,jj,1,2,1,2) * zs21_12 + alambd(ji,jj,1,2,2,2) * zs21_22   &
353                  &          - alambd(ji,jj,2,1,1,1) * zs22_11 - alambd(ji,jj,2,1,2,1) * zs22_21   &
354                  &          - alambd(ji,jj,2,1,1,2) * zs22_12 - alambd(ji,jj,2,1,2,2) * zs22_22
355
356               zc2v(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs21_21 + alambd(ji,jj,2,2,2,2) * zs21_22   &
357                  &          - alambd(ji,jj,2,2,1,1) * zs21_11 - alambd(ji,jj,2,2,1,2) * zs21_12   &
358                  &          - alambd(ji,jj,1,1,2,1) * zs22_21 - alambd(ji,jj,1,1,1,1) * zs22_11   &
359                  &          + alambd(ji,jj,1,1,2,2) * zs22_22 + alambd(ji,jj,1,1,1,2) * zs22_12   &
360                  &          - alambd(ji,jj,1,2,1,1) * zs11_11 - alambd(ji,jj,1,2,2,1) * zs11_21   &
361                  &          - alambd(ji,jj,1,2,1,2) * zs11_12 - alambd(ji,jj,1,2,2,2) * zs11_22   &
362                  &          + alambd(ji,jj,2,1,1,1) * zs12_11 + alambd(ji,jj,2,1,2,1) * zs12_21   &
363                  &          + alambd(ji,jj,2,1,1,2) * zs12_12 + alambd(ji,jj,2,1,2,2) * zs12_22
364            END DO
365         END DO
366
367         ! GAUSS-SEIDEL method
368         !                                                      ! ================ !
369iflag:   DO jter = 1 , nbitdr                                   !    Relaxation    !
370            !                                                   ! ================ !
371!CDIR NOVERRCHK
372            DO jj = k_j1+1, k_jpj-1
373!CDIR NOVERRCHK
374               DO ji = 2, fs_jpim1   ! NO vector opt.
375                  !
376                  ze11 =   akappa(ji,jj-1,1,1) * zu_a(ji+1,jj) + akappa(ji,jj-1,1,2) * zv_a(ji+1,jj)
377                  ze12 = + akappa(ji,jj-1,2,2) * zu_a(ji+1,jj) - akappa(ji,jj-1,2,1) * zv_a(ji+1,jj)
378                  ze22 = + akappa(ji,jj-1,2,2) * zv_a(ji+1,jj) + akappa(ji,jj-1,2,1) * zu_a(ji+1,jj)
379                  ze21 =   akappa(ji,jj-1,1,1) * zv_a(ji+1,jj) - akappa(ji,jj-1,1,2) * zu_a(ji+1,jj)
380                  zvis11 = 2.0 * zviseta (ji,jj-1) + dm
381                  zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
382                  zvis12 =       zviseta (ji,jj-1) + dm
383                  zvis21 =       zviseta (ji,jj-1)
384                  zdiag = zvis22 * ( ze11 + ze22 )
385                  zs11_21 =  zvis11 * ze11 + zdiag
386                  zs12_21 =  zvis12 * ze12 + zvis21 * ze21
387                  zs22_21 =  zvis11 * ze22 + zdiag
388                  zs21_21 =  zvis12 * ze21 + zvis21 * ze12
389
390                  ze11 =   akappa(ji-1,jj,1,1) * ( zu_a(ji  ,jj+1) - zu_a(ji-1,jj+1) )   &
391                     &   + akappa(ji-1,jj,1,2) * ( zv_a(ji  ,jj+1) + zv_a(ji-1,jj+1) )
392                  ze12 = + akappa(ji-1,jj,2,2) * ( zu_a(ji-1,jj+1) + zu_a(ji  ,jj+1) )   &
393                     &   - akappa(ji-1,jj,2,1) * ( zv_a(ji-1,jj+1) + zv_a(ji  ,jj+1) )
394                  ze22 = + akappa(ji-1,jj,2,2) * ( zv_a(ji-1,jj+1) + zv_a(ji  ,jj+1) )   &
395                     &   + akappa(ji-1,jj,2,1) * ( zu_a(ji-1,jj+1) + zu_a(ji  ,jj+1) )
396                  ze21 =   akappa(ji-1,jj,1,1) * ( zv_a(ji  ,jj+1) - zv_a(ji-1,jj+1) )   &
397                     &   - akappa(ji-1,jj,1,2) * ( zu_a(ji  ,jj+1) + zu_a(ji-1,jj+1) )
398                  zvis11 = 2.0 * zviseta (ji-1,jj) + dm
399                  zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
400                  zvis12 =       zviseta (ji-1,jj) + dm
401                  zvis21 =       zviseta (ji-1,jj)
402                  zdiag = zvis22 * ( ze11 + ze22 )
403                  zs11_12 =  zvis11 * ze11 + zdiag
404                  zs12_12 =  zvis12 * ze12 + zvis21 * ze21
405                  zs22_12 =  zvis11 * ze22 + zdiag
406                  zs21_12 =  zvis12 * ze21 + zvis21 * ze12
407
408                  ze11 =   akappa(ji,jj,1,1) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) - zu_a(ji  ,jj+1) )   &
409                     &   + akappa(ji,jj,1,2) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) + zv_a(ji  ,jj+1) )
410                  ze12 = - akappa(ji,jj,2,2) * ( zu_a(ji+1,jj) - zu_a(ji  ,jj+1) - zu_a(ji+1,jj+1) )   &
411                     &   - akappa(ji,jj,2,1) * ( zv_a(ji+1,jj) + zv_a(ji  ,jj+1) + zv_a(ji+1,jj+1) )
412                  ze22 = - akappa(ji,jj,2,2) * ( zv_a(ji+1,jj) - zv_a(ji  ,jj+1) - zv_a(ji+1,jj+1) )   &
413                     &   + akappa(ji,jj,2,1) * ( zu_a(ji+1,jj) + zu_a(ji  ,jj+1) + zu_a(ji+1,jj+1) )
414                  ze21 =   akappa(ji,jj,1,1) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) - zv_a(ji  ,jj+1) )   &
415                     &   - akappa(ji,jj,1,2) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) + zu_a(ji  ,jj+1) )
416                  zvis11 = 2.0 * zviseta (ji,jj) + dm
417                  zvis22 =       zviszeta(ji,jj) - zviseta(ji,jj)
418                  zvis12 =       zviseta (ji,jj) + dm
419                  zvis21 =       zviseta (ji,jj)
420                  zdiag = zvis22 * ( ze11 + ze22 )
421                  zs11_22 =  zvis11 * ze11 + zdiag
422                  zs12_22 =  zvis12 * ze12 + zvis21 * ze21
423                  zs22_22 =  zvis11 * ze22 + zdiag
424                  zs21_22 =  zvis12 * ze21 + zvis21 * ze12
425
426            ! 2nd part
427                  ze11 =   akappa(ji-1,jj-1,1,1) * ( zu_a(ji  ,jj-1) - zu_a(ji-1,jj-1) - zu_a(ji-1,jj) )   &
428                     &   + akappa(ji-1,jj-1,1,2) * ( zv_a(ji  ,jj-1) + zv_a(ji-1,jj-1) + zv_a(ji-1,jj) )
429                  ze12 = - akappa(ji-1,jj-1,2,2) * ( zu_a(ji-1,jj-1) + zu_a(ji  ,jj-1) - zu_a(ji-1,jj) )   &
430                     &   - akappa(ji-1,jj-1,2,1) * ( zv_a(ji-1,jj-1) + zv_a(ji  ,jj-1) + zv_a(ji-1,jj) )
431                  ze22 = - akappa(ji-1,jj-1,2,2) * ( zv_a(ji-1,jj-1) + zv_a(ji  ,jj-1) - zv_a(ji-1,jj) )   &
432                     &   + akappa(ji-1,jj-1,2,1) * ( zu_a(ji-1,jj-1) + zu_a(ji  ,jj-1) + zu_a(ji-1,jj) )
433                  ze21 =   akappa(ji-1,jj-1,1,1) * ( zv_a(ji  ,jj-1) - zv_a(ji-1,jj-1) - zv_a(ji-1,jj) )   &
434                     &  -  akappa(ji-1,jj-1,1,2) * ( zu_a(ji  ,jj-1) + zu_a(ji-1,jj-1) + zu_a(ji-1,jj) )
435                  zvis11 = 2.0 * zviseta (ji-1,jj-1) + dm
436                  zvis22 =       zviszeta(ji-1,jj-1) - zviseta(ji-1,jj-1)
437                  zvis12 =       zviseta (ji-1,jj-1) + dm
438                  zvis21 =       zviseta (ji-1,jj-1)
439                  zdiag = zvis22 * ( ze11 + ze22 )
440                  zs11_11 =  zvis11 * ze11 + zdiag
441                  zs12_11 =  zvis12 * ze12 + zvis21 * ze21
442                  zs22_11 =  zvis11 * ze22 + zdiag
443                  zs21_11 =  zvis12 * ze21 + zvis21 * ze12
444
445                  ze11 =   akappa(ji,jj-1,1,1) * ( zu_a(ji+1,jj-1) - zu_a(ji  ,jj-1) )   &
446                     &   + akappa(ji,jj-1,1,2) * ( zv_a(ji+1,jj-1) + zv_a(ji  ,jj-1) )
447                  ze12 = - akappa(ji,jj-1,2,2) * ( zu_a(ji  ,jj-1) + zu_a(ji+1,jj-1) )   &
448                     &   - akappa(ji,jj-1,2,1) * ( zv_a(ji  ,jj-1) + zv_a(ji+1,jj-1) )
449                  ze22 = - akappa(ji,jj-1,2,2) * ( zv_a(ji  ,jj-1) + zv_a(ji+1,jj-1) )   &
450                     &   + akappa(ji,jj-1,2,1) * ( zu_a(ji  ,jj-1) + zu_a(ji+1,jj-1) )
451                  ze21 =   akappa(ji,jj-1,1,1) * ( zv_a(ji+1,jj-1) - zv_a(ji  ,jj-1) )   &
452                     &   - akappa(ji,jj-1,1,2) * ( zu_a(ji+1,jj-1) + zu_a(ji  ,jj-1) )
453                  zvis11 = 2.0 * zviseta (ji,jj-1) + dm
454                  zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
455                  zvis12 =       zviseta (ji,jj-1) + dm
456                  zvis21 =       zviseta (ji,jj-1)
457                  zdiag = zvis22 * ( ze11 + ze22 )
458                  zs11_21 =  zs11_21 + zvis11 * ze11 + zdiag
459                  zs12_21 =  zs12_21 + zvis12 * ze12 + zvis21 * ze21
460                  zs22_21 =  zs22_21 + zvis11 * ze22 + zdiag
461                  zs21_21 =  zs21_21 + zvis12 * ze21 + zvis21 * ze12
462
463                  ze11 = - akappa(ji-1,jj,1,1) * zu_a(ji-1,jj) + akappa(ji-1,jj,1,2) * zv_a(ji-1,jj)
464                  ze12 = - akappa(ji-1,jj,2,2) * zu_a(ji-1,jj) - akappa(ji-1,jj,2,1) * zv_a(ji-1,jj)
465                  ze22 = - akappa(ji-1,jj,2,2) * zv_a(ji-1,jj) + akappa(ji-1,jj,2,1) * zu_a(ji-1,jj)
466                  ze21 = - akappa(ji-1,jj,1,1) * zv_a(ji-1,jj) - akappa(ji-1,jj,1,2) * zu_a(ji-1,jj)
467                  zvis11 = 2.0 * zviseta (ji-1,jj) + dm
468                  zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
469                  zvis12 =       zviseta (ji-1,jj) + dm
470                  zvis21 =       zviseta (ji-1,jj)
471                  zdiag = zvis22 * ( ze11 + ze22 )
472                  zs11_12 =  zs11_12 + zvis11 * ze11 + zdiag
473                  zs12_12 =  zs12_12 + zvis12 * ze12 + zvis21 * ze21
474                  zs22_12 =  zs22_12 + zvis11 * ze22 + zdiag
475                  zs21_12 =  zs21_12 + zvis12 * ze21 + zvis21 * ze12
476
477                  zd1 = + alambd(ji,jj,2,2,2,1) * zs11_21 + alambd(ji,jj,2,2,2,2) * zs11_22  &
478                     &  - alambd(ji,jj,2,2,1,1) * zs11_11 - alambd(ji,jj,2,2,1,2) * zs11_12  &
479                     &  - alambd(ji,jj,1,1,2,1) * zs12_21 - alambd(ji,jj,1,1,1,1) * zs12_11  &
480                     &  + alambd(ji,jj,1,1,2,2) * zs12_22 + alambd(ji,jj,1,1,1,2) * zs12_12  &
481                     &  + alambd(ji,jj,1,2,1,1) * zs21_11 + alambd(ji,jj,1,2,2,1) * zs21_21  &
482                     &  + alambd(ji,jj,1,2,1,2) * zs21_12 + alambd(ji,jj,1,2,2,2) * zs21_22  &
483                     &  - alambd(ji,jj,2,1,1,1) * zs22_11 - alambd(ji,jj,2,1,2,1) * zs22_21  &
484                     &  - alambd(ji,jj,2,1,1,2) * zs22_12 - alambd(ji,jj,2,1,2,2) * zs22_22
485
486                  zd2 = + alambd(ji,jj,2,2,2,1) * zs21_21 + alambd(ji,jj,2,2,2,2) * zs21_22  &
487                     &  - alambd(ji,jj,2,2,1,1) * zs21_11 - alambd(ji,jj,2,2,1,2) * zs21_12  &
488                     &  - alambd(ji,jj,1,1,2,1) * zs22_21 - alambd(ji,jj,1,1,1,1) * zs22_11  &
489                     &  + alambd(ji,jj,1,1,2,2) * zs22_22 + alambd(ji,jj,1,1,1,2) * zs22_12  &
490                     &  - alambd(ji,jj,1,2,1,1) * zs11_11 - alambd(ji,jj,1,2,2,1) * zs11_21  &
491                     &  - alambd(ji,jj,1,2,1,2) * zs11_12 - alambd(ji,jj,1,2,2,2) * zs11_22  &
492                     &  + alambd(ji,jj,2,1,1,1) * zs12_11 + alambd(ji,jj,2,1,2,1) * zs12_21  &
493                     &  + alambd(ji,jj,2,1,1,2) * zs12_12 + alambd(ji,jj,2,1,2,2) * zs12_22
494
495                  zur     = zu_a(ji,jj) - u_oce(ji,jj)
496                  zvr     = zv_a(ji,jj) - v_oce(ji,jj)
497!!!!
498                  zmod    = SQRT( zur*zur + zvr*zvr ) * ( 1.0 - zfrld(ji,jj) )
499                  za      = rhoco * zmod
500!!!!
501!!gm chg resul    za      = rhoco * SQRT( zur*zur + zvr*zvr ) * ( 1.0 - zfrld(ji,jj) )
502                  zac     = za * cangvg
503                  zmpzas  = alpha * zcorl(ji,jj) + za * zsang(ji,jj)
504                  zmassdt = zusdtp * zmass(ji,jj)
505                  zcorlal = ( 1.0 - alpha ) * zcorl(ji,jj)
506
507                  za1 =  zmassdt * zu0(ji,jj) + zcorlal * zv0(ji,jj) + za1ct(ji,jj)   &
508                     &        + za * ( cangvg * u_oce(ji,jj) - zsang(ji,jj) * v_oce(ji,jj) )
509                  za2 =  zmassdt * zv0(ji,jj) - zcorlal * zu0(ji,jj) + za2ct(ji,jj)   &
510                     &        + za * ( cangvg * v_oce(ji,jj) + zsang(ji,jj) * u_oce(ji,jj) )
511                  zb1    = zmassdt + zac - zc1u(ji,jj)
512                  zb2    = zmpzas        - zc2u(ji,jj)
513                  zc1    = zmpzas        + zc1v(ji,jj)
514                  zc2    = zmassdt + zac - zc2v(ji,jj)
515                  zdeter = zc1 * zb2 + zc2 * zb1
516                  zden   = SIGN( rone, zdeter) / MAX( epsd , ABS( zdeter ) )
517                  zunw   = (  ( za1 + zd1 ) * zc2 + ( za2 + zd2 ) * zc1 ) * zden
518                  zvnw   = (  ( za2 + zd2 ) * zb1 - ( za1 + zd1 ) * zb2 ) * zden
519                  zmask  = ( 1.0 - MAX( rzero, SIGN( rone , 1.0 - zmass(ji,jj) ) ) ) * tmu(ji,jj)
520
521                  zu_n(ji,jj) = ( zu_a(ji,jj) + om * ( zunw - zu_a(ji,jj) ) * tmu(ji,jj) ) * zmask
522                  zv_n(ji,jj) = ( zv_a(ji,jj) + om * ( zvnw - zv_a(ji,jj) ) * tmu(ji,jj) ) * zmask
523               END DO
524            END DO
525
526            CALL lbc_lnk( zu_n(:,1:jpj), 'I', -1. )
527            CALL lbc_lnk( zv_n(:,1:jpj), 'I', -1. )
528
529            ! Test of Convergence
530            DO jj = k_j1+1 , k_jpj-1
531               zresr(:,jj) = MAX( ABS( zu_a(:,jj) - zu_n(:,jj) ) , ABS( zv_a(:,jj) - zv_n(:,jj) ) )
532            END DO
533            zresm = MAXVAL( zresr(1:jpi,k_j1+1:k_jpj-1) )
534!!!! this should be faster on scalar processor
535!           zresm = MAXVAL(  MAX( ABS( zu_a(1:jpi,k_j1+1:k_jpj-1) - zu_n(1:jpi,k_j1+1:k_jpj-1) ),   &
536!              &                  ABS( zv_a(1:jpi,k_j1+1:k_jpj-1) - zv_n(1:jpi,k_j1+1:k_jpj-1) ) )  )
537!!!!
538            IF( lk_mpp )   CALL mpp_max( zresm )   ! max over the global domain
539
540            DO jj = k_j1, k_jpj
541               zu_a(:,jj) = zu_n(:,jj)
542               zv_a(:,jj) = zv_n(:,jj)
543            END DO
544
545            IF( zresm <= resl )   EXIT   iflag
546
547            !                                                   ! ================ !
548         END DO    iflag                                        !  end Relaxation  !
549         !                                                      ! ================ !
550
551         IF( zindu == 0 ) THEN      ! even iteration
552            DO jj = k_j1 , k_jpj-1
553               zu0(:,jj) = zu_a(:,jj)
554               zv0(:,jj) = zv_a(:,jj)
555            END DO
556         ENDIF
557         !                                                ! ==================== !
558      END DO                                              !  end loop over iter  !
559      !                                                   ! ==================== !
560
561      u_ice(:,:) = zu_a(:,1:jpj)
562      v_ice(:,:) = zv_a(:,1:jpj)
563
564      IF(ln_ctl) THEN
565         WRITE(charout,FMT="('lim_rhg  : res =',D23.16, ' iter =',I4)") zresm, jter
566         CALL prt_ctl_info(charout)
567         CALL prt_ctl(tab2d_1=u_ice, clinfo1=' lim_rhg  : u_ice :', tab2d_2=v_ice, clinfo2=' v_ice :')
568      ENDIF
569
570   END SUBROUTINE lim_rhg_2
571
572#else
573   !!----------------------------------------------------------------------
574   !!   Default option          Dummy module       NO 2.0 LIM sea-ice model
575   !!----------------------------------------------------------------------
576CONTAINS
577   SUBROUTINE lim_rhg_2( k1 , k2 )       ! Dummy routine
578      WRITE(*,*) 'lim_rhg_2: You should not have seen this print! error?', k1, k2
579   END SUBROUTINE lim_rhg_2
580#endif
581
582   !!==============================================================================
583END MODULE limrhg_2
Note: See TracBrowser for help on using the repository browser.