| 1 | MODULE limsbc_2 |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE limsbc_2 *** |
|---|
| 4 | !! computation of the flux at the sea ice/ocean interface |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 00-01 (H. Goosse) Original code |
|---|
| 7 | !! 02-07 (C. Ethe, G. Madec) re-writing F90 |
|---|
| 8 | !! 06-07 (G. Madec) surface module |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | #if defined key_lim2 |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | !! 'key_lim2' LIM 2.0 sea-ice model |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! lim_sbc_2 : flux at the ice / ocean interface |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE par_oce ! ocean parameters |
|---|
| 18 | USE dom_oce ! ocean domain |
|---|
| 19 | USE sbc_ice ! surface boundary condition |
|---|
| 20 | USE sbc_oce ! surface boundary condition |
|---|
| 21 | USE phycst ! physical constants |
|---|
| 22 | USE ice_oce ! sea-ice variable |
|---|
| 23 | USE ice_2 ! LIM sea-ice variables |
|---|
| 24 | USE dynspg_oce ! choice of the surface pressure gradient scheme |
|---|
| 25 | |
|---|
| 26 | USE lbclnk ! ocean lateral boundary condition |
|---|
| 27 | USE in_out_manager ! I/O manager |
|---|
| 28 | USE albedo ! albedo parameters |
|---|
| 29 | USE prtctl ! Print control |
|---|
| 30 | USE cpl_oasis3, ONLY : lk_cpl |
|---|
| 31 | |
|---|
| 32 | IMPLICIT NONE |
|---|
| 33 | PRIVATE |
|---|
| 34 | |
|---|
| 35 | PUBLIC lim_sbc_2 ! called by sbc_ice_lim_2 |
|---|
| 36 | |
|---|
| 37 | REAL(wp) :: epsi16 = 1.e-16 ! constant values |
|---|
| 38 | REAL(wp) :: rzero = 0.e0 |
|---|
| 39 | REAL(wp) :: rone = 1.e0 |
|---|
| 40 | |
|---|
| 41 | !! * Substitutions |
|---|
| 42 | # include "vectopt_loop_substitute.h90" |
|---|
| 43 | !!---------------------------------------------------------------------- |
|---|
| 44 | !! LIM 2.0, UCL-LOCEAN-IPSL (2006) |
|---|
| 45 | !! $Id$ |
|---|
| 46 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
|---|
| 47 | !!---------------------------------------------------------------------- |
|---|
| 48 | |
|---|
| 49 | CONTAINS |
|---|
| 50 | |
|---|
| 51 | SUBROUTINE lim_sbc_2( kt ) |
|---|
| 52 | !!------------------------------------------------------------------- |
|---|
| 53 | !! *** ROUTINE lim_sbc_2 *** |
|---|
| 54 | !! |
|---|
| 55 | !! ** Purpose : Update surface ocean boundary condition over areas |
|---|
| 56 | !! that are at least partially covered by sea-ice |
|---|
| 57 | !! |
|---|
| 58 | !! ** Action : - comput. of the momentum, heat and freshwater/salt |
|---|
| 59 | !! fluxes at the ice-ocean interface. |
|---|
| 60 | !! - Update |
|---|
| 61 | !! |
|---|
| 62 | !! ** Outputs : - qsr : sea heat flux: solar |
|---|
| 63 | !! - qns : sea heat flux: non solar |
|---|
| 64 | !! - emp : freshwater budget: volume flux |
|---|
| 65 | !! - emps : freshwater budget: concentration/dillution |
|---|
| 66 | !! - utau : sea surface i-stress (ocean referential) |
|---|
| 67 | !! - vtau : sea surface j-stress (ocean referential) |
|---|
| 68 | !! - fr_i : ice fraction |
|---|
| 69 | !! - tn_ice : sea-ice surface temperature |
|---|
| 70 | !! - alb_ice : sea-ice alberdo (lk_cpl=T) |
|---|
| 71 | !! |
|---|
| 72 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
|---|
| 73 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
|---|
| 74 | !!--------------------------------------------------------------------- |
|---|
| 75 | INTEGER :: kt ! number of iteration |
|---|
| 76 | !! |
|---|
| 77 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 78 | INTEGER :: ifvt, i1mfr, idfr ! some switches |
|---|
| 79 | INTEGER :: iflt, ial, iadv, ifral, ifrdv |
|---|
| 80 | REAL(wp) :: zqsr , zqns ! solar & non solar heat flux |
|---|
| 81 | REAL(wp) :: zinda ! switch for testing the values of ice concentration |
|---|
| 82 | REAL(wp) :: zfons ! salt exchanges at the ice/ocean interface |
|---|
| 83 | REAL(wp) :: zemp ! freshwater exchanges at the ice/ocean interface |
|---|
| 84 | REAL(wp) :: zfrldu, zfrldv ! lead fraction at U- & V-points |
|---|
| 85 | REAL(wp) :: zutau , zvtau ! lead fraction at U- & V-points |
|---|
| 86 | REAL(wp) :: zu_io , zv_io ! 2 components of the ice-ocean velocity |
|---|
| 87 | ! interface 2D --> 3D |
|---|
| 88 | REAL(wp), DIMENSION(jpi,jpj,1) :: zalb ! albedo of ice under overcast sky |
|---|
| 89 | REAL(wp), DIMENSION(jpi,jpj,1) :: zalbp ! albedo of ice under clear sky |
|---|
| 90 | REAL(wp), DIMENSION(jpi,jpj,1) :: zsist ! surface ice temperature (K) |
|---|
| 91 | REAL(wp), DIMENSION(jpi,jpj,1) :: zhicif ! ice thickness |
|---|
| 92 | REAL(wp), DIMENSION(jpi,jpj,1) :: zhsnif ! snow thickness |
|---|
| 93 | REAL(wp) :: zsang, zmod, zfm |
|---|
| 94 | REAL(wp), DIMENSION(jpi,jpj) :: ztio_u, ztio_v ! ocean stress below sea-ice |
|---|
| 95 | |
|---|
| 96 | !!--------------------------------------------------------------------- |
|---|
| 97 | |
|---|
| 98 | IF( kt == nit000 ) THEN |
|---|
| 99 | IF(lwp) WRITE(numout,*) |
|---|
| 100 | IF(lwp) WRITE(numout,*) 'lim_sbc_2 : LIM 2.0 sea-ice - surface boundary condition' |
|---|
| 101 | IF(lwp) WRITE(numout,*) '~~~~~~~~~ ' |
|---|
| 102 | ENDIF |
|---|
| 103 | |
|---|
| 104 | !------------------------------------------! |
|---|
| 105 | ! heat flux at the ocean surface ! |
|---|
| 106 | !------------------------------------------! |
|---|
| 107 | |
|---|
| 108 | !!gm |
|---|
| 109 | !!gm CAUTION |
|---|
| 110 | !!gm re-verifies the non solar expression, especially over open ocen |
|---|
| 111 | !!gm |
|---|
| 112 | DO jj = 1, jpj |
|---|
| 113 | DO ji = 1, jpi |
|---|
| 114 | zinda = 1.0 - MAX( rzero , SIGN( rone, - ( 1.0 - pfrld(ji,jj) ) ) ) |
|---|
| 115 | ifvt = zinda * MAX( rzero , SIGN( rone, - phicif(ji,jj) ) ) |
|---|
| 116 | i1mfr = 1.0 - MAX( rzero , SIGN( rone, - ( 1.0 - frld(ji,jj) ) ) ) |
|---|
| 117 | idfr = 1.0 - MAX( rzero , SIGN( rone, frld(ji,jj) - pfrld(ji,jj) ) ) |
|---|
| 118 | iflt = zinda * (1 - i1mfr) * (1 - ifvt ) |
|---|
| 119 | ial = ifvt * i1mfr + ( 1 - ifvt ) * idfr |
|---|
| 120 | iadv = ( 1 - i1mfr ) * zinda |
|---|
| 121 | ifral = ( 1 - i1mfr * ( 1 - ial ) ) |
|---|
| 122 | ifrdv = ( 1 - ifral * ( 1 - ial ) ) * iadv |
|---|
| 123 | |
|---|
| 124 | !!$ zinda = 1.0 - AINT( pfrld(ji,jj) ) ! = 0. if pure ocean else 1. (at previous time) |
|---|
| 125 | !!$ |
|---|
| 126 | !!$ i1mfr = 1.0 - AINT( frld(ji,jj) ) ! = 0. if pure ocean else 1. (at current time) |
|---|
| 127 | !!$ |
|---|
| 128 | !!$ IF( phicif(ji,jj) <= 0. ) THEN ; ifvt = zinda ! = 1. if (snow and no ice at previous time) else 0. ??? |
|---|
| 129 | !!$ ELSE ; ifvt = 0. |
|---|
| 130 | !!$ ENDIF |
|---|
| 131 | !!$ |
|---|
| 132 | !!$ IF( frld(ji,jj) >= pfrld(ji,jj) ) THEN ; idfr = 0. ! = 0. if lead fraction increases from previous to current |
|---|
| 133 | !!$ ELSE ; idfr = 1. |
|---|
| 134 | !!$ ENDIF |
|---|
| 135 | !!$ |
|---|
| 136 | !!$ iflt = zinda * (1 - i1mfr) * (1 - ifvt ) ! = 1. if ice (not only snow) at previous and pure ocean at current |
|---|
| 137 | !!$ |
|---|
| 138 | !!$ ial = ifvt * i1mfr + ( 1 - ifvt ) * idfr |
|---|
| 139 | !!$! snow no ice ice ice or nothing lead fraction increases |
|---|
| 140 | !!$! at previous now at previous |
|---|
| 141 | !!$! -> ice aera increases ??? -> ice aera decreases ??? |
|---|
| 142 | !!$ |
|---|
| 143 | !!$ iadv = ( 1 - i1mfr ) * zinda |
|---|
| 144 | !!$! pure ocean ice at |
|---|
| 145 | !!$! at current previous |
|---|
| 146 | !!$! -> = 1. if ice disapear between previous and current |
|---|
| 147 | !!$ |
|---|
| 148 | !!$ ifral = ( 1 - i1mfr * ( 1 - ial ) ) |
|---|
| 149 | !!$! ice at ??? |
|---|
| 150 | !!$! current |
|---|
| 151 | !!$! -> ??? |
|---|
| 152 | !!$ |
|---|
| 153 | !!$ ifrdv = ( 1 - ifral * ( 1 - ial ) ) * iadv |
|---|
| 154 | !!$! ice disapear |
|---|
| 155 | !!$ |
|---|
| 156 | !!$ |
|---|
| 157 | |
|---|
| 158 | ! computation the solar flux at ocean surface |
|---|
| 159 | #if defined key_coupled |
|---|
| 160 | zqsr = qsr_tot(ji,jj) + ( fstric(ji,jj) - qsr_ice(ji,jj) ) * ( 1.0 - pfrld(ji,jj) ) |
|---|
| 161 | #else |
|---|
| 162 | zqsr = pfrld(ji,jj) * qsr(ji,jj) + ( 1. - pfrld(ji,jj) ) * fstric(ji,jj) |
|---|
| 163 | #endif |
|---|
| 164 | ! computation the non solar heat flux at ocean surface |
|---|
| 165 | zqns = - ( 1. - thcm(ji,jj) ) * zqsr & ! part of the solar energy used in leads |
|---|
| 166 | & + iflt * ( fscmbq(ji,jj) + ffltbif(ji,jj) ) & |
|---|
| 167 | & + ifral * ( ial * qcmif(ji,jj) + (1 - ial) * qldif(ji,jj) ) / rdt_ice & |
|---|
| 168 | & + ifrdv * ( qfvbq(ji,jj) + qdtcn(ji,jj) ) / rdt_ice |
|---|
| 169 | |
|---|
| 170 | fsbbq(ji,jj) = ( 1.0 - ( ifvt + iflt ) ) * fscmbq(ji,jj) ! ??? |
|---|
| 171 | |
|---|
| 172 | qsr (ji,jj) = zqsr ! solar heat flux |
|---|
| 173 | qns (ji,jj) = zqns - fdtcn(ji,jj) ! non solar heat flux |
|---|
| 174 | END DO |
|---|
| 175 | END DO |
|---|
| 176 | |
|---|
| 177 | !------------------------------------------! |
|---|
| 178 | ! mass flux at the ocean surface ! |
|---|
| 179 | !------------------------------------------! |
|---|
| 180 | |
|---|
| 181 | !!gm |
|---|
| 182 | !!gm CAUTION |
|---|
| 183 | !!gm re-verifies the emp & emps expression, especially the absence of 1-frld on zfm |
|---|
| 184 | !!gm |
|---|
| 185 | DO jj = 1, jpj |
|---|
| 186 | DO ji = 1, jpi |
|---|
| 187 | |
|---|
| 188 | #if defined key_coupled |
|---|
| 189 | zemp = emp_tot(ji,jj) - emp_ice(ji,jj) * ( 1. - pfrld(ji,jj) ) & ! |
|---|
| 190 | & + rdmsnif(ji,jj) / rdt_ice ! freshwaterflux due to snow melting |
|---|
| 191 | #else |
|---|
| 192 | !!$ ! computing freshwater exchanges at the ice/ocean interface |
|---|
| 193 | !!$ zpme = - evap(ji,jj) * frld(ji,jj) & ! evaporation over oceanic fraction |
|---|
| 194 | !!$ & + tprecip(ji,jj) & ! total precipitation |
|---|
| 195 | !!$ & - sprecip(ji,jj) * ( 1. - pfrld(ji,jj) ) & ! remov. snow precip over ice |
|---|
| 196 | !!$ & - rdmsnif(ji,jj) / rdt_ice ! freshwaterflux due to snow melting |
|---|
| 197 | ! computing freshwater exchanges at the ice/ocean interface |
|---|
| 198 | zemp = + emp(ji,jj) * frld(ji,jj) & ! e-p budget over open ocean fraction |
|---|
| 199 | & - tprecip(ji,jj) * ( 1. - frld(ji,jj) ) & ! liquid precipitation reaches directly the ocean |
|---|
| 200 | & + sprecip(ji,jj) * ( 1. - pfrld(ji,jj) ) & ! taking into account change in ice cover within the time step |
|---|
| 201 | & + rdmsnif(ji,jj) / rdt_ice ! freshwaterflux due to snow melting |
|---|
| 202 | ! ! ice-covered fraction: |
|---|
| 203 | #endif |
|---|
| 204 | |
|---|
| 205 | ! computing salt exchanges at the ice/ocean interface |
|---|
| 206 | zfons = ( soce - sice ) * ( rdmicif(ji,jj) / rdt_ice ) |
|---|
| 207 | |
|---|
| 208 | ! converting the salt flux from ice to a freshwater flux from ocean |
|---|
| 209 | zfm = zfons / ( sss_m(ji,jj) + epsi16 ) |
|---|
| 210 | |
|---|
| 211 | emps(ji,jj) = zemp + zfm ! surface ocean concentration/dilution effect (use on SSS evolution) |
|---|
| 212 | emp (ji,jj) = zemp ! surface ocean volume flux (use on sea-surface height evolution) |
|---|
| 213 | |
|---|
| 214 | END DO |
|---|
| 215 | END DO |
|---|
| 216 | |
|---|
| 217 | IF( lk_dynspg_rl ) emp (:,:) = emps(:,:) ! rigid-lid formulation : emp = emps |
|---|
| 218 | |
|---|
| 219 | !------------------------------------------! |
|---|
| 220 | ! momentum flux at the ocean surface ! |
|---|
| 221 | !------------------------------------------! |
|---|
| 222 | |
|---|
| 223 | IF ( ln_limdyn ) THEN ! Update the stress over ice-over area (only in ice-dynamic case) |
|---|
| 224 | ! ! otherwise the atmosphere-ocean stress is used everywhere |
|---|
| 225 | |
|---|
| 226 | ! ... ice stress over ocean with a ice-ocean rotation angle (at I-point) |
|---|
| 227 | !CDIR NOVERRCHK |
|---|
| 228 | DO jj = 1, jpj |
|---|
| 229 | !CDIR NOVERRCHK |
|---|
| 230 | DO ji = 1, jpi |
|---|
| 231 | ! ... change the cosinus angle sign in the south hemisphere |
|---|
| 232 | zsang = SIGN(1.e0, gphif(ji,jj) ) * sangvg |
|---|
| 233 | ! ... ice velocity relative to the ocean |
|---|
| 234 | zu_io = ui_ice(ji,jj) - ui_oce(ji,jj) |
|---|
| 235 | zv_io = vi_ice(ji,jj) - vi_oce(ji,jj) |
|---|
| 236 | zmod = rhoco * SQRT( zu_io * zu_io + zv_io * zv_io ) |
|---|
| 237 | ! ... ice stress over ocean with a ice-ocean rotation angle (at I-point) |
|---|
| 238 | ztio_u(ji,jj) = zmod * ( cangvg * zu_io - zsang * zv_io ) |
|---|
| 239 | ztio_v(ji,jj) = zmod * ( cangvg * zv_io + zsang * zu_io ) |
|---|
| 240 | ! |
|---|
| 241 | END DO |
|---|
| 242 | END DO |
|---|
| 243 | |
|---|
| 244 | DO jj = 2, jpjm1 |
|---|
| 245 | DO ji = 2, jpim1 |
|---|
| 246 | ! ... ice-cover wheighted ice-ocean stress at U and V-points (from I-point values) |
|---|
| 247 | zutau = 0.5 * ( ztio_u(ji+1,jj) + ztio_u(ji+1,jj+1) ) |
|---|
| 248 | zvtau = 0.5 * ( ztio_v(ji,jj+1) + ztio_v(ji+1,jj+1) ) |
|---|
| 249 | ! ... open-ocean (lead) fraction at U- & V-points (from T-point values) |
|---|
| 250 | zfrldu = 0.5 * ( frld (ji,jj) + frld (ji+1,jj ) ) |
|---|
| 251 | zfrldv = 0.5 * ( frld (ji,jj) + frld (ji ,jj+1) ) |
|---|
| 252 | ! update surface ocean stress |
|---|
| 253 | utau(ji,jj) = zfrldu * utau(ji,jj) + ( 1. - zfrldu ) * zutau |
|---|
| 254 | vtau(ji,jj) = zfrldv * vtau(ji,jj) + ( 1. - zfrldv ) * zvtau |
|---|
| 255 | ! |
|---|
| 256 | END DO |
|---|
| 257 | END DO |
|---|
| 258 | |
|---|
| 259 | ! boundary condition on the stress (utau,vtau) |
|---|
| 260 | CALL lbc_lnk( utau, 'U', -1. ) |
|---|
| 261 | CALL lbc_lnk( vtau, 'V', -1. ) |
|---|
| 262 | |
|---|
| 263 | ENDIF |
|---|
| 264 | |
|---|
| 265 | !-----------------------------------------------! |
|---|
| 266 | ! Storing the transmitted variables ! |
|---|
| 267 | !-----------------------------------------------! |
|---|
| 268 | |
|---|
| 269 | fr_i (:,:) = 1.0 - frld(:,:) ! sea-ice fraction |
|---|
| 270 | |
|---|
| 271 | IF ( lk_cpl ) THEN |
|---|
| 272 | ! Ice surface temperature |
|---|
| 273 | tn_ice(:,:) = sist(:,:) ! sea-ice surface temperature |
|---|
| 274 | ! Computation of snow/ice and ocean albedo |
|---|
| 275 | ! INTERFACE 3D versus 2D |
|---|
| 276 | zsist (:,:,1) = sist (:,:) |
|---|
| 277 | zhicif(:,:,1) = hicif(:,:) ; zhsnif(:,:,1) = hsnif(:,:) |
|---|
| 278 | CALL albedo_ice( zsist, zhicif, zhsnif, zalbp, zalb ) |
|---|
| 279 | alb_ice(:,:) = 0.5 * ( zalbp(:,:,1) + zalb (:,:,1) ) ! Ice albedo (mean clear and overcast skys) |
|---|
| 280 | ENDIF |
|---|
| 281 | |
|---|
| 282 | IF(ln_ctl) THEN |
|---|
| 283 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' lim_sbc: qsr : ', tab2d_2=qns , clinfo2=' qns : ') |
|---|
| 284 | CALL prt_ctl(tab2d_1=emp , clinfo1=' lim_sbc: emp : ', tab2d_2=emps , clinfo2=' emps : ') |
|---|
| 285 | CALL prt_ctl(tab2d_1=utau , clinfo1=' lim_sbc: utau : ', mask1=umask, & |
|---|
| 286 | & tab2d_2=vtau , clinfo2=' vtau : ' , mask2=vmask ) |
|---|
| 287 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' lim_sbc: fr_i : ', tab2d_2=tn_ice, clinfo2=' tn_ice : ') |
|---|
| 288 | ENDIF |
|---|
| 289 | |
|---|
| 290 | END SUBROUTINE lim_sbc_2 |
|---|
| 291 | |
|---|
| 292 | #else |
|---|
| 293 | !!---------------------------------------------------------------------- |
|---|
| 294 | !! Default option : Dummy module NO LIM 2.0 sea-ice model |
|---|
| 295 | !!---------------------------------------------------------------------- |
|---|
| 296 | CONTAINS |
|---|
| 297 | SUBROUTINE lim_sbc_2 ! Dummy routine |
|---|
| 298 | END SUBROUTINE lim_sbc_2 |
|---|
| 299 | #endif |
|---|
| 300 | |
|---|
| 301 | !!====================================================================== |
|---|
| 302 | END MODULE limsbc_2 |
|---|
