1 | MODULE dynadv_cen2 |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE dynadv *** |
---|
4 | !! Ocean dynamics: Update the momentum trend with the flux form advection |
---|
5 | !! using a 2nd order centred scheme |
---|
6 | !!====================================================================== |
---|
7 | !! History : 9.0 ! 06-08 (G. Madec, S. Theetten) Original code |
---|
8 | !!---------------------------------------------------------------------- |
---|
9 | |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | !! dyn_adv_cen2 : flux form momentum advection (ln_dynadv_cen2=T) |
---|
12 | !! trends using a 2nd order centred scheme |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | USE oce ! ocean dynamics and tracers |
---|
15 | USE dom_oce ! ocean space and time domain |
---|
16 | USE dynspg_oce ! surface pressure gradient |
---|
17 | USE in_out_manager ! I/O manager |
---|
18 | USE dynspg_rl ! I/O manager |
---|
19 | |
---|
20 | IMPLICIT NONE |
---|
21 | PRIVATE |
---|
22 | |
---|
23 | !! * Routine accessibility |
---|
24 | PUBLIC dyn_adv_cen2 ! routine called by step.F90 |
---|
25 | |
---|
26 | !! * Substitutions |
---|
27 | # include "domzgr_substitute.h90" |
---|
28 | # include "vectopt_loop_substitute.h90" |
---|
29 | !!---------------------------------------------------------------------- |
---|
30 | !! OPA 9.0 , LODYC-IPSL (2006) |
---|
31 | !! $Header$ |
---|
32 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
---|
33 | !!---------------------------------------------------------------------- |
---|
34 | |
---|
35 | CONTAINS |
---|
36 | |
---|
37 | SUBROUTINE dyn_adv_cen2( kt ) |
---|
38 | !!---------------------------------------------------------------------- |
---|
39 | !! *** ROUTINE dyn_adv_cen2 *** |
---|
40 | !! |
---|
41 | !! ** Purpose : Compute the now momentum advection trend in flux form |
---|
42 | !! and the general trend of the momentum equation. |
---|
43 | !! |
---|
44 | !! ** Method : Trend evaluated using now fields (centered in time) |
---|
45 | !! |
---|
46 | !! ** Action : - Update (ua,va) with the now vorticity term trend |
---|
47 | !! - save the trends in (utrd,vtrd) in 2 parts (relative |
---|
48 | !! and planetary vorticity trends) ('key_trddyn') |
---|
49 | !!---------------------------------------------------------------------- |
---|
50 | USE oce, ONLY: zfu => ta, & ! use ta as 3D workspace |
---|
51 | zfv => sa ! use sa as 3D workspace |
---|
52 | |
---|
53 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
---|
54 | |
---|
55 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
56 | REAL(wp) :: zua, zva, zbu, zbv ! temporary scalars |
---|
57 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zfu_t, zfu_f, zfu_uw ! 3D workspace |
---|
58 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zfv_t, zfv_f, zfv_vw ! " " |
---|
59 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zfw ! " " |
---|
60 | !!---------------------------------------------------------------------- |
---|
61 | |
---|
62 | IF( kt == nit000 ) THEN |
---|
63 | IF(lwp) WRITE(numout,*) |
---|
64 | IF(lwp) WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection' |
---|
65 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~' |
---|
66 | ENDIF |
---|
67 | |
---|
68 | |
---|
69 | ! I. Horizontal advection |
---|
70 | ! ----------------------- |
---|
71 | ! ! =============== |
---|
72 | DO jk = 1, jpkm1 ! Horizontal slab |
---|
73 | ! ! =============== |
---|
74 | ! horizontal volume fluxes |
---|
75 | zfu(:,:,jk) = 0.25 * e2u(:,:) * fse3u(:,:,jk) * un(:,:,jk) |
---|
76 | zfv(:,:,jk) = 0.25 * e1v(:,:) * fse3v(:,:,jk) * vn(:,:,jk) |
---|
77 | |
---|
78 | ! horizontal momentum fluxes at T- and F-point |
---|
79 | DO jj = 1, jpjm1 |
---|
80 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
81 | zfu_t(ji+1,jj ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj ,jk) ) * ( un(ji,jj,jk) + un(ji+1,jj ,jk) ) |
---|
82 | zfv_f(ji ,jj ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj ,jk) ) * ( un(ji,jj,jk) + un(ji ,jj+1,jk) ) |
---|
83 | zfu_f(ji ,jj ,jk) = ( zfu(ji,jj,jk) + zfu(ji ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji+1,jj ,jk) ) |
---|
84 | zfv_t(ji ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji ,jj+1,jk) ) |
---|
85 | END DO |
---|
86 | END DO |
---|
87 | |
---|
88 | ! divergence of horizontal momentum fluxes |
---|
89 | DO jj = 2, jpjm1 |
---|
90 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
91 | zbu = e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) |
---|
92 | zbv = e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) |
---|
93 | ! horizontal advective trends |
---|
94 | zua = - ( zfu_t(ji+1,jj ,jk) - zfu_t(ji ,jj ,jk) & |
---|
95 | & + zfv_f(ji ,jj ,jk) - zfv_f(ji ,jj-1,jk) ) / zbu |
---|
96 | zva = - ( zfu_f(ji ,jj ,jk) - zfu_f(ji-1,jj ,jk) & |
---|
97 | & + zfv_t(ji ,jj+1,jk) - zfv_t(ji ,jj ,jk) ) / zbv |
---|
98 | ! add it to the general tracer trends |
---|
99 | ua(ji,jj,jk) = ua(ji,jj,jk) + zua |
---|
100 | va(ji,jj,jk) = va(ji,jj,jk) + zva |
---|
101 | #if defined key_trddyn |
---|
102 | utrd(ji,jj,jk,1) = zua ! save the horizontal advective trend of momentum |
---|
103 | vtrd(ji,jj,jk,1) = zva |
---|
104 | #endif |
---|
105 | END DO |
---|
106 | END DO |
---|
107 | ! ! =============== |
---|
108 | END DO ! End of slab |
---|
109 | ! ! =============== |
---|
110 | |
---|
111 | |
---|
112 | ! II. Vertical advection |
---|
113 | ! ---------------------- |
---|
114 | |
---|
115 | ! Second order centered tracer flux at w-point |
---|
116 | DO jk = 1, jpkm1 |
---|
117 | ! Vertical volume fluxes |
---|
118 | zfw(:,:,jk) = 0.25 * e1t(:,:) * e2t(:,:) * wn(:,:,jk) |
---|
119 | ! Vertical advective fluxes |
---|
120 | IF( jk == 1 ) THEN |
---|
121 | zfu_uw(:,:,jpk) = 0.e0 ! Bottom value : flux set to zero |
---|
122 | zfv_vw(:,:,jpk) = 0.e0 |
---|
123 | ! ! Surface value |
---|
124 | IF( lk_dynspg_rl ) THEN ! rigid lid : flux set to zero |
---|
125 | zfu_uw(:,:, 1 ) = 0.e0 |
---|
126 | zfv_vw(:,:, 1 ) = 0.e0 |
---|
127 | ELSE ! free surface-constant volume |
---|
128 | DO jj = 2, jpjm1 |
---|
129 | DO ji = fs_2, fs_jpim1 |
---|
130 | zfu_uw(ji,jj, 1 ) = 2.e0 * ( zfw(ji,jj,1) + zfw(ji+1,jj ,1) ) * un(ji,jj,1) |
---|
131 | zfv_vw(ji,jj, 1 ) = 2.e0 * ( zfw(ji,jj,1) + zfw(ji ,jj+1,1) ) * vn(ji,jj,1) |
---|
132 | END DO |
---|
133 | END DO |
---|
134 | ENDIF |
---|
135 | ELSE |
---|
136 | ! ! interior fluxes |
---|
137 | DO jj = 2, jpjm1 |
---|
138 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
139 | zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk)+ zfw(ji+1,jj ,jk) ) * ( un(ji,jj,jk) + un(ji,jj,jk-1) ) |
---|
140 | zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk)+ zfw(ji ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji,jj,jk-1) ) |
---|
141 | END DO |
---|
142 | END DO |
---|
143 | ENDIF |
---|
144 | END DO |
---|
145 | |
---|
146 | ! momentum flux divergence at u-, v-points added to the general trend |
---|
147 | DO jk = 1, jpkm1 |
---|
148 | DO jj = 2, jpjm1 |
---|
149 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
150 | zua = - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) ) & |
---|
151 | & / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) ) |
---|
152 | zva = - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) ) & |
---|
153 | & / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) ) |
---|
154 | ! add it to the general tracer trends |
---|
155 | ua(ji,jj,jk) = ua(ji,jj,jk) + zua |
---|
156 | va(ji,jj,jk) = va(ji,jj,jk) + zva |
---|
157 | END DO |
---|
158 | END DO |
---|
159 | END DO |
---|
160 | |
---|
161 | END SUBROUTINE dyn_adv_cen2 |
---|
162 | |
---|
163 | !!============================================================================== |
---|
164 | END MODULE dynadv_cen2 |
---|