New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in trunk/NEMO/OPA_SRC/DYN – NEMO

source: trunk/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 553

Last change on this file since 553 was 541, checked in by opalod, 18 years ago

nemo_v1_bugfix_065:RB: move namelist declaration for compatibility with Agrif
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 52.2 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  1.0  !  87-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  91-11  (G. Madec)
8   !!            7.0  !  96-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  97-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  02-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  02-08  (A. Bozec)  hpg_zps: Original code
12   !!            9.0  !  05-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                           Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!            9.0  !  05-11  (G. Madec) style & small optimisation
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   dyn_hpg      : update the momentum trend with the now horizontal
19   !!                  gradient of the hydrostatic pressure
20   !!                  default case : k-j-i loops (vector opt. available)
21   !!       hpg_ctl  : initialisation and control of options
22   !!       hpg_zco  : z-coordinate scheme
23   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
24   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
25   !!       hpg_hel  : s-coordinate (helsinki modification)
26   !!       hpg_wdj  : s-coordinate (weighted density jacobian)
27   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
28   !!       hpg_rot  : s-coordinate (ROTated axes scheme)
29   !!----------------------------------------------------------------------
30   USE oce             ! ocean dynamics and tracers
31   USE dom_oce         ! ocean space and time domain
32   USE dynhpg_jki      !
33   USE phycst          ! physical constants
34   USE in_out_manager  ! I/O manager
35   USE trdmod          ! ocean dynamics trends
36   USE trdmod_oce      ! ocean variables trends
37   USE prtctl          ! Print control
38   USE lbclnk          ! lateral boundary condition
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   dyn_hpg    ! routine called by step module
44
45#if defined key_mpp_omp
46   !!----------------------------------------------------------------------
47   !!   'key_mpp_omp' :                                 j-k-i loop (j-slab)
48   !!----------------------------------------------------------------------
49   LOGICAL, PUBLIC, PARAMETER ::   lk_dynhpg_jki = .TRUE.    !: OpenMP hpg flag
50   LOGICAL, PUBLIC, PARAMETER ::   lk_dynhpg     = .FALSE.   !: vector hpg flag
51#else
52   !!----------------------------------------------------------------------
53   !!   default case :                             k-j-i loop (vector opt.)
54   !!----------------------------------------------------------------------   
55   LOGICAL, PUBLIC, PARAMETER ::   lk_dynhpg_jki = .FALSE.   !: OpenMP hpg flag
56   LOGICAL, PUBLIC, PARAMETER ::   lk_dynhpg     = .TRUE.    !: vector hpg flag
57#endif
58
59   !!* Namelist nam_dynhpg : Choice of horizontal pressure gradient computation
60   LOGICAL  ::   ln_hpg_zco = .TRUE.    ! z-coordinate - full steps
61   LOGICAL  ::   ln_hpg_zps = .FALSE.   ! z-coordinate - partial steps (interpolation)
62   LOGICAL  ::   ln_hpg_sco = .FALSE.   ! s-coordinate (standard jacobian formulation)
63   LOGICAL  ::   ln_hpg_hel = .FALSE.   ! s-coordinate (helsinki modification)
64   LOGICAL  ::   ln_hpg_wdj = .FALSE.   ! s-coordinate (weighted density jacobian)
65   LOGICAL  ::   ln_hpg_djc = .FALSE.   ! s-coordinate (Density Jacobian with Cubic polynomial)
66   LOGICAL  ::   ln_hpg_rot = .FALSE.   ! s-coordinate (ROTated axes scheme)
67   REAL(wp) ::   gamm       = 0.e0      ! weighting coefficient
68
69   INTEGER  ::   nhpg  =  0             ! = 0 to 6, type of pressure gradient scheme used
70      !                                 ! (deduced from ln_hpg_... flags)
71
72   !! * Substitutions
73#  include "domzgr_substitute.h90"
74#  include "vectopt_loop_substitute.h90"
75   !!----------------------------------------------------------------------
76   !!   OPA 9.0 , LOCEAN-IPSL (2005)
77   !! $Header$
78   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
79   !!----------------------------------------------------------------------
80
81CONTAINS
82
83   SUBROUTINE dyn_hpg( kt )
84      !!---------------------------------------------------------------------
85      !!                  ***  ROUTINE dyn_hpg  ***
86      !!
87      !! ** Method  :   Call the hydrostatic pressure gradient routine
88      !!              using the scheme defined in the namelist
89      !!   
90      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
91      !!             - Save the trend (l_trddyn=T)
92      !!----------------------------------------------------------------------
93      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
94      !!
95      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ztrdu, ztrdv   ! 3D temporary workspace
96      !!----------------------------------------------------------------------
97   
98      IF( kt == nit000 )   CALL hpg_ctl      ! initialisation & control of options
99
100      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
101         ztrdu(:,:,:) = ua(:,:,:) 
102         ztrdv(:,:,:) = va(:,:,:) 
103      ENDIF     
104
105      SELECT CASE ( nhpg )      ! Hydrastatic pressure gradient computation
106      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
107      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
108      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
109      CASE (  3 )   ;   CALL hpg_hel    ( kt )      ! s-coordinate (helsinki modification)
110      CASE (  4 )   ;   CALL hpg_wdj    ( kt )      ! s-coordinate (weighted density jacobian)
111      CASE (  5 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
112      CASE (  6 )   ;   CALL hpg_rot    ( kt )      ! s-coordinate (ROTated axes scheme)
113      CASE ( 10 )   ;   CALL hpg_zco_jki( kt )      ! z-coordinate (k-j-i)
114      CASE ( 11 )   ;   CALL hpg_zps_jki( kt )      ! z-coordinate plus partial steps (interpolation) (k-j-i)
115      CASE ( 12 )   ;   CALL hpg_sco_jki( kt )      ! s-coordinate (standard jacobian formulation) (k-j-i)
116      END SELECT
117
118      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
119         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
120         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
121         CALL trd_mod( ztrdu, ztrdv, jpdyn_trd_hpg, 'DYN', kt )
122      ENDIF         
123      !
124      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
125         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
126      !
127   END SUBROUTINE dyn_hpg
128
129
130   SUBROUTINE hpg_ctl
131      !!----------------------------------------------------------------------
132      !!                 ***  ROUTINE hpg_ctl  ***
133      !!
134      !! ** Purpose :   initializations for the hydrostatic pressure gradient
135      !!              computation and consistency control
136      !!
137      !! ** Action  :   Read the namelist namdynhpg and check the consistency
138      !!      with the type of vertical coordinate used (zco, zps, sco)
139      !!----------------------------------------------------------------------
140      INTEGER ::   ioptio = 0      ! temporary integer
141
142      NAMELIST/nam_dynhpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco, ln_hpg_hel,   &
143         &                 ln_hpg_wdj, ln_hpg_djc, ln_hpg_rot, gamm
144      !!----------------------------------------------------------------------
145
146      REWIND ( numnam )               ! Read Namelist nam_dynhpg : pressure gradient calculation options
147      READ   ( numnam, nam_dynhpg )
148
149      IF(lwp) THEN                    ! Control print
150         WRITE(numout,*)
151         WRITE(numout,*) 'dyn:hpg_ctl : hydrostatic pressure gradient control'
152         WRITE(numout,*) '~~~~~~~~~~~'
153         WRITE(numout,*) '       Namelist nam_dynhpg : choice of hpg scheme'
154         WRITE(numout,*) '          z-coord. - full steps                          ln_hpg_zco = ', ln_hpg_zco
155         WRITE(numout,*) '          z-coord. - partial steps (interpolation)       ln_hpg_zps = ', ln_hpg_zps
156         WRITE(numout,*) '          s-coord. (standard jacobian formulation)       ln_hpg_sco = ', ln_hpg_sco
157         WRITE(numout,*) '          s-coord. (helsinki modification)               ln_hpg_hel = ', ln_hpg_hel
158         WRITE(numout,*) '          s-coord. (weighted density jacobian)           ln_hpg_wdj = ', ln_hpg_wdj
159         WRITE(numout,*) '          s-coord. (Density Jacobian: Cubic polynomial)  ln_hpg_djc = ', ln_hpg_djc
160         WRITE(numout,*) '          s-coord. (ROTated axes scheme)                 ln_hpg_rot = ', ln_hpg_rot
161         WRITE(numout,*) '          weighting coeff. (wdj scheme)                     gamm       = ', gamm
162      ENDIF
163
164      !                               ! Set nhpg from ln_hpg_... flags
165      IF( ln_hpg_zco )   nhpg = 0
166      IF( ln_hpg_zps )   nhpg = 1
167      IF( ln_hpg_sco )   nhpg = 2
168      IF( ln_hpg_hel )   nhpg = 3
169      IF( ln_hpg_wdj )   nhpg = 4
170      IF( ln_hpg_djc )   nhpg = 5
171      IF( ln_hpg_rot )   nhpg = 6
172
173      !                               ! Consitency check
174      ioptio = 0 
175      IF( ln_hpg_zco )   ioptio = ioptio + 1
176      IF( ln_hpg_zps )   ioptio = ioptio + 1
177      IF( ln_hpg_sco )   ioptio = ioptio + 1
178      IF( ln_hpg_hel )   ioptio = ioptio + 1
179      IF( ln_hpg_wdj )   ioptio = ioptio + 1
180      IF( ln_hpg_djc )   ioptio = ioptio + 1
181      IF( ln_hpg_rot )   ioptio = ioptio + 1
182      IF ( ioptio /= 1 )   CALL ctl_stop( ' NO or several hydrostatic pressure gradient options used' )
183
184      IF( lk_dynhpg_jki ) THEN
185         nhpg = nhpg + 10
186         IF(lwp) WRITE(numout,*)
187         IF(lwp) WRITE(numout,*) '          Autotasking or OPENMP: use j-k-i loops (i.e. _jki routines)'
188      ENDIF
189      !
190   END SUBROUTINE hpg_ctl
191
192
193   SUBROUTINE hpg_zco( kt )
194      !!---------------------------------------------------------------------
195      !!                  ***  ROUTINE hpg_zco  ***
196      !!
197      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
198      !!      The now hydrostatic pressure gradient at a given level, jk,
199      !!      is computed by taking the vertical integral of the in-situ
200      !!      density gradient along the model level from the suface to that
201      !!      level:    zhpi = grav .....
202      !!                zhpj = grav .....
203      !!      add it to the general momentum trend (ua,va).
204      !!            ua = ua - 1/e1u * zhpi
205      !!            va = va - 1/e2v * zhpj
206      !!
207      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
208      !!----------------------------------------------------------------------
209      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
210      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
211      !!
212      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
213      !!
214      INTEGER  ::   ji, jj, jk       ! dummy loop indices
215      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
216      !!----------------------------------------------------------------------
217     
218      IF( kt == nit000 ) THEN
219         IF(lwp) WRITE(numout,*)
220         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
221         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
222      ENDIF
223     
224      ! Local constant initialization
225      zcoef0 = - grav * 0.5
226
227      ! Surface value
228      DO jj = 2, jpjm1
229         DO ji = fs_2, fs_jpim1   ! vector opt.
230            zcoef1 = zcoef0 * fse3w(ji,jj,1)
231            ! hydrostatic pressure gradient
232            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
233            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
234            ! add to the general momentum trend
235            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
236            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
237         END DO
238      END DO
239      !
240      ! interior value (2=<jk=<jpkm1)
241      DO jk = 2, jpkm1
242         DO jj = 2, jpjm1
243            DO ji = fs_2, fs_jpim1   ! vector opt.
244               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
245               ! hydrostatic pressure gradient
246               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
247                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
248                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
249
250               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
251                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
252                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
253               ! add to the general momentum trend
254               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
255               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
256            END DO
257         END DO
258      END DO
259      !
260   END SUBROUTINE hpg_zco
261
262
263   SUBROUTINE hpg_zps( kt )
264      !!---------------------------------------------------------------------
265      !!                 ***  ROUTINE hpg_zps  ***
266      !!                   
267      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
268      !!
269      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
270      !!----------------------------------------------------------------------
271      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
272      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
273      !!
274      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
275      !!
276      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
277      INTEGER  ::   iku, ikv                         ! temporary integers
278      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
279      !!----------------------------------------------------------------------
280
281      IF( kt == nit000 ) THEN
282         IF(lwp) WRITE(numout,*)
283         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
284         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
285      ENDIF
286
287      ! Local constant initialization
288      zcoef0 = - grav * 0.5
289
290      !  Surface value
291      DO jj = 2, jpjm1
292         DO ji = fs_2, fs_jpim1   ! vector opt.
293            zcoef1 = zcoef0 * fse3w(ji,jj,1)
294            ! hydrostatic pressure gradient
295            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
296            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
297            ! add to the general momentum trend
298            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
299            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
300         END DO
301      END DO
302
303      ! interior value (2=<jk=<jpkm1)
304      DO jk = 2, jpkm1
305         DO jj = 2, jpjm1
306            DO ji = fs_2, fs_jpim1   ! vector opt.
307               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
308               ! hydrostatic pressure gradient
309               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
310                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
311                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
312
313               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
314                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
315                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
316               ! add to the general momentum trend
317               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
318               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
319            END DO
320         END DO
321      END DO
322
323      ! partial steps correction at the last level  (new gradient with  intgrd.F)
324# if defined key_vectopt_loop
325         jj = 1
326         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
327# else
328      DO jj = 2, jpjm1
329         DO ji = 2, jpim1
330# endif
331            iku = MIN ( mbathy(ji,jj), mbathy(ji+1,jj) ) - 1
332            ikv = MIN ( mbathy(ji,jj), mbathy(ji,jj+1) ) - 1
333            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
334            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
335            ! on i-direction
336            IF ( iku > 2 ) THEN
337               ! subtract old value
338               ua(ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)
339               ! compute the new one
340               zhpi (ji,jj,iku) = zhpi(ji,jj,iku-1)   &
341                  + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
342               ! add the new one to the general momentum trend
343               ua(ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)
344            ENDIF
345            ! on j-direction
346            IF ( ikv > 2 ) THEN
347               ! subtract old value
348               va(ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)
349               ! compute the new one
350               zhpj (ji,jj,ikv) = zhpj(ji,jj,ikv-1)   &
351                  + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
352               ! add the new one to the general momentum trend
353               va(ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)
354            ENDIF
355# if ! defined key_vectopt_loop
356         END DO
357# endif
358      END DO
359      !
360   END SUBROUTINE hpg_zps
361
362
363   SUBROUTINE hpg_sco( kt )
364      !!---------------------------------------------------------------------
365      !!                  ***  ROUTINE hpg_sco  ***
366      !!
367      !! ** Method  :   s-coordinate case. Jacobian scheme.
368      !!      The now hydrostatic pressure gradient at a given level, jk,
369      !!      is computed by taking the vertical integral of the in-situ
370      !!      density gradient along the model level from the suface to that
371      !!      level. s-coordinates (ln_sco): a corrective term is added
372      !!      to the horizontal pressure gradient :
373      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
374      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
375      !!      add it to the general momentum trend (ua,va).
376      !!         ua = ua - 1/e1u * zhpi
377      !!         va = va - 1/e2v * zhpj
378      !!
379      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
380      !!----------------------------------------------------------------------
381      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
382      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
383      !!
384      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
385      !!
386      INTEGER  ::   ji, jj, jk           ! dummy loop indices
387      REAL(wp) ::   zcoef0, zuap, zvap   ! temporary scalars
388      !!----------------------------------------------------------------------
389
390      IF( kt == nit000 ) THEN
391         IF(lwp) WRITE(numout,*)
392         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
393         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
394      ENDIF
395
396      ! Local constant initialization
397      zcoef0 = - grav * 0.5
398
399      ! Surface value
400      DO jj = 2, jpjm1
401         DO ji = fs_2, fs_jpim1   ! vector opt.   
402            ! hydrostatic pressure gradient along s-surfaces
403            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)   &
404               &                                  - fse3w(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
405            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)   &
406               &                                  - fse3w(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
407            ! s-coordinate pressure gradient correction
408            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) )   &
409               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
410            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) )   &
411               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
412            ! add to the general momentum trend
413            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
414            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
415         END DO 
416      END DO   
417           
418      ! interior value (2=<jk=<jpkm1)
419      DO jk = 2, jpkm1                                 
420         DO jj = 2, jpjm1     
421            DO ji = fs_2, fs_jpim1   ! vector opt.     
422               ! hydrostatic pressure gradient along s-surfaces
423               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   & 
424                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   & 
425                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  )
426               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
427                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
428                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  )
429               ! s-coordinate pressure gradient correction
430               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) )   &
431                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
432               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) )   &
433                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
434               ! add to the general momentum trend
435               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
436               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
437            END DO
438         END DO
439      END DO
440      !
441   END SUBROUTINE hpg_sco
442
443
444   SUBROUTINE hpg_hel( kt )
445      !!---------------------------------------------------------------------
446      !!                  ***  ROUTINE hpg_hel  ***
447      !!
448      !! ** Method  :   s-coordinate case.
449      !!      The now hydrostatic pressure gradient at a given level
450      !!      jk is computed by taking the vertical integral of the in-situ
451      !!      density gradient along the model level from the suface to that
452      !!      level. s-coordinates (ln_sco): a corrective term is added
453      !!      to the horizontal pressure gradient :
454      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
455      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
456      !!      add it to the general momentum trend (ua,va).
457      !!         ua = ua - 1/e1u * zhpi
458      !!         va = va - 1/e2v * zhpj
459      !!
460      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
461      !!             - Save the trend (l_trddyn=T)
462      !!----------------------------------------------------------------------
463      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
464      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
465      !!
466      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
467      !!
468      INTEGER  ::   ji, jj, jk           ! dummy loop indices
469      REAL(wp) ::   zcoef0, zuap, zvap   ! temporary scalars
470      !!----------------------------------------------------------------------
471
472      IF( kt == nit000 ) THEN
473         IF(lwp) WRITE(numout,*)
474         IF(lwp) WRITE(numout,*) 'dyn:hpg_hel : hydrostatic pressure gradient trend'
475         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, helsinki modified scheme'
476      ENDIF
477
478      ! Local constant initialization
479      zcoef0 = - grav * 0.5
480 
481      ! Surface value
482      DO jj = 2, jpjm1
483         DO ji = fs_2, fs_jpim1   ! vector opt.
484            ! hydrostatic pressure gradient along s-surfaces
485            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)  &
486               &                                  - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
487            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3t(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)  &
488               &                                  - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
489            ! s-coordinate pressure gradient correction
490            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) )   &
491               &           * ( fsdept(ji+1,jj,1) - fsdept(ji,jj,1) ) / e1u(ji,jj)
492            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) )   &
493               &           * ( fsdept(ji,jj+1,1) - fsdept(ji,jj,1) ) / e2v(ji,jj)
494            ! add to the general momentum trend
495            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
496            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
497         END DO
498      END DO
499      !
500      ! interior value (2=<jk=<jpkm1)
501      DO jk = 2, jpkm1
502         DO jj = 2, jpjm1
503            DO ji = fs_2, fs_jpim1   ! vector opt.
504               ! hydrostatic pressure gradient along s-surfaces
505               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
506                  &           +  zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj,jk  ) * rhd(ji+1,jj,jk)     &
507                  &                                     -fse3t(ji  ,jj,jk  ) * rhd(ji  ,jj,jk)   ) &
508                  &           +  zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj,jk-1) * rhd(ji+1,jj,jk-1)   &
509                  &                                     -fse3t(ji  ,jj,jk-1) * rhd(ji  ,jj,jk-1) )
510               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
511                  &           +  zcoef0 / e2v(ji,jj) * ( fse3t(ji,jj+1,jk  ) * rhd(ji,jj+1,jk)   &
512                  &                                     -fse3t(ji,jj  ,jk  ) * rhd(ji,jj,  jk)   ) &
513                  &           +  zcoef0 / e2v(ji,jj) * ( fse3t(ji,jj+1,jk-1) * rhd(ji,jj+1,jk-1) &
514                  &                                     -fse3t(ji,jj  ,jk-1) * rhd(ji,jj,  jk-1) )
515               ! s-coordinate pressure gradient correction
516               zuap = - zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )   &
517                  &            * ( fsdept(ji+1,jj,jk) - fsdept(ji,jj,jk) ) / e1u(ji,jj)
518               zvap = - zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )   &
519                  &            * ( fsdept(ji,jj+1,jk) - fsdept(ji,jj,jk) ) / e2v(ji,jj)
520               ! add to the general momentum trend
521               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
522               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
523            END DO
524         END DO
525      END DO
526      !
527   END SUBROUTINE hpg_hel
528
529
530   SUBROUTINE hpg_wdj( kt )
531      !!---------------------------------------------------------------------
532      !!                  ***  ROUTINE hpg_wdj  ***
533      !!
534      !! ** Method  :   Weighted Density Jacobian (wdj) scheme (song 1998)
535      !!      The weighting coefficients from the namelist parameter gamm
536      !!      (alpha=0.5-gamm ; beta=1-alpha=0.5+gamm)
537      !!
538      !! Reference : Song, Mon. Wea. Rev., 126, 3213-3230, 1998.
539      !!----------------------------------------------------------------------
540      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
541      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
542      !!
543      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
544      !!
545      INTEGER  ::   ji, jj, jk           ! dummy loop indices
546      REAL(wp) ::   zcoef0, zuap, zvap   ! temporary scalars
547      REAL(wp) ::   zalph , zbeta        !    "         "
548      !!----------------------------------------------------------------------
549
550      IF( kt == nit000 ) THEN
551         IF(lwp) WRITE(numout,*)
552         IF(lwp) WRITE(numout,*) 'dyn:hpg_wdj : hydrostatic pressure gradient trend'
553         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   Weighted Density Jacobian'
554      ENDIF
555
556      ! Local constant initialization
557      zcoef0 = - grav * 0.5
558      zalph  = 0.5 - gamm        ! weighting coefficients (alpha=0.5-gamm)
559      zbeta  = 0.5 + gamm        !                        (beta =1-alpha=0.5+gamm)
560
561      ! Surface value (no ponderation)
562      DO jj = 2, jpjm1
563         DO ji = fs_2, fs_jpim1   ! vector opt.
564            ! hydrostatic pressure gradient along s-surfaces
565            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * (  fse3w(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)   &
566               &                                   - fse3w(ji  ,jj  ,1) * rhd(ji  ,jj  ,1)  )
567            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * (  fse3w(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)   &
568               &                                   - fse3w(ji  ,jj  ,1) * rhd(ji,  jj  ,1)  )
569            ! s-coordinate pressure gradient correction
570            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) )   &
571               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
572            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) )   &
573               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
574            ! add to the general momentum trend
575            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
576            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
577         END DO
578      END DO
579
580      ! Interior value (2=<jk=<jpkm1) (weighted with zalph & zbeta)
581      DO jk = 2, jpkm1
582         DO jj = 2, jpjm1
583            DO ji = fs_2, fs_jpim1   ! vector opt.
584               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)                            &
585                  &           * (   (            fsde3w(ji+1,jj,jk  ) + fsde3w(ji,jj,jk  )        &
586                  &                            - fsde3w(ji+1,jj,jk-1) - fsde3w(ji,jj,jk-1)    )   &
587                  &               * (  zalph * ( rhd   (ji+1,jj,jk-1) - rhd   (ji,jj,jk-1) )      &
588                  &                  + zbeta * ( rhd   (ji+1,jj,jk  ) - rhd   (ji,jj,jk  ) )  )   &
589                  &             -   (            rhd   (ji+1,jj,jk  ) + rhd   (ji,jj,jk  )        &
590                  &                           - rhd   (ji+1,jj,jk-1) - rhd   (ji,jj,jk-1)     )   &
591                  &               * (  zalph * ( fsde3w(ji+1,jj,jk-1) - fsde3w(ji,jj,jk-1) )      &
592                  &                  + zbeta * ( fsde3w(ji+1,jj,jk  ) - fsde3w(ji,jj,jk  ) )  )  )
593               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)                            &
594                  &           * (   (           fsde3w(ji,jj+1,jk  ) + fsde3w(ji,jj,jk  )         &
595                  &                           - fsde3w(ji,jj+1,jk-1) - fsde3w(ji,jj,jk-1)     )   &
596                  &               * (  zalph * ( rhd   (ji,jj+1,jk-1) - rhd   (ji,jj,jk-1) )      &
597                  &                  + zbeta * ( rhd   (ji,jj+1,jk  ) - rhd   (ji,jj,jk  ) )  )   &
598                  &             -   (            rhd   (ji,jj+1,jk  ) + rhd   (ji,jj,jk  )        &
599                  &                            - rhd   (ji,jj+1,jk-1) - rhd   (ji,jj,jk-1)    )   &
600                  &               * (  zalph * ( fsde3w(ji,jj+1,jk-1) - fsde3w(ji,jj,jk-1) )      &
601                  &                  + zbeta * ( fsde3w(ji,jj+1,jk  ) - fsde3w(ji,jj,jk  ) )  )  )
602               ! add to the general momentum trend
603               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
604               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
605            END DO
606         END DO
607      END DO
608      !
609   END SUBROUTINE hpg_wdj
610
611
612   SUBROUTINE hpg_djc( kt )
613      !!---------------------------------------------------------------------
614      !!                  ***  ROUTINE hpg_djc  ***
615      !!
616      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
617      !!
618      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
619      !!----------------------------------------------------------------------
620      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
621      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
622      !!
623      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
624      !!
625      INTEGER  ::   ji, jj, jk          ! dummy loop indices
626      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
627      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
628      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
629      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhox, dzx, drhou, dzu, rho_i   ! 3D workspace
630      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhoy, dzy, drhov, dzv, rho_j   !  "      "
631      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhoz, dzz, drhow, dzw, rho_k   !  "      "
632      !!----------------------------------------------------------------------
633
634      IF( kt == nit000 ) THEN
635         IF(lwp) WRITE(numout,*)
636         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
637         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
638      ENDIF
639
640
641      ! Local constant initialization
642      zcoef0 = - grav * 0.5
643      z1_10  = 1.0 / 10.0
644      z1_12  = 1.0 / 12.0
645
646      !----------------------------------------------------------------------------------------
647      !  compute and store in provisional arrays elementary vertical and horizontal differences
648      !----------------------------------------------------------------------------------------
649
650!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
651
652      DO jk = 2, jpkm1
653         DO jj = 2, jpjm1
654            DO ji = fs_2, fs_jpim1   ! vector opt.
655               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
656               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
657               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
658               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
659               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
660               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
661            END DO
662         END DO
663      END DO
664
665      !-------------------------------------------------------------------------
666      ! compute harmonic averages using eq. 5.18
667      !-------------------------------------------------------------------------
668      zep = 1.e-15
669
670!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
671!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
672
673      DO jk = 2, jpkm1
674         DO jj = 2, jpjm1
675            DO ji = fs_2, fs_jpim1   ! vector opt.
676               cffw = 2.0 * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
677
678               cffu = 2.0 * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
679               cffx = 2.0 * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
680 
681               cffv = 2.0 * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
682               cffy = 2.0 * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
683
684               IF( cffw > zep) THEN
685                  drhow(ji,jj,jk) = 2.0 *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
686                     &                  / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
687               ELSE
688                  drhow(ji,jj,jk) = 0.e0
689               ENDIF
690
691               dzw(ji,jj,jk) = 2.0 *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
692                  &                / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
693
694               IF( cffu > zep ) THEN
695                  drhou(ji,jj,jk) = 2.0 *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
696                     &                  / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
697               ELSE
698                  drhou(ji,jj,jk ) = 0.e0
699               ENDIF
700
701               IF( cffx > zep ) THEN
702                  dzu(ji,jj,jk) = 2.0*dzx(ji+1,jj,jk)*dzx(ji,jj,jk)   &
703                     &            /(dzx(ji+1,jj,jk)+dzx(ji,jj,jk))
704               ELSE
705                  dzu(ji,jj,jk) = 0.e0
706               ENDIF
707
708               IF( cffv > zep ) THEN
709                  drhov(ji,jj,jk) = 2.0 *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
710                     &                  / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
711               ELSE
712                  drhov(ji,jj,jk) = 0.e0
713               ENDIF
714
715               IF( cffy > zep ) THEN
716                  dzv(ji,jj,jk) = 2.0 *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
717                     &                / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
718               ELSE
719                  dzv(ji,jj,jk) = 0.e0
720               ENDIF
721
722            END DO
723         END DO
724      END DO
725
726      !----------------------------------------------------------------------------------
727      ! apply boundary conditions at top and bottom using 5.36-5.37
728      !----------------------------------------------------------------------------------
729      drhow(:,:, 1 ) = 1.5 * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5 * drhow(:,:,  2  )
730      drhou(:,:, 1 ) = 1.5 * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5 * drhou(:,:,  2  )
731      drhov(:,:, 1 ) = 1.5 * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5 * drhov(:,:,  2  )
732
733      drhow(:,:,jpk) = 1.5 * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5 * drhow(:,:,jpkm1)
734      drhou(:,:,jpk) = 1.5 * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5 * drhou(:,:,jpkm1)
735      drhov(:,:,jpk) = 1.5 * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5 * drhov(:,:,jpkm1)
736
737
738      !--------------------------------------------------------------
739      ! Upper half of top-most grid box, compute and store
740      !-------------------------------------------------------------
741
742!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
743!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
744
745      DO jj = 2, jpjm1
746         DO ji = fs_2, fs_jpim1   ! vector opt.
747            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )            &
748               &                   * (  rhd(ji,jj,1)                                 &
749               &                     + 0.5 * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
750               &                           * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
751               &                           / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  ) 
752         END DO
753      END DO
754
755!!bug gm    : here also, simplification is possible
756!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
757
758      DO jk = 2, jpkm1
759         DO jj = 2, jpjm1
760            DO ji = fs_2, fs_jpim1   ! vector opt.
761
762               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
763                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
764                  &            - grav * z1_10 * (                                                                     &
765                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
766                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
767                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
768                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
769                  &                             )
770
771               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
772                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
773                  &            - grav* z1_10 * (                                                                      &
774                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
775                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
776                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
777                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
778                  &                            )
779
780               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
781                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
782                  &            - grav* z1_10 * (                                                                      &
783                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
784                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
785                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
786                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
787                  &                            )
788
789            END DO
790         END DO
791      END DO
792      CALL lbc_lnk(rho_k,'W',1.)
793      CALL lbc_lnk(rho_i,'U',1.)
794      CALL lbc_lnk(rho_j,'V',1.)
795
796
797      ! ---------------
798      !  Surface value
799      ! ---------------
800      DO jj = 2, jpjm1
801         DO ji = fs_2, fs_jpim1   ! vector opt.
802            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
803            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
804            ! add to the general momentum trend
805            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
806            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
807         END DO
808      END DO
809
810      ! ----------------
811      !  interior value   (2=<jk=<jpkm1)
812      ! ----------------
813      DO jk = 2, jpkm1
814         DO jj = 2, jpjm1 
815            DO ji = fs_2, fs_jpim1   ! vector opt.
816               ! hydrostatic pressure gradient along s-surfaces
817               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
818                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
819                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
820               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
821                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
822                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
823               ! add to the general momentum trend
824               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
825               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
826            END DO
827         END DO
828      END DO
829      !
830   END SUBROUTINE hpg_djc
831
832
833   SUBROUTINE hpg_rot( kt )
834      !!---------------------------------------------------------------------
835      !!                  ***  ROUTINE hpg_rot  ***
836      !!
837      !! ** Method  :   rotated axes scheme (Thiem and Berntsen 2005)
838      !!
839      !! Reference: Thiem & Berntsen, Ocean Modelling, In press, 2005.
840      !!----------------------------------------------------------------------
841      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
842      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
843      !!
844      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
845      !!
846      INTEGER  ::   ji, jj, jk          ! dummy loop indices
847      REAL(wp) ::   zforg, zcoef0, zuap, zmskd1, zmskd1m   ! temporary scalar
848      REAL(wp) ::   zfrot        , zvap, zmskd2, zmskd2m   !    "         "
849      REAL(wp), DIMENSION(jpi,jpj)     ::   zdistr, zsina, zcosa                ! 2D workspace
850      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpiorg, zhpirot, zhpitra, zhpine   ! 3D workspace
851      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpjorg, zhpjrot, zhpjtra, zhpjne   !  "      "
852      !!----------------------------------------------------------------------
853
854      IF( kt == nit000 ) THEN
855         IF(lwp) WRITE(numout,*)
856         IF(lwp) WRITE(numout,*) 'dyn:hpg_rot : hydrostatic pressure gradient trend'
857         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, rotated axes scheme used'
858      ENDIF
859
860      ! -------------------------------
861      !  Local constant initialization
862      ! -------------------------------
863      zcoef0 = - grav * 0.5
864      zforg  = 0.95e0
865      zfrot  = 1.e0 - zforg
866
867      ! inverse of the distance between 2 diagonal T-points (defined at F-point) (here zcoef0/distance)
868      zdistr(:,:) = zcoef0 / SQRT( e1f(:,:)*e1f(:,:) + e2f(:,:)*e1f(:,:) )
869
870      ! sinus and cosinus of diagonal angle at F-point
871      zsina(:,:) = ATAN2( e2f(:,:), e1f(:,:) )
872      zcosa(:,:) = COS( zsina(:,:) )
873      zsina(:,:) = SIN( zsina(:,:) )
874
875      ! ---------------
876      !  Surface value
877      ! ---------------
878      ! compute and add to the general trend the pressure gradients along the axes
879      DO jj = 2, jpjm1
880         DO ji = fs_2, fs_jpim1   ! vector opt.
881            ! hydrostatic pressure gradient along s-surfaces
882            zhpiorg(ji,jj,1) = zcoef0 / e1u(ji,jj) * (  fse3t(ji+1,jj,1) * rhd(ji+1,jj,1)   &
883               &                                      - fse3t(ji  ,jj,1) * rhd(ji  ,jj,1)  )
884            zhpjorg(ji,jj,1) = zcoef0 / e2v(ji,jj) * (  fse3t(ji,jj+1,1) * rhd(ji,jj+1,1)   &
885               &                                      - fse3t(ji,jj  ,1) * rhd(ji,jj  ,1)  )
886            ! s-coordinate pressure gradient correction
887            zuap = -zcoef0 * ( rhd   (ji+1,jj  ,1) + rhd   (ji,jj,1) )   &
888               &           * ( fsdept(ji+1,jj  ,1) - fsdept(ji,jj,1) ) / e1u(ji,jj)
889            zvap = -zcoef0 * ( rhd   (ji  ,jj+1,1) + rhd   (ji,jj,1) )   &
890               &           * ( fsdept(ji  ,jj+1,1) - fsdept(ji,jj,1) ) / e2v(ji,jj)
891            ! add to the general momentum trend
892            ua(ji,jj,1) = ua(ji,jj,1) + zforg * ( zhpiorg(ji,jj,1) + zuap )
893            va(ji,jj,1) = va(ji,jj,1) + zforg * ( zhpjorg(ji,jj,1) + zvap )
894         END DO
895      END DO
896
897      ! compute the pressure gradients in the diagonal directions
898      DO jj = 1, jpjm1
899         DO ji = 1, fs_jpim1   ! vector opt.
900            zmskd1 = tmask(ji+1,jj+1,1) * tmask(ji  ,jj,1)      ! mask in the 1st diagnonal
901            zmskd2 = tmask(ji  ,jj+1,1) * tmask(ji+1,jj,1)      ! mask in the 2nd diagnonal
902            ! hydrostatic pressure gradient along s-surfaces
903            zhpitra(ji,jj,1) = zdistr(ji,jj) * zmskd1 * (  fse3t(ji+1,jj+1,1) * rhd(ji+1,jj+1,1)   &
904               &                                         - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1)  )
905            zhpjtra(ji,jj,1) = zdistr(ji,jj) * zmskd2 * (  fse3t(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)   &
906               &                                         - fse3t(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)  )
907            ! s-coordinate pressure gradient correction
908            zuap = -zdistr(ji,jj) * zmskd1 * ( rhd   (ji+1,jj+1,1) + rhd   (ji  ,jj,1) )   &
909               &                           * ( fsdept(ji+1,jj+1,1) - fsdept(ji  ,jj,1) )
910            zvap = -zdistr(ji,jj) * zmskd2 * ( rhd   (ji  ,jj+1,1) + rhd   (ji+1,jj,1) )   &
911               &                           * ( fsdept(ji  ,jj+1,1) - fsdept(ji+1,jj,1) )
912            ! back rotation
913            zhpine(ji,jj,1) = zcosa(ji,jj) * ( zhpitra(ji,jj,1) + zuap )   &
914               &            - zsina(ji,jj) * ( zhpjtra(ji,jj,1) + zvap )
915            zhpjne(ji,jj,1) = zsina(ji,jj) * ( zhpitra(ji,jj,1) + zuap )   &
916               &            + zcosa(ji,jj) * ( zhpjtra(ji,jj,1) + zvap )
917         END DO
918      END DO
919
920      ! interpolate and add to the general trend the diagonal gradient
921      DO jj = 2, jpjm1
922         DO ji = fs_2, fs_jpim1   ! vector opt.
923            ! averaging
924            zhpirot(ji,jj,1) = 0.5 * ( zhpine(ji,jj,1) + zhpine(ji  ,jj-1,1) )
925            zhpjrot(ji,jj,1) = 0.5 * ( zhpjne(ji,jj,1) + zhpjne(ji-1,jj  ,1) )
926            ! add to the general momentum trend
927            ua(ji,jj,1) = ua(ji,jj,1) + zfrot * zhpirot(ji,jj,1) 
928            va(ji,jj,1) = va(ji,jj,1) + zfrot * zhpjrot(ji,jj,1) 
929         END DO
930      END DO
931
932      ! -----------------
933      ! 2. interior value (2=<jk=<jpkm1)
934      ! -----------------
935      ! compute and add to the general trend the pressure gradients along the axes
936      DO jk = 2, jpkm1
937         DO jj = 2, jpjm1
938            DO ji = fs_2, fs_jpim1   ! vector opt.
939               ! hydrostatic pressure gradient along s-surfaces
940               zhpiorg(ji,jj,jk) = zhpiorg(ji,jj,jk-1)                                                 &
941                  &              +  zcoef0 / e1u(ji,jj) * (  fse3t(ji+1,jj,jk  ) * rhd(ji+1,jj,jk  )   &
942                  &                                        - fse3t(ji  ,jj,jk  ) * rhd(ji  ,jj,jk  )   &
943                  &                                        + fse3t(ji+1,jj,jk-1) * rhd(ji+1,jj,jk-1)   &
944                  &                                        - fse3t(ji  ,jj,jk-1) * rhd(ji  ,jj,jk-1)  )
945               zhpjorg(ji,jj,jk) = zhpjorg(ji,jj,jk-1)                                                 &
946                  &              +  zcoef0 / e2v(ji,jj) * (  fse3t(ji,jj+1,jk  ) * rhd(ji,jj+1,jk  )   &
947                  &                                        - fse3t(ji,jj  ,jk  ) * rhd(ji,jj,  jk  )   &
948                  &                                        + fse3t(ji,jj+1,jk-1) * rhd(ji,jj+1,jk-1)   &
949                  &                                        - fse3t(ji,jj  ,jk-1) * rhd(ji,jj,  jk-1)  )
950               ! s-coordinate pressure gradient correction
951               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) )   &
952                  &            * ( fsdept(ji+1,jj  ,jk) - fsdept(ji,jj,jk) ) / e1u(ji,jj)
953               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) )   &
954                  &            * ( fsdept(ji  ,jj+1,jk) - fsdept(ji,jj,jk) ) / e2v(ji,jj)
955               ! add to the general momentum trend
956               ua(ji,jj,jk) = ua(ji,jj,jk) + zforg*( zhpiorg(ji,jj,jk) + zuap )
957               va(ji,jj,jk) = va(ji,jj,jk) + zforg*( zhpjorg(ji,jj,jk) + zvap )
958            END DO
959         END DO
960      END DO
961
962      ! compute the pressure gradients in the diagonal directions
963      DO jk = 2, jpkm1
964         DO jj = 1, jpjm1
965            DO ji = 1, fs_jpim1   ! vector opt.
966               zmskd1  = tmask(ji+1,jj+1,jk  ) * tmask(ji  ,jj,jk  )      ! level jk   mask in the 1st diagnonal
967               zmskd1m = tmask(ji+1,jj+1,jk-1) * tmask(ji  ,jj,jk-1)      ! level jk-1    "               "     
968               zmskd2  = tmask(ji  ,jj+1,jk  ) * tmask(ji+1,jj,jk  )      ! level jk   mask in the 2nd diagnonal
969               zmskd2m = tmask(ji  ,jj+1,jk-1) * tmask(ji+1,jj,jk-1)      ! level jk-1    "               "     
970               ! hydrostatic pressure gradient along s-surfaces
971               zhpitra(ji,jj,jk) = zhpitra(ji,jj,jk-1)                                                       &
972                  &              + zdistr(ji,jj) * zmskd1  * ( fse3t(ji+1,jj+1,jk  ) * rhd(ji+1,jj+1,jk)     &
973                  &                                           -fse3t(ji  ,jj  ,jk  ) * rhd(ji  ,jj  ,jk) )   &
974                  &              + zdistr(ji,jj) * zmskd1m * ( fse3t(ji+1,jj+1,jk-1) * rhd(ji+1,jj+1,jk-1)   &
975                  &                                           -fse3t(ji  ,jj  ,jk-1) * rhd(ji  ,jj  ,jk-1) )
976               zhpjtra(ji,jj,jk) = zhpjtra(ji,jj,jk-1)                                                       &
977                  &              + zdistr(ji,jj) * zmskd2  * ( fse3t(ji  ,jj+1,jk  ) * rhd(ji  ,jj+1,jk)     &
978                  &                                           -fse3t(ji+1,jj  ,jk  ) * rhd(ji+1,jj,  jk) )   &
979                  &              + zdistr(ji,jj) * zmskd2m * ( fse3t(ji  ,jj+1,jk-1) * rhd(ji  ,jj+1,jk-1)   &
980                  &                                           -fse3t(ji+1,jj  ,jk-1) * rhd(ji+1,jj,  jk-1) )
981               ! s-coordinate pressure gradient correction
982               zuap = - zdistr(ji,jj) * zmskd1 * ( rhd   (ji+1,jj+1,jk) + rhd   (ji  ,jj,jk) )   &
983                  &                            * ( fsdept(ji+1,jj+1,jk) - fsdept(ji  ,jj,jk) )
984               zvap = - zdistr(ji,jj) * zmskd2 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji+1,jj,jk) )   &
985                  &                            * ( fsdept(ji  ,jj+1,jk) - fsdept(ji+1,jj,jk) )
986               ! back rotation
987               zhpine(ji,jj,jk) = zcosa(ji,jj) * ( zhpitra(ji,jj,jk) + zuap )   &
988                  &             - zsina(ji,jj) * ( zhpjtra(ji,jj,jk) + zvap )
989               zhpjne(ji,jj,jk) = zsina(ji,jj) * ( zhpitra(ji,jj,jk) + zuap )   &
990                  &             + zcosa(ji,jj) * ( zhpjtra(ji,jj,jk) + zvap )
991            END DO
992         END DO
993      END DO
994
995      ! interpolate and add to the general trend
996      DO jk = 2, jpkm1
997         DO jj = 2, jpjm1
998            DO ji = fs_2, fs_jpim1   ! vector opt.
999               ! averaging
1000               zhpirot(ji,jj,jk) = 0.5 * ( zhpine(ji,jj,jk) + zhpine(ji  ,jj-1,jk) )
1001               zhpjrot(ji,jj,jk) = 0.5 * ( zhpjne(ji,jj,jk) + zhpjne(ji-1,jj  ,jk) )
1002               ! add to the general momentum trend
1003               ua(ji,jj,jk) = ua(ji,jj,jk) + zfrot * zhpirot(ji,jj,jk) 
1004               va(ji,jj,jk) = va(ji,jj,jk) + zfrot * zhpjrot(ji,jj,jk) 
1005            END DO
1006         END DO
1007      END DO
1008      !
1009   END SUBROUTINE hpg_rot
1010
1011   !!======================================================================
1012END MODULE dynhpg
Note: See TracBrowser for help on using the repository browser.