source: trunk/NEMO/OPA_SRC/DYN/dynspg_exp.F90 @ 1495

MODULE dynspg_exp
   !!======================================================================
   !!                   ***  MODULE  dynspg_exp  ***
   !! Ocean dynamics:  surface pressure gradient trend
   !!======================================================================
   !! History :  9.0  !  2005-11  (V. Garnier, G. Madec, L. Bessieres) Original code
   !!----------------------------------------------------------------------
#if defined key_dynspg_exp   ||   defined key_esopa
   !!----------------------------------------------------------------------
   !!   'key_dynspg_exp'           free sfce cst vol. without filter nor ts
   !!----------------------------------------------------------------------
   !!   dyn_spg_exp  : update the momentum trend with the surface 
   !!                      pressure gradient in the free surface constant  
   !!                      volume case with vector optimization
   !!----------------------------------------------------------------------
   USE oce             ! ocean dynamics and tracers 
   USE dom_oce         ! ocean space and time domain 
   USE sbc_oce         ! surface boundary condition: ocean
   USE obc_oce         ! Lateral open boundary condition
   USE phycst          ! physical constants
   USE obc_par         ! open boundary condition parameters
   USE obcdta          ! open boundary condition data     (obc_dta_bt routine)
   USE in_out_manager  ! I/O manager
   USE lib_mpp         ! distributed memory computing library
   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
   USE prtctl          ! Print control
   USE iom             ! I/O library
   USE restart         ! only for lrst_oce

   IMPLICIT NONE
   PRIVATE

   PUBLIC   dyn_spg_exp   ! routine called by step.F90

   !! * Substitutions
#  include "domzgr_substitute.h90"
#  include "vectopt_loop_substitute.h90"
   !!----------------------------------------------------------------------
   !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009) 
   !! $Id$
   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) 
   !!----------------------------------------------------------------------

CONTAINS

   SUBROUTINE dyn_spg_exp( kt )
      !!----------------------------------------------------------------------
      !!                  ***  routine dyn_spg_exp  ***
      !!
      !! ** Purpose :   Compute the now trend due to the surface pressure
      !!      gradient in case of explicit free surface formulation and 
      !!      add it to the general trend of momentum equation. Compute
      !!      the free surface.
      !!
      !! ** Method  :   Explicit free surface formulation. The surface pressure
      !!      gradient is given by:
      !!         spgu = 1/rau0 d/dx(ps) =  g/e1u di( sshn )
      !!         spgv = 1/rau0 d/dy(ps) =  g/e2v dj( sshn )
      !!      -1- Compute the now surface pressure gradient
      !!      -2- Add it to the general trend
      !!
      !! ** Action : - Update (ua,va) with the surf. pressure gradient trend
      !!---------------------------------------------------------------------
      INTEGER, INTENT( in )  ::   kt         ! ocean time-step index
      !!
      INTEGER  ::   ji, jj, jk               ! dummy loop indices
      !!----------------------------------------------------------------------

      IF( kt == nit000 ) THEN
         IF(lwp) WRITE(numout,*)
         IF(lwp) WRITE(numout,*) 'dyn_spg_exp : surface pressure gradient trend'
         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   (explicit free surface)'

         ! set to zero free surface specific arrays
         spgu(:,:) = 0.e0                     ! surface pressure gradient (i-direction)
         spgv(:,:) = 0.e0                     ! surface pressure gradient (j-direction)
      ENDIF

      ! read or estimate sea surface height and vertically integrated velocities
      IF( lk_obc )   CALL obc_dta_bt( kt, 0 )

      ! Surface pressure gradient (now)
      DO jj = 2, jpjm1
         DO ji = fs_2, fs_jpim1   ! vector opt.
            spgu(ji,jj) = - grav * ( sshn(ji+1,jj) - sshn(ji,jj) ) / e1u(ji,jj)
            spgv(ji,jj) = - grav * ( sshn(ji,jj+1) - sshn(ji,jj) ) / e2v(ji,jj)
         END DO
      END DO

      ! Add the surface pressure trend to the general trend
      DO jk = 1, jpkm1
         DO jj = 2, jpjm1
            DO ji = fs_2, fs_jpim1   ! vector opt.
               ua(ji,jj,jk) = ua(ji,jj,jk) + spgu(ji,jj)
               va(ji,jj,jk) = va(ji,jj,jk) + spgv(ji,jj)
            END DO
         END DO
      END DO

   END SUBROUTINE dyn_spg_exp

#else
   !!----------------------------------------------------------------------
   !!   Default case :   Empty module   No standart explicit free surface 
   !!----------------------------------------------------------------------
CONTAINS
   SUBROUTINE dyn_spg_exp( kt )       ! Empty routine
      WRITE(*,*) 'dyn_spg_exp: You should not have seen this print! error?', kt
   END SUBROUTINE dyn_spg_exp
#endif

   !!======================================================================
END MODULE dynspg_exp