1 | MODULE dynzdf_exp |
---|
2 | !!============================================================================== |
---|
3 | !! *** MODULE dynzdf_exp *** |
---|
4 | !! Ocean dynamics: vertical component(s) of the momentum mixing trend |
---|
5 | !!============================================================================== |
---|
6 | !! History : ! 90-10 (B. Blanke) Original code |
---|
7 | !! ! 97-05 (G. Madec) vertical component of isopycnal |
---|
8 | !! 8.5 ! 02-08 (G. Madec) F90: Free form and module |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | !! dyn_zdf_exp : update the momentum trend with the vertical diffu- |
---|
13 | !! sion using an explicit time-stepping scheme. |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | !! * Modules used |
---|
16 | USE oce ! ocean dynamics and tracers |
---|
17 | USE dom_oce ! ocean space and time domain |
---|
18 | USE phycst ! physical constants |
---|
19 | USE zdf_oce ! ocean vertical physics |
---|
20 | USE sbc_oce ! surface boundary condition: ocean |
---|
21 | USE in_out_manager ! I/O manager |
---|
22 | |
---|
23 | IMPLICIT NONE |
---|
24 | PRIVATE |
---|
25 | |
---|
26 | !! * Routine accessibility |
---|
27 | PUBLIC dyn_zdf_exp ! called by step.F90 |
---|
28 | |
---|
29 | !! * Substitutions |
---|
30 | # include "domzgr_substitute.h90" |
---|
31 | # include "vectopt_loop_substitute.h90" |
---|
32 | !!---------------------------------------------------------------------- |
---|
33 | !! OPA 9.0 , LOCEAN-IPSL (2005) |
---|
34 | !! $Id$ |
---|
35 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
---|
36 | !!---------------------------------------------------------------------- |
---|
37 | |
---|
38 | CONTAINS |
---|
39 | |
---|
40 | SUBROUTINE dyn_zdf_exp( kt, p2dt ) |
---|
41 | !!---------------------------------------------------------------------- |
---|
42 | !! *** ROUTINE dyn_zdf_exp *** |
---|
43 | !! |
---|
44 | !! ** Purpose : Compute the trend due to the vert. momentum diffusion |
---|
45 | !! |
---|
46 | !! ** Method : Explicit forward time stepping with a time splitting |
---|
47 | !! technique. The vertical diffusion of momentum is given by: |
---|
48 | !! diffu = dz( avmu dz(u) ) = 1/e3u dk+1( avmu/e3uw dk(ub) ) |
---|
49 | !! Surface boundary conditions: wind stress input |
---|
50 | !! Bottom boundary conditions : bottom stress (cf zdfbfr.F90) |
---|
51 | !! Add this trend to the general trend ua : |
---|
52 | !! ua = ua + dz( avmu dz(u) ) |
---|
53 | !! |
---|
54 | !! ** Action : - Update (ua,va) with the vertical diffusive trend |
---|
55 | !!--------------------------------------------------------------------- |
---|
56 | !! * Arguments |
---|
57 | INTEGER , INTENT( in ) :: kt ! ocean time-step index |
---|
58 | REAL(wp), INTENT( in ) :: p2dt ! time-step |
---|
59 | |
---|
60 | !! * Local declarations |
---|
61 | INTEGER :: ji, jj, jk, jl ! dummy loop indices |
---|
62 | REAL(wp) :: zrau0r, zlavmr, zua, zva ! temporary scalars |
---|
63 | REAL(wp), DIMENSION(jpi,jpk) :: zwx, zwy, zwz, zww ! temporary workspace arrays |
---|
64 | !!---------------------------------------------------------------------- |
---|
65 | |
---|
66 | IF( kt == nit000 ) THEN |
---|
67 | IF(lwp) WRITE(numout,*) |
---|
68 | IF(lwp) WRITE(numout,*) 'dyn_zdf_exp : vertical momentum diffusion explicit operator' |
---|
69 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ ' |
---|
70 | ENDIF |
---|
71 | |
---|
72 | ! Local constant initialization |
---|
73 | ! ----------------------------- |
---|
74 | zrau0r = 1. / rau0 ! inverse of the reference density |
---|
75 | zlavmr = 1. / float( nn_zdfexp ) ! inverse of the number of sub time step |
---|
76 | |
---|
77 | ! ! =============== |
---|
78 | DO jj = 2, jpjm1 ! Vertical slab |
---|
79 | ! ! =============== |
---|
80 | |
---|
81 | ! Surface boundary condition |
---|
82 | DO ji = 2, jpim1 |
---|
83 | zwy(ji,1) = utau(ji,jj) * zrau0r |
---|
84 | zww(ji,1) = vtau(ji,jj) * zrau0r |
---|
85 | END DO |
---|
86 | |
---|
87 | ! Initialization of x, z and contingently trends array |
---|
88 | DO jk = 1, jpk |
---|
89 | DO ji = 2, jpim1 |
---|
90 | zwx(ji,jk) = ub(ji,jj,jk) |
---|
91 | zwz(ji,jk) = vb(ji,jj,jk) |
---|
92 | END DO |
---|
93 | END DO |
---|
94 | |
---|
95 | ! Time splitting loop |
---|
96 | DO jl = 1, nn_zdfexp |
---|
97 | |
---|
98 | ! First vertical derivative |
---|
99 | DO jk = 2, jpk |
---|
100 | DO ji = 2, jpim1 |
---|
101 | zwy(ji,jk) = avmu(ji,jj,jk) * ( zwx(ji,jk-1) - zwx(ji,jk) ) / fse3uw(ji,jj,jk) |
---|
102 | zww(ji,jk) = avmv(ji,jj,jk) * ( zwz(ji,jk-1) - zwz(ji,jk) ) / fse3vw(ji,jj,jk) |
---|
103 | END DO |
---|
104 | END DO |
---|
105 | |
---|
106 | ! Second vertical derivative and trend estimation at kt+l*rdt/nn_zdfexp |
---|
107 | DO jk = 1, jpkm1 |
---|
108 | DO ji = 2, jpim1 |
---|
109 | zua = zlavmr*( zwy(ji,jk) - zwy(ji,jk+1) ) / fse3u(ji,jj,jk) |
---|
110 | zva = zlavmr*( zww(ji,jk) - zww(ji,jk+1) ) / fse3v(ji,jj,jk) |
---|
111 | ua(ji,jj,jk) = ua(ji,jj,jk) + zua |
---|
112 | va(ji,jj,jk) = va(ji,jj,jk) + zva |
---|
113 | |
---|
114 | zwx(ji,jk) = zwx(ji,jk) + p2dt*zua*umask(ji,jj,jk) |
---|
115 | zwz(ji,jk) = zwz(ji,jk) + p2dt*zva*vmask(ji,jj,jk) |
---|
116 | END DO |
---|
117 | END DO |
---|
118 | |
---|
119 | END DO |
---|
120 | |
---|
121 | ! ! =============== |
---|
122 | END DO ! End of slab |
---|
123 | ! ! =============== |
---|
124 | |
---|
125 | END SUBROUTINE dyn_zdf_exp |
---|
126 | |
---|
127 | !!============================================================================== |
---|
128 | END MODULE dynzdf_exp |
---|