New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diagap.F90 in trunk/NEMO/OPA_SRC/DIA – NEMO

source: trunk/NEMO/OPA_SRC/DIA/diagap.F90 @ 239

Last change on this file since 239 was 239, checked in by opalod, 19 years ago

CT : UPDATE172 : remove all direct acces modules and the related cpp key key_fdir
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 10.4 KB
Line 
1MODULE diagap
2   !!======================================================================
3   !!                       ***  MODULE  diagap  ***
4   !! Ocean diagnostics : computation of model-data tracer gap
5   !!======================================================================
6#if defined key_diagap
7   !!----------------------------------------------------------------------
8   !!   'key_diagap' :                           model-data gap diagnostics
9   !!----------------------------------------------------------------------
10   !!   dia_gap      : model and data level mean temperature and salinity
11   !!----------------------------------------------------------------------
12   !! * Modules used
13   USE oce             ! ocean dynamics and tracers
14   USE dom_oce         ! ocean space and time domain
15   USE in_out_manager  ! I/O manager
16   USE dtatem          ! ???
17   USE dtasal          ! ???
18   USE daymod          ! calendar
19   USE dianam          ! build name of file (routine)
20   USE lib_mpp         ! distributed memory computing library
21
22   IMPLICIT NONE
23   PRIVATE
24
25   !! * Routine accessibility
26   PUBLIC dia_gap     ! called in step.F90 module
27
28   !! * Shared module variables
29   LOGICAL, PUBLIC, PARAMETER ::   lk_diagap = .TRUE.   !: model-data diagnostics flag
30
31   !! * Module variables
32   INTEGER ::                 &
33!???  numgap,                 &  ! logical unit for differences diagnostic
34      ngap  ,                 &  ! time step frequency
35      nprg                       ! switch for control print
36   ! netcdf files and index common
37   INTEGER ::   &
38      nhoridg, ndepidg,             &
39      ndex(1)
40   REAL(wp) ::     &
41      vol                        ! total ocean volume
42   REAL(wp), DIMENSION(jpk) ::   &
43      volk , volkr,           &  ! level ocean volume and its inverse
44      tdtag, sdtag,           &  ! level mean data temperature & salinity
45      tmodg, smodg               ! level mean model temperature & salinity
46
47   !! * Substitutions
48#  include "domzgr_substitute.h90"
49   !!----------------------------------------------------------------------
50   !!   OPA 9.0 , LODYC-IPSL  (2003)
51   !!----------------------------------------------------------------------
52
53CONTAINS
54
55   SUBROUTINE dia_gap( kt )
56      !!----------------------------------------------------------------------
57      !!                ***  ROUTINE dia_gap  ***
58      !!
59      !! ** Purpose :   Compute model and data level mean T and S profiles
60      !!      and output it in numgap (NetCDF or direct access file)
61      !!
62      !! ** Method :
63      !!         tracers (model) : tn, sn
64      !!         tracers (data)  : t_dta, s_dta
65      !!         difference between model and data tracers
66      !!         variance between model and data tracers
67      !!
68      !! ** Action  :   output in file numgap
69      !!
70      !! History :
71      !!   6.0  !  91-10  (G. Madec)  Original code
72      !!   7.0  !  92-07  (M. Imbard)  Add variance and mpp staff
73      !!   8.5  !  02-07  (G. Madec)  Free form, F90
74      !!----------------------------------------------------------------------
75      !! * Modules used
76      USE ioipsl
77
78      !! * Arguments
79      INTEGER, INTENT(in) ::   kt           ! ocean time-step index
80
81      !! * local declarations
82      INTEGER ::   ji, jj, jk   ! dummy loop indices
83      INTEGER ::   it
84      CHARACTER (len=40) ::   clhstnam
85      CHARACTER (len=40) ::   clop
86      REAL(wp) ::   zbt, zdt    ! temporary scalar
87      REAL(wp) ::   zsto, zout, zmax, zjulian
88      REAL(wp), DIMENSION(jpi) ::   zfoo
89      REAL(wp), DIMENSION(jpj) ::   zloo
90
91      NAMELIST/namgap/ ngap, nprg
92      !!----------------------------------------------------------------------
93
94
95      ! 0. initialization
96      ! -----------------
97
98      zdt = rdt
99      IF( nacc == 1 )   zdt = rdtmin
100
101      IF( kt == nit000 ) THEN
102
103         IF(lwp) WRITE(numout,*)
104         IF(lwp) WRITE(numout,*) 'dia_gap : level mean model-data gap'
105         IF(lwp) WRITE(numout,*) '~~~~~~~'
106
107         ! Read diagap parameters in namelist namgap
108         ngap = 15
109         nprg = 15
110
111         REWIND( numnam )
112         READ( numnam, namgap )
113
114         IF(lwp) WRITE(numout,*) '          time step frequency for gap     ngap  = ',ngap
115         IF(lwp) WRITE(numout,*) '          switch for control print gap    nprg  = ',nprg
116
117         ! horizontal slab volume (tmask_i to take into account only interior ocean domain)
118         volk(:) = 0.e0
119         DO jk = 1, jpkm1
120            DO jj = 1, jpj
121               DO ji = 1, jpi
122                  zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) * tmask_i(ji,jj)
123                  volk(jk) = volk(jk) + tmask(ji,jj,jk) * zbt
124               END DO
125            END DO
126         END DO
127         IF( lk_mpp )   CALL mpp_sum( volk, jpk )   ! sum over the global domain
128
129         volkr(:) = 0.e0
130         DO jk = 1, jpk
131            IF( volk(jk) /= 0.e0 )   volkr(jk) = 1.e0 / volk(jk)
132         END DO
133         IF(lwp) THEN
134            WRITE(numout,*)
135            WRITE(numout,*) '     volume of each horizontal slab (km3) :'
136            DO jk = 1, jpkm1
137               WRITE(numout,9010) jk, volk(jk) * 1.e-9
138            END DO
139         ENDIF
1409010     FORMAT( 9X, 'level ', i3, f15.3 )
141
142         ! basin volume
143         vol = 0.e0
144         DO jk = 1, jpkm1
145            vol = vol + volk(jk)
146         END DO
147         IF(lwp) WRITE(numout,*)
148         IF(lwp) WRITE(numout,*) '     basin volume : ',vol*1.e-9, '  km3'
149
150         ! OPEN netcdf file
151
152         ! Define frequency of output and means
153         zsto = ngap * zdt
154         clop = "ave(x)"
155         zout = ngap * zdt
156         zmax = FLOAT( nitend - nit000 + 1 ) * zdt
157         zfoo(1:jpi) = 0.e0
158         zloo(1:jpj) = 0.e0
159
160         ! Compute julian date from starting date of the run
161
162         CALL ymds2ju( nyear, nmonth, nday, 0.e0, zjulian )
163
164         CALL dia_nam( clhstnam, ngap, 'diagap' )
165         IF(lwp) WRITE(numout,*) 'Name of diagap NETCDF file ', clhstnam
166         ! Horizontal grid : zphi()
167         CALL histbeg( clhstnam, 1, zfoo, 1, zloo,   &
168                        1, 1, 1, 1, 0, zjulian, zdt, nhoridg, numgap )
169         ! Vertical grids : gdept, gdepw
170         CALL histvert( numgap, "deptht", "Vertical T levels",   &
171                         "m", jpk, gdept, ndepidg )
172
173         ! define fields to be stored
174         ! mo(temp/sali)(da/mo/va): mean ocean temperature/salinity data/model/differences
175
176          CALL histdef( numgap, "motempda", "Mean Data Temperature","C",   &
177                        1, 1, nhoridg, jpk, 1, jpk, ndepidg, 32, clop,   &
178                        zsto,zout )
179          CALL histdef(numgap, "mosalida", "Mean Data Salinity","PSU",   &
180                        1, 1, nhoridg, jpk, 1, jpk, ndepidg, 32, clop,   &
181                        zsto,zout )
182          CALL histdef(numgap, "motempmo", "Mean Model Temperature","C",   &
183                        1, 1, nhoridg, jpk, 1, jpk, ndepidg, 32, clop,   &
184                        zsto,zout )
185          CALL histdef(numgap, "mosalimo", "Mean Model Salinity","PSU",   &
186                        1, 1, nhoridg, jpk, 1, jpk, ndepidg, 32, clop,   &
187                        zsto,zout )
188          CALL histend( numgap )
189          ndex(1) = 0
190      ENDIF
191
192
193      ! 1. horizontal averaged
194      ! ----------------------
195
196      IF( MOD( kt, ngap ) == 0 ) THEN
197
198         ! initialization
199         tdtag(:) = 0.e0
200         sdtag(:) = 0.e0
201         tmodg(:) = 0.e0
202         smodg(:) = 0.e0
203         
204         !  c a u t i o n  : use of tmask_i : average over the interior domain only
205         
206         ! sum
207         DO jk = 1, jpkm1
208            DO jj = 1, jpj
209              DO ji = 1, jpi
210                zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) * tmask_i(ji,jj)
211                tdtag(jk) = tdtag(jk) + zbt * t_dta(ji,jj,jk) * volkr(jk)
212                sdtag(jk) = sdtag(jk) + zbt * s_dta(ji,jj,jk) * volkr(jk)
213                tmodg(jk) = tmodg(jk) + zbt * tn  (ji,jj,jk) * volkr(jk)
214                smodg(jk) = smodg(jk) + zbt * sn  (ji,jj,jk) * volkr(jk)
215              END DO 
216            END DO 
217         END DO
218
219
220         ! 2. Basin averaged
221         ! -----------------
222         
223         DO jk = 1, jpkm1
224            tdtag(jpk) = tdtag(jpk) + tdtag(jk) * volk(jk) / vol
225            sdtag(jpk) = sdtag(jpk) + sdtag(jk) * volk(jk) / vol
226            tmodg(jpk) = tmodg(jpk) + tmodg(jk) * volk(jk) / vol
227            smodg(jpk) = smodg(jpk) + smodg(jk) * volk(jk) / vol
228         END DO 
229          IF( lk_mpp)   CALL mpp_sum( tdtag, jpk )   ! sum over the global domain
230          IF( lk_mpp)   CALL mpp_sum( sdtag, jpk )
231          IF( lk_mpp)   CALL mpp_sum( tmodg, jpk )
232          IF( lk_mpp)   CALL mpp_sum( smodg, jpk )
233
234          ! 3.  Averaged output in file numgap
235          ! ----------------------------======
236
237          IF( MOD( kt, nprg ) == 0 ) THEN
238              IF(lwp) THEN
239                  WRITE(numout,*) 'dia_gap: time step = ', kt, 'model - data'
240                  WRITE(numout,9300)
241
242                  DO jk = 1, jpk
243                    WRITE(numout,9310) tdtag(jk), tmodg(jk), tdtag(jk) - tmodg(jk), jk, fsdept(1,1,jk),   &
244                                       sdtag(jk), smodg(jk), sdtag(jk) - smodg(jk)
245                  END DO 
246              ENDIF
247          ENDIF
248
249 9300     FORMAT('  T-data  T-model    diff.   level  depth    S-data  S-model    diff.' )
250 9310     FORMAT( 3(f8.3,1x),i5,f9.0,2x,3(f8.3,1x) )
251
252          ! Output in file numgap
253
254          ! Netcdf write
255
256          IF (lwp ) THEN   ! Ok even in mpp after the call to mpp_sum
257             it = kt - nit000 + 1       ! define time axis
258             CALL histwrite( numgap, "motempda", it, tdtag, jpk, ndex )
259             CALL histwrite( numgap, "mosalida", it, sdtag, jpk, ndex )
260             CALL histwrite( numgap, "motempmo", it, tmodg, jpk, ndex )
261             CALL histwrite( numgap, "mosalimo", it, smodg, jpk, ndex )
262          END IF
263      ENDIF
264
265      ! Closing numgap file
266
267      IF( kt == nitend ) THEN
268         CALL histclo( numgap )      !   Netcdf file
269      ENDIF
270
271   END SUBROUTINE dia_gap
272
273#else
274   !!----------------------------------------------------------------------
275   !!   Default option :                                       Dummy module
276   !!----------------------------------------------------------------------
277   LOGICAL, PUBLIC, PARAMETER ::   lk_diagap = .FALSE.    !: diagap flag
278CONTAINS
279   SUBROUTINE dia_gap( kt )           ! Dummy routine
280      WRITE(*,*) 'dia_gap: You should not have seen this print! error?', kt
281   END SUBROUTINE dia_gap
282#endif
283
284   !!======================================================================
285END MODULE diagap
Note: See TracBrowser for help on using the repository browser.