1 | MODULE limsbc_2 |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE limsbc_2 *** |
---|
4 | !! computation of the flux at the sea ice/ocean interface |
---|
5 | !!====================================================================== |
---|
6 | !! History : 00-01 (H. Goosse) Original code |
---|
7 | !! 02-07 (C. Ethe, G. Madec) re-writing F90 |
---|
8 | !! 06-07 (G. Madec) surface module |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | #if defined key_lim2 |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | !! 'key_lim2' LIM 2.0 sea-ice model |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | !! lim_sbc_2 : flux at the ice / ocean interface |
---|
16 | !!---------------------------------------------------------------------- |
---|
17 | USE par_oce ! ocean parameters |
---|
18 | USE dom_oce ! ocean domain |
---|
19 | USE sbc_ice ! surface boundary condition |
---|
20 | USE sbc_oce ! surface boundary condition |
---|
21 | USE phycst ! physical constants |
---|
22 | USE ice_2 ! LIM sea-ice variables |
---|
23 | |
---|
24 | USE lbclnk ! ocean lateral boundary condition |
---|
25 | USE in_out_manager ! I/O manager |
---|
26 | USE iom ! |
---|
27 | USE albedo ! albedo parameters |
---|
28 | USE prtctl ! Print control |
---|
29 | USE cpl_oasis3, ONLY : lk_cpl |
---|
30 | |
---|
31 | IMPLICIT NONE |
---|
32 | PRIVATE |
---|
33 | |
---|
34 | PUBLIC lim_sbc_2 ! called by sbc_ice_lim_2 |
---|
35 | |
---|
36 | REAL(wp) :: epsi16 = 1.e-16 ! constant values |
---|
37 | REAL(wp) :: rzero = 0.e0 |
---|
38 | REAL(wp) :: rone = 1.e0 |
---|
39 | REAL(wp), DIMENSION(jpi,jpj) :: soce_r |
---|
40 | REAL(wp), DIMENSION(jpi,jpj) :: sice_r |
---|
41 | |
---|
42 | !! * Substitutions |
---|
43 | # include "vectopt_loop_substitute.h90" |
---|
44 | !!---------------------------------------------------------------------- |
---|
45 | !! LIM 2.0, UCL-LOCEAN-IPSL (2006) |
---|
46 | !! $Id$ |
---|
47 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
---|
48 | !!---------------------------------------------------------------------- |
---|
49 | |
---|
50 | CONTAINS |
---|
51 | |
---|
52 | SUBROUTINE lim_sbc_2( kt ) |
---|
53 | !!------------------------------------------------------------------- |
---|
54 | !! *** ROUTINE lim_sbc_2 *** |
---|
55 | !! |
---|
56 | !! ** Purpose : Update surface ocean boundary condition over areas |
---|
57 | !! that are at least partially covered by sea-ice |
---|
58 | !! |
---|
59 | !! ** Action : - comput. of the momentum, heat and freshwater/salt |
---|
60 | !! fluxes at the ice-ocean interface. |
---|
61 | !! - Update |
---|
62 | !! |
---|
63 | !! ** Outputs : - qsr : sea heat flux: solar |
---|
64 | !! - qns : sea heat flux: non solar |
---|
65 | !! - emp : freshwater budget: volume flux |
---|
66 | !! - emps : freshwater budget: concentration/dillution |
---|
67 | !! - utau : sea surface i-stress (ocean referential) |
---|
68 | !! - vtau : sea surface j-stress (ocean referential) |
---|
69 | !! - fr_i : ice fraction |
---|
70 | !! - tn_ice : sea-ice surface temperature |
---|
71 | !! - alb_ice : sea-ice alberdo (lk_cpl=T) |
---|
72 | !! |
---|
73 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
---|
74 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
---|
75 | !!--------------------------------------------------------------------- |
---|
76 | INTEGER :: kt ! number of iteration |
---|
77 | !! |
---|
78 | INTEGER :: ji, jj ! dummy loop indices |
---|
79 | INTEGER :: ifvt, i1mfr, idfr ! some switches |
---|
80 | INTEGER :: iflt, ial, iadv, ifral, ifrdv |
---|
81 | INTEGER :: ii0, ii1, ij0, ij1 ! temporary integers |
---|
82 | REAL(wp) :: zqsr , zqns ! solar & non solar heat flux |
---|
83 | REAL(wp) :: zinda ! switch for testing the values of ice concentration |
---|
84 | REAL(wp) :: zfons ! salt exchanges at the ice/ocean interface |
---|
85 | REAL(wp) :: zemp ! freshwater exchanges at the ice/ocean interface |
---|
86 | REAL(wp) :: zfrldu, zfrldv ! lead fraction at U- & V-points |
---|
87 | REAL(wp) :: zutau , zvtau ! lead fraction at U- & V-points |
---|
88 | REAL(wp) :: zu_io , zv_io ! 2 components of the ice-ocean velocity |
---|
89 | ! interface 2D --> 3D |
---|
90 | REAL(wp), DIMENSION(jpi,jpj,1) :: zalb ! albedo of ice under overcast sky |
---|
91 | REAL(wp), DIMENSION(jpi,jpj,1) :: zalbp ! albedo of ice under clear sky |
---|
92 | REAL(wp) :: zsang, zmod, zfm |
---|
93 | REAL(wp), DIMENSION(jpi,jpj) :: ztio_u, ztio_v ! ocean stress below sea-ice |
---|
94 | REAL(wp), DIMENSION(jpi,jpj) :: zqnsoce ! save qns before its modification by ice model |
---|
95 | |
---|
96 | !!--------------------------------------------------------------------- |
---|
97 | |
---|
98 | IF( kt == nit000 ) THEN |
---|
99 | IF(lwp) WRITE(numout,*) |
---|
100 | IF(lwp) WRITE(numout,*) 'lim_sbc_2 : LIM 2.0 sea-ice - surface boundary condition' |
---|
101 | IF(lwp) WRITE(numout,*) '~~~~~~~~~ ' |
---|
102 | |
---|
103 | soce_r(:,:) = soce |
---|
104 | sice_r(:,:) = sice |
---|
105 | ! |
---|
106 | IF( cp_cfg == "orca" .AND. jp_cfg == 2 ) THEN |
---|
107 | ! ! ======================= |
---|
108 | ! ! ORCA_R2 configuration |
---|
109 | ! ! ======================= |
---|
110 | ii0 = 145 ; ii1 = 180 ! Baltic Sea |
---|
111 | ij0 = 113 ; ij1 = 130 ; soce_r(mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 4.e0 |
---|
112 | sice_r(mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 2.e0 |
---|
113 | ENDIF |
---|
114 | ! |
---|
115 | ENDIF |
---|
116 | |
---|
117 | !------------------------------------------! |
---|
118 | ! heat flux at the ocean surface ! |
---|
119 | !------------------------------------------! |
---|
120 | |
---|
121 | !!gm |
---|
122 | !!gm CAUTION |
---|
123 | !!gm re-verifies the non solar expression, especially over open ocen |
---|
124 | !!gm |
---|
125 | zqnsoce(:,:) = qns(:,:) |
---|
126 | DO jj = 1, jpj |
---|
127 | DO ji = 1, jpi |
---|
128 | zinda = 1.0 - MAX( rzero , SIGN( rone, - ( 1.0 - pfrld(ji,jj) ) ) ) |
---|
129 | ifvt = zinda * MAX( rzero , SIGN( rone, - phicif(ji,jj) ) ) |
---|
130 | i1mfr = 1.0 - MAX( rzero , SIGN( rone, - ( 1.0 - frld(ji,jj) ) ) ) |
---|
131 | idfr = 1.0 - MAX( rzero , SIGN( rone, frld(ji,jj) - pfrld(ji,jj) ) ) |
---|
132 | iflt = zinda * (1 - i1mfr) * (1 - ifvt ) |
---|
133 | ial = ifvt * i1mfr + ( 1 - ifvt ) * idfr |
---|
134 | iadv = ( 1 - i1mfr ) * zinda |
---|
135 | ifral = ( 1 - i1mfr * ( 1 - ial ) ) |
---|
136 | ifrdv = ( 1 - ifral * ( 1 - ial ) ) * iadv |
---|
137 | |
---|
138 | !!$ zinda = 1.0 - AINT( pfrld(ji,jj) ) ! = 0. if pure ocean else 1. (at previous time) |
---|
139 | !!$ |
---|
140 | !!$ i1mfr = 1.0 - AINT( frld(ji,jj) ) ! = 0. if pure ocean else 1. (at current time) |
---|
141 | !!$ |
---|
142 | !!$ IF( phicif(ji,jj) <= 0. ) THEN ; ifvt = zinda ! = 1. if (snow and no ice at previous time) else 0. ??? |
---|
143 | !!$ ELSE ; ifvt = 0. |
---|
144 | !!$ ENDIF |
---|
145 | !!$ |
---|
146 | !!$ IF( frld(ji,jj) >= pfrld(ji,jj) ) THEN ; idfr = 0. ! = 0. if lead fraction increases from previous to current |
---|
147 | !!$ ELSE ; idfr = 1. |
---|
148 | !!$ ENDIF |
---|
149 | !!$ |
---|
150 | !!$ iflt = zinda * (1 - i1mfr) * (1 - ifvt ) ! = 1. if ice (not only snow) at previous and pure ocean at current |
---|
151 | !!$ |
---|
152 | !!$ ial = ifvt * i1mfr + ( 1 - ifvt ) * idfr |
---|
153 | !!$! snow no ice ice ice or nothing lead fraction increases |
---|
154 | !!$! at previous now at previous |
---|
155 | !!$! -> ice aera increases ??? -> ice aera decreases ??? |
---|
156 | !!$ |
---|
157 | !!$ iadv = ( 1 - i1mfr ) * zinda |
---|
158 | !!$! pure ocean ice at |
---|
159 | !!$! at current previous |
---|
160 | !!$! -> = 1. if ice disapear between previous and current |
---|
161 | !!$ |
---|
162 | !!$ ifral = ( 1 - i1mfr * ( 1 - ial ) ) |
---|
163 | !!$! ice at ??? |
---|
164 | !!$! current |
---|
165 | !!$! -> ??? |
---|
166 | !!$ |
---|
167 | !!$ ifrdv = ( 1 - ifral * ( 1 - ial ) ) * iadv |
---|
168 | !!$! ice disapear |
---|
169 | !!$ |
---|
170 | !!$ |
---|
171 | |
---|
172 | ! computation the solar flux at ocean surface |
---|
173 | #if defined key_coupled |
---|
174 | zqsr = qsr_tot(ji,jj) + ( fstric(ji,jj) - qsr_ice(ji,jj,1) ) * ( 1.0 - pfrld(ji,jj) ) |
---|
175 | #else |
---|
176 | zqsr = pfrld(ji,jj) * qsr(ji,jj) + ( 1. - pfrld(ji,jj) ) * fstric(ji,jj) |
---|
177 | #endif |
---|
178 | ! computation the non solar heat flux at ocean surface |
---|
179 | zqns = - ( 1. - thcm(ji,jj) ) * zqsr & ! part of the solar energy used in leads |
---|
180 | & + iflt * ( fscmbq(ji,jj) + ffltbif(ji,jj) ) & |
---|
181 | & + ifral * ( ial * qcmif(ji,jj) + (1 - ial) * qldif(ji,jj) ) / rdt_ice & |
---|
182 | & + ifrdv * ( qfvbq(ji,jj) + qdtcn(ji,jj) ) / rdt_ice |
---|
183 | |
---|
184 | fsbbq(ji,jj) = ( 1.0 - ( ifvt + iflt ) ) * fscmbq(ji,jj) ! ??? |
---|
185 | |
---|
186 | qsr (ji,jj) = zqsr ! solar heat flux |
---|
187 | qns (ji,jj) = zqns - fdtcn(ji,jj) ! non solar heat flux |
---|
188 | END DO |
---|
189 | END DO |
---|
190 | |
---|
191 | CALL iom_put( 'qns_io_cea', qns(:,:) - zqnsoce(:,:) * pfrld(:,:) ) |
---|
192 | CALL iom_put( 'qsr_io_cea', fstric(:,:) * (1. - pfrld(:,:)) ) |
---|
193 | |
---|
194 | !------------------------------------------! |
---|
195 | ! mass flux at the ocean surface ! |
---|
196 | !------------------------------------------! |
---|
197 | |
---|
198 | !!gm |
---|
199 | !!gm CAUTION |
---|
200 | !!gm re-verifies the emp & emps expression, especially the absence of 1-frld on zfm |
---|
201 | !!gm |
---|
202 | DO jj = 1, jpj |
---|
203 | DO ji = 1, jpi |
---|
204 | |
---|
205 | #if defined key_coupled |
---|
206 | zemp = emp_tot(ji,jj) - emp_ice(ji,jj) * ( 1. - pfrld(ji,jj) ) & ! |
---|
207 | & + rdmsnif(ji,jj) / rdt_ice ! freshwaterflux due to snow melting |
---|
208 | #else |
---|
209 | !!$ ! computing freshwater exchanges at the ice/ocean interface |
---|
210 | !!$ zpme = - evap(ji,jj) * frld(ji,jj) & ! evaporation over oceanic fraction |
---|
211 | !!$ & + tprecip(ji,jj) & ! total precipitation |
---|
212 | !!$ & - sprecip(ji,jj) * ( 1. - pfrld(ji,jj) ) & ! remov. snow precip over ice |
---|
213 | !!$ & - rdmsnif(ji,jj) / rdt_ice ! freshwaterflux due to snow melting |
---|
214 | ! computing freshwater exchanges at the ice/ocean interface |
---|
215 | zemp = + emp(ji,jj) * frld(ji,jj) & ! e-p budget over open ocean fraction |
---|
216 | & - tprecip(ji,jj) * ( 1. - frld(ji,jj) ) & ! liquid precipitation reaches directly the ocean |
---|
217 | & + sprecip(ji,jj) * ( 1. - pfrld(ji,jj) ) & ! taking into account change in ice cover within the time step |
---|
218 | & + rdmsnif(ji,jj) / rdt_ice ! freshwaterflux due to snow melting |
---|
219 | ! ! ice-covered fraction: |
---|
220 | #endif |
---|
221 | |
---|
222 | ! computing salt exchanges at the ice/ocean interface |
---|
223 | zfons = ( soce_r(ji,jj) - sice_r(ji,jj) ) * ( rdmicif(ji,jj) / rdt_ice ) |
---|
224 | |
---|
225 | ! converting the salt flux from ice to a freshwater flux from ocean |
---|
226 | zfm = zfons / ( sss_m(ji,jj) + epsi16 ) |
---|
227 | |
---|
228 | emps(ji,jj) = zemp + zfm ! surface ocean concentration/dilution effect (use on SSS evolution) |
---|
229 | emp (ji,jj) = zemp ! surface ocean volume flux (use on sea-surface height evolution) |
---|
230 | |
---|
231 | END DO |
---|
232 | END DO |
---|
233 | |
---|
234 | !------------------------------------------! |
---|
235 | ! momentum flux at the ocean surface ! |
---|
236 | !------------------------------------------! |
---|
237 | |
---|
238 | IF ( ln_limdyn ) THEN ! Update the stress over ice-over area (only in ice-dynamic case) |
---|
239 | ! ! otherwise the atmosphere-ocean stress is used everywhere |
---|
240 | |
---|
241 | ! ... ice stress over ocean with a ice-ocean rotation angle (at I-point) |
---|
242 | !CDIR NOVERRCHK |
---|
243 | DO jj = 1, jpj |
---|
244 | !CDIR NOVERRCHK |
---|
245 | DO ji = 1, jpi |
---|
246 | ! ... change the cosinus angle sign in the south hemisphere |
---|
247 | zsang = SIGN(1.e0, gphif(ji,jj) ) * sangvg |
---|
248 | ! ... ice velocity relative to the ocean at I-point |
---|
249 | zu_io = u_ice(ji,jj) - u_oce(ji,jj) |
---|
250 | zv_io = v_ice(ji,jj) - v_oce(ji,jj) |
---|
251 | zmod = rhoco * SQRT( zu_io * zu_io + zv_io * zv_io ) |
---|
252 | ! ... ice stress over ocean with a ice-ocean rotation angle (at I-point) |
---|
253 | ztio_u(ji,jj) = zmod * ( cangvg * zu_io - zsang * zv_io ) |
---|
254 | ztio_v(ji,jj) = zmod * ( cangvg * zv_io + zsang * zu_io ) |
---|
255 | ! |
---|
256 | END DO |
---|
257 | END DO |
---|
258 | |
---|
259 | DO jj = 2, jpjm1 |
---|
260 | DO ji = 2, jpim1 |
---|
261 | ! ... ice-cover wheighted ice-ocean stress at U and V-points (from I-point values) |
---|
262 | zutau = 0.5 * ( ztio_u(ji+1,jj) + ztio_u(ji+1,jj+1) ) |
---|
263 | zvtau = 0.5 * ( ztio_v(ji,jj+1) + ztio_v(ji+1,jj+1) ) |
---|
264 | ! ... open-ocean (lead) fraction at U- & V-points (from T-point values) |
---|
265 | zfrldu = 0.5 * ( frld (ji,jj) + frld (ji+1,jj ) ) |
---|
266 | zfrldv = 0.5 * ( frld (ji,jj) + frld (ji ,jj+1) ) |
---|
267 | ! update surface ocean stress |
---|
268 | utau(ji,jj) = zfrldu * utau(ji,jj) + ( 1. - zfrldu ) * zutau |
---|
269 | vtau(ji,jj) = zfrldv * vtau(ji,jj) + ( 1. - zfrldv ) * zvtau |
---|
270 | ! |
---|
271 | END DO |
---|
272 | END DO |
---|
273 | |
---|
274 | ! boundary condition on the stress (utau,vtau) |
---|
275 | CALL lbc_lnk( utau, 'U', -1. ) |
---|
276 | CALL lbc_lnk( vtau, 'V', -1. ) |
---|
277 | |
---|
278 | ENDIF |
---|
279 | |
---|
280 | !-----------------------------------------------! |
---|
281 | ! Coupling variables ! |
---|
282 | !-----------------------------------------------! |
---|
283 | |
---|
284 | IF ( lk_cpl ) THEN |
---|
285 | ! Ice surface temperature |
---|
286 | tn_ice(:,:,1) = sist(:,:) ! sea-ice surface temperature |
---|
287 | ! Computation of snow/ice and ocean albedo |
---|
288 | CALL albedo_ice( tn_ice, reshape( hicif, (/jpi,jpj,1/) ), reshape( hsnif, (/jpi,jpj,1/) ), zalbp, zalb ) |
---|
289 | alb_ice(:,:,1) = 0.5 * ( zalbp(:,:,1) + zalb (:,:,1) ) ! Ice albedo (mean clear and overcast skys) |
---|
290 | CALL iom_put( "icealb_cea", alb_ice(:,:,1) * fr_i(:,:) ) ! ice albedo |
---|
291 | ENDIF |
---|
292 | |
---|
293 | IF(ln_ctl) THEN |
---|
294 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' lim_sbc: qsr : ', tab2d_2=qns , clinfo2=' qns : ') |
---|
295 | CALL prt_ctl(tab2d_1=emp , clinfo1=' lim_sbc: emp : ', tab2d_2=emps , clinfo2=' emps : ') |
---|
296 | CALL prt_ctl(tab2d_1=utau , clinfo1=' lim_sbc: utau : ', mask1=umask, & |
---|
297 | & tab2d_2=vtau , clinfo2=' vtau : ' , mask2=vmask ) |
---|
298 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' lim_sbc: fr_i : ', tab2d_2=tn_ice(:,:,1), clinfo2=' tn_ice : ') |
---|
299 | ENDIF |
---|
300 | |
---|
301 | END SUBROUTINE lim_sbc_2 |
---|
302 | |
---|
303 | #else |
---|
304 | !!---------------------------------------------------------------------- |
---|
305 | !! Default option : Dummy module NO LIM 2.0 sea-ice model |
---|
306 | !!---------------------------------------------------------------------- |
---|
307 | CONTAINS |
---|
308 | SUBROUTINE lim_sbc_2 ! Dummy routine |
---|
309 | END SUBROUTINE lim_sbc_2 |
---|
310 | #endif |
---|
311 | |
---|
312 | !!====================================================================== |
---|
313 | END MODULE limsbc_2 |
---|