New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in trunk/NEMO/OPA_SRC/DYN – NEMO

source: trunk/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 474

Last change on this file since 474 was 474, checked in by opalod, 18 years ago

nemo_v1_update_061: SM: end of ctl_stop + mpi optimization in _bilap
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 54.4 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6
7   !!----------------------------------------------------------------------
8   !!   dyn_hpg      : update the momentum trend with the now horizontal
9   !!                  gradient of the hydrostatic pressure
10   !!                  default case : k-j-i loops (vector opt. available)
11   !!       hpg_ctl  : initialisation and control of options
12   !!       hpg_zco  : z-coordinate scheme
13   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
14   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
15   !!       hpg_hel  : s-coordinate (helsinki modification)
16   !!       hpg_wdj  : s-coordinate (weighted density jacobian)
17   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
18   !!       hpg_rot  : s-coordinate (ROTated axes scheme)
19   !!----------------------------------------------------------------------
20   !! * Modules used
21   USE oce             ! ocean dynamics and tracers
22   USE dom_oce         ! ocean space and time domain
23   USE dynhpg_jki      !
24   USE phycst          ! physical constants
25   USE in_out_manager  ! I/O manager
26   USE trdmod          ! ocean dynamics trends
27   USE trdmod_oce      ! ocean variables trends
28   USE prtctl          ! Print control
29   USE lbclnk          ! lateral boundary condition
30
31   IMPLICIT NONE
32   PRIVATE
33
34   !! * Accessibility
35   PUBLIC dyn_hpg                ! routine called by step.F90
36
37#if defined key_mpp_omp
38   !!----------------------------------------------------------------------
39   !!   'key_mpp_omp' :                                 j-k-i loop (j-slab)
40   !!----------------------------------------------------------------------
41   LOGICAL, PUBLIC, PARAMETER ::   lk_dynhpg_jki = .TRUE.    !: OpenMP hpg flag
42   LOGICAL, PUBLIC, PARAMETER ::   lk_dynhpg     = .FALSE.   !: vector hpg flag
43#else
44   !!----------------------------------------------------------------------
45   !!   default case :                             k-j-i loop (vector opt.)
46   !!----------------------------------------------------------------------   
47   LOGICAL, PUBLIC, PARAMETER ::   lk_dynhpg_jki = .FALSE.   !: OpenMP hpg flag
48   LOGICAL, PUBLIC, PARAMETER ::   lk_dynhpg     = .TRUE.    !: vector hpg flag
49#endif
50
51   !! * Share module variables
52   LOGICAL  ::               & !!! ** nam_dynhpg **   hpg flags
53      ln_hpg_zco = .TRUE. ,  &  ! z-coordinate - full steps
54      ln_hpg_zps = .FALSE.,  &  ! z-coordinate - partial steps (interpolation)
55      ln_hpg_sco = .FALSE.,  &  ! s-coordinate (standard jacobian formulation)
56      ln_hpg_hel = .FALSE.,  &  ! s-coordinate (helsinki modification)
57      ln_hpg_wdj = .FALSE.,  &  ! s-coordinate (weighted density jacobian)
58      ln_hpg_djc = .FALSE.,  &  ! s-coordinate (Density Jacobian with Cubic polynomial)
59      ln_hpg_rot = .FALSE.      ! s-coordinate (ROTated axes scheme)
60
61   REAL(wp) ::               & !!! ** nam_dynhpg **
62      gamm = 0.e0               ! weighting coefficient
63
64   INTEGER  ::               &  !
65      nhpg  =  0                 ! = 0 to 6, type of pressure gradient scheme used
66      !                         ! (deduced from ln_hpg_... flags)
67
68   !! * Substitutions
69#  include "domzgr_substitute.h90"
70#  include "vectopt_loop_substitute.h90"
71   !!----------------------------------------------------------------------
72   !!   OPA 9.0 , LOCEAN-IPSL (2005)
73   !! $Header$
74   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
75   !!----------------------------------------------------------------------
76
77CONTAINS
78
79   SUBROUTINE dyn_hpg( kt )
80      !!---------------------------------------------------------------------
81      !!                  ***  ROUTINE dyn_hpg  ***
82      !!
83      !! ** Method  :   Call the hydrostatic pressure gradient routine
84      !!      using the scheme defined in the namelist (nhpg parameter)
85      !!   
86      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
87      !!             - Save the trend (l_trddyn=T)
88      !!             - Control print  (ln_ctl)
89      !!
90      !! History :
91      !!   9.0  !  05-10  (A. Beckmann, G. Madec) various s-coordinate options
92      !!----------------------------------------------------------------------
93      !! * Arguments
94      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
95
96      !! * local declarations
97      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &
98         ztrdu, ztrdv                         ! 3D temporary workspace
99      !!----------------------------------------------------------------------
100   
101      IF( kt == nit000 )   CALL hpg_ctl      ! initialisation & control of options
102
103      ! Temporary saving of ua and va trends (l_trddyn)
104      IF( l_trddyn )   THEN
105         ztrdu(:,:,:) = ua(:,:,:) 
106         ztrdv(:,:,:) = va(:,:,:) 
107      ENDIF     
108
109      SELECT CASE ( nhpg )      ! Hydrastatic pressure gradient computation
110      CASE ( 0 )                  ! z-coordinate
111         CALL hpg_zco( kt )
112      CASE ( 1 )                  ! z-coordinate plus partial steps (interpolation)
113         CALL hpg_zps( kt )
114      CASE ( 2 )                  ! s-coordinate (standard jacobian formulation)
115         CALL hpg_sco( kt )
116      CASE ( 3 )                  ! s-coordinate (helsinki modification)
117         CALL hpg_hel( kt )
118      CASE ( 4 )                  ! s-coordinate (weighted density jacobian)
119         CALL hpg_wdj( kt )
120      CASE ( 5 )                  ! s-coordinate (Density Jacobian with Cubic polynomial)
121         CALL hpg_djc( kt )
122      CASE ( 6 )                  ! s-coordinate (ROTated axes scheme)
123         CALL hpg_rot( kt )
124      CASE ( 10 )                  ! z-coordinate
125         CALL hpg_zco_jki( kt )
126      CASE ( 11 )                  ! z-coordinate plus partial steps (interpolation)
127         CALL hpg_zps_jki( kt )
128      CASE ( 12 )                  ! s-coordinate (standard jacobian formulation)
129         CALL hpg_sco_jki( kt )
130      END SELECT
131
132      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
133      IF( l_trddyn )   THEN
134         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
135         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
136         CALL trd_mod( ztrdu, ztrdv, jpdtdhpg, 'DYN', kt )
137      ENDIF         
138     
139      IF(ln_ctl) THEN         ! print sum trends (used for debugging)
140         CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask, &
141            &          tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
142      ENDIF
143     
144   END SUBROUTINE dyn_hpg
145
146
147   SUBROUTINE hpg_ctl
148      !!----------------------------------------------------------------------
149      !!                 ***  ROUTINE hpg_ctl  ***
150      !!
151      !! ** Purpose :   initializations for the hydrostatic pressure gradient
152      !!              computation and consistency control
153      !!
154      !! ** Action  :   Read the namelist namdynhpg and check the consistency
155      !!      with the type of vertical coordinate used (zco, zps, sco)
156      !!
157      !! History :
158      !!   9.0  !  05-10  (A. Beckmann)  Original code
159      !!----------------------------------------------------------------------
160      INTEGER ::   ioptio = 0      ! temporary integer
161
162      NAMELIST/nam_dynhpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,               &
163         &                 ln_hpg_hel, ln_hpg_wdj, ln_hpg_djc, ln_hpg_rot,   &
164         &                 gamm
165      !!----------------------------------------------------------------------
166
167      ! Read Namelist nam_dynhpg : pressure gradient calculation options
168      REWIND ( numnam )
169      READ   ( numnam, nam_dynhpg )
170
171      ! Control print
172      IF(lwp) THEN
173         WRITE(numout,*)
174         WRITE(numout,*) 'dyn:hpg_ctl : hydrostatic pressure gradient control'
175         WRITE(numout,*) '~~~~~~~~~~~'
176         WRITE(numout,*) '       Namelist nam_dynhpg : choice of hpg scheme'
177         WRITE(numout,*) '          z-coord. - full steps                          ln_hpg_zco = ', ln_hpg_zco
178         WRITE(numout,*) '          z-coord. - partial steps (interpolation)       ln_hpg_zps = ', ln_hpg_zps
179         WRITE(numout,*) '          s-coord. (standard jacobian formulation)       ln_hpg_sco = ', ln_hpg_sco
180         WRITE(numout,*) '          s-coord. (helsinki modification)               ln_hpg_hel = ', ln_hpg_hel
181         WRITE(numout,*) '          s-coord. (weighted density jacobian)           ln_hpg_wdj = ', ln_hpg_wdj
182         WRITE(numout,*) '          s-coord. (Density Jacobian: Cubic polynomial)  ln_hpg_djc = ', ln_hpg_djc
183         WRITE(numout,*) '          s-coord. (ROTated axes scheme)                 ln_hpg_rot = ', ln_hpg_rot
184         WRITE(numout,*) '          weighting coeff. (wdj scheme)                     gamm       = ', gamm
185      ENDIF
186
187      ! set nhpg from ln_hpg_... flags
188      IF( ln_hpg_zco )   nhpg = 0
189      IF( ln_hpg_zps )   nhpg = 1
190      IF( ln_hpg_sco )   nhpg = 2
191      IF( ln_hpg_hel )   nhpg = 3
192      IF( ln_hpg_wdj )   nhpg = 4
193      IF( ln_hpg_djc )   nhpg = 5
194      IF( ln_hpg_rot )   nhpg = 6
195
196      ! Consitency check
197      ioptio = 0 
198      IF( ln_hpg_zco )   ioptio = ioptio + 1
199      IF( ln_hpg_zps )   ioptio = ioptio + 1
200      IF( ln_hpg_sco )   ioptio = ioptio + 1
201      IF( ln_hpg_hel )   ioptio = ioptio + 1
202      IF( ln_hpg_wdj )   ioptio = ioptio + 1
203      IF( ln_hpg_djc )   ioptio = ioptio + 1
204      IF( ln_hpg_rot )   ioptio = ioptio + 1
205      IF ( ioptio > 1 )   &
206           &   CALL ctl_stop( ' several hydrostatic pressure gradient options used' )
207
208      IF( lk_dynhpg_jki ) THEN
209         nhpg = nhpg + 10
210         IF(lwp) WRITE(numout,*)
211         IF(lwp) WRITE(numout,*) '          Autotasking or OPENMP: use j-k-i loops (i.e. _jki routines)'
212      ENDIF
213
214   END SUBROUTINE hpg_ctl
215
216
217   SUBROUTINE hpg_zco( kt )
218      !!---------------------------------------------------------------------
219      !!                  ***  ROUTINE hpg_zco  ***
220      !!
221      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
222      !!      The now hydrostatic pressure gradient at a given level, jk,
223      !!      is computed by taking the vertical integral of the in-situ
224      !!      density gradient along the model level from the suface to that
225      !!      level:    zhpi = grav .....
226      !!                zhpj = grav .....
227      !!      add it to the general momentum trend (ua,va).
228      !!            ua = ua - 1/e1u * zhpi
229      !!            va = va - 1/e2v * zhpj
230      !!
231      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
232      !!
233      !! History :
234      !!   1.0  !  87-09  (P. Andrich, M.-A. Foujols)  Original code
235      !!   5.0  !  91-11  (G. Madec)
236      !!   7.0  !  96-01  (G. Madec)
237      !!   8.0  !  97-05  (G. Madec)  split dynber into dynkeg and dynhpg
238      !!   8.5  !  02-07  (G. Madec)  F90: Free form and module
239      !!----------------------------------------------------------------------
240      !! * modules used
241      USE oce, ONLY :   zhpi => ta,  &  ! use ta as 3D workspace
242         &              zhpj => sa      ! use sa as 3D workspace
243     
244      !! * Arguments
245      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
246     
247      !! * local declarations
248      INTEGER ::   ji, jj, jk           ! dummy loop indices
249      REAL(wp) ::   &   
250         zcoef0, zcoef1                 ! temporary scalars
251      !!----------------------------------------------------------------------
252     
253      IF( kt == nit000 ) THEN
254         IF(lwp) WRITE(numout,*)
255         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
256         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
257      ENDIF
258     
259     
260      ! Local constant initialization
261      ! -----------------------------
262      zcoef0 = - grav * 0.5
263
264      ! Surface value
265      ! -------------
266      DO jj = 2, jpjm1
267         DO ji = fs_2, fs_jpim1   ! vector opt.
268            zcoef1 = zcoef0 * fse3w(ji,jj,1)
269            ! hydrostatic pressure gradient
270            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
271            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
272            ! add to the general momentum trend
273            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
274            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
275         END DO
276      END DO
277
278      ! interior value (2=<jk=<jpkm1)
279      ! --------------
280      DO jk = 2, jpkm1
281         DO jj = 2, jpjm1
282            DO ji = fs_2, fs_jpim1   ! vector opt.
283               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
284               ! hydrostatic pressure gradient
285               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
286                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
287                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
288
289               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
290                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
291                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
292               ! add to the general momentum trend
293               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
294               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
295            END DO
296         END DO
297      END DO
298
299   END SUBROUTINE hpg_zco
300
301
302   SUBROUTINE hpg_zps( kt )
303      !!---------------------------------------------------------------------
304      !!                 ***  ROUTINE hpg_zps  ***
305      !!                   
306      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
307      !!
308      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
309      !!   
310      !! History :
311      !!   8.5  !  02-08  (A. Bozec)  Original code
312      !!   9.0  !  04-08  (G. Madec)  F90
313      !!----------------------------------------------------------------------
314      !! * modules used                                 
315      USE oce, ONLY :   zhpi => ta,  &  ! use ta as 3D workspace
316         &              zhpj => sa      ! use sa as 3D workspace
317               
318      !! * Arguments
319      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
320
321      !! * local declarations
322      INTEGER ::   ji, jj, jk           ! dummy loop indices
323      INTEGER ::   iku, ikv             ! temporary integers
324      REAL(wp) ::   &
325         zcoef0, zcoef1,             &  ! temporary scalars
326         zcoef2, zcoef3                 !    "         "
327      !!----------------------------------------------------------------------
328
329      IF( kt == nit000 ) THEN
330         IF(lwp) WRITE(numout,*)
331         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
332         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps'
333         IF(lwp) WRITE(numout,*) '              vector optimization'
334      ENDIF
335
336
337      ! 0. Local constant initialization
338      ! --------------------------------
339      zcoef0 = - grav * 0.5
340
341      ! 1. Surface value
342      ! ----------------
343      DO jj = 2, jpjm1
344         DO ji = fs_2, fs_jpim1   ! vector opt.
345            zcoef1 = zcoef0 * fse3w(ji,jj,1)
346            ! hydrostatic pressure gradient
347            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
348            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
349            ! add to the general momentum trend
350            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
351            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
352         END DO
353      END DO
354
355      ! 2. interior value (2=<jk=<jpkm1)
356      ! -----------------
357      DO jk = 2, jpkm1
358         DO jj = 2, jpjm1
359            DO ji = fs_2, fs_jpim1   ! vector opt.
360               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
361               ! hydrostatic pressure gradient
362               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
363                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
364                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
365
366               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
367                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
368                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
369               ! add to the general momentum trend
370               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
371               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
372            END DO
373         END DO
374      END DO
375
376      ! partial steps correction at the last level  (new gradient with  intgrd.F)
377# if defined key_vectopt_loop
378         jj = 1
379         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
380# else
381      DO jj = 2, jpjm1
382         DO ji = 2, jpim1
383# endif
384            iku = MIN ( mbathy(ji,jj), mbathy(ji+1,jj) ) - 1
385            ikv = MIN ( mbathy(ji,jj), mbathy(ji,jj+1) ) - 1
386            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
387            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
388            ! on i-direction
389            IF ( iku > 2 ) THEN
390               ! subtract old value
391               ua(ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)
392               ! compute the new one
393               zhpi (ji,jj,iku) = zhpi(ji,jj,iku-1)   &
394                  + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
395               ! add the new one to the general momentum trend
396               ua(ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)
397            ENDIF
398            ! on j-direction
399            IF ( ikv > 2 ) THEN
400               ! subtract old value
401               va(ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)
402               ! compute the new one
403               zhpj (ji,jj,ikv) = zhpj(ji,jj,ikv-1)   &
404                  + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
405               ! add the new one to the general momentum trend
406               va(ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)
407            ENDIF
408# if ! defined key_vectopt_loop
409         END DO
410# endif
411      END DO
412
413   END SUBROUTINE hpg_zps
414
415
416   SUBROUTINE hpg_sco( kt )
417      !!---------------------------------------------------------------------
418      !!                  ***  ROUTINE hpg_sco  ***
419      !!
420      !! ** Method  :   s-coordinate case. Jacobian scheme.
421      !!      The now hydrostatic pressure gradient at a given level, jk,
422      !!      is computed by taking the vertical integral of the in-situ
423      !!      density gradient along the model level from the suface to that
424      !!      level. s-coordinates (ln_sco): a corrective term is added
425      !!      to the horizontal pressure gradient :
426      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
427      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
428      !!      add it to the general momentum trend (ua,va).
429      !!         ua = ua - 1/e1u * zhpi
430      !!         va = va - 1/e2v * zhpj
431      !!
432      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
433      !!
434      !! History :
435      !!   7.0  !  96-01  (G. Madec)  s-coordinates
436      !!        !  97-05  (G. Madec)  split dynber into dynkeg and dynhpg
437      !!   8.5  !  02-08  (G. Madec)  F90: Free form and module, vector opt.
438      !!   9.0  !  04-08  (C. Talandier) New trends organization
439      !!   9.0  !  05-10  (A. Beckmann) various s-coordinate options
440      !!----------------------------------------------------------------------
441      !! * modules used
442      USE oce, ONLY :   zhpi => ta,  &  ! use ta as 3D workspace
443         &              zhpj => sa      ! use sa as 3D workspace
444
445      !! * Arguments
446      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
447
448      !! * Local declarations
449      INTEGER ::   ji, jj, jk           ! dummy loop indices
450      REAL(wp) ::   &
451         zcoef0, zuap, zvap             ! temporary scalars
452      !!----------------------------------------------------------------------
453
454      IF( kt == nit000 ) THEN
455         IF(lwp) WRITE(numout,*)
456         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
457         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
458      ENDIF
459
460
461      ! 0. Local constant initialization
462      ! --------------------------------
463      zcoef0 = - grav * 0.5
464
465
466      ! 1. Surface value
467      ! ----------------                         
468      DO jj = 2, jpjm1
469         DO ji = fs_2, fs_jpim1   ! vector opt.   
470            ! hydrostatic pressure gradient along s-surfaces
471            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)   &
472               &                                  - fse3w(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
473            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)   &
474               &                                  - fse3w(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
475            ! s-coordinate pressure gradient correction
476            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) )   &
477               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
478            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) )   &
479               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
480            ! add to the general momentum trend
481            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
482            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
483         END DO 
484      END DO   
485           
486               
487      ! 2. interior value (2=<jk=<jpkm1)
488      ! -----------------     
489      DO jk = 2, jpkm1                                 
490         DO jj = 2, jpjm1     
491            DO ji = fs_2, fs_jpim1   ! vector opt.     
492               ! hydrostatic pressure gradient along s-surfaces
493               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   & 
494                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   & 
495                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  )
496               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
497                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
498                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  )
499               ! s-coordinate pressure gradient correction
500               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) )   &
501                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
502               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) )   &
503                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
504               ! add to the general momentum trend
505               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
506               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
507            END DO
508         END DO
509      END DO
510
511   END SUBROUTINE hpg_sco
512
513
514   SUBROUTINE hpg_hel( kt )
515      !!---------------------------------------------------------------------
516      !!                  ***  ROUTINE hpg_hel  ***
517      !!
518      !! ** Method  :   s-coordinate case.
519      !!      The now hydrostatic pressure gradient at a given level
520      !!      jk is computed by taking the vertical integral of the in-situ
521      !!      density gradient along the model level from the suface to that
522      !!      level. s-coordinates (ln_sco): a corrective term is added
523      !!      to the horizontal pressure gradient :
524      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
525      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
526      !!      add it to the general momentum trend (ua,va).
527      !!         ua = ua - 1/e1u * zhpi
528      !!         va = va - 1/e2v * zhpj
529      !!
530      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
531      !!             - Save the trend (l_trddyn=T)
532      !!
533      !! History :
534      !!   9.0  !  05-10  (A. Beckmann)  Original code
535      !!----------------------------------------------------------------------
536      !! * modules used
537      USE oce, ONLY :   zhpi => ta,  &  ! use ta as 3D workspace
538         &              zhpj => sa      ! use sa as 3D workspace
539
540      !! * Arguments
541      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
542     
543      !! * Local declarations
544      INTEGER ::   ji, jj, jk           ! dummy loop indices
545      REAL(wp) ::   &
546         zcoef0, zuap, zvap             ! temporary scalars
547      !!----------------------------------------------------------------------
548
549      IF( kt == nit000 ) THEN
550         IF(lwp) WRITE(numout,*)
551         IF(lwp) WRITE(numout,*) 'dyn:hpg_hel : hydrostatic pressure gradient trend'
552         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, helsinki modified scheme'
553      ENDIF
554
555
556      ! 0. Local constant initialization
557      ! --------------------------------
558      zcoef0 = - grav * 0.5
559
560 
561      ! 1. Surface value
562      ! ----------------
563      DO jj = 2, jpjm1
564         DO ji = fs_2, fs_jpim1   ! vector opt.
565            ! hydrostatic pressure gradient along s-surfaces
566            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)  &
567               &                                  - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
568            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3t(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)  &
569               &                                  - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
570            ! s-coordinate pressure gradient correction
571            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) )   &
572               &           * ( fsdept(ji+1,jj,1) - fsdept(ji,jj,1) ) / e1u(ji,jj)
573            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) )   &
574               &           * ( fsdept(ji,jj+1,1) - fsdept(ji,jj,1) ) / e2v(ji,jj)
575            ! add to the general momentum trend
576            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
577            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
578         END DO
579      END DO
580
581      ! 2. interior value (2=<jk=<jpkm1)
582      ! -----------------
583      DO jk = 2, jpkm1
584         DO jj = 2, jpjm1
585            DO ji = fs_2, fs_jpim1   ! vector opt.
586               ! hydrostatic pressure gradient along s-surfaces
587               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
588                  &           +  zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj,jk  ) * rhd(ji+1,jj,jk)     &
589                  &                                     -fse3t(ji  ,jj,jk  ) * rhd(ji  ,jj,jk)   ) &
590                  &           +  zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj,jk-1) * rhd(ji+1,jj,jk-1)   &
591                  &                                     -fse3t(ji  ,jj,jk-1) * rhd(ji  ,jj,jk-1) )
592               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
593                  &           +  zcoef0 / e2v(ji,jj) * ( fse3t(ji,jj+1,jk  ) * rhd(ji,jj+1,jk)   &
594                  &                                     -fse3t(ji,jj  ,jk  ) * rhd(ji,jj,  jk)   ) &
595                  &           +  zcoef0 / e2v(ji,jj) * ( fse3t(ji,jj+1,jk-1) * rhd(ji,jj+1,jk-1) &
596                  &                                     -fse3t(ji,jj  ,jk-1) * rhd(ji,jj,  jk-1) )
597               ! s-coordinate pressure gradient correction
598               zuap = - zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )   &
599                  &            * ( fsdept(ji+1,jj,jk) - fsdept(ji,jj,jk) ) / e1u(ji,jj)
600               zvap = - zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )   &
601                  &            * ( fsdept(ji,jj+1,jk) - fsdept(ji,jj,jk) ) / e2v(ji,jj)
602               ! add to the general momentum trend
603               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
604               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
605            END DO
606         END DO
607      END DO
608
609   END SUBROUTINE hpg_hel
610
611
612   SUBROUTINE hpg_wdj( kt )
613      !!---------------------------------------------------------------------
614      !!                  ***  ROUTINE hpg_wdj  ***
615      !!
616      !! ** Method  :   Weighted Density Jacobian (wdj) scheme (song 1998)
617      !!      The weighting coefficients from the namelist parameter gamm
618      !!      (alpha=0.5-gamm ; beta=1-alpha=0.5+gamm)
619      !!
620      !! Reference : Song, Mon. Wea. Rev., 126, 3213-3230, 1998.
621      !!
622      !! History :
623      !!   9.0  !  05-05  (B.W. An)  Original code
624      !!        !  05-10  (G. Madec) style & small optimisation
625      !!----------------------------------------------------------------------
626      !! * modules used
627      USE oce, ONLY :   zhpi => ta,  &  ! use ta as 3D workspace
628         &              zhpj => sa      ! use sa as 3D workspace
629
630      !! * Arguments
631      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
632
633      !! * Local declarations
634      INTEGER ::   ji, jj, jk           ! dummy loop indices
635      REAL(wp) ::   &
636         zcoef0, zuap, zvap,         &  ! temporary scalars
637         zalph , zbeta                  !    "         "
638      !!----------------------------------------------------------------------
639
640      IF( kt == nit000 ) THEN
641         IF(lwp) WRITE(numout,*)
642         IF(lwp) WRITE(numout,*) 'dyn:hpg_wdj : hydrostatic pressure gradient trend'
643         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   Weighted Density Jacobian'
644      ENDIF
645
646
647      ! Local constant initialization
648      ! -----------------------------
649      zcoef0 = - grav * 0.5
650      zalph  = 0.5 - gamm        ! weighting coefficients (alpha=0.5-gamm)
651      zbeta  = 0.5 + gamm        !                        (beta =1-alpha=0.5+gamm)
652
653      ! Surface value (no ponderation)
654      ! -------------
655      DO jj = 2, jpjm1
656         DO ji = fs_2, fs_jpim1   ! vector opt.
657            ! hydrostatic pressure gradient along s-surfaces
658            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * (  fse3w(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)   &
659               &                                   - fse3w(ji  ,jj  ,1) * rhd(ji  ,jj  ,1)  )
660            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * (  fse3w(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)   &
661               &                                   - fse3w(ji  ,jj  ,1) * rhd(ji,  jj  ,1)  )
662            ! s-coordinate pressure gradient correction
663            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) )   &
664               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
665            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) )   &
666               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
667            ! add to the general momentum trend
668            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
669            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
670         END DO
671      END DO
672
673      ! Interior value (2=<jk=<jpkm1) (weighted with zalph & zbeta)
674      ! --------------
675      DO jk = 2, jpkm1
676         DO jj = 2, jpjm1
677            DO ji = fs_2, fs_jpim1   ! vector opt.
678               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)                            &
679                  &           * (   (            fsde3w(ji+1,jj,jk  ) + fsde3w(ji,jj,jk  )        &
680                  &                            - fsde3w(ji+1,jj,jk-1) - fsde3w(ji,jj,jk-1)    )   &
681                  &               * (  zalph * ( rhd   (ji+1,jj,jk-1) - rhd   (ji,jj,jk-1) )      &
682                  &                  + zbeta * ( rhd   (ji+1,jj,jk  ) - rhd   (ji,jj,jk  ) )  )   &
683                  &             -   (            rhd   (ji+1,jj,jk  ) + rhd   (ji,jj,jk  )        &
684                  &                           - rhd   (ji+1,jj,jk-1) - rhd   (ji,jj,jk-1)     )   &
685                  &               * (  zalph * ( fsde3w(ji+1,jj,jk-1) - fsde3w(ji,jj,jk-1) )      &
686                  &                  + zbeta * ( fsde3w(ji+1,jj,jk  ) - fsde3w(ji,jj,jk  ) )  )  )
687               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)                            &
688                  &           * (   (           fsde3w(ji,jj+1,jk  ) + fsde3w(ji,jj,jk  )         &
689                  &                           - fsde3w(ji,jj+1,jk-1) - fsde3w(ji,jj,jk-1)     )   &
690                  &               * (  zalph * ( rhd   (ji,jj+1,jk-1) - rhd   (ji,jj,jk-1) )      &
691                  &                  + zbeta * ( rhd   (ji,jj+1,jk  ) - rhd   (ji,jj,jk  ) )  )   &
692                  &             -   (            rhd   (ji,jj+1,jk  ) + rhd   (ji,jj,jk  )        &
693                  &                            - rhd   (ji,jj+1,jk-1) - rhd   (ji,jj,jk-1)    )   &
694                  &               * (  zalph * ( fsde3w(ji,jj+1,jk-1) - fsde3w(ji,jj,jk-1) )      &
695                  &                  + zbeta * ( fsde3w(ji,jj+1,jk  ) - fsde3w(ji,jj,jk  ) )  )  )
696               ! add to the general momentum trend
697               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
698               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
699            END DO
700         END DO
701      END DO
702
703   END SUBROUTINE hpg_wdj
704
705
706   SUBROUTINE hpg_djc( kt )
707      !!---------------------------------------------------------------------
708      !!                  ***  ROUTINE hpg_djc  ***
709      !!
710      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
711      !!
712      !! Reference: Shchepetkin, A.F. & J.C. McWilliams, J. Geophys. Res.,
713      !!            108(C3), 3090, 2003
714      !! History :
715      !!   9.0  !  05-05  (B.W. An)  Original code
716      !!----------------------------------------------------------------------
717      !! * modules used
718      USE oce, ONLY :   zhpi => ta,  &  ! use ta as 3D workspace
719         &              zhpj => sa      ! use sa as 3D workspace
720
721      !! * Arguments
722      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
723     
724      !! * Local declarations
725      INTEGER ::   ji, jj, jk           ! dummy loop indices
726      REAL(wp) ::   &
727         zcoef0, z1_10, cffu, cffx,  &  ! temporary scalars
728                 z1_12, cffv, cffy,  &  !    "         "
729         zep   , cffw                   !    "         "
730      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &  ! 3D workspace
731         drhox, dzx, drhou, dzu, rho_i,     &
732         drhoy, dzy, drhov, dzv, rho_j,     &
733         drhoz, dzz, drhow, dzw, rho_k
734      !!----------------------------------------------------------------------
735
736      IF( kt == nit000 ) THEN
737         IF(lwp) WRITE(numout,*)
738         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
739         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
740      ENDIF
741
742
743      ! 0. Local constant initialization
744      ! --------------------------------
745      zcoef0 = - grav * 0.5
746      z1_10  = 1.0 / 10.0
747      z1_12  = 1.0 / 12.0
748
749      !----------------------------------------------------------------------------------------
750      !  compute and store in provisional arrays elementary vertical and horizontal differences
751      !----------------------------------------------------------------------------------------
752
753!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
754
755      DO jk = 2, jpkm1
756         DO jj = 2, jpjm1
757            DO ji = fs_2, fs_jpim1   ! vector opt.
758               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
759               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
760               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
761               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
762               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
763               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
764            END DO
765         END DO
766      END DO
767
768      !-------------------------------------------------------------------------
769      ! compute harmonic averages using eq. 5.18
770      !-------------------------------------------------------------------------
771      zep = 1.e-15
772
773      !!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
774      !!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
775
776      DO jk = 2, jpkm1
777         DO jj = 2, jpjm1
778            DO ji = fs_2, fs_jpim1   ! vector opt.
779               cffw = 2.0 * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
780
781               cffu = 2.0 * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
782               cffx = 2.0 * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
783 
784               cffv = 2.0 * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
785               cffy = 2.0 * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
786
787               IF( cffw > zep) THEN
788                  drhow(ji,jj,jk) = 2.0 *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
789                     &                  / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
790               ELSE
791                  drhow(ji,jj,jk) = 0.e0
792               ENDIF
793
794               dzw(ji,jj,jk) = 2.0 *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
795                  &                / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
796
797               IF( cffu > zep ) THEN
798                  drhou(ji,jj,jk) = 2.0 *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
799                     &                  / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
800               ELSE
801                  drhou(ji,jj,jk ) = 0.e0
802               ENDIF
803
804               IF( cffx > zep ) THEN
805                  dzu(ji,jj,jk) = 2.0*dzx(ji+1,jj,jk)*dzx(ji,jj,jk)   &
806                     &            /(dzx(ji+1,jj,jk)+dzx(ji,jj,jk))
807               ELSE
808                  dzu(ji,jj,jk) = 0.e0
809               ENDIF
810
811               IF( cffv > zep ) THEN
812                  drhov(ji,jj,jk) = 2.0 *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
813                     &                  / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
814               ELSE
815                  drhov(ji,jj,jk) = 0.e0
816               ENDIF
817
818               IF( cffy > zep ) THEN
819                  dzv(ji,jj,jk) = 2.0 *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
820                     &                / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
821               ELSE
822                  dzv(ji,jj,jk) = 0.e0
823               ENDIF
824
825            END DO
826         END DO
827      END DO
828
829      !----------------------------------------------------------------------------------
830      ! apply boundary conditions at top and bottom using 5.36-5.37
831      !----------------------------------------------------------------------------------
832      drhow(:,:, 1 ) = 1.5 * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5 * drhow(:,:,  2  )
833      drhou(:,:, 1 ) = 1.5 * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5 * drhou(:,:,  2  )
834      drhov(:,:, 1 ) = 1.5 * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5 * drhov(:,:,  2  )
835
836      drhow(:,:,jpk) = 1.5 * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5 * drhow(:,:,jpkm1)
837      drhou(:,:,jpk) = 1.5 * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5 * drhou(:,:,jpkm1)
838      drhov(:,:,jpk) = 1.5 * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5 * drhov(:,:,jpkm1)
839
840
841      !--------------------------------------------------------------
842      ! Upper half of top-most grid box, compute and store
843      !-------------------------------------------------------------
844
845!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
846!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
847
848      DO jj = 2, jpjm1
849         DO ji = fs_2, fs_jpim1   ! vector opt.
850            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )            &
851               &                   * (  rhd(ji,jj,1)                                 &
852               &                     + 0.5 * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
853               &                           * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
854               &                           / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  ) 
855         END DO
856      END DO
857
858!!bug gm    : here also, simplification is possible
859!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
860
861      DO jk = 2, jpkm1
862         DO jj = 2, jpjm1
863            DO ji = fs_2, fs_jpim1   ! vector opt.
864
865               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
866                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
867                  &            - grav * z1_10 * (                                                                     &
868                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
869                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
870                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
871                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
872                  &                             )
873
874               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
875                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
876                  &            - grav* z1_10 * (                                                                      &
877                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
878                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
879                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
880                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
881                  &                            )
882
883               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
884                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
885                  &            - grav* z1_10 * (                                                                      &
886                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
887                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
888                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
889                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
890                  &                            )
891
892            END DO
893         END DO
894      END DO
895      CALL lbc_lnk(rho_k,'W',1.)
896      CALL lbc_lnk(rho_i,'U',1.)
897      CALL lbc_lnk(rho_j,'V',1.)
898
899
900      ! ---------------
901      !  Surface value
902      ! ---------------
903      DO jj = 2, jpjm1
904         DO ji = fs_2, fs_jpim1   ! vector opt.
905            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
906            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
907            ! add to the general momentum trend
908            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
909            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
910         END DO
911      END DO
912
913      ! ----------------
914      !  interior value   (2=<jk=<jpkm1)
915      ! ----------------
916      DO jk = 2, jpkm1
917         DO jj = 2, jpjm1 
918            DO ji = fs_2, fs_jpim1   ! vector opt.
919               ! hydrostatic pressure gradient along s-surfaces
920               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
921                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
922                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
923               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
924                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
925                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
926               ! add to the general momentum trend
927               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
928               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
929            END DO
930         END DO
931      END DO
932
933   END SUBROUTINE hpg_djc
934
935
936   SUBROUTINE hpg_rot( kt )
937      !!---------------------------------------------------------------------
938      !!                  ***  ROUTINE hpg_rot  ***
939      !!
940      !! ** Method  :   rotated axes scheme (Thiem and Berntsen 2005)
941      !!
942      !! Reference: Thiem & Berntsen, Ocean Modelling, In press, 2005.
943      !! History :
944      !!   9.0  !  05-07 (B.W. An)
945      !!   9.0  !  05-10 (A. Beckmann) adapted to non-equidistant and masked grids
946      !!----------------------------------------------------------------------
947      !! * modules used
948      USE oce, ONLY :   zhpi => ta,         &  ! use ta as 3D workspace
949         &              zhpj => sa             ! use sa as 3D workspace
950
951      !! * Arguments
952      INTEGER, INTENT( in ) ::   kt            ! ocean time-step index
953     
954      !! * Local declarations
955      INTEGER ::   ji, jj, jk                  ! dummy loop indices
956      REAL(wp) ::   &
957         zforg, zcoef0, zuap, zmskd1, zmskd1m,                             &
958         zfrot        , zvap, zmskd2, zmskd2m
959      REAL(wp), DIMENSION(jpi,jpj) ::       &  ! 2D temporary workspace
960         zdistr, zsina, zcosa             
961      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &  ! 3D temporary workspace
962         zhpiorg, zhpirot, zhpitra, zhpine, & 
963         zhpjorg, zhpjrot, zhpjtra, zhpjne
964      !!----------------------------------------------------------------------
965
966      IF( kt == nit000 ) THEN
967         IF(lwp) WRITE(numout,*)
968         IF(lwp) WRITE(numout,*) 'dyn:hpg_rot : hydrostatic pressure gradient trend'
969         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, rotated axes scheme used'
970      ENDIF
971
972      ! -------------------------------
973      !  Local constant initialization
974      ! -------------------------------
975      zcoef0 = - grav * 0.5
976      zforg  = 0.95e0
977      zfrot  = 1.e0 - zforg
978
979      ! inverse of the distance between 2 diagonal T-points (defined at F-point) (here zcoef0/distance)
980      zdistr(:,:) = zcoef0 / SQRT( e1f(:,:)*e1f(:,:) + e2f(:,:)*e1f(:,:) )
981
982      ! sinus and cosinus of diagonal angle at F-point
983      zsina(:,:) = ATAN2( e2f(:,:), e1f(:,:) )
984      zcosa(:,:) = COS( zsina(:,:) )
985      zsina(:,:) = SIN( zsina(:,:) )
986
987      ! ---------------
988      !  Surface value
989      ! ---------------
990      ! compute and add to the general trend the pressure gradients along the axes
991      DO jj = 2, jpjm1
992         DO ji = fs_2, fs_jpim1   ! vector opt.
993            ! hydrostatic pressure gradient along s-surfaces
994            zhpiorg(ji,jj,1) = zcoef0 / e1u(ji,jj) * (  fse3t(ji+1,jj,1) * rhd(ji+1,jj,1)   &
995               &                                      - fse3t(ji  ,jj,1) * rhd(ji  ,jj,1)  )
996            zhpjorg(ji,jj,1) = zcoef0 / e2v(ji,jj) * (  fse3t(ji,jj+1,1) * rhd(ji,jj+1,1)   &
997               &                                      - fse3t(ji,jj  ,1) * rhd(ji,jj  ,1)  )
998            ! s-coordinate pressure gradient correction
999            zuap = -zcoef0 * ( rhd   (ji+1,jj  ,1) + rhd   (ji,jj,1) )   &
1000               &           * ( fsdept(ji+1,jj  ,1) - fsdept(ji,jj,1) ) / e1u(ji,jj)
1001            zvap = -zcoef0 * ( rhd   (ji  ,jj+1,1) + rhd   (ji,jj,1) )   &
1002               &           * ( fsdept(ji  ,jj+1,1) - fsdept(ji,jj,1) ) / e2v(ji,jj)
1003            ! add to the general momentum trend
1004            ua(ji,jj,1) = ua(ji,jj,1) + zforg * ( zhpiorg(ji,jj,1) + zuap )
1005            va(ji,jj,1) = va(ji,jj,1) + zforg * ( zhpjorg(ji,jj,1) + zvap )
1006         END DO
1007      END DO
1008
1009      ! compute the pressure gradients in the diagonal directions
1010      DO jj = 1, jpjm1
1011         DO ji = 1, fs_jpim1   ! vector opt.
1012            zmskd1 = tmask(ji+1,jj+1,1) * tmask(ji  ,jj,1)      ! mask in the 1st diagnonal
1013            zmskd2 = tmask(ji  ,jj+1,1) * tmask(ji+1,jj,1)      ! mask in the 2nd diagnonal
1014            ! hydrostatic pressure gradient along s-surfaces
1015            zhpitra(ji,jj,1) = zdistr(ji,jj) * zmskd1 * (  fse3t(ji+1,jj+1,1) * rhd(ji+1,jj+1,1)   &
1016               &                                         - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1)  )
1017            zhpjtra(ji,jj,1) = zdistr(ji,jj) * zmskd2 * (  fse3t(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)   &
1018               &                                         - fse3t(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)  )
1019            ! s-coordinate pressure gradient correction
1020            zuap = -zdistr(ji,jj) * zmskd1 * ( rhd   (ji+1,jj+1,1) + rhd   (ji  ,jj,1) )   &
1021               &                           * ( fsdept(ji+1,jj+1,1) - fsdept(ji  ,jj,1) )
1022            zvap = -zdistr(ji,jj) * zmskd2 * ( rhd   (ji  ,jj+1,1) + rhd   (ji+1,jj,1) )   &
1023               &                           * ( fsdept(ji  ,jj+1,1) - fsdept(ji+1,jj,1) )
1024            ! back rotation
1025            zhpine(ji,jj,1) = zcosa(ji,jj) * ( zhpitra(ji,jj,1) + zuap )   &
1026               &            - zsina(ji,jj) * ( zhpjtra(ji,jj,1) + zvap )
1027            zhpjne(ji,jj,1) = zsina(ji,jj) * ( zhpitra(ji,jj,1) + zuap )   &
1028               &            + zcosa(ji,jj) * ( zhpjtra(ji,jj,1) + zvap )
1029         END DO
1030      END DO
1031
1032      ! interpolate and add to the general trend the diagonal gradient
1033      DO jj = 2, jpjm1
1034         DO ji = fs_2, fs_jpim1   ! vector opt.
1035            ! averaging
1036            zhpirot(ji,jj,1) = 0.5 * ( zhpine(ji,jj,1) + zhpine(ji  ,jj-1,1) )
1037            zhpjrot(ji,jj,1) = 0.5 * ( zhpjne(ji,jj,1) + zhpjne(ji-1,jj  ,1) )
1038            ! add to the general momentum trend
1039            ua(ji,jj,1) = ua(ji,jj,1) + zfrot * zhpirot(ji,jj,1) 
1040            va(ji,jj,1) = va(ji,jj,1) + zfrot * zhpjrot(ji,jj,1) 
1041         END DO
1042      END DO
1043
1044      ! -----------------
1045      ! 2. interior value (2=<jk=<jpkm1)
1046      ! -----------------
1047      ! compute and add to the general trend the pressure gradients along the axes
1048      DO jk = 2, jpkm1
1049         DO jj = 2, jpjm1
1050            DO ji = fs_2, fs_jpim1   ! vector opt.
1051               ! hydrostatic pressure gradient along s-surfaces
1052               zhpiorg(ji,jj,jk) = zhpiorg(ji,jj,jk-1)                                                 &
1053                  &              +  zcoef0 / e1u(ji,jj) * (  fse3t(ji+1,jj,jk  ) * rhd(ji+1,jj,jk  )   &
1054                  &                                        - fse3t(ji  ,jj,jk  ) * rhd(ji  ,jj,jk  )   &
1055                  &                                        + fse3t(ji+1,jj,jk-1) * rhd(ji+1,jj,jk-1)   &
1056                  &                                        - fse3t(ji  ,jj,jk-1) * rhd(ji  ,jj,jk-1)  )
1057               zhpjorg(ji,jj,jk) = zhpjorg(ji,jj,jk-1)                                                 &
1058                  &              +  zcoef0 / e2v(ji,jj) * (  fse3t(ji,jj+1,jk  ) * rhd(ji,jj+1,jk  )   &
1059                  &                                        - fse3t(ji,jj  ,jk  ) * rhd(ji,jj,  jk  )   &
1060                  &                                        + fse3t(ji,jj+1,jk-1) * rhd(ji,jj+1,jk-1)   &
1061                  &                                        - fse3t(ji,jj  ,jk-1) * rhd(ji,jj,  jk-1)  )
1062               ! s-coordinate pressure gradient correction
1063               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) )   &
1064                  &            * ( fsdept(ji+1,jj  ,jk) - fsdept(ji,jj,jk) ) / e1u(ji,jj)
1065               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) )   &
1066                  &            * ( fsdept(ji  ,jj+1,jk) - fsdept(ji,jj,jk) ) / e2v(ji,jj)
1067               ! add to the general momentum trend
1068               ua(ji,jj,jk) = ua(ji,jj,jk) + zforg*( zhpiorg(ji,jj,jk) + zuap )
1069               va(ji,jj,jk) = va(ji,jj,jk) + zforg*( zhpjorg(ji,jj,jk) + zvap )
1070            END DO
1071         END DO
1072      END DO
1073
1074      ! compute the pressure gradients in the diagonal directions
1075      DO jk = 2, jpkm1
1076         DO jj = 1, jpjm1
1077            DO ji = 1, fs_jpim1   ! vector opt.
1078               zmskd1  = tmask(ji+1,jj+1,jk  ) * tmask(ji  ,jj,jk  )      ! level jk   mask in the 1st diagnonal
1079               zmskd1m = tmask(ji+1,jj+1,jk-1) * tmask(ji  ,jj,jk-1)      ! level jk-1    "               "     
1080               zmskd2  = tmask(ji  ,jj+1,jk  ) * tmask(ji+1,jj,jk  )      ! level jk   mask in the 2nd diagnonal
1081               zmskd2m = tmask(ji  ,jj+1,jk-1) * tmask(ji+1,jj,jk-1)      ! level jk-1    "               "     
1082               ! hydrostatic pressure gradient along s-surfaces
1083               zhpitra(ji,jj,jk) = zhpitra(ji,jj,jk-1)                                                       &
1084                  &              + zdistr(ji,jj) * zmskd1  * ( fse3t(ji+1,jj+1,jk  ) * rhd(ji+1,jj+1,jk)     &
1085                  &                                           -fse3t(ji  ,jj  ,jk  ) * rhd(ji  ,jj  ,jk) )   &
1086                  &              + zdistr(ji,jj) * zmskd1m * ( fse3t(ji+1,jj+1,jk-1) * rhd(ji+1,jj+1,jk-1)   &
1087                  &                                           -fse3t(ji  ,jj  ,jk-1) * rhd(ji  ,jj  ,jk-1) )
1088               zhpjtra(ji,jj,jk) = zhpjtra(ji,jj,jk-1)                                                       &
1089                  &              + zdistr(ji,jj) * zmskd2  * ( fse3t(ji  ,jj+1,jk  ) * rhd(ji  ,jj+1,jk)     &
1090                  &                                           -fse3t(ji+1,jj  ,jk  ) * rhd(ji+1,jj,  jk) )   &
1091                  &              + zdistr(ji,jj) * zmskd2m * ( fse3t(ji  ,jj+1,jk-1) * rhd(ji  ,jj+1,jk-1)   &
1092                  &                                           -fse3t(ji+1,jj  ,jk-1) * rhd(ji+1,jj,  jk-1) )
1093               ! s-coordinate pressure gradient correction
1094               zuap = - zdistr(ji,jj) * zmskd1 * ( rhd   (ji+1,jj+1,jk) + rhd   (ji  ,jj,jk) )   &
1095                  &                            * ( fsdept(ji+1,jj+1,jk) - fsdept(ji  ,jj,jk) )
1096               zvap = - zdistr(ji,jj) * zmskd2 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji+1,jj,jk) )   &
1097                  &                            * ( fsdept(ji  ,jj+1,jk) - fsdept(ji+1,jj,jk) )
1098               ! back rotation
1099               zhpine(ji,jj,jk) = zcosa(ji,jj) * ( zhpitra(ji,jj,jk) + zuap )   &
1100                  &             - zsina(ji,jj) * ( zhpjtra(ji,jj,jk) + zvap )
1101               zhpjne(ji,jj,jk) = zsina(ji,jj) * ( zhpitra(ji,jj,jk) + zuap )   &
1102                  &             + zcosa(ji,jj) * ( zhpjtra(ji,jj,jk) + zvap )
1103            END DO
1104         END DO
1105      END DO
1106
1107      ! interpolate and add to the general trend
1108      DO jk = 2, jpkm1
1109         DO jj = 2, jpjm1
1110            DO ji = fs_2, fs_jpim1   ! vector opt.
1111               ! averaging
1112               zhpirot(ji,jj,jk) = 0.5 * ( zhpine(ji,jj,jk) + zhpine(ji  ,jj-1,jk) )
1113               zhpjrot(ji,jj,jk) = 0.5 * ( zhpjne(ji,jj,jk) + zhpjne(ji-1,jj  ,jk) )
1114               ! add to the general momentum trend
1115               ua(ji,jj,jk) = ua(ji,jj,jk) + zfrot * zhpirot(ji,jj,jk) 
1116               va(ji,jj,jk) = va(ji,jj,jk) + zfrot * zhpjrot(ji,jj,jk) 
1117            END DO
1118         END DO
1119      END DO
1120
1121   END SUBROUTINE hpg_rot
1122
1123   !!======================================================================
1124END MODULE dynhpg
Note: See TracBrowser for help on using the repository browser.