New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limtrp_2.F90 in trunk/NEMO/LIM_SRC_2 – NEMO

source: trunk/NEMO/LIM_SRC_2/limtrp_2.F90 @ 1470

Last change on this file since 1470 was 1470, checked in by smasson, 15 years ago

[uv]i_ice and [uv]i_oce renamed [uv]_ice and [uv]_oce, see ticket:453
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 15.3 KB
Line 
1MODULE limtrp_2
2   !!======================================================================
3   !!                       ***  MODULE limtrp_2   ***
4   !! LIM 2.0 transport ice model : sea-ice advection/diffusion
5   !!======================================================================
6#if defined key_lim2
7   !!----------------------------------------------------------------------
8   !!   'key_lim2' :                                  LIM 2.0 sea-ice model
9   !!----------------------------------------------------------------------
10   !!   lim_trp_2      : advection/diffusion process of sea ice
11   !!   lim_trp_init_2 : initialization and namelist read
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE phycst
15   USE dom_oce
16   USE daymod
17   USE in_out_manager  ! I/O manager
18   USE dom_ice_2
19   USE ice_2
20   USE limistate_2
21   USE limadv_2
22   USE limhdf_2
23   USE lbclnk
24   USE lib_mpp
25
26   IMPLICIT NONE
27   PRIVATE
28
29   !! * Routine accessibility
30   PUBLIC lim_trp_2     ! called by sbc_ice_lim_2
31
32   !! * Shared module variables
33   REAL(wp), PUBLIC  ::   &  !:
34      bound  = 0.e0          !: boundary condit. (0.0 no-slip, 1.0 free-slip)
35
36   !! * Module variables
37   REAL(wp)  ::           &  ! constant values
38      epsi06 = 1.e-06  ,  &
39      epsi03 = 1.e-03  ,  &
40      epsi16 = 1.e-16  ,  &
41      rzero  = 0.e0    ,  &
42      rone   = 1.e0
43
44   !! * Substitution
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !!   LIM 2.0,  UCL-LOCEAN-IPSL (2005)
48   !! $Id$
49   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
50   !!----------------------------------------------------------------------
51
52CONTAINS
53
54   SUBROUTINE lim_trp_2( kt )
55      !!-------------------------------------------------------------------
56      !!                   ***  ROUTINE lim_trp_2 ***
57      !!                   
58      !! ** purpose : advection/diffusion process of sea ice
59      !!
60      !! ** method  : variables included in the process are scalar,   
61      !!     other values are considered as second order.
62      !!     For advection, a second order Prather scheme is used. 
63      !!
64      !! ** action :
65      !!
66      !! History :
67      !!   1.0  !  00-01 (LIM)  Original code
68      !!        !  01-05 (G. Madec, R. Hordoir) opa norm
69      !!   2.0  !  04-01 (G. Madec, C. Ethe)  F90, mpp
70      !!---------------------------------------------------------------------
71      INTEGER, INTENT(in) ::   kt     ! number of iteration
72
73      INTEGER  ::   ji, jj, jk,   &  ! dummy loop indices
74         &          initad           ! number of sub-timestep for the advection
75
76      REAL(wp) ::  &                             
77         zindb  ,  &
78         zacrith, &
79         zindsn , &
80         zindic , &
81         zusvosn, &
82         zusvoic, &
83         zignm  , &
84         zindhe , &
85         zvbord , &
86         zcfl   , &
87         zusnit , &
88         zrtt, ztsn, ztic1, ztic2
89
90      REAL(wp), DIMENSION(jpi,jpj)  ::   &  ! temporary workspace
91         zui_u , zvi_v , zsm   ,         &
92         zs0ice, zs0sn , zs0a  ,         &
93         zs0c0 , zs0c1 , zs0c2 ,         &
94         zs0st
95      !---------------------------------------------------------------------
96
97      IF( kt == nit000  )   CALL lim_trp_init_2      ! Initialization (first time-step only)
98
99      zsm(:,:) = area(:,:)
100     
101      IF( ln_limdyn ) THEN
102         !-------------------------------------!
103         !   Advection of sea ice properties   !
104         !-------------------------------------!
105
106         ! ice velocities at ocean U- and V-points (zui_u,zvi_v)
107         ! ---------------------------------------
108         ! zvbord factor between 1 and 2 to take into account slip or no-slip boundary conditions.       
109         zvbord = 1.0 + ( 1.0 - bound )
110         DO jj = 1, jpjm1
111            DO ji = 1, jpim1
112               zui_u(ji,jj) = ( u_ice(ji+1,jj  ) + u_ice(ji+1,jj+1) ) / ( MAX( tmu(ji+1,jj  ) + tmu(ji+1,jj+1), zvbord ) )
113               zvi_v(ji,jj) = ( v_ice(ji  ,jj+1) + v_ice(ji+1,jj+1) ) / ( MAX( tmu(ji  ,jj+1) + tmu(ji+1,jj+1), zvbord ) )
114            END DO
115         END DO
116         ! Lateral boundary conditions on zui_u, zvi_v
117         CALL lbc_lnk( zui_u, 'U', -1. )
118         CALL lbc_lnk( zvi_v, 'V', -1. )
119
120         ! CFL test for stability
121         ! ----------------------
122         zcfl  = 0.e0
123         zcfl  = MAX( zcfl, MAXVAL( ABS( zui_u(1:jpim1, :     ) ) * rdt_ice / e1u(1:jpim1, :     ) ) )
124         zcfl  = MAX( zcfl, MAXVAL( ABS( zvi_v( :     ,1:jpjm1) ) * rdt_ice / e2v( :     ,1:jpjm1) ) )
125
126         IF (lk_mpp ) CALL mpp_max(zcfl)
127
128         IF ( zcfl > 0.5 .AND. lwp )   WRITE(numout,*) 'lim_trp_2 : violation of cfl criterion the ',nday,'th day, cfl = ',zcfl
129
130         ! content of properties
131         ! ---------------------
132         zs0sn (:,:) =  hsnm(:,:) * area(:,:)                 ! Snow volume.
133         zs0ice(:,:) =  hicm (:,:) * area(:,:)                ! Ice volume.
134         zs0a  (:,:) =  ( 1.0 - frld(:,:) ) * area(:,:)       ! Surface covered by ice.
135         zs0c0 (:,:) =  tbif(:,:,1) / rt0_snow * zs0sn(:,:)   ! Heat content of the snow layer.
136         zs0c1 (:,:) =  tbif(:,:,2) / rt0_ice  * zs0ice(:,:)  ! Heat content of the first ice layer.
137         zs0c2 (:,:) =  tbif(:,:,3) / rt0_ice  * zs0ice(:,:)  ! Heat content of the second ice layer.
138         zs0st (:,:) =  qstoif(:,:) / xlic     * zs0a(:,:)    ! Heat reservoir for brine pockets.
139         
140 
141         ! Advection
142         ! ---------
143         ! If ice drift field is too fast, use an appropriate time step for advection.         
144         initad = 1 + INT( MAX( rzero, SIGN( rone, zcfl-0.5 ) ) )
145         zusnit = 1.0 / REAL( initad ) 
146         
147         IF ( MOD( nday , 2 ) == 0) THEN
148            DO jk = 1,initad
149               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
150               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
151               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
152               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
153               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
154               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
155               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
156               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
157               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
158               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
159               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
160               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
161               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
162               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
163            END DO
164         ELSE
165            DO jk = 1, initad
166               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
167               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
168               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
169               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
170               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
171               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
172               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
173               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
174               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
175               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
176               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
177               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
178               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
179               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
180            END DO
181         ENDIF
182                       
183         ! recover the properties from their contents
184         ! ------------------------------------------
185         zs0ice(:,:) = zs0ice(:,:) / area(:,:)
186         zs0sn (:,:) = zs0sn (:,:) / area(:,:)
187         zs0a  (:,:) = zs0a  (:,:) / area(:,:)
188         zs0c0 (:,:) = zs0c0 (:,:) / area(:,:)
189         zs0c1 (:,:) = zs0c1 (:,:) / area(:,:)
190         zs0c2 (:,:) = zs0c2 (:,:) / area(:,:)
191         zs0st (:,:) = zs0st (:,:) / area(:,:)
192
193
194         !-------------------------------------!
195         !   Diffusion of sea ice properties   !
196         !-------------------------------------!
197
198         ! Masked eddy diffusivity coefficient at ocean U- and V-points
199         ! ------------------------------------------------------------
200         DO jj = 1, jpjm1          ! NB: has not to be defined on jpj line and jpi row
201            DO ji = 1 , fs_jpim1   ! vector opt.
202               pahu(ji,jj) = ( 1.0 - MAX( rzero, SIGN( rone, -zs0a(ji  ,jj) ) ) )   &
203                  &        * ( 1.0 - MAX( rzero, SIGN( rone, -zs0a(ji+1,jj) ) ) ) * ahiu(ji,jj)
204               pahv(ji,jj) = ( 1.0 - MAX( rzero, SIGN( rone, -zs0a(ji,jj  ) ) ) )   &
205                  &        * ( 1.0 - MAX( rzero, SIGN( rone,- zs0a(ji,jj+1) ) ) ) * ahiv(ji,jj)
206            END DO
207         END DO
208
209         ! diffusion
210         ! ---------
211         CALL lim_hdf_2( zs0ice )
212         CALL lim_hdf_2( zs0sn  )
213         CALL lim_hdf_2( zs0a   )
214         CALL lim_hdf_2( zs0c0  )
215         CALL lim_hdf_2( zs0c1  )
216         CALL lim_hdf_2( zs0c2  )
217         CALL lim_hdf_2( zs0st  )
218
219         zs0ice(:,:) = MAX( rzero, zs0ice(:,:) * area(:,:) )    !!bug:  est-ce utile
220         zs0sn (:,:) = MAX( rzero, zs0sn (:,:) * area(:,:) )    !!bug:  cf /area  juste apres
221         zs0a  (:,:) = MAX( rzero, zs0a  (:,:) * area(:,:) )    !! suppression des 2 change le resultat...
222         zs0c0 (:,:) = MAX( rzero, zs0c0 (:,:) * area(:,:) )
223         zs0c1 (:,:) = MAX( rzero, zs0c1 (:,:) * area(:,:) )
224         zs0c2 (:,:) = MAX( rzero, zs0c2 (:,:) * area(:,:) )
225         zs0st (:,:) = MAX( rzero, zs0st (:,:) * area(:,:) )
226
227
228         ! -------------------------------------------------------------------!
229         !   Up-dating and limitation of sea ice properties after transport   !
230         ! -------------------------------------------------------------------!
231
232         ! Up-dating and limitation of sea ice properties after transport.
233         DO jj = 1, jpj
234!!!iii      zindhe = REAL( MAX( 0, isign(1, jj - njeq ) ) )              !ibug mpp  !!bugmpp  njeq!
235            zindhe = MAX( 0.e0, SIGN( 1.e0, fcor(1,jj) ) )              ! = 0 for SH, =1 for NH
236            DO ji = 1, jpi
237
238               ! Recover mean values over the grid squares.
239               zs0sn (ji,jj) = MAX( rzero, zs0sn (ji,jj)/area(ji,jj) )
240               zs0ice(ji,jj) = MAX( rzero, zs0ice(ji,jj)/area(ji,jj) )
241               zs0a  (ji,jj) = MAX( rzero, zs0a  (ji,jj)/area(ji,jj) )
242               zs0c0 (ji,jj) = MAX( rzero, zs0c0 (ji,jj)/area(ji,jj) )
243               zs0c1 (ji,jj) = MAX( rzero, zs0c1 (ji,jj)/area(ji,jj) )
244               zs0c2 (ji,jj) = MAX( rzero, zs0c2 (ji,jj)/area(ji,jj) )
245               zs0st (ji,jj) = MAX( rzero, zs0st (ji,jj)/area(ji,jj) )
246
247               ! Recover in situ values.
248               zindb         = MAX( rzero, SIGN( rone, zs0a(ji,jj) - epsi06 ) )
249               zacrith       = 1.0 - ( zindhe * acrit(1) + ( 1.0 - zindhe ) * acrit(2) )
250               zs0a (ji,jj)  = zindb * MIN( zs0a(ji,jj), zacrith )
251               hsnif(ji,jj)  = zindb * ( zs0sn(ji,jj) /MAX( zs0a(ji,jj), epsi16 ) )
252               hicif(ji,jj)  = zindb * ( zs0ice(ji,jj)/MAX( zs0a(ji,jj), epsi16 ) )
253               zindsn        = MAX( rzero, SIGN( rone, hsnif(ji,jj) - epsi06 ) )
254               zindic        = MAX( rzero, SIGN( rone, hicif(ji,jj) - epsi03 ) )
255               zindb         = MAX( zindsn, zindic )
256               zs0a (ji,jj)  = zindb * zs0a(ji,jj)
257               frld (ji,jj)  = 1.0 - zs0a(ji,jj)
258               hsnif(ji,jj)  = zindsn * hsnif(ji,jj)
259               hicif(ji,jj)  = zindic * hicif(ji,jj)
260               zusvosn       = 1.0/MAX( hsnif(ji,jj) * zs0a(ji,jj), epsi16 )
261               zusvoic       = 1.0/MAX( hicif(ji,jj) * zs0a(ji,jj), epsi16 )
262               zignm         = MAX( rzero,  SIGN( rone, hsndif - hsnif(ji,jj) ) )
263               zrtt          = 173.15 * rone 
264               ztsn          =          zignm   * tbif(ji,jj,1)  &
265                              + ( 1.0 - zignm ) * MIN( MAX( zrtt, rt0_snow * zusvosn * zs0c0(ji,jj)) , tfu(ji,jj) ) 
266               ztic1          = MIN( MAX( zrtt, rt0_ice * zusvoic * zs0c1(ji,jj) ) , tfu(ji,jj) )
267               ztic2          = MIN( MAX( zrtt, rt0_ice * zusvoic * zs0c2(ji,jj) ) , tfu(ji,jj) )
268 
269               tbif(ji,jj,1) = zindsn * ztsn  + ( 1.0 - zindsn ) * tfu(ji,jj)               
270               tbif(ji,jj,2) = zindic * ztic1 + ( 1.0 - zindic ) * tfu(ji,jj)
271               tbif(ji,jj,3) = zindic * ztic2 + ( 1.0 - zindic ) * tfu(ji,jj)
272               qstoif(ji,jj) = zindb  * xlic * zs0st(ji,jj) /  MAX( zs0a(ji,jj), epsi16 )
273            END DO
274         END DO
275         
276      ENDIF
277     
278   END SUBROUTINE lim_trp_2
279
280
281   SUBROUTINE lim_trp_init_2
282      !!-------------------------------------------------------------------
283      !!                  ***  ROUTINE lim_trp_init_2  ***
284      !!
285      !! ** Purpose :   initialization of ice advection parameters
286      !!
287      !! ** Method  : Read the namicetrp namelist and check the parameter
288      !!       values called at the first timestep (nit000)
289      !!
290      !! ** input   :   Namelist namicetrp
291      !!
292      !! history :
293      !!   2.0  !  03-08 (C. Ethe)  Original code
294      !!-------------------------------------------------------------------
295      NAMELIST/namicetrp/ bound
296      !!-------------------------------------------------------------------
297
298      ! Read Namelist namicetrp
299      REWIND ( numnam_ice )
300      READ   ( numnam_ice  , namicetrp )
301      IF(lwp) THEN
302         WRITE(numout,*)
303         WRITE(numout,*) 'lim_trp_init_2 : Ice parameters for advection '
304         WRITE(numout,*) '~~~~~~~~~~~~~~'
305         WRITE(numout,*) '   boundary conditions (0. no-slip, 1. free-slip) bound  = ', bound
306      ENDIF
307           
308   END SUBROUTINE lim_trp_init_2
309
310#else
311   !!----------------------------------------------------------------------
312   !!   Default option         Empty Module                No sea-ice model
313   !!----------------------------------------------------------------------
314CONTAINS
315   SUBROUTINE lim_trp_2        ! Empty routine
316   END SUBROUTINE lim_trp_2
317#endif
318
319   !!======================================================================
320END MODULE limtrp_2
Note: See TracBrowser for help on using the repository browser.