New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in trunk/NEMO/OPA_SRC/DYN – NEMO

source: trunk/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 746

Last change on this file since 746 was 719, checked in by ctlod, 17 years ago

get back to the nemo_v2_3 version for trunk
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 52.7 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  1.0  !  87-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  91-11  (G. Madec)
8   !!            7.0  !  96-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  97-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  02-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  02-08  (A. Bozec)  hpg_zps: Original code
12   !!            9.0  !  05-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                           Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!            9.0  !  05-11  (G. Madec) style & small optimisation
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   dyn_hpg      : update the momentum trend with the now horizontal
19   !!                  gradient of the hydrostatic pressure
20   !!                  default case : k-j-i loops (vector opt. available)
21   !!       hpg_ctl  : initialisation and control of options
22   !!       hpg_zco  : z-coordinate scheme
23   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
24   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
25   !!       hpg_hel  : s-coordinate (helsinki modification)
26   !!       hpg_wdj  : s-coordinate (weighted density jacobian)
27   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
28   !!       hpg_rot  : s-coordinate (ROTated axes scheme)
29   !!----------------------------------------------------------------------
30   USE oce             ! ocean dynamics and tracers
31   USE dom_oce         ! ocean space and time domain
32   USE dynhpg_jki      !
33   USE phycst          ! physical constants
34   USE in_out_manager  ! I/O manager
35   USE trdmod          ! ocean dynamics trends
36   USE trdmod_oce      ! ocean variables trends
37   USE prtctl          ! Print control
38   USE lbclnk          ! lateral boundary condition
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   dyn_hpg    ! routine called by step module
44
45#if defined key_mpp_omp
46   !!----------------------------------------------------------------------
47   !!   'key_mpp_omp' :                                 j-k-i loop (j-slab)
48   !!----------------------------------------------------------------------
49   LOGICAL, PUBLIC, PARAMETER ::   lk_dynhpg_jki = .TRUE.    !: OpenMP hpg flag
50   LOGICAL, PUBLIC, PARAMETER ::   lk_dynhpg     = .FALSE.   !: vector hpg flag
51#else
52   !!----------------------------------------------------------------------
53   !!   default case :                             k-j-i loop (vector opt.)
54   !!----------------------------------------------------------------------   
55   LOGICAL, PUBLIC, PARAMETER ::   lk_dynhpg_jki = .FALSE.   !: OpenMP hpg flag
56   LOGICAL, PUBLIC, PARAMETER ::   lk_dynhpg     = .TRUE.    !: vector hpg flag
57#endif
58
59   !!* Namelist nam_dynhpg : Choice of horizontal pressure gradient computation
60   LOGICAL  ::   ln_hpg_zco = .TRUE.    ! z-coordinate - full steps
61   LOGICAL  ::   ln_hpg_zps = .FALSE.   ! z-coordinate - partial steps (interpolation)
62   LOGICAL  ::   ln_hpg_sco = .FALSE.   ! s-coordinate (standard jacobian formulation)
63   LOGICAL  ::   ln_hpg_hel = .FALSE.   ! s-coordinate (helsinki modification)
64   LOGICAL  ::   ln_hpg_wdj = .FALSE.   ! s-coordinate (weighted density jacobian)
65   LOGICAL  ::   ln_hpg_djc = .FALSE.   ! s-coordinate (Density Jacobian with Cubic polynomial)
66   LOGICAL  ::   ln_hpg_rot = .FALSE.   ! s-coordinate (ROTated axes scheme)
67   REAL(wp) ::   gamm       = 0.e0      ! weighting coefficient
68
69   INTEGER  ::   nhpg  =  0             ! = 0 to 6, type of pressure gradient scheme used
70      !                                 ! (deduced from ln_hpg_... flags)
71
72   !! * Substitutions
73#  include "domzgr_substitute.h90"
74#  include "vectopt_loop_substitute.h90"
75   !!----------------------------------------------------------------------
76   !!   OPA 9.0 , LOCEAN-IPSL (2005)
77   !! $Header$
78   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
79   !!----------------------------------------------------------------------
80
81CONTAINS
82
83   SUBROUTINE dyn_hpg( kt )
84      !!---------------------------------------------------------------------
85      !!                  ***  ROUTINE dyn_hpg  ***
86      !!
87      !! ** Method  :   Call the hydrostatic pressure gradient routine
88      !!              using the scheme defined in the namelist
89      !!   
90      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
91      !!             - Save the trend (l_trddyn=T)
92      !!----------------------------------------------------------------------
93      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
94      !!
95      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ztrdu, ztrdv   ! 3D temporary workspace
96      !!----------------------------------------------------------------------
97   
98      IF( kt == nit000 )   CALL hpg_ctl      ! initialisation & control of options
99
100      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
101         ztrdu(:,:,:) = ua(:,:,:) 
102         ztrdv(:,:,:) = va(:,:,:) 
103      ENDIF     
104
105      SELECT CASE ( nhpg )      ! Hydrastatic pressure gradient computation
106      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
107      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
108      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
109      CASE (  3 )   ;   CALL hpg_hel    ( kt )      ! s-coordinate (helsinki modification)
110      CASE (  4 )   ;   CALL hpg_wdj    ( kt )      ! s-coordinate (weighted density jacobian)
111      CASE (  5 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
112      CASE (  6 )   ;   CALL hpg_rot    ( kt )      ! s-coordinate (ROTated axes scheme)
113      CASE ( 10 )   ;   CALL hpg_zco_jki( kt )      ! z-coordinate (k-j-i)
114      CASE ( 11 )   ;   CALL hpg_zps_jki( kt )      ! z-coordinate plus partial steps (interpolation) (k-j-i)
115      CASE ( 12 )   ;   CALL hpg_sco_jki( kt )      ! s-coordinate (standard jacobian formulation) (k-j-i)
116      END SELECT
117
118      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
119         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
120         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
121         CALL trd_mod( ztrdu, ztrdv, jpdyn_trd_hpg, 'DYN', kt )
122      ENDIF         
123      !
124      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
125         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
126      !
127   END SUBROUTINE dyn_hpg
128
129
130   SUBROUTINE hpg_ctl
131      !!----------------------------------------------------------------------
132      !!                 ***  ROUTINE hpg_ctl  ***
133      !!
134      !! ** Purpose :   initializations for the hydrostatic pressure gradient
135      !!              computation and consistency control
136      !!
137      !! ** Action  :   Read the namelist namdynhpg and check the consistency
138      !!      with the type of vertical coordinate used (zco, zps, sco)
139      !!----------------------------------------------------------------------
140      INTEGER ::   ioptio = 0      ! temporary integer
141
142      NAMELIST/nam_dynhpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco, ln_hpg_hel,   &
143         &                 ln_hpg_wdj, ln_hpg_djc, ln_hpg_rot, gamm
144      !!----------------------------------------------------------------------
145
146      REWIND ( numnam )               ! Read Namelist nam_dynhpg : pressure gradient calculation options
147      READ   ( numnam, nam_dynhpg )
148
149      IF(lwp) THEN                    ! Control print
150         WRITE(numout,*)
151         WRITE(numout,*) 'dyn:hpg_ctl : hydrostatic pressure gradient control'
152         WRITE(numout,*) '~~~~~~~~~~~'
153         WRITE(numout,*) '       Namelist nam_dynhpg : choice of hpg scheme'
154         WRITE(numout,*) '          z-coord. - full steps                          ln_hpg_zco = ', ln_hpg_zco
155         WRITE(numout,*) '          z-coord. - partial steps (interpolation)       ln_hpg_zps = ', ln_hpg_zps
156         WRITE(numout,*) '          s-coord. (standard jacobian formulation)       ln_hpg_sco = ', ln_hpg_sco
157         WRITE(numout,*) '          s-coord. (helsinki modification)               ln_hpg_hel = ', ln_hpg_hel
158         WRITE(numout,*) '          s-coord. (weighted density jacobian)           ln_hpg_wdj = ', ln_hpg_wdj
159         WRITE(numout,*) '          s-coord. (Density Jacobian: Cubic polynomial)  ln_hpg_djc = ', ln_hpg_djc
160         WRITE(numout,*) '          s-coord. (ROTated axes scheme)                 ln_hpg_rot = ', ln_hpg_rot
161         WRITE(numout,*) '          weighting coeff. (wdj scheme)                     gamm       = ', gamm
162      ENDIF
163
164      IF( lk_vvl .AND. .NOT. ln_hpg_sco )   THEN
165         CALL ctl_stop( 'hpg_ctl : variable volume key_vvl compatible only with the standard jacobian formulation hpg_sco')
166      ENDIF
167
168      !                               ! Set nhpg from ln_hpg_... flags
169      IF( ln_hpg_zco )   nhpg = 0
170      IF( ln_hpg_zps )   nhpg = 1
171      IF( ln_hpg_sco )   nhpg = 2
172      IF( ln_hpg_hel )   nhpg = 3
173      IF( ln_hpg_wdj )   nhpg = 4
174      IF( ln_hpg_djc )   nhpg = 5
175      IF( ln_hpg_rot )   nhpg = 6
176
177      !                               ! Consitency check
178      ioptio = 0 
179      IF( ln_hpg_zco )   ioptio = ioptio + 1
180      IF( ln_hpg_zps )   ioptio = ioptio + 1
181      IF( ln_hpg_sco )   ioptio = ioptio + 1
182      IF( ln_hpg_hel )   ioptio = ioptio + 1
183      IF( ln_hpg_wdj )   ioptio = ioptio + 1
184      IF( ln_hpg_djc )   ioptio = ioptio + 1
185      IF( ln_hpg_rot )   ioptio = ioptio + 1
186      IF ( ioptio /= 1 )   CALL ctl_stop( ' NO or several hydrostatic pressure gradient options used' )
187
188      IF( lk_dynhpg_jki ) THEN
189         nhpg = nhpg + 10
190         IF(lwp) WRITE(numout,*)
191         IF(lwp) WRITE(numout,*) '          Autotasking or OPENMP: use j-k-i loops (i.e. _jki routines)'
192      ENDIF
193      !
194   END SUBROUTINE hpg_ctl
195
196
197   SUBROUTINE hpg_zco( kt )
198      !!---------------------------------------------------------------------
199      !!                  ***  ROUTINE hpg_zco  ***
200      !!
201      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
202      !!      The now hydrostatic pressure gradient at a given level, jk,
203      !!      is computed by taking the vertical integral of the in-situ
204      !!      density gradient along the model level from the suface to that
205      !!      level:    zhpi = grav .....
206      !!                zhpj = grav .....
207      !!      add it to the general momentum trend (ua,va).
208      !!            ua = ua - 1/e1u * zhpi
209      !!            va = va - 1/e2v * zhpj
210      !!
211      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
212      !!----------------------------------------------------------------------
213      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
214      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
215      !!
216      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
217      !!
218      INTEGER  ::   ji, jj, jk       ! dummy loop indices
219      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
220      !!----------------------------------------------------------------------
221     
222      IF( kt == nit000 ) THEN
223         IF(lwp) WRITE(numout,*)
224         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
225         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
226      ENDIF
227     
228      ! Local constant initialization
229      zcoef0 = - grav * 0.5
230
231      ! Surface value
232      DO jj = 2, jpjm1
233         DO ji = fs_2, fs_jpim1   ! vector opt.
234            zcoef1 = zcoef0 * fse3w(ji,jj,1)
235            ! hydrostatic pressure gradient
236            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
237            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
238            ! add to the general momentum trend
239            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
240            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
241         END DO
242      END DO
243      !
244      ! interior value (2=<jk=<jpkm1)
245      DO jk = 2, jpkm1
246         DO jj = 2, jpjm1
247            DO ji = fs_2, fs_jpim1   ! vector opt.
248               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
249               ! hydrostatic pressure gradient
250               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
251                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
252                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
253
254               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
255                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
256                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
257               ! add to the general momentum trend
258               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
259               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
260            END DO
261         END DO
262      END DO
263      !
264   END SUBROUTINE hpg_zco
265
266
267   SUBROUTINE hpg_zps( kt )
268      !!---------------------------------------------------------------------
269      !!                 ***  ROUTINE hpg_zps  ***
270      !!                   
271      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
272      !!
273      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
274      !!----------------------------------------------------------------------
275      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
276      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
277      !!
278      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
279      !!
280      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
281      INTEGER  ::   iku, ikv                         ! temporary integers
282      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
283      !!----------------------------------------------------------------------
284
285      IF( kt == nit000 ) THEN
286         IF(lwp) WRITE(numout,*)
287         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
288         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
289      ENDIF
290
291      ! Local constant initialization
292      zcoef0 = - grav * 0.5
293
294      !  Surface value
295      DO jj = 2, jpjm1
296         DO ji = fs_2, fs_jpim1   ! vector opt.
297            zcoef1 = zcoef0 * fse3w(ji,jj,1)
298            ! hydrostatic pressure gradient
299            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
300            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
301            ! add to the general momentum trend
302            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
303            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
304         END DO
305      END DO
306
307      ! interior value (2=<jk=<jpkm1)
308      DO jk = 2, jpkm1
309         DO jj = 2, jpjm1
310            DO ji = fs_2, fs_jpim1   ! vector opt.
311               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
312               ! hydrostatic pressure gradient
313               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
314                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
315                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
316
317               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
318                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
319                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
320               ! add to the general momentum trend
321               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
322               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
323            END DO
324         END DO
325      END DO
326
327      ! partial steps correction at the last level  (new gradient with  intgrd.F)
328# if defined key_vectopt_loop
329         jj = 1
330         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
331# else
332      DO jj = 2, jpjm1
333         DO ji = 2, jpim1
334# endif
335            iku = MIN ( mbathy(ji,jj), mbathy(ji+1,jj) ) - 1
336            ikv = MIN ( mbathy(ji,jj), mbathy(ji,jj+1) ) - 1
337            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
338            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
339            ! on i-direction
340            IF ( iku > 2 ) THEN
341               ! subtract old value
342               ua(ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)
343               ! compute the new one
344               zhpi (ji,jj,iku) = zhpi(ji,jj,iku-1)   &
345                  + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
346               ! add the new one to the general momentum trend
347               ua(ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)
348            ENDIF
349            ! on j-direction
350            IF ( ikv > 2 ) THEN
351               ! subtract old value
352               va(ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)
353               ! compute the new one
354               zhpj (ji,jj,ikv) = zhpj(ji,jj,ikv-1)   &
355                  + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
356               ! add the new one to the general momentum trend
357               va(ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)
358            ENDIF
359# if ! defined key_vectopt_loop
360         END DO
361# endif
362      END DO
363      !
364   END SUBROUTINE hpg_zps
365
366
367   SUBROUTINE hpg_sco( kt )
368      !!---------------------------------------------------------------------
369      !!                  ***  ROUTINE hpg_sco  ***
370      !!
371      !! ** Method  :   s-coordinate case. Jacobian scheme.
372      !!      The now hydrostatic pressure gradient at a given level, jk,
373      !!      is computed by taking the vertical integral of the in-situ
374      !!      density gradient along the model level from the suface to that
375      !!      level. s-coordinates (ln_sco): a corrective term is added
376      !!      to the horizontal pressure gradient :
377      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
378      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
379      !!      add it to the general momentum trend (ua,va).
380      !!         ua = ua - 1/e1u * zhpi
381      !!         va = va - 1/e2v * zhpj
382      !!
383      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
384      !!----------------------------------------------------------------------
385      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
386      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
387      !!
388      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
389      !!
390      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
391      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
392      !!----------------------------------------------------------------------
393
394      IF( kt == nit000 ) THEN
395         IF(lwp) WRITE(numout,*)
396         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
397         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
398      ENDIF
399
400      ! Local constant initialization
401      zcoef0 = - grav * 0.5
402      ! To use density and not density anomaly
403      IF ( lk_vvl ) THEN   ;     znad = 1.            ! Variable volume
404      ELSE                 ;     znad = 0.e0          ! Fixed volume
405      ENDIF
406
407      ! Surface value
408      DO jj = 2, jpjm1
409         DO ji = fs_2, fs_jpim1   ! vector opt.   
410            ! hydrostatic pressure gradient along s-surfaces
411            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
412               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
413            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
414               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
415            ! s-coordinate pressure gradient correction
416            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2*znad )   &
417               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
418            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2*znad )   &
419               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
420            ! add to the general momentum trend
421            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
422            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
423         END DO 
424      END DO   
425           
426      ! interior value (2=<jk=<jpkm1)
427      DO jk = 2, jpkm1                                 
428         DO jj = 2, jpjm1     
429            DO ji = fs_2, fs_jpim1   ! vector opt.     
430               ! hydrostatic pressure gradient along s-surfaces
431               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   & 
432                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   & 
433                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
434               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
435                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
436                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
437               ! s-coordinate pressure gradient correction
438               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2*znad )   &
439                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
440               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2*znad )   &
441                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
442               ! add to the general momentum trend
443               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
444               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
445            END DO
446         END DO
447      END DO
448      !
449   END SUBROUTINE hpg_sco
450
451
452   SUBROUTINE hpg_hel( kt )
453      !!---------------------------------------------------------------------
454      !!                  ***  ROUTINE hpg_hel  ***
455      !!
456      !! ** Method  :   s-coordinate case.
457      !!      The now hydrostatic pressure gradient at a given level
458      !!      jk is computed by taking the vertical integral of the in-situ
459      !!      density gradient along the model level from the suface to that
460      !!      level. s-coordinates (ln_sco): a corrective term is added
461      !!      to the horizontal pressure gradient :
462      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
463      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
464      !!      add it to the general momentum trend (ua,va).
465      !!         ua = ua - 1/e1u * zhpi
466      !!         va = va - 1/e2v * zhpj
467      !!
468      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
469      !!             - Save the trend (l_trddyn=T)
470      !!----------------------------------------------------------------------
471      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
472      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
473      !!
474      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
475      !!
476      INTEGER  ::   ji, jj, jk           ! dummy loop indices
477      REAL(wp) ::   zcoef0, zuap, zvap   ! temporary scalars
478      !!----------------------------------------------------------------------
479
480      IF( kt == nit000 ) THEN
481         IF(lwp) WRITE(numout,*)
482         IF(lwp) WRITE(numout,*) 'dyn:hpg_hel : hydrostatic pressure gradient trend'
483         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, helsinki modified scheme'
484      ENDIF
485
486      ! Local constant initialization
487      zcoef0 = - grav * 0.5
488 
489      ! Surface value
490      DO jj = 2, jpjm1
491         DO ji = fs_2, fs_jpim1   ! vector opt.
492            ! hydrostatic pressure gradient along s-surfaces
493            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)  &
494               &                                  - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
495            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3t(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)  &
496               &                                  - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
497            ! s-coordinate pressure gradient correction
498            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) )   &
499               &           * ( fsdept(ji+1,jj,1) - fsdept(ji,jj,1) ) / e1u(ji,jj)
500            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) )   &
501               &           * ( fsdept(ji,jj+1,1) - fsdept(ji,jj,1) ) / e2v(ji,jj)
502            ! add to the general momentum trend
503            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
504            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
505         END DO
506      END DO
507      !
508      ! interior value (2=<jk=<jpkm1)
509      DO jk = 2, jpkm1
510         DO jj = 2, jpjm1
511            DO ji = fs_2, fs_jpim1   ! vector opt.
512               ! hydrostatic pressure gradient along s-surfaces
513               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
514                  &           +  zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj,jk  ) * rhd(ji+1,jj,jk)     &
515                  &                                     -fse3t(ji  ,jj,jk  ) * rhd(ji  ,jj,jk)   ) &
516                  &           +  zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj,jk-1) * rhd(ji+1,jj,jk-1)   &
517                  &                                     -fse3t(ji  ,jj,jk-1) * rhd(ji  ,jj,jk-1) )
518               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
519                  &           +  zcoef0 / e2v(ji,jj) * ( fse3t(ji,jj+1,jk  ) * rhd(ji,jj+1,jk)   &
520                  &                                     -fse3t(ji,jj  ,jk  ) * rhd(ji,jj,  jk)   ) &
521                  &           +  zcoef0 / e2v(ji,jj) * ( fse3t(ji,jj+1,jk-1) * rhd(ji,jj+1,jk-1) &
522                  &                                     -fse3t(ji,jj  ,jk-1) * rhd(ji,jj,  jk-1) )
523               ! s-coordinate pressure gradient correction
524               zuap = - zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )   &
525                  &            * ( fsdept(ji+1,jj,jk) - fsdept(ji,jj,jk) ) / e1u(ji,jj)
526               zvap = - zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )   &
527                  &            * ( fsdept(ji,jj+1,jk) - fsdept(ji,jj,jk) ) / e2v(ji,jj)
528               ! add to the general momentum trend
529               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
530               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
531            END DO
532         END DO
533      END DO
534      !
535   END SUBROUTINE hpg_hel
536
537
538   SUBROUTINE hpg_wdj( kt )
539      !!---------------------------------------------------------------------
540      !!                  ***  ROUTINE hpg_wdj  ***
541      !!
542      !! ** Method  :   Weighted Density Jacobian (wdj) scheme (song 1998)
543      !!      The weighting coefficients from the namelist parameter gamm
544      !!      (alpha=0.5-gamm ; beta=1-alpha=0.5+gamm)
545      !!
546      !! Reference : Song, Mon. Wea. Rev., 126, 3213-3230, 1998.
547      !!----------------------------------------------------------------------
548      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
549      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
550      !!
551      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
552      !!
553      INTEGER  ::   ji, jj, jk           ! dummy loop indices
554      REAL(wp) ::   zcoef0, zuap, zvap   ! temporary scalars
555      REAL(wp) ::   zalph , zbeta        !    "         "
556      !!----------------------------------------------------------------------
557
558      IF( kt == nit000 ) THEN
559         IF(lwp) WRITE(numout,*)
560         IF(lwp) WRITE(numout,*) 'dyn:hpg_wdj : hydrostatic pressure gradient trend'
561         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   Weighted Density Jacobian'
562      ENDIF
563
564      ! Local constant initialization
565      zcoef0 = - grav * 0.5
566      zalph  = 0.5 - gamm        ! weighting coefficients (alpha=0.5-gamm)
567      zbeta  = 0.5 + gamm        !                        (beta =1-alpha=0.5+gamm)
568
569      ! Surface value (no ponderation)
570      DO jj = 2, jpjm1
571         DO ji = fs_2, fs_jpim1   ! vector opt.
572            ! hydrostatic pressure gradient along s-surfaces
573            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * (  fse3w(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)   &
574               &                                   - fse3w(ji  ,jj  ,1) * rhd(ji  ,jj  ,1)  )
575            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * (  fse3w(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)   &
576               &                                   - fse3w(ji  ,jj  ,1) * rhd(ji,  jj  ,1)  )
577            ! s-coordinate pressure gradient correction
578            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) )   &
579               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
580            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) )   &
581               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
582            ! add to the general momentum trend
583            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
584            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
585         END DO
586      END DO
587
588      ! Interior value (2=<jk=<jpkm1) (weighted with zalph & zbeta)
589      DO jk = 2, jpkm1
590         DO jj = 2, jpjm1
591            DO ji = fs_2, fs_jpim1   ! vector opt.
592               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)                            &
593                  &           * (   (            fsde3w(ji+1,jj,jk  ) + fsde3w(ji,jj,jk  )        &
594                  &                            - fsde3w(ji+1,jj,jk-1) - fsde3w(ji,jj,jk-1)    )   &
595                  &               * (  zalph * ( rhd   (ji+1,jj,jk-1) - rhd   (ji,jj,jk-1) )      &
596                  &                  + zbeta * ( rhd   (ji+1,jj,jk  ) - rhd   (ji,jj,jk  ) )  )   &
597                  &             -   (            rhd   (ji+1,jj,jk  ) + rhd   (ji,jj,jk  )        &
598                  &                           - rhd   (ji+1,jj,jk-1) - rhd   (ji,jj,jk-1)     )   &
599                  &               * (  zalph * ( fsde3w(ji+1,jj,jk-1) - fsde3w(ji,jj,jk-1) )      &
600                  &                  + zbeta * ( fsde3w(ji+1,jj,jk  ) - fsde3w(ji,jj,jk  ) )  )  )
601               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)                            &
602                  &           * (   (           fsde3w(ji,jj+1,jk  ) + fsde3w(ji,jj,jk  )         &
603                  &                           - fsde3w(ji,jj+1,jk-1) - fsde3w(ji,jj,jk-1)     )   &
604                  &               * (  zalph * ( rhd   (ji,jj+1,jk-1) - rhd   (ji,jj,jk-1) )      &
605                  &                  + zbeta * ( rhd   (ji,jj+1,jk  ) - rhd   (ji,jj,jk  ) )  )   &
606                  &             -   (            rhd   (ji,jj+1,jk  ) + rhd   (ji,jj,jk  )        &
607                  &                            - rhd   (ji,jj+1,jk-1) - rhd   (ji,jj,jk-1)    )   &
608                  &               * (  zalph * ( fsde3w(ji,jj+1,jk-1) - fsde3w(ji,jj,jk-1) )      &
609                  &                  + zbeta * ( fsde3w(ji,jj+1,jk  ) - fsde3w(ji,jj,jk  ) )  )  )
610               ! add to the general momentum trend
611               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
612               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
613            END DO
614         END DO
615      END DO
616      !
617   END SUBROUTINE hpg_wdj
618
619
620   SUBROUTINE hpg_djc( kt )
621      !!---------------------------------------------------------------------
622      !!                  ***  ROUTINE hpg_djc  ***
623      !!
624      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
625      !!
626      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
627      !!----------------------------------------------------------------------
628      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
629      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
630      !!
631      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
632      !!
633      INTEGER  ::   ji, jj, jk          ! dummy loop indices
634      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
635      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
636      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
637      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhox, dzx, drhou, dzu, rho_i   ! 3D workspace
638      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhoy, dzy, drhov, dzv, rho_j   !  "      "
639      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhoz, dzz, drhow, dzw, rho_k   !  "      "
640      !!----------------------------------------------------------------------
641
642      IF( kt == nit000 ) THEN
643         IF(lwp) WRITE(numout,*)
644         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
645         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
646      ENDIF
647
648
649      ! Local constant initialization
650      zcoef0 = - grav * 0.5
651      z1_10  = 1.0 / 10.0
652      z1_12  = 1.0 / 12.0
653
654      !----------------------------------------------------------------------------------------
655      !  compute and store in provisional arrays elementary vertical and horizontal differences
656      !----------------------------------------------------------------------------------------
657
658!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
659
660      DO jk = 2, jpkm1
661         DO jj = 2, jpjm1
662            DO ji = fs_2, fs_jpim1   ! vector opt.
663               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
664               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
665               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
666               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
667               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
668               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
669            END DO
670         END DO
671      END DO
672
673      !-------------------------------------------------------------------------
674      ! compute harmonic averages using eq. 5.18
675      !-------------------------------------------------------------------------
676      zep = 1.e-15
677
678!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
679!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
680
681      DO jk = 2, jpkm1
682         DO jj = 2, jpjm1
683            DO ji = fs_2, fs_jpim1   ! vector opt.
684               cffw = 2.0 * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
685
686               cffu = 2.0 * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
687               cffx = 2.0 * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
688 
689               cffv = 2.0 * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
690               cffy = 2.0 * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
691
692               IF( cffw > zep) THEN
693                  drhow(ji,jj,jk) = 2.0 *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
694                     &                  / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
695               ELSE
696                  drhow(ji,jj,jk) = 0.e0
697               ENDIF
698
699               dzw(ji,jj,jk) = 2.0 *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
700                  &                / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
701
702               IF( cffu > zep ) THEN
703                  drhou(ji,jj,jk) = 2.0 *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
704                     &                  / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
705               ELSE
706                  drhou(ji,jj,jk ) = 0.e0
707               ENDIF
708
709               IF( cffx > zep ) THEN
710                  dzu(ji,jj,jk) = 2.0*dzx(ji+1,jj,jk)*dzx(ji,jj,jk)   &
711                     &            /(dzx(ji+1,jj,jk)+dzx(ji,jj,jk))
712               ELSE
713                  dzu(ji,jj,jk) = 0.e0
714               ENDIF
715
716               IF( cffv > zep ) THEN
717                  drhov(ji,jj,jk) = 2.0 *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
718                     &                  / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
719               ELSE
720                  drhov(ji,jj,jk) = 0.e0
721               ENDIF
722
723               IF( cffy > zep ) THEN
724                  dzv(ji,jj,jk) = 2.0 *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
725                     &                / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
726               ELSE
727                  dzv(ji,jj,jk) = 0.e0
728               ENDIF
729
730            END DO
731         END DO
732      END DO
733
734      !----------------------------------------------------------------------------------
735      ! apply boundary conditions at top and bottom using 5.36-5.37
736      !----------------------------------------------------------------------------------
737      drhow(:,:, 1 ) = 1.5 * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5 * drhow(:,:,  2  )
738      drhou(:,:, 1 ) = 1.5 * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5 * drhou(:,:,  2  )
739      drhov(:,:, 1 ) = 1.5 * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5 * drhov(:,:,  2  )
740
741      drhow(:,:,jpk) = 1.5 * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5 * drhow(:,:,jpkm1)
742      drhou(:,:,jpk) = 1.5 * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5 * drhou(:,:,jpkm1)
743      drhov(:,:,jpk) = 1.5 * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5 * drhov(:,:,jpkm1)
744
745
746      !--------------------------------------------------------------
747      ! Upper half of top-most grid box, compute and store
748      !-------------------------------------------------------------
749
750!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
751!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
752
753      DO jj = 2, jpjm1
754         DO ji = fs_2, fs_jpim1   ! vector opt.
755            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )            &
756               &                   * (  rhd(ji,jj,1)                                 &
757               &                     + 0.5 * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
758               &                           * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
759               &                           / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  ) 
760         END DO
761      END DO
762
763!!bug gm    : here also, simplification is possible
764!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
765
766      DO jk = 2, jpkm1
767         DO jj = 2, jpjm1
768            DO ji = fs_2, fs_jpim1   ! vector opt.
769
770               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
771                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
772                  &            - grav * z1_10 * (                                                                     &
773                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
774                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
775                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
776                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
777                  &                             )
778
779               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
780                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
781                  &            - grav* z1_10 * (                                                                      &
782                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
783                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
784                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
785                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
786                  &                            )
787
788               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
789                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
790                  &            - grav* z1_10 * (                                                                      &
791                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
792                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
793                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
794                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
795                  &                            )
796
797            END DO
798         END DO
799      END DO
800      CALL lbc_lnk(rho_k,'W',1.)
801      CALL lbc_lnk(rho_i,'U',1.)
802      CALL lbc_lnk(rho_j,'V',1.)
803
804
805      ! ---------------
806      !  Surface value
807      ! ---------------
808      DO jj = 2, jpjm1
809         DO ji = fs_2, fs_jpim1   ! vector opt.
810            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
811            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
812            ! add to the general momentum trend
813            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
814            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
815         END DO
816      END DO
817
818      ! ----------------
819      !  interior value   (2=<jk=<jpkm1)
820      ! ----------------
821      DO jk = 2, jpkm1
822         DO jj = 2, jpjm1 
823            DO ji = fs_2, fs_jpim1   ! vector opt.
824               ! hydrostatic pressure gradient along s-surfaces
825               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
826                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
827                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
828               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
829                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
830                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
831               ! add to the general momentum trend
832               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
833               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
834            END DO
835         END DO
836      END DO
837      !
838   END SUBROUTINE hpg_djc
839
840
841   SUBROUTINE hpg_rot( kt )
842      !!---------------------------------------------------------------------
843      !!                  ***  ROUTINE hpg_rot  ***
844      !!
845      !! ** Method  :   rotated axes scheme (Thiem and Berntsen 2005)
846      !!
847      !! Reference: Thiem & Berntsen, Ocean Modelling, In press, 2005.
848      !!----------------------------------------------------------------------
849      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
850      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
851      !!
852      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
853      !!
854      INTEGER  ::   ji, jj, jk          ! dummy loop indices
855      REAL(wp) ::   zforg, zcoef0, zuap, zmskd1, zmskd1m   ! temporary scalar
856      REAL(wp) ::   zfrot        , zvap, zmskd2, zmskd2m   !    "         "
857      REAL(wp), DIMENSION(jpi,jpj)     ::   zdistr, zsina, zcosa                ! 2D workspace
858      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpiorg, zhpirot, zhpitra, zhpine   ! 3D workspace
859      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpjorg, zhpjrot, zhpjtra, zhpjne   !  "      "
860      !!----------------------------------------------------------------------
861
862      IF( kt == nit000 ) THEN
863         IF(lwp) WRITE(numout,*)
864         IF(lwp) WRITE(numout,*) 'dyn:hpg_rot : hydrostatic pressure gradient trend'
865         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, rotated axes scheme used'
866      ENDIF
867
868      ! -------------------------------
869      !  Local constant initialization
870      ! -------------------------------
871      zcoef0 = - grav * 0.5
872      zforg  = 0.95e0
873      zfrot  = 1.e0 - zforg
874
875      ! inverse of the distance between 2 diagonal T-points (defined at F-point) (here zcoef0/distance)
876      zdistr(:,:) = zcoef0 / SQRT( e1f(:,:)*e1f(:,:) + e2f(:,:)*e1f(:,:) )
877
878      ! sinus and cosinus of diagonal angle at F-point
879      zsina(:,:) = ATAN2( e2f(:,:), e1f(:,:) )
880      zcosa(:,:) = COS( zsina(:,:) )
881      zsina(:,:) = SIN( zsina(:,:) )
882
883      ! ---------------
884      !  Surface value
885      ! ---------------
886      ! compute and add to the general trend the pressure gradients along the axes
887      DO jj = 2, jpjm1
888         DO ji = fs_2, fs_jpim1   ! vector opt.
889            ! hydrostatic pressure gradient along s-surfaces
890            zhpiorg(ji,jj,1) = zcoef0 / e1u(ji,jj) * (  fse3t(ji+1,jj,1) * rhd(ji+1,jj,1)   &
891               &                                      - fse3t(ji  ,jj,1) * rhd(ji  ,jj,1)  )
892            zhpjorg(ji,jj,1) = zcoef0 / e2v(ji,jj) * (  fse3t(ji,jj+1,1) * rhd(ji,jj+1,1)   &
893               &                                      - fse3t(ji,jj  ,1) * rhd(ji,jj  ,1)  )
894            ! s-coordinate pressure gradient correction
895            zuap = -zcoef0 * ( rhd   (ji+1,jj  ,1) + rhd   (ji,jj,1) )   &
896               &           * ( fsdept(ji+1,jj  ,1) - fsdept(ji,jj,1) ) / e1u(ji,jj)
897            zvap = -zcoef0 * ( rhd   (ji  ,jj+1,1) + rhd   (ji,jj,1) )   &
898               &           * ( fsdept(ji  ,jj+1,1) - fsdept(ji,jj,1) ) / e2v(ji,jj)
899            ! add to the general momentum trend
900            ua(ji,jj,1) = ua(ji,jj,1) + zforg * ( zhpiorg(ji,jj,1) + zuap )
901            va(ji,jj,1) = va(ji,jj,1) + zforg * ( zhpjorg(ji,jj,1) + zvap )
902         END DO
903      END DO
904
905      ! compute the pressure gradients in the diagonal directions
906      DO jj = 1, jpjm1
907         DO ji = 1, fs_jpim1   ! vector opt.
908            zmskd1 = tmask(ji+1,jj+1,1) * tmask(ji  ,jj,1)      ! mask in the 1st diagnonal
909            zmskd2 = tmask(ji  ,jj+1,1) * tmask(ji+1,jj,1)      ! mask in the 2nd diagnonal
910            ! hydrostatic pressure gradient along s-surfaces
911            zhpitra(ji,jj,1) = zdistr(ji,jj) * zmskd1 * (  fse3t(ji+1,jj+1,1) * rhd(ji+1,jj+1,1)   &
912               &                                         - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1)  )
913            zhpjtra(ji,jj,1) = zdistr(ji,jj) * zmskd2 * (  fse3t(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)   &
914               &                                         - fse3t(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)  )
915            ! s-coordinate pressure gradient correction
916            zuap = -zdistr(ji,jj) * zmskd1 * ( rhd   (ji+1,jj+1,1) + rhd   (ji  ,jj,1) )   &
917               &                           * ( fsdept(ji+1,jj+1,1) - fsdept(ji  ,jj,1) )
918            zvap = -zdistr(ji,jj) * zmskd2 * ( rhd   (ji  ,jj+1,1) + rhd   (ji+1,jj,1) )   &
919               &                           * ( fsdept(ji  ,jj+1,1) - fsdept(ji+1,jj,1) )
920            ! back rotation
921            zhpine(ji,jj,1) = zcosa(ji,jj) * ( zhpitra(ji,jj,1) + zuap )   &
922               &            - zsina(ji,jj) * ( zhpjtra(ji,jj,1) + zvap )
923            zhpjne(ji,jj,1) = zsina(ji,jj) * ( zhpitra(ji,jj,1) + zuap )   &
924               &            + zcosa(ji,jj) * ( zhpjtra(ji,jj,1) + zvap )
925         END DO
926      END DO
927
928      ! interpolate and add to the general trend the diagonal gradient
929      DO jj = 2, jpjm1
930         DO ji = fs_2, fs_jpim1   ! vector opt.
931            ! averaging
932            zhpirot(ji,jj,1) = 0.5 * ( zhpine(ji,jj,1) + zhpine(ji  ,jj-1,1) )
933            zhpjrot(ji,jj,1) = 0.5 * ( zhpjne(ji,jj,1) + zhpjne(ji-1,jj  ,1) )
934            ! add to the general momentum trend
935            ua(ji,jj,1) = ua(ji,jj,1) + zfrot * zhpirot(ji,jj,1) 
936            va(ji,jj,1) = va(ji,jj,1) + zfrot * zhpjrot(ji,jj,1) 
937         END DO
938      END DO
939
940      ! -----------------
941      ! 2. interior value (2=<jk=<jpkm1)
942      ! -----------------
943      ! compute and add to the general trend the pressure gradients along the axes
944      DO jk = 2, jpkm1
945         DO jj = 2, jpjm1
946            DO ji = fs_2, fs_jpim1   ! vector opt.
947               ! hydrostatic pressure gradient along s-surfaces
948               zhpiorg(ji,jj,jk) = zhpiorg(ji,jj,jk-1)                                                 &
949                  &              +  zcoef0 / e1u(ji,jj) * (  fse3t(ji+1,jj,jk  ) * rhd(ji+1,jj,jk  )   &
950                  &                                        - fse3t(ji  ,jj,jk  ) * rhd(ji  ,jj,jk  )   &
951                  &                                        + fse3t(ji+1,jj,jk-1) * rhd(ji+1,jj,jk-1)   &
952                  &                                        - fse3t(ji  ,jj,jk-1) * rhd(ji  ,jj,jk-1)  )
953               zhpjorg(ji,jj,jk) = zhpjorg(ji,jj,jk-1)                                                 &
954                  &              +  zcoef0 / e2v(ji,jj) * (  fse3t(ji,jj+1,jk  ) * rhd(ji,jj+1,jk  )   &
955                  &                                        - fse3t(ji,jj  ,jk  ) * rhd(ji,jj,  jk  )   &
956                  &                                        + fse3t(ji,jj+1,jk-1) * rhd(ji,jj+1,jk-1)   &
957                  &                                        - fse3t(ji,jj  ,jk-1) * rhd(ji,jj,  jk-1)  )
958               ! s-coordinate pressure gradient correction
959               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) )   &
960                  &            * ( fsdept(ji+1,jj  ,jk) - fsdept(ji,jj,jk) ) / e1u(ji,jj)
961               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) )   &
962                  &            * ( fsdept(ji  ,jj+1,jk) - fsdept(ji,jj,jk) ) / e2v(ji,jj)
963               ! add to the general momentum trend
964               ua(ji,jj,jk) = ua(ji,jj,jk) + zforg*( zhpiorg(ji,jj,jk) + zuap )
965               va(ji,jj,jk) = va(ji,jj,jk) + zforg*( zhpjorg(ji,jj,jk) + zvap )
966            END DO
967         END DO
968      END DO
969
970      ! compute the pressure gradients in the diagonal directions
971      DO jk = 2, jpkm1
972         DO jj = 1, jpjm1
973            DO ji = 1, fs_jpim1   ! vector opt.
974               zmskd1  = tmask(ji+1,jj+1,jk  ) * tmask(ji  ,jj,jk  )      ! level jk   mask in the 1st diagnonal
975               zmskd1m = tmask(ji+1,jj+1,jk-1) * tmask(ji  ,jj,jk-1)      ! level jk-1    "               "     
976               zmskd2  = tmask(ji  ,jj+1,jk  ) * tmask(ji+1,jj,jk  )      ! level jk   mask in the 2nd diagnonal
977               zmskd2m = tmask(ji  ,jj+1,jk-1) * tmask(ji+1,jj,jk-1)      ! level jk-1    "               "     
978               ! hydrostatic pressure gradient along s-surfaces
979               zhpitra(ji,jj,jk) = zhpitra(ji,jj,jk-1)                                                       &
980                  &              + zdistr(ji,jj) * zmskd1  * ( fse3t(ji+1,jj+1,jk  ) * rhd(ji+1,jj+1,jk)     &
981                  &                                           -fse3t(ji  ,jj  ,jk  ) * rhd(ji  ,jj  ,jk) )   &
982                  &              + zdistr(ji,jj) * zmskd1m * ( fse3t(ji+1,jj+1,jk-1) * rhd(ji+1,jj+1,jk-1)   &
983                  &                                           -fse3t(ji  ,jj  ,jk-1) * rhd(ji  ,jj  ,jk-1) )
984               zhpjtra(ji,jj,jk) = zhpjtra(ji,jj,jk-1)                                                       &
985                  &              + zdistr(ji,jj) * zmskd2  * ( fse3t(ji  ,jj+1,jk  ) * rhd(ji  ,jj+1,jk)     &
986                  &                                           -fse3t(ji+1,jj  ,jk  ) * rhd(ji+1,jj,  jk) )   &
987                  &              + zdistr(ji,jj) * zmskd2m * ( fse3t(ji  ,jj+1,jk-1) * rhd(ji  ,jj+1,jk-1)   &
988                  &                                           -fse3t(ji+1,jj  ,jk-1) * rhd(ji+1,jj,  jk-1) )
989               ! s-coordinate pressure gradient correction
990               zuap = - zdistr(ji,jj) * zmskd1 * ( rhd   (ji+1,jj+1,jk) + rhd   (ji  ,jj,jk) )   &
991                  &                            * ( fsdept(ji+1,jj+1,jk) - fsdept(ji  ,jj,jk) )
992               zvap = - zdistr(ji,jj) * zmskd2 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji+1,jj,jk) )   &
993                  &                            * ( fsdept(ji  ,jj+1,jk) - fsdept(ji+1,jj,jk) )
994               ! back rotation
995               zhpine(ji,jj,jk) = zcosa(ji,jj) * ( zhpitra(ji,jj,jk) + zuap )   &
996                  &             - zsina(ji,jj) * ( zhpjtra(ji,jj,jk) + zvap )
997               zhpjne(ji,jj,jk) = zsina(ji,jj) * ( zhpitra(ji,jj,jk) + zuap )   &
998                  &             + zcosa(ji,jj) * ( zhpjtra(ji,jj,jk) + zvap )
999            END DO
1000         END DO
1001      END DO
1002
1003      ! interpolate and add to the general trend
1004      DO jk = 2, jpkm1
1005         DO jj = 2, jpjm1
1006            DO ji = fs_2, fs_jpim1   ! vector opt.
1007               ! averaging
1008               zhpirot(ji,jj,jk) = 0.5 * ( zhpine(ji,jj,jk) + zhpine(ji  ,jj-1,jk) )
1009               zhpjrot(ji,jj,jk) = 0.5 * ( zhpjne(ji,jj,jk) + zhpjne(ji-1,jj  ,jk) )
1010               ! add to the general momentum trend
1011               ua(ji,jj,jk) = ua(ji,jj,jk) + zfrot * zhpirot(ji,jj,jk) 
1012               va(ji,jj,jk) = va(ji,jj,jk) + zfrot * zhpjrot(ji,jj,jk) 
1013            END DO
1014         END DO
1015      END DO
1016      !
1017   END SUBROUTINE hpg_rot
1018
1019   !!======================================================================
1020END MODULE dynhpg
Note: See TracBrowser for help on using the repository browser.