1 | MODULE flxrnf |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE flxrnf *** |
---|
4 | !! Ocean forcing: runoff |
---|
5 | !!===================================================================== |
---|
6 | #if defined key_orca_r05 |
---|
7 | !!---------------------------------------------------------------------- |
---|
8 | !! 'key_orca_r05' ORCA R05 configuration |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | # include "flxrnf_ORCA_R05.h90" |
---|
11 | #else |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! Default option Standard runoffs |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | |
---|
16 | !!---------------------------------------------------------------------- |
---|
17 | !! flx_rnf : monthly runoff read in a NetCDF file |
---|
18 | !!---------------------------------------------------------------------- |
---|
19 | !! * Modules used |
---|
20 | USE dom_oce ! ocean space and time domain |
---|
21 | USE phycst ! physical constants |
---|
22 | USE in_out_manager ! I/O manager |
---|
23 | USE daymod ! calendar |
---|
24 | USE ioipsl ! NetCDF IPSL library |
---|
25 | |
---|
26 | IMPLICIT NONE |
---|
27 | PRIVATE |
---|
28 | |
---|
29 | !! * Routine accessibility |
---|
30 | PUBLIC flx_rnf ! routine call in step module |
---|
31 | |
---|
32 | !! * Shared module variables |
---|
33 | REAL(wp), PUBLIC, DIMENSION(jpi,jpj) :: & !: |
---|
34 | runoff, & !: monthly runoff (kg/m2/s) |
---|
35 | upsadv, & !: mixed adv scheme in straits vicinity (hori.) |
---|
36 | upsrnfh !: mixed adv scheme in runoffs vicinity (hori.) |
---|
37 | REAL(wp), PUBLIC, DIMENSION(jpk) :: & !: |
---|
38 | upsrnfz !: mixed adv scheme in runoffs vicinity (vert.) |
---|
39 | INTEGER, PUBLIC :: & !: |
---|
40 | nrunoff = 0 , & !: runoff option (namelist) |
---|
41 | nrnf1, nrnf2 !: first and second record used |
---|
42 | |
---|
43 | !! * Module variable |
---|
44 | REAL(wp), DIMENSION(jpi,jpj,2) :: & !: |
---|
45 | rnfdta !: monthly runoff data array (kg/m2/s) |
---|
46 | |
---|
47 | !!---------------------------------------------------------------------- |
---|
48 | !! OPA 9.0 , LOCEAN-IPSL (2005) |
---|
49 | !! $Header$ |
---|
50 | !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt |
---|
51 | !!---------------------------------------------------------------------- |
---|
52 | |
---|
53 | CONTAINS |
---|
54 | |
---|
55 | SUBROUTINE flx_rnf( kt ) |
---|
56 | !!---------------------------------------------------------------------- |
---|
57 | !! *** ROUTINE flx_rnf *** |
---|
58 | !! |
---|
59 | !! ** Purpose : Introduce a climatological run off forcing |
---|
60 | !! |
---|
61 | !! ** Method : |
---|
62 | !! Initialze each mouth of river with a monthly climatology |
---|
63 | !! provided from different data. |
---|
64 | !! C a u t i o n : upward water flux, runoff is negative |
---|
65 | !! set at the last loop of the routine |
---|
66 | !! |
---|
67 | !! ** Action : |
---|
68 | !! |
---|
69 | !! References : |
---|
70 | !! J. D. Milliman and R. H. Meade, 1983 : world-wide delivery |
---|
71 | !! of river sediment to the oceans, journal of geology vol 91 |
---|
72 | !! pp 1-21. |
---|
73 | !! G. L. Russell and J. R. Miller, 1990 : global river runoff |
---|
74 | !! calculated from a global atmospheric general circulation |
---|
75 | !! model, journal of hydrology, 117(1990), pp 241-254. |
---|
76 | !! F. Van Der Leeden, Troise F. L., Todd D. K. : the water |
---|
77 | !! encyclopedia, second edition, lewis publishers. |
---|
78 | !! J. W. Weatherly, J. E. Walsh : The effects of precipitation |
---|
79 | !! and river runoff in a coupled ice-ocean model of Arctic |
---|
80 | !! Climate dynamics 1996 12:785,798 |
---|
81 | !! Jacobs et al. 1992. J. Glaciol. 38 (130) 375-387. |
---|
82 | !! |
---|
83 | !! History : |
---|
84 | !! ! 94-10 (G.Madec, M. Pontaud, M. Imbard) Original code |
---|
85 | !! ! 97-03 (G.Madec) time dependent version |
---|
86 | !! ! 98-06 (J.M. Molines) exact computation of zxy |
---|
87 | !! for months that are not 30 days |
---|
88 | !! ! 98-07 (M. Imbard) ORCA and mpp option |
---|
89 | !! ! 99-08 (J.P. Boulanger H.L.Ayina) New rivers and |
---|
90 | !! values given in m3/s |
---|
91 | !! ! 00-04 (G. Madec, K. Roberts) add antarctica ice discharge. |
---|
92 | !! ! 00-11 (R. Hordoir, E. Durand) NetCDF FORMAT |
---|
93 | !! 8.5 ! 02-09 (G. Madec) F90: Free form and module |
---|
94 | !!---------------------------------------------------------------------- |
---|
95 | !! * arguments |
---|
96 | INTEGER, INTENT( in ) :: kt ! ocean time step |
---|
97 | |
---|
98 | !! * Local declarations |
---|
99 | # if ! defined key_coupled |
---|
100 | INTEGER :: ji, jj ! dummy loop indices |
---|
101 | INTEGER :: & |
---|
102 | i15 , imois , iman, & ! temporary integers |
---|
103 | idbd, idmeom ! " " |
---|
104 | REAL(wp) :: zxy |
---|
105 | # endif |
---|
106 | CHARACTER (len=32) :: & |
---|
107 | clname = 'runoff_1m_nomask' ! monthly runoff filename |
---|
108 | INTEGER, PARAMETER :: jpmois = 12 |
---|
109 | INTEGER :: ipi, ipj, ipk ! temporary integers |
---|
110 | INTEGER :: ii0, ii1, ij0, ij1 ! " " |
---|
111 | INTEGER, DIMENSION(jpmois) :: & |
---|
112 | istep ! temporary workspace |
---|
113 | REAL(wp) :: zdate0, zdt ! temporary scalars |
---|
114 | REAL(wp), DIMENSION(jpk) :: & |
---|
115 | zlev ! temporary workspace |
---|
116 | REAL(wp), DIMENSION(jpi,jpj) :: & |
---|
117 | zlon, zlat, & ! temporary workspace |
---|
118 | zcoefr ! coeff of advection link to runoff |
---|
119 | !!---------------------------------------------------------------------- |
---|
120 | |
---|
121 | IF( kt == nit000 ) THEN |
---|
122 | |
---|
123 | SELECT CASE ( nrunoff ) |
---|
124 | |
---|
125 | CASE ( 0 ) |
---|
126 | IF(lwp) WRITE(numout,*) |
---|
127 | IF(lwp) WRITE(numout,*) 'flx_rnf : No runoff in this simulation (nrunoff=0)' |
---|
128 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
---|
129 | |
---|
130 | CASE ( 1 ) |
---|
131 | IF(lwp) WRITE(numout,*) |
---|
132 | IF(lwp) WRITE(numout,*) 'flx_rnf : monthly runoff (nrunoff=1)' |
---|
133 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
---|
134 | |
---|
135 | CASE ( 2 ) |
---|
136 | IF(lwp) WRITE(numout,*) |
---|
137 | IF(lwp) WRITE(numout,*) 'flx_rnf : monthly runoff with upsteam advection' |
---|
138 | IF(lwp) WRITE(numout,*) '~~~~~~~ in the vicinity of river mouths (nrunoff=2)' |
---|
139 | |
---|
140 | CASE DEFAULT |
---|
141 | IF(lwp) WRITE(numout,cform_err) |
---|
142 | IF(lwp) WRITE(numout,*) ' Error nrunoff = ', nrunoff, ' /= 0, 1 or 2' |
---|
143 | nstop = nstop + 1 |
---|
144 | |
---|
145 | END SELECT |
---|
146 | |
---|
147 | ! Set runoffs and upstream coeff to zero |
---|
148 | runoff (:,:) = 0.e0 |
---|
149 | upsrnfh(:,:) = 0.e0 |
---|
150 | upsrnfz(:) = 0.e0 |
---|
151 | upsadv (:,:) = 0.e0 |
---|
152 | |
---|
153 | ENDIF |
---|
154 | |
---|
155 | |
---|
156 | ! 1. Initialization |
---|
157 | ! ----------------- |
---|
158 | |
---|
159 | IF( nrunoff == 1 .OR. nrunoff == 2 ) THEN |
---|
160 | # if ! defined key_coupled |
---|
161 | |
---|
162 | ! year, month, day |
---|
163 | |
---|
164 | iman = jpmois |
---|
165 | i15 = nday / 16 |
---|
166 | imois = nmonth + i15 - 1 |
---|
167 | IF( imois == 0 ) imois = iman |
---|
168 | ! Number of days in the month |
---|
169 | IF( nleapy == 1 .AND. MOD( nyear, 4 ) == 0 ) THEN |
---|
170 | idbd = nbiss(imois) |
---|
171 | ELSEIF( nleapy > 1 ) THEN |
---|
172 | idbd = nleapy |
---|
173 | ELSE |
---|
174 | idbd = nobis(imois) |
---|
175 | ENDIF |
---|
176 | ! Number of days between imois, 15 and the end of month |
---|
177 | idmeom = idbd - 15 |
---|
178 | # endif |
---|
179 | ipi = jpiglo |
---|
180 | ipj = jpjglo |
---|
181 | ipk = jpk |
---|
182 | zdt = rdt |
---|
183 | |
---|
184 | ! Open file |
---|
185 | |
---|
186 | IF( kt == nit000 ) THEN |
---|
187 | CALL flinopen( clname, mig(1), nlci, mjg(1), nlcj, & |
---|
188 | & .false., ipi, ipj, ipk, zlon, & |
---|
189 | & zlat, zlev, jpmois, istep, zdate0, & |
---|
190 | & zdt, numrnf ) |
---|
191 | ! Title, dimensions and tests |
---|
192 | # if ! defined key_coupled |
---|
193 | IF( iman /= jpmois ) THEN |
---|
194 | IF(lwp) WRITE(numout,*) |
---|
195 | IF(lwp) WRITE(numout,*) 'problem with time coordinates' |
---|
196 | IF(lwp) WRITE(numout,*) ' iman ', iman, ' jpmois ', jpmois |
---|
197 | nstop = nstop + 1 |
---|
198 | ENDIF |
---|
199 | IF(lwp) WRITE(numout,*) iman, istep, zdate0, rdt, numrnf |
---|
200 | IF(lwp) WRITE(numout,*) 'numrnf=', numrnf |
---|
201 | IF(lwp) WRITE(numout,*) 'jpmois=', jpmois |
---|
202 | IF(lwp) WRITE(numout,*) 'zdt=', zdt |
---|
203 | # endif |
---|
204 | IF(ipi /= jpidta .AND. ipj /= jpjdta .AND. ipk /= 1) THEN |
---|
205 | IF(lwp)WRITE(numout,*) ' ' |
---|
206 | IF(lwp)WRITE(numout,*) 'problem with dimensions' |
---|
207 | IF(lwp)WRITE(numout,*) ' ipi ', ipi, ' jpidta ', jpidta |
---|
208 | IF(lwp)WRITE(numout,*) ' ipj ', ipj, ' jpjdta ', jpjdta |
---|
209 | IF(lwp)WRITE(numout,*) ' ipk ', ipk, ' =? 1' |
---|
210 | nstop = nstop + 1 |
---|
211 | ENDIF |
---|
212 | IF(lwp)WRITE(numout,*) 'ipi=', ipi, ' ipj=', ipj, ' ipk=', ipk |
---|
213 | ENDIF |
---|
214 | |
---|
215 | # if ! defined key_coupled |
---|
216 | |
---|
217 | ! 2. Read monthly file of runoff |
---|
218 | ! ------------------------------ |
---|
219 | |
---|
220 | IF( kt == nit000 .OR. imois /= nrnf1 ) THEN |
---|
221 | |
---|
222 | ! Calendar computation for interpolation |
---|
223 | ! nrnf1 number of the first array record used in the simulation |
---|
224 | ! nrnf2 number of the last array record |
---|
225 | |
---|
226 | nrnf1 = imois |
---|
227 | nrnf2 = nrnf1 + 1 |
---|
228 | nrnf1 = MOD( nrnf1, iman ) |
---|
229 | IF( nrnf1 == 0 ) nrnf1 = iman |
---|
230 | nrnf2 = MOD( nrnf2, iman ) |
---|
231 | IF( nrnf2 == 0 ) nrnf2 = iman |
---|
232 | |
---|
233 | IF(lwp) THEN |
---|
234 | WRITE(numout,*) |
---|
235 | WRITE(numout,*) ' runoff monthly field' |
---|
236 | WRITE(numout,*) ' --------------------' |
---|
237 | WRITE(numout,*) ' NetCDF format' |
---|
238 | WRITE(numout,*) |
---|
239 | WRITE(numout,*) 'first array record used nrnf1 ',nrnf1 |
---|
240 | WRITE(numout,*) 'last array record used nrnf2 ',nrnf2 |
---|
241 | WRITE(numout,*) |
---|
242 | ENDIF |
---|
243 | |
---|
244 | ! Read monthly runoff data in kg/m2/s |
---|
245 | !ibug |
---|
246 | IF( kt == nit000 ) rnfdta(:,:,:) = 0.e0 |
---|
247 | !ibug |
---|
248 | CALL flinget( numrnf, 'sorunoff', jpidta, jpjdta, 1, jpmois & |
---|
249 | & , nrnf1, nrnf1, mig(1), nlci, mjg(1), nlcj, rnfdta(1:nlci,1:nlcj,1) ) |
---|
250 | CALL flinget( numrnf, 'sorunoff', jpidta, jpjdta, 1, jpmois & |
---|
251 | & , nrnf2, nrnf2, mig(1), nlci, mjg(1), nlcj, rnfdta(1:nlci,1:nlcj,2) ) |
---|
252 | |
---|
253 | IF(lwp) WRITE(numout,*) |
---|
254 | IF(lwp) WRITE(numout,*) ' read runoff field ok' |
---|
255 | IF(lwp) WRITE(numout,*) |
---|
256 | |
---|
257 | ENDIF |
---|
258 | |
---|
259 | ! Linear interpolation and conversion in upward water flux |
---|
260 | ! C a u t i o n : runoff is negative and in kg/m2/s |
---|
261 | |
---|
262 | zxy = FLOAT( nday + idmeom - idbd * i15 ) / idbd |
---|
263 | |
---|
264 | runoff(:,:) = -( ( 1.e0 - zxy ) * rnfdta(:,:,1) + zxy * rnfdta(:,:,2) ) |
---|
265 | |
---|
266 | ! Runoff reduction |
---|
267 | DO jj = 1, jpj |
---|
268 | DO ji = 1, jpi |
---|
269 | IF( gphit(ji,jj) > 40 .AND. gphit(ji,jj) < 65 ) runoff(ji,jj) = 0.85 * runoff(ji,jj) |
---|
270 | END DO |
---|
271 | END DO |
---|
272 | |
---|
273 | # endif |
---|
274 | |
---|
275 | ENDIF |
---|
276 | |
---|
277 | |
---|
278 | ! 3. Mixed advection scheme |
---|
279 | ! ------------------------- |
---|
280 | |
---|
281 | IF( nrunoff == 2 .AND. kt == nit000 ) THEN |
---|
282 | |
---|
283 | ! Upstream and centered scheme in the vicinity of river mouths |
---|
284 | |
---|
285 | ! Creates the array coef that contains the coefficient to affect to |
---|
286 | ! the upstream scheme. advection scheme will be: |
---|
287 | ! coefr * upstream + (1- coefr) centered |
---|
288 | ! coefr must be between 0 and 1. |
---|
289 | !ibug |
---|
290 | zcoefr(:,:) = 0.e0 |
---|
291 | !ibug |
---|
292 | |
---|
293 | CALL flinget( numrnf, 'socoefr', jpidta, jpjdta, 1, jpmois, nrnf1, & |
---|
294 | & nrnf1, mig(1), nlci, mjg(1), nlcj, zcoefr(1:nlci,1:nlcj) ) |
---|
295 | |
---|
296 | IF(lwp) WRITE(numout,*) |
---|
297 | IF(lwp) WRITE(numout,*) ' read coefr for advection ok' |
---|
298 | IF(lwp) WRITE(numout,*) |
---|
299 | |
---|
300 | upsrnfh(:,:) = zcoefr(:,:) |
---|
301 | upsrnfz(:) = 0.e0 |
---|
302 | upsrnfz(1) = 1.0 |
---|
303 | upsrnfz(2) = 1.0 |
---|
304 | upsrnfz(3) = 0.5 |
---|
305 | upsrnfz(4) = 0.25 |
---|
306 | upsrnfz(5) = 0.125 |
---|
307 | |
---|
308 | IF( cp_cfg == "orca" .AND. jp_cfg == 2 ) THEN |
---|
309 | ! ORCA_R2 configuration : upstream scheme in the Sound Strait |
---|
310 | ij0 = 116 ; ij1 = 116 |
---|
311 | ii0 = 144 ; ii1 = 144 ; upsrnfh( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.25 |
---|
312 | ii0 = 145 ; ii1 = 147 ; upsrnfh( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.50 |
---|
313 | ii0 = 148 ; ii1 = 148 ; upsrnfh( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.25 |
---|
314 | ENDIF |
---|
315 | |
---|
316 | ENDIF |
---|
317 | |
---|
318 | ! Upstream and centered scheme in the vicinity of some straits |
---|
319 | |
---|
320 | IF( kt == nit000 ) THEN |
---|
321 | |
---|
322 | IF( cp_cfg == "orca" ) THEN |
---|
323 | |
---|
324 | SELECT CASE ( jp_cfg ) |
---|
325 | ! ! ======================= |
---|
326 | CASE ( 4 ) ! ORCA_R4 configuration |
---|
327 | ! ! ======================= |
---|
328 | |
---|
329 | ! ! Gibraltar Strait |
---|
330 | ii0 = 70 ; ii1 = 71 |
---|
331 | ij0 = 52 ; ij1 = 53 ; upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.50 |
---|
332 | |
---|
333 | ! ! ======================= |
---|
334 | CASE ( 2 ) ! ORCA_R2 configuration |
---|
335 | ! ! ======================= |
---|
336 | |
---|
337 | ! ! Gibraltar Strait |
---|
338 | ij0 = 102 ; ij1 = 102 |
---|
339 | ii0 = 138 ; ii1 = 138 ; upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.20 |
---|
340 | ii0 = 139 ; ii1 = 139 ; upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.40 |
---|
341 | ii0 = 140 ; ii1 = 140 ; upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.50 |
---|
342 | ij0 = 101 ; ij1 = 102 |
---|
343 | ii0 = 141 ; ii1 = 141 ; upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.50 |
---|
344 | |
---|
345 | ! ! Bab el Mandeb Strait |
---|
346 | ij0 = 87 ; ij1 = 88 |
---|
347 | ii0 = 164 ; ii1 = 164 ; upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.10 |
---|
348 | ij0 = 88 ; ij1 = 88 |
---|
349 | ii0 = 163 ; ii1 = 163 ; upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.25 |
---|
350 | ii0 = 162 ; ii1 = 162 ; upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.40 |
---|
351 | ii0 = 160 ; ii1 = 161 ; upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.50 |
---|
352 | ij0 = 89 ; ij1 = 89 |
---|
353 | ii0 = 158 ; ii1 = 160 ; upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.25 |
---|
354 | ij0 = 90 ; ij1 = 90 |
---|
355 | ii0 = 160 ; ii1 = 160 ; upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.25 |
---|
356 | |
---|
357 | ! ! Sound Strait |
---|
358 | ij0 = 116 ; ij1 = 116 |
---|
359 | ii0 = 145 ; ii1 = 147 ; upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.50 |
---|
360 | |
---|
361 | END SELECT |
---|
362 | |
---|
363 | ENDIF |
---|
364 | |
---|
365 | ENDIF |
---|
366 | |
---|
367 | ! 4. Closing all files |
---|
368 | ! -------------------- |
---|
369 | |
---|
370 | IF( kt == nitend .AND. nrunoff >= 1 ) CALL flinclo( numrnf ) |
---|
371 | |
---|
372 | END SUBROUTINE flx_rnf |
---|
373 | |
---|
374 | #endif |
---|
375 | !!====================================================================== |
---|
376 | END MODULE flxrnf |
---|