New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iom.F90 in trunk/NEMO/OPA_SRC/IOM – NEMO

source: trunk/NEMO/OPA_SRC/IOM/iom.F90 @ 1359

Last change on this file since 1359 was 1359, checked in by smasson, 15 years ago

first implementation of iom_put, see ticket:387
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 50.7 KB
Line 
1MODULE iom
2   !!=====================================================================
3   !!                    ***  MODULE  iom ***
4   !! Input/Output manager :  Library to read input files
5   !!====================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!             "   ! 07 07  (D. Storkey) Changes to iom_gettime
9   !!--------------------------------------------------------------------
10   !!gm  caution add !DIR nec: improved performance to be checked as well as no result changes
11
12   !!--------------------------------------------------------------------
13   !!   iom_open       : open a file read only
14   !!   iom_close      : close a file or all files opened by iom
15   !!   iom_get        : read a field (interfaced to several routines)
16   !!   iom_gettime    : read the time axis cdvar in the file
17   !!   iom_varid      : get the id of a variable in a file
18   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
19   !!--------------------------------------------------------------------
20   USE in_out_manager  ! I/O manager
21   USE dom_oce         ! ocean space and time domain
22   USE lbclnk          ! lateal boundary condition / mpp exchanges
23   USE iom_def         ! iom variables definitions
24   USE iom_ioipsl      ! NetCDF format with IOIPSL library
25   USE iom_nf90        ! NetCDF format with native NetCDF library
26   USE iom_rstdimg     ! restarts access direct format "dimg" style...
27
28#if defined key_ioserver
29   USE mod_event_client
30# endif
31
32   IMPLICIT NONE
33   PUBLIC   !   must be public to be able to access iom_def through iom
34   
35   PUBLIC iom_init, iom_open, iom_close, iom_setkt, iom_varid, iom_get, iom_gettime, iom_rstput, iom_put
36
37   PRIVATE iom_rp0d, iom_rp1d, iom_rp2d, iom_rp3d
38   PRIVATE iom_g0d, iom_g1d, iom_g2d, iom_g3d, iom_get_123d
39   PRIVATE iom_p2d, iom_p3d
40#if defined key_ioserver
41   PRIVATE iom_init_chkcpp
42   PRIVATE set_grid
43# endif
44
45   INTERFACE iom_get
46      MODULE PROCEDURE iom_g0d, iom_g1d, iom_g2d, iom_g3d
47   END INTERFACE
48   INTERFACE iom_rstput
49      MODULE PROCEDURE iom_rp0d, iom_rp1d, iom_rp2d, iom_rp3d
50   END INTERFACE
51  INTERFACE iom_put
52     MODULE PROCEDURE iom_p2d, iom_p3d
53  END INTERFACE
54#if defined key_ioserver
55   INTERFACE iom_setkt
56      MODULE PROCEDURE event__set_timestep
57   END INTERFACE
58# endif
59
60   !!----------------------------------------------------------------------
61   !!  OPA 9.0 , LOCEAN-IPSL (2006)
62   !! $Id$
63   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
64   !!----------------------------------------------------------------------
65
66CONTAINS
67
68   SUBROUTINE iom_init( pjulian )
69      !!----------------------------------------------------------------------
70      !!                     ***  ROUTINE   ***
71      !!
72      !! ** Purpose :   
73      !!
74      !!----------------------------------------------------------------------
75      REAL(wp), INTENT(in) ::  pjulian   !: julian day at nit000 = 0
76#if defined key_ioserver
77      !!----------------------------------------------------------------------
78      ! read the xml file
79      CALL event__parse_xml_file( 'iodef.xml' )   ! <- to get from the nameliste (namrun)...
80
81      ! calendar parameters
82      CALL event__set_time_parameters( nit000 - 1, pjulian, rdt )
83
84      ! horizontal grid definition
85      CALL set_grid( "grid_T", glamt, gphit )
86      CALL set_grid( "grid_U", glamu, gphiu )
87      CALL set_grid( "grid_V", glamv, gphiv )
88      CALL set_grid( "grid_W", glamt, gphit )
89
90      ! vertical grid definition
91      CALL event__set_vert_axis( "deptht", gdept_0 )
92      CALL event__set_vert_axis( "depthu", gdept_0 )
93      CALL event__set_vert_axis( "depthv", gdept_0 )
94      CALL event__set_vert_axis( "depthw", gdepw_0 )
95
96      ! consistency regarding CPP keys...
97      CALL iom_init_chkcpp
98
99      ! end file definition
100      CALL event__close_io_definition
101#endif
102
103   END SUBROUTINE iom_init
104
105
106   SUBROUTINE iom_open( cdname, kiomid, ldwrt, kdom, kiolib, ldstop, ldiof )
107      !!---------------------------------------------------------------------
108      !!                   ***  SUBROUTINE  iom_open  ***
109      !!
110      !! ** Purpose :  open an input file (return 0 if not found)
111      !!---------------------------------------------------------------------
112      CHARACTER(len=*), INTENT(in   )           ::   cdname   ! File name
113      INTEGER         , INTENT(  out)           ::   kiomid   ! iom identifier of the opened file
114      LOGICAL         , INTENT(in   ), OPTIONAL ::   ldwrt    ! open in write modeb          (default = .FALSE.)
115      INTEGER         , INTENT(in   ), OPTIONAL ::   kdom     ! Type of domain to be written (default = jpdom_local_noovlap)
116      INTEGER         , INTENT(in   ), OPTIONAL ::   kiolib   ! library used to open the file (default = jpnf90)
117      LOGICAL         , INTENT(in   ), OPTIONAL ::   ldstop   ! stop if open to read a non-existing file (default = .TRUE.)
118      LOGICAL         , INTENT(in   ), OPTIONAL ::   ldiof    ! Interp On the Fly, needed for AGRIF (default = .FALSE.)
119
120      CHARACTER(LEN=100)    ::   clname    ! the name of the file based on cdname [[+clcpu]+clcpu]
121      CHARACTER(LEN=100)    ::   cltmpn    ! tempory name to store clname (in writting mode)
122      CHARACTER(LEN=10)     ::   clsuffix  ! ".nc" or ".dimg"
123      CHARACTER(LEN=15)     ::   clcpu     ! the cpu number (max jpmax_digits digits)
124      CHARACTER(LEN=100)    ::   clinfo    ! info character
125      LOGICAL               ::   llok      ! check the existence
126      LOGICAL               ::   llwrt     ! local definition of ldwrt
127      LOGICAL               ::   llnoov    ! local definition to read overlap
128      LOGICAL               ::   llstop    ! local definition of ldstop
129      LOGICAL               ::   lliof     ! local definition of ldiof
130      INTEGER               ::   iolib     ! library do we use to open the file
131      INTEGER               ::   icnt      ! counter for digits in clcpu (max = jpmax_digits)
132      INTEGER               ::   iln, ils  ! lengths of character
133      INTEGER               ::   idom      ! type of domain
134      INTEGER               ::   istop     !
135      INTEGER, DIMENSION(2,5) ::   idompar ! domain parameters:
136      ! local number of points for x,y dimensions
137      ! position of first local point for x,y dimensions
138      ! position of last local point for x,y dimensions
139      ! start halo size for x,y dimensions
140      ! end halo size for x,y dimensions
141      !---------------------------------------------------------------------
142      ! Initializations and control
143      ! =============
144      kiomid = -1
145      clinfo = '                    iom_open ~~~  '
146      istop = nstop
147      ! if iom_open is called for the first time: initialize iom_file(:)%nfid to 0
148      ! (could be done when defining iom_file in f95 but not in f90)
149      IF( iom_open_init == 0 ) THEN
150         iom_file(:)%nfid = 0
151         iom_open_init = 1
152      ENDIF
153      ! do we read or write the file?
154      IF( PRESENT(ldwrt) ) THEN   ;   llwrt = ldwrt
155      ELSE                        ;   llwrt = .FALSE.
156      ENDIF
157      ! do we call ctl_stop if we try to open a non-existing file in read mode?
158      IF( PRESENT(ldstop) ) THEN   ;   llstop = ldstop
159      ELSE                         ;   llstop = .TRUE.
160      ENDIF
161      ! what library do we use to open the file?
162      IF( PRESENT(kiolib) ) THEN   ;   iolib = kiolib
163      ELSE                         ;   iolib = jpnf90
164      ENDIF
165      ! are we using interpolation on the fly?
166      IF( PRESENT(ldiof) ) THEN   ;   lliof = ldiof
167      ELSE                        ;   lliof = .FALSE.
168      ENDIF
169      ! do we read the overlap
170      ! ugly patch SM+JMM+RB to overwrite global definition in some cases
171      llnoov = (jpni * jpnj ) == jpnij .AND. .NOT. lk_agrif 
172      ! create the file name by added, if needed, TRIM(Agrif_CFixed()) and TRIM(clsuffix)
173      ! =============
174      clname   = trim(cdname)
175#if defined key_agrif
176      IF ( .NOT. Agrif_Root() .AND. .NOT. lliof ) THEN
177         iln    = INDEX(clname,'/') 
178         cltmpn = clname(1:iln)
179         clname = clname(iln+1:LEN_TRIM(clname))
180         clname=TRIM(cltmpn)//TRIM(Agrif_CFixed())//'_'//TRIM(clname)
181      ENDIF
182#endif   
183      ! which suffix should we use?
184      SELECT CASE (iolib)
185      CASE (jpioipsl ) ;   clsuffix = '.nc'
186      CASE (jpnf90   ) ;   clsuffix = '.nc'
187      CASE (jprstdimg) ;   clsuffix = '.dimg'
188      CASE DEFAULT     ;   clsuffix = ''
189         CALL ctl_stop( TRIM(clinfo), 'accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
190      END SELECT
191      ! Add the suffix if needed
192      iln = LEN_TRIM(clname)
193      ils = LEN_TRIM(clsuffix)
194      IF( iln <= ils .OR. INDEX( TRIM(clname), TRIM(clsuffix), back = .TRUE. ) /= iln - ils + 1 )   &
195         &   clname = TRIM(clname)//TRIM(clsuffix)
196      cltmpn = clname   ! store this name
197      ! try to find if the file to be opened already exist
198      ! =============
199      INQUIRE( FILE = clname, EXIST = llok )
200      IF( .NOT.llok ) THEN
201         ! we try to add the cpu number to the name
202         IF( iolib == jprstdimg ) THEN   ;   WRITE(clcpu,*) narea
203         ELSE                            ;   WRITE(clcpu,*) narea-1
204         ENDIF
205         clcpu  = TRIM(ADJUSTL(clcpu))
206         iln = INDEX(clname,TRIM(clsuffix), back = .TRUE.)
207         clname = clname(1:iln-1)//'_'//TRIM(clcpu)//TRIM(clsuffix)
208         icnt = 0
209         INQUIRE( FILE = clname, EXIST = llok ) 
210         ! we try different formats for the cpu number by adding 0
211         DO WHILE( .NOT.llok .AND. icnt < jpmax_digits )
212            clcpu  = "0"//trim(clcpu)
213            clname = clname(1:iln-1)//'_'//TRIM(clcpu)//TRIM(clsuffix)
214            INQUIRE( FILE = clname, EXIST = llok )
215            icnt = icnt + 1
216         END DO
217      ENDIF
218      IF( llwrt ) THEN
219         ! check the domain definition
220! JMM + SM: ugly patch before getting the new version of lib_mpp)
221!         idom = jpdom_local_noovlap   ! default definition
222         IF( llnoov ) THEN   ;   idom = jpdom_local_noovlap   ! default definition
223         ELSE                ;   idom = jpdom_local_full      ! default definition
224         ENDIF
225         IF( PRESENT(kdom) )   idom = kdom
226         ! create the domain informations
227         ! =============
228         SELECT CASE (idom)
229         CASE (jpdom_local_full)
230            idompar(:,1) = (/ jpi             , jpj              /)
231            idompar(:,2) = (/ nimpp           , njmpp            /)
232            idompar(:,3) = (/ nimpp + jpi - 1 , njmpp + jpj - 1  /)
233            idompar(:,4) = (/ nldi - 1        , nldj - 1         /)
234            idompar(:,5) = (/ jpi - nlei      , jpj - nlej       /)
235         CASE (jpdom_local_noextra)
236            idompar(:,1) = (/ nlci            , nlcj             /)
237            idompar(:,2) = (/ nimpp           , njmpp            /)
238            idompar(:,3) = (/ nimpp + nlci - 1, njmpp + nlcj - 1 /)
239            idompar(:,4) = (/ nldi - 1        , nldj - 1         /)
240            idompar(:,5) = (/ nlci - nlei     , nlcj - nlej      /)
241         CASE (jpdom_local_noovlap)
242            idompar(:,1) = (/ nlei  - nldi + 1, nlej  - nldj + 1 /)
243            idompar(:,2) = (/ nimpp + nldi - 1, njmpp + nldj - 1 /)
244            idompar(:,3) = (/ nimpp + nlei - 1, njmpp + nlej - 1 /)
245            idompar(:,4) = (/ 0               , 0                /)
246            idompar(:,5) = (/ 0               , 0                /)
247         CASE DEFAULT
248            CALL ctl_stop( TRIM(clinfo), 'wrong value of kdom, only jpdom_local* cases are accepted' )
249         END SELECT
250      ENDIF
251      ! Open the NetCDF or RSTDIMG file
252      ! =============
253      ! do we have some free file identifier?
254      IF( MINVAL(iom_file(:)%nfid) /= 0 )   &
255         &   CALL ctl_stop( TRIM(clinfo), 'No more free file identifier', 'increase jpmax_files in iom_def' )
256      ! if no file was found...
257      IF( .NOT. llok ) THEN
258         IF( .NOT. llwrt ) THEN   ! we are in read mode
259            IF( llstop ) THEN   ;   CALL ctl_stop( TRIM(clinfo), 'File '//TRIM(cltmpn)//'* not found' )
260            ELSE                ;   istop = nstop + 1   ! make sure that istop /= nstop so we don't open the file
261            ENDIF
262         ELSE                     ! we are in write mode so we
263            clname = cltmpn       ! get back the file name without the cpu number
264         ENDIF
265      ENDIF
266      IF( istop == nstop ) THEN   ! no error within this routine
267         SELECT CASE (iolib)
268         CASE (jpioipsl )   ;   CALL iom_ioipsl_open(  clname, kiomid, llwrt, llok, idompar )
269         CASE (jpnf90   )   ;   CALL iom_nf90_open(    clname, kiomid, llwrt, llok, idompar )
270         CASE (jprstdimg)   ;   CALL iom_rstdimg_open( clname, kiomid, llwrt, llok, idompar )
271         CASE DEFAULT
272            CALL ctl_stop( TRIM(clinfo)//' accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
273         END SELECT
274      ENDIF
275      !
276   END SUBROUTINE iom_open
277
278
279   SUBROUTINE iom_close( kiomid )
280      !!--------------------------------------------------------------------
281      !!                   ***  SUBROUTINE  iom_close  ***
282      !!
283      !! ** Purpose : close an input file, or all files opened by iom
284      !!--------------------------------------------------------------------
285      INTEGER, INTENT(inout), OPTIONAL ::   kiomid   ! iom identifier of the file to be closed
286      !                                              ! return 0 when file is properly closed
287      !                                              ! No argument: all files opened by iom are closed
288
289      INTEGER ::   jf         ! dummy loop indices
290      INTEGER ::   i_s, i_e   ! temporary integer
291      CHARACTER(LEN=100)    ::   clinfo    ! info character
292      !---------------------------------------------------------------------
293      !
294      clinfo = '                    iom_close ~~~  '
295      IF( PRESENT(kiomid) ) THEN
296         i_s = kiomid
297         i_e = kiomid
298      ELSE
299         i_s = 1
300         i_e = jpmax_files
301#if defined key_ioserver
302         CALL event__stop_ioserver
303#endif
304      ENDIF
305
306      IF( i_s > 0 ) THEN
307         DO jf = i_s, i_e
308            IF( iom_file(jf)%nfid > 0 ) THEN
309               SELECT CASE (iom_file(jf)%iolib)
310               CASE (jpioipsl )   ;   CALL iom_ioipsl_close(  jf )
311               CASE (jpnf90   )   ;   CALL iom_nf90_close(    jf )
312               CASE (jprstdimg)   ;   CALL iom_rstdimg_close( jf )
313               CASE DEFAULT
314                  CALL ctl_stop( TRIM(clinfo)//' accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
315               END SELECT
316               iom_file(jf)%nfid       = 0          ! free the id
317               IF( PRESENT(kiomid) )   kiomid = 0   ! return 0 as id to specify that the file was closed
318               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' close file: '//TRIM(iom_file(jf)%name)//' ok'
319            ELSEIF( PRESENT(kiomid) ) THEN
320               WRITE(ctmp1,*) '--->',  kiomid
321               CALL ctl_stop( TRIM(clinfo)//' Invalid file identifier', ctmp1 )
322            ENDIF
323         END DO
324      ENDIF
325      !   
326   END SUBROUTINE iom_close
327
328
329   FUNCTION iom_varid ( kiomid, cdvar, kdimsz, ldstop ) 
330      !!-----------------------------------------------------------------------
331      !!                  ***  FUNCTION  iom_varid  ***
332      !!
333      !! ** Purpose : get the id of a variable in a file (return 0 if not found)
334      !!-----------------------------------------------------------------------
335      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
336      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
337      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of the dimensions
338      LOGICAL              , INTENT(in   ), OPTIONAL ::   ldstop   ! stop if looking for non-existing variable (default = .TRUE.)
339      !
340      INTEGER                        ::   iom_varid, iiv, i_nvd
341      LOGICAL                        ::   ll_fnd
342      CHARACTER(LEN=100)             ::   clinfo                   ! info character
343      LOGICAL                        ::   llstop                   ! local definition of ldstop
344      !!-----------------------------------------------------------------------
345      iom_varid = 0                         ! default definition
346      ! do we call ctl_stop if we look for non-existing variable?
347      IF( PRESENT(ldstop) ) THEN   ;   llstop = ldstop
348      ELSE                         ;   llstop = .TRUE.
349      ENDIF
350      !
351      IF( kiomid > 0 ) THEN
352         clinfo = 'iom_varid, file: '//trim(iom_file(kiomid)%name)//', var: '//trim(cdvar)
353         IF( iom_file(kiomid)%nfid == 0 ) THEN
354            CALL ctl_stop( trim(clinfo), 'the file is not open' )
355         ELSE
356            ll_fnd  = .FALSE.
357            iiv = 0
358            !
359            DO WHILE ( .NOT.ll_fnd .AND. iiv < iom_file(kiomid)%nvars )
360               iiv = iiv + 1
361               ll_fnd  = ( TRIM(cdvar) == TRIM(iom_file(kiomid)%cn_var(iiv)) )
362            END DO
363            !
364            IF( .NOT.ll_fnd ) THEN
365               iiv = iiv + 1
366               IF( iiv <= jpmax_vars ) THEN
367                  SELECT CASE (iom_file(kiomid)%iolib)
368                  CASE (jpioipsl )   ;   iom_varid = iom_ioipsl_varid( kiomid, cdvar, iiv, kdimsz )
369                  CASE (jpnf90   )   ;   iom_varid = iom_nf90_varid  ( kiomid, cdvar, iiv, kdimsz )
370                  CASE (jprstdimg)   ;   iom_varid = -1   ! all variables are listed in iom_file
371                  CASE DEFAULT   
372                     CALL ctl_stop( TRIM(clinfo)//' accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
373                  END SELECT
374               ELSE
375                  CALL ctl_stop( trim(clinfo), 'Too many variables in the file '//iom_file(kiomid)%name,   &
376                        &                         'increase the parameter jpmax_vars')
377               ENDIF
378               IF( llstop .AND. iom_varid == -1 )   CALL ctl_stop( TRIM(clinfo)//' not found' ) 
379            ELSE
380               iom_varid = iiv
381               IF( PRESENT(kdimsz) ) THEN
382                  i_nvd = iom_file(kiomid)%ndims(iiv)
383                  IF( i_nvd == size(kdimsz) ) THEN
384                     kdimsz(:) = iom_file(kiomid)%dimsz(1:i_nvd,iiv)
385                  ELSE
386                     WRITE(ctmp1,*) i_nvd, size(kdimsz)
387                     CALL ctl_stop( trim(clinfo), 'error in kdimsz size'//trim(ctmp1) )
388                  ENDIF
389               ENDIF
390            ENDIF
391         ENDIF
392      ENDIF
393      !
394   END FUNCTION iom_varid
395
396
397   !!----------------------------------------------------------------------
398   !!                   INTERFACE iom_get
399   !!----------------------------------------------------------------------
400   SUBROUTINE iom_g0d( kiomid, cdvar, pvar )
401      INTEGER         , INTENT(in   )                 ::   kiomid    ! Identifier of the file
402      CHARACTER(len=*), INTENT(in   )                 ::   cdvar     ! Name of the variable
403      REAL(wp)        , INTENT(  out)                 ::   pvar      ! read field
404      !
405      INTEGER               :: idvar   ! variable id
406      !
407      IF( kiomid > 0 ) THEN
408         idvar = iom_varid( kiomid, cdvar )
409         IF( iom_file(kiomid)%nfid > 0 .AND. idvar > 0 ) THEN
410            SELECT CASE (iom_file(kiomid)%iolib)
411            CASE (jpioipsl )   ;   CALL iom_ioipsl_get(  kiomid, idvar, pvar )
412            CASE (jpnf90   )   ;   CALL iom_nf90_get(    kiomid, idvar, pvar )
413            CASE (jprstdimg)   ;   CALL iom_rstdimg_get( kiomid, idvar, pvar )
414            CASE DEFAULT   
415               CALL ctl_stop( 'iom_g0d: accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
416            END SELECT
417         ENDIF
418      ENDIF
419   END SUBROUTINE iom_g0d
420
421   SUBROUTINE iom_g1d( kiomid, kdom, cdvar, pvar, ktime, kstart, kcount )
422      INTEGER         , INTENT(in   )                         ::   kiomid    ! Identifier of the file
423      INTEGER         , INTENT(in   )                         ::   kdom      ! Type of domain to be read
424      CHARACTER(len=*), INTENT(in   )                         ::   cdvar     ! Name of the variable
425      REAL(wp)        , INTENT(  out), DIMENSION(:)           ::   pvar      ! read field
426      INTEGER         , INTENT(in   )              , OPTIONAL ::   ktime     ! record number
427      INTEGER         , INTENT(in   ), DIMENSION(1), OPTIONAL ::   kstart    ! start axis position of the reading
428      INTEGER         , INTENT(in   ), DIMENSION(1), OPTIONAL ::   kcount    ! number of points in each axis
429      !
430      IF( kiomid > 0 ) THEN
431         IF( iom_file(kiomid)%nfid > 0 ) CALL iom_get_123d( kiomid, kdom       , cdvar        , pv_r1d=pvar,   &
432              &                                                     ktime=ktime, kstart=kstart, kcount=kcount )
433      ENDIF
434   END SUBROUTINE iom_g1d
435
436   SUBROUTINE iom_g2d( kiomid, kdom, cdvar, pvar, ktime, kstart, kcount )
437      INTEGER         , INTENT(in   )                           ::   kiomid    ! Identifier of the file
438      INTEGER         , INTENT(in   )                           ::   kdom      ! Type of domain to be read
439      CHARACTER(len=*), INTENT(in   )                           ::   cdvar     ! Name of the variable
440      REAL(wp)        , INTENT(  out), DIMENSION(:,:)           ::   pvar      ! read field
441      INTEGER         , INTENT(in   )                , OPTIONAL ::   ktime     ! record number
442      INTEGER         , INTENT(in   ), DIMENSION(2)  , OPTIONAL ::   kstart    ! start axis position of the reading
443      INTEGER         , INTENT(in   ), DIMENSION(2)  , OPTIONAL ::   kcount    ! number of points in each axis
444      !
445      IF( kiomid > 0 ) THEN
446         IF( iom_file(kiomid)%nfid > 0 ) CALL iom_get_123d( kiomid, kdom       , cdvar        , pv_r2d=pvar,   &
447              &                                                     ktime=ktime, kstart=kstart, kcount=kcount )
448      ENDIF
449   END SUBROUTINE iom_g2d
450
451   SUBROUTINE iom_g3d( kiomid, kdom, cdvar, pvar, ktime, kstart, kcount )
452      INTEGER         , INTENT(in   )                             ::   kiomid    ! Identifier of the file
453      INTEGER         , INTENT(in   )                             ::   kdom      ! Type of domain to be read
454      CHARACTER(len=*), INTENT(in   )                             ::   cdvar     ! Name of the variable
455      REAL(wp)        , INTENT(  out), DIMENSION(:,:,:)           ::   pvar      ! read field
456      INTEGER         , INTENT(in   )                  , OPTIONAL ::   ktime     ! record number
457      INTEGER         , INTENT(in   ), DIMENSION(3)    , OPTIONAL ::   kstart    ! start axis position of the reading
458      INTEGER         , INTENT(in   ), DIMENSION(3)    , OPTIONAL ::   kcount    ! number of points in each axis
459      !
460      IF( kiomid > 0 ) THEN
461         IF( iom_file(kiomid)%nfid > 0 ) CALL iom_get_123d( kiomid, kdom       , cdvar        , pv_r3d=pvar,   &
462              &                                                     ktime=ktime, kstart=kstart, kcount=kcount )
463      ENDIF
464   END SUBROUTINE iom_g3d
465   !!----------------------------------------------------------------------
466
467   SUBROUTINE iom_get_123d( kiomid, kdom  , cdvar ,   &
468         &                  pv_r1d, pv_r2d, pv_r3d,   &
469         &                  ktime , kstart, kcount  )
470      !!-----------------------------------------------------------------------
471      !!                  ***  ROUTINE  iom_get_123d  ***
472      !!
473      !! ** Purpose : read a 1D/2D/3D variable
474      !!
475      !! ** Method : read ONE record at each CALL
476      !!-----------------------------------------------------------------------
477      INTEGER                    , INTENT(in   )           ::   kiomid     ! Identifier of the file
478      INTEGER                    , INTENT(in   )           ::   kdom       ! Type of domain to be read
479      CHARACTER(len=*)           , INTENT(in   )           ::   cdvar      ! Name of the variable
480      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d     ! read field (1D case)
481      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d     ! read field (2D case)
482      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d     ! read field (3D case)
483      INTEGER                    , INTENT(in   ), OPTIONAL ::   ktime      ! record number
484      INTEGER , DIMENSION(:)     , INTENT(in   ), OPTIONAL ::   kstart     ! start position of the reading in each axis
485      INTEGER , DIMENSION(:)     , INTENT(in   ), OPTIONAL ::   kcount     ! number of points to be read in each axis
486      !
487      LOGICAL                        ::   llnoov      ! local definition to read overlap
488      INTEGER                        ::   jl          ! loop on number of dimension
489      INTEGER                        ::   idom        ! type of domain
490      INTEGER                        ::   idvar       ! id of the variable
491      INTEGER                        ::   inbdim      ! number of dimensions of the variable
492      INTEGER                        ::   idmspc      ! number of spatial dimensions
493      INTEGER                        ::   itime       ! record number
494      INTEGER                        ::   istop       ! temporary value of nstop
495      INTEGER                        ::   ix1, ix2, iy1, iy2   ! subdomain indexes
496      INTEGER                        ::   ji, jj      ! loop counters
497      INTEGER                        ::   irankpv       !
498      INTEGER                        ::   ind1, ind2  ! substring index
499      INTEGER, DIMENSION(jpmax_dims) ::   istart      ! starting point to read for each axis
500      INTEGER, DIMENSION(jpmax_dims) ::   icnt        ! number of value to read along each axis
501      INTEGER, DIMENSION(jpmax_dims) ::   idimsz      ! size of the dimensions of the variable
502      INTEGER, DIMENSION(jpmax_dims) ::   ishape      ! size of the dimensions of the variable
503      REAL(wp)                       ::   zscf, zofs  ! sacle_factor and add_offset
504      INTEGER                        ::   itmp        ! temporary integer
505      CHARACTER(LEN=100)             ::   clinfo      ! info character
506      CHARACTER(LEN=100)             ::   clname      ! file name
507      CHARACTER(LEN=1)               ::   clrankpv, cldmspc      !
508      !---------------------------------------------------------------------
509      !
510      clname = iom_file(kiomid)%name   !   esier to read
511      clinfo = '          iom_get_123d, file: '//trim(clname)//', var: '//trim(cdvar)
512      ! local definition of the domain ?
513      idom = kdom
514      ! do we read the overlap
515      ! ugly patch SM+JMM+RB to overwrite global definition in some cases
516      llnoov = (jpni * jpnj ) == jpnij .AND. .NOT. lk_agrif 
517      ! check kcount and kstart optionals parameters...
518      IF( PRESENT(kcount) .AND. (.NOT. PRESENT(kstart)) ) CALL ctl_stop(trim(clinfo), 'kcount present needs kstart present')
519      IF( PRESENT(kstart) .AND. (.NOT. PRESENT(kcount)) ) CALL ctl_stop(trim(clinfo), 'kstart present needs kcount present')
520      IF( PRESENT(kstart) .AND. idom /= jpdom_unknown   ) CALL ctl_stop(trim(clinfo), 'kstart present needs kdom = jpdom_unknown')
521
522      ! Search for the variable in the data base (eventually actualize data)
523      istop = nstop
524      idvar = iom_varid( kiomid, cdvar )
525      !
526      IF( idvar > 0 ) THEN
527         ! to write iom_file(kiomid)%dimsz in a shorter way !
528         idimsz(:) = iom_file(kiomid)%dimsz(:, idvar) 
529         inbdim = iom_file(kiomid)%ndims(idvar)            ! number of dimensions in the file
530         idmspc = inbdim                                   ! number of spatial dimensions in the file
531         IF( iom_file(kiomid)%luld(idvar) )   idmspc = inbdim - 1
532         IF( idmspc > 3 )   CALL ctl_stop(trim(clinfo), 'the file has more than 3 spatial dimensions this case is not coded...') 
533         !
534         ! update idom definition...
535         ! Identify the domain in case of jpdom_auto(glo/dta) definition
536         IF( idom == jpdom_autoglo .OR. idom == jpdom_autodta ) THEN           
537            IF( idom == jpdom_autoglo ) THEN   ;   idom = jpdom_global 
538            ELSE                               ;   idom = jpdom_data
539            ENDIF
540            ind1 = INDEX( clname, '_', back = .TRUE. ) + 1
541            ind2 = INDEX( clname, '.', back = .TRUE. ) - 1
542            IF( ind2 > ind1 ) THEN   ;   IF( VERIFY( clname(ind1:ind2), '0123456789' ) == 0 )   idom = jpdom_local   ;   ENDIF
543         ENDIF
544         ! Identify the domain in case of jpdom_local definition
545         IF( idom == jpdom_local ) THEN
546            IF(     idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN   ;   idom = jpdom_local_full
547            ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN   ;   idom = jpdom_local_noextra
548            ELSEIF( idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN   ;   idom = jpdom_local_noovlap
549            ELSE   ;   CALL ctl_stop( trim(clinfo), 'impossible to identify the local domain' )
550            ENDIF
551         ENDIF
552         !
553         ! check the consistency between input array and data rank in the file
554         !
555         ! initializations
556         itime = 1
557         IF( PRESENT(ktime) ) itime = ktime
558
559         irankpv = 1 * COUNT( (/PRESENT(pv_r1d)/) ) + 2 * COUNT( (/PRESENT(pv_r2d)/) ) + 3 * COUNT( (/PRESENT(pv_r3d)/) )
560         WRITE(clrankpv, fmt='(i1)') irankpv
561         WRITE(cldmspc , fmt='(i1)') idmspc
562         !
563         IF(     idmspc <  irankpv ) THEN
564            CALL ctl_stop( TRIM(clinfo), 'The file has only '//cldmspc//' spatial dimension',   &
565               &                         'it is impossible to read a '//clrankpv//'D array from this file...' )
566         ELSEIF( idmspc == irankpv ) THEN
567            IF( PRESENT(pv_r1d) .AND. idom /= jpdom_unknown )   &
568               &   CALL ctl_stop( TRIM(clinfo), 'case not coded...You must use jpdom_unknown' )
569         ELSEIF( idmspc >  irankpv ) THEN
570               IF( PRESENT(pv_r2d) .AND. itime == 1 .AND. idimsz(3) == 1 .AND. idmspc == 3 ) THEN
571                  CALL ctl_warn( trim(clinfo), '2D array but 3 spatial dimensions for the data...'              ,   &
572                        &         'As the size of the z dimension is 1 and as we try to read the first record, ',   &
573                        &         'we accept this case, even if there is a possible mix-up between z and time dimension' )   
574                  idmspc = idmspc - 1
575               ELSE
576                  CALL ctl_stop( TRIM(clinfo), 'To keep iom lisibility, when reading a '//clrankpv//'D array,'         ,   &
577                     &                         'we do not accept data with more than '//cldmspc//' spatial dimension',   &
578                     &                         'Use ncwa -a to suppress the unnecessary dimensions' )
579               ENDIF
580         ENDIF
581
582         !
583         ! definition of istart and icnt
584         !
585         icnt  (:) = 1
586         istart(:) = 1
587         istart(idmspc+1) = itime
588
589         IF(              PRESENT(kstart)       ) THEN ; istart(1:idmspc) = kstart(1:idmspc) ; icnt(1:idmspc) = kcount(1:idmspc)
590         ELSE
591            IF(           idom == jpdom_unknown ) THEN                                       ; icnt(1:idmspc) = idimsz(1:idmspc)
592            ELSE
593               IF( .NOT. PRESENT(pv_r1d) ) THEN   !   not a 1D array
594                  IF(     idom == jpdom_data    ) THEN ; istart(1:2) = (/ mig(1), mjg(1) /)  ! icnt(1:2) done bellow
595                  ELSEIF( idom == jpdom_global  ) THEN ; istart(1:2) = (/ nimpp , njmpp  /)  ! icnt(1:2) done bellow
596                  ENDIF
597                  ! we do not read the overlap                     -> we start to read at nldi, nldj
598! JMM + SM: ugly patch before getting the new version of lib_mpp)
599!                  IF( idom /= jpdom_local_noovlap )   istart(1:2) = istart(1:2) + (/ nldi - 1, nldj - 1 /)
600                  IF( llnoov .AND. idom /= jpdom_local_noovlap ) istart(1:2) = istart(1:2) + (/ nldi - 1, nldj - 1 /)
601                  ! we do not read the overlap and the extra-halos -> from nldi to nlei and from nldj to nlej
602! JMM + SM: ugly patch before getting the new version of lib_mpp)
603!                  icnt(1:2) = (/ nlei - nldi + 1, nlej - nldj + 1 /)
604                  IF( llnoov ) THEN   ;   icnt(1:2) = (/ nlei - nldi + 1, nlej - nldj + 1 /)
605                  ELSE                ;   icnt(1:2) = (/ nlci           , nlcj            /)
606                  ENDIF
607                  IF( PRESENT(pv_r3d) ) THEN
608                     IF( idom == jpdom_data ) THEN   ; icnt(3) = jpkdta
609                     ELSE                            ; icnt(3) = jpk
610                     ENDIF
611                  ENDIF
612               ENDIF
613            ENDIF
614         ENDIF
615
616         ! check that istart and icnt can be used with this file
617         !-
618         DO jl = 1, jpmax_dims
619            itmp = istart(jl)+icnt(jl)-1
620            IF( itmp > idimsz(jl) .AND. idimsz(jl) /= 0 ) THEN
621               WRITE( ctmp1, FMT="('(istart(', i1, ') + icnt(', i1, ') - 1) = ', i5)" ) jl, jl, itmp
622               WRITE( ctmp2, FMT="(' is larger than idimsz(', i1,') = ', i5)"         ) jl, idimsz(jl)
623               CALL ctl_stop( trim(clinfo), 'start and count too big regarding to the size of the data, ', ctmp1, ctmp2 )     
624            ENDIF
625         END DO
626
627         ! check that icnt matches the input array
628         !-     
629         IF( idom == jpdom_unknown ) THEN
630            IF( irankpv == 1 )        ishape(1:1) = SHAPE(pv_r1d)
631            IF( irankpv == 2 )        ishape(1:2) = SHAPE(pv_r2d)
632            IF( irankpv == 3 )        ishape(1:3) = SHAPE(pv_r3d)
633            ctmp1 = 'd'
634         ELSE
635            IF( irankpv == 2 ) THEN
636! JMM + SM: ugly patch before getting the new version of lib_mpp)
637!               ishape(1:2) = SHAPE(pv_r2d(nldi:nlei,nldj:nlej  ))   ;   ctmp1 = 'd(nldi:nlei,nldj:nlej)'
638               IF( llnoov ) THEN ; ishape(1:2)=SHAPE(pv_r2d(nldi:nlei,nldj:nlej  )) ; ctmp1='d(nldi:nlei,nldj:nlej)'
639               ELSE              ; ishape(1:2)=SHAPE(pv_r2d(1   :nlci,1   :nlcj  )) ; ctmp1='d(1:nlci,1:nlcj)'
640               ENDIF
641            ENDIF
642            IF( irankpv == 3 ) THEN 
643! JMM + SM: ugly patch before getting the new version of lib_mpp)
644!               ishape(1:3) = SHAPE(pv_r3d(nldi:nlei,nldj:nlej,:))   ;   ctmp1 = 'd(nldi:nlei,nldj:nlej,:)'
645               IF( llnoov ) THEN ; ishape(1:3)=SHAPE(pv_r3d(nldi:nlei,nldj:nlej,:)) ; ctmp1='d(nldi:nlei,nldj:nlej,:)'
646               ELSE              ; ishape(1:3)=SHAPE(pv_r3d(1   :nlci,1   :nlcj,:)) ; ctmp1='d(1:nlci,1:nlcj,:)'
647               ENDIF
648            ENDIF
649         ENDIF
650         
651         DO jl = 1, irankpv
652            WRITE( ctmp2, FMT="(', ', i1,'): ', i5,' /= icnt(', i1,'):', i5)" ) jl, ishape(jl), jl, icnt(jl)
653            IF( ishape(jl) /= icnt(jl) )   CALL ctl_stop( TRIM(clinfo), 'size(pv_r'//clrankpv//TRIM(ctmp1)//TRIM(ctmp2) )
654         END DO
655
656      ENDIF
657
658      ! read the data
659      !-     
660      IF( idvar > 0 .AND. istop == nstop ) THEN   ! no additional errors until this point...
661         !
662         ! find the right index of the array to be read
663! JMM + SM: ugly patch before getting the new version of lib_mpp)
664!         IF( idom /= jpdom_unknown ) THEN   ;   ix1 = nldi   ;   ix2 = nlei      ;   iy1 = nldj   ;   iy2 = nlej
665!         ELSE                               ;   ix1 = 1      ;   ix2 = icnt(1)   ;   iy1 = 1      ;   iy2 = icnt(2)
666!         ENDIF
667         IF( llnoov ) THEN
668            IF( idom /= jpdom_unknown ) THEN   ;   ix1 = nldi   ;   ix2 = nlei      ;   iy1 = nldj   ;   iy2 = nlej
669            ELSE                               ;   ix1 = 1      ;   ix2 = icnt(1)   ;   iy1 = 1      ;   iy2 = icnt(2)
670            ENDIF
671         ELSE
672            IF( idom /= jpdom_unknown ) THEN   ;   ix1 = 1      ;   ix2 = nlci      ;   iy1 = 1      ;   iy2 = nlcj
673            ELSE                               ;   ix1 = 1      ;   ix2 = icnt(1)   ;   iy1 = 1      ;   iy2 = icnt(2)
674            ENDIF
675         ENDIF
676     
677         SELECT CASE (iom_file(kiomid)%iolib)
678         CASE (jpioipsl )   ;   CALL iom_ioipsl_get(  kiomid, idvar, inbdim, istart, icnt, ix1, ix2, iy1, iy2,   &
679            &                                         pv_r1d, pv_r2d, pv_r3d )
680         CASE (jpnf90   )   ;   CALL iom_nf90_get(    kiomid, idvar, inbdim, istart, icnt, ix1, ix2, iy1, iy2,   &
681            &                                         pv_r1d, pv_r2d, pv_r3d )
682         CASE (jprstdimg)   ;   CALL iom_rstdimg_get( kiomid, idom, idvar, ix1, ix2, iy1, iy2,   &
683            &                                         pv_r1d, pv_r2d, pv_r3d )
684         CASE DEFAULT   
685            CALL ctl_stop( TRIM(clinfo)//' accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
686         END SELECT
687
688         IF( istop == nstop ) THEN   ! no additional errors until this point...
689            IF(lwp) WRITE(numout,"(10x,' read ',a,' (rec: ',i4,') in ',a,' ok')") TRIM(cdvar), itime, TRIM(iom_file(kiomid)%name)
690         
691            !--- overlap areas and extra hallows (mpp)
692            IF(     PRESENT(pv_r2d) .AND. idom /= jpdom_unknown ) THEN
693               CALL lbc_lnk( pv_r2d,'Z',-999.,'no0' )
694            ELSEIF( PRESENT(pv_r3d) .AND. idom /= jpdom_unknown ) THEN
695               ! this if could be simplified with the new lbc_lnk that works with any size of the 3rd dimension
696               IF( icnt(3) == jpk ) THEN
697                  CALL lbc_lnk( pv_r3d,'Z',-999.,'no0' )
698               ELSE   ! put some arbitrary value (a call to lbc_lnk will be done later...)
699                  DO jj = nlcj+1, jpj   ;   pv_r3d(1:nlci, jj, :) = pv_r3d(1:nlci, nlej, :)   ;   END DO
700                  DO ji = nlci+1, jpi   ;   pv_r3d(ji    , : , :) = pv_r3d(nlei  , :   , :)   ;   END DO
701               ENDIF
702            ENDIF
703           
704            !--- Apply scale_factor and offset
705            zscf = iom_file(kiomid)%scf(idvar)      ! scale factor
706            zofs = iom_file(kiomid)%ofs(idvar)      ! offset
707            IF(     PRESENT(pv_r1d) ) THEN
708               IF( zscf /= 1. )   pv_r1d(:) = pv_r1d(:) * zscf 
709               IF( zofs /= 0. )   pv_r1d(:) = pv_r1d(:) + zofs
710            ELSEIF( PRESENT(pv_r2d) ) THEN
711               !CDIR COLLAPSE
712               IF( zscf /= 1.)   pv_r2d(:,:) = pv_r2d(:,:) * zscf
713               !CDIR COLLAPSE
714               IF( zofs /= 0.)   pv_r2d(:,:) = pv_r2d(:,:) + zofs
715            ELSEIF( PRESENT(pv_r3d) ) THEN
716               !CDIR COLLAPSE
717               IF( zscf /= 1.)   pv_r3d(:,:,:) = pv_r3d(:,:,:) * zscf
718               !CDIR COLLAPSE
719               IF( zofs /= 0.)   pv_r3d(:,:,:) = pv_r3d(:,:,:) + zofs
720            ENDIF
721            !
722         ENDIF
723         !
724      ENDIF
725      !
726   END SUBROUTINE iom_get_123d
727
728
729   SUBROUTINE iom_gettime( kiomid, ptime, cdvar, kntime, cdunits, cdcalendar )
730      !!--------------------------------------------------------------------
731      !!                   ***  SUBROUTINE iom_gettime  ***
732      !!
733      !! ** Purpose : read the time axis cdvar in the file
734      !!--------------------------------------------------------------------
735      INTEGER                    , INTENT(in   ) ::   kiomid     ! file Identifier
736      REAL(wp), DIMENSION(:)     , INTENT(  out) ::   ptime      ! the time axis
737      CHARACTER(len=*), OPTIONAL , INTENT(in   ) ::   cdvar      ! time axis name
738      INTEGER         , OPTIONAL , INTENT(  out) ::   kntime     ! number of times in file
739      CHARACTER(len=*), OPTIONAL , INTENT(  out) ::   cdunits    ! units attribute of time coordinate
740      CHARACTER(len=*), OPTIONAL , INTENT(  out) ::   cdcalendar ! calendar attribute of
741      !
742      INTEGER, DIMENSION(1) :: kdimsz
743      INTEGER            ::   idvar    ! id of the variable
744      CHARACTER(LEN=32)  ::   tname    ! local name of time coordinate
745      CHARACTER(LEN=100) ::   clinfo   ! info character
746      !---------------------------------------------------------------------
747      !
748      IF ( PRESENT(cdvar) ) THEN
749         tname = cdvar
750      ELSE
751         tname = iom_file(kiomid)%uldname
752      ENDIF
753      IF( kiomid > 0 ) THEN
754         clinfo = 'iom_gettime, file: '//trim(iom_file(kiomid)%name)//', var: '//trim(tname)
755         IF ( PRESENT(kntime) ) THEN
756            idvar  = iom_varid( kiomid, tname, kdimsz = kdimsz )
757            kntime = kdimsz(1)
758         ELSE
759            idvar = iom_varid( kiomid, tname )
760         ENDIF
761         !
762         ptime(:) = 0. ! default definition
763         IF( idvar > 0 ) THEN
764            IF( iom_file(kiomid)%ndims(idvar) == 1 ) THEN
765               IF( iom_file(kiomid)%luld(idvar) ) THEN
766                  IF( iom_file(kiomid)%dimsz(1,idvar) == size(ptime) ) THEN
767                     SELECT CASE (iom_file(kiomid)%iolib)
768                     CASE (jpioipsl )   ;   CALL iom_ioipsl_gettime( kiomid, idvar, ptime, cdunits, cdcalendar )
769                     CASE (jpnf90   )   ;   CALL iom_nf90_gettime(   kiomid, idvar, ptime, cdunits, cdcalendar )
770                     CASE (jprstdimg)   ;   CALL ctl_stop( TRIM(clinfo)//' case IO library == jprstdimg not coded...' )
771                     CASE DEFAULT   
772                        CALL ctl_stop( TRIM(clinfo)//' accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
773                     END SELECT
774                  ELSE
775                     WRITE(ctmp1,*) 'error with the size of ptime ',size(ptime),iom_file(kiomid)%dimsz(1,idvar)
776                     CALL ctl_stop( trim(clinfo), trim(ctmp1) )
777                  ENDIF
778               ELSE
779                  CALL ctl_stop( trim(clinfo), 'variable dimension is not unlimited... use iom_get' )
780               ENDIF
781            ELSE
782               CALL ctl_stop( trim(clinfo), 'the variable has more than 1 dimension' )
783            ENDIF
784         ELSE
785            CALL ctl_stop( trim(clinfo), 'variable not found in '//iom_file(kiomid)%name )
786         ENDIF
787      ENDIF
788      !
789   END SUBROUTINE iom_gettime
790
791
792   !!----------------------------------------------------------------------
793   !!                   INTERFACE iom_rstput
794   !!----------------------------------------------------------------------
795   SUBROUTINE iom_rp0d( kt, kwrite, kiomid, cdvar, pvar, ktype )
796      INTEGER         , INTENT(in)                         ::   kt       ! ocean time-step
797      INTEGER         , INTENT(in)                         ::   kwrite   ! writing time-step
798      INTEGER         , INTENT(in)                         ::   kiomid   ! Identifier of the file
799      CHARACTER(len=*), INTENT(in)                         ::   cdvar    ! time axis name
800      REAL(wp)        , INTENT(in)                         ::   pvar     ! written field
801      INTEGER         , INTENT(in), OPTIONAL               ::   ktype    ! variable external type
802      INTEGER :: ivid   ! variable id
803      IF( kiomid > 0 ) THEN
804         IF( iom_file(kiomid)%nfid > 0 ) THEN
805            ivid = iom_varid( kiomid, cdvar, ldstop = .FALSE. )
806            SELECT CASE (iom_file(kiomid)%iolib)
807            CASE (jpioipsl )   ;   CALL iom_ioipsl_rstput( kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r0d = pvar )
808            CASE (jpnf90   )   ;   CALL iom_nf90_rstput(   kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r0d = pvar )
809            CASE (jprstdimg)   ;   IF( kt == kwrite )    CALL iom_rstdimg_rstput( kiomid, cdvar, ivid, pvar )
810            CASE DEFAULT     
811               CALL ctl_stop( 'iom_rp0d: accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
812            END SELECT
813         ENDIF
814      ENDIF
815   END SUBROUTINE iom_rp0d
816
817   SUBROUTINE iom_rp1d( kt, kwrite, kiomid, cdvar, pvar, ktype )
818      INTEGER         , INTENT(in)                         ::   kt       ! ocean time-step
819      INTEGER         , INTENT(in)                         ::   kwrite   ! writing time-step
820      INTEGER         , INTENT(in)                         ::   kiomid   ! Identifier of the file
821      CHARACTER(len=*), INTENT(in)                         ::   cdvar    ! time axis name
822      REAL(wp)        , INTENT(in), DIMENSION(        jpk) ::   pvar     ! written field
823      INTEGER         , INTENT(in), OPTIONAL               ::   ktype    ! variable external type
824      INTEGER :: ivid   ! variable id
825      IF( kiomid > 0 ) THEN
826         IF( iom_file(kiomid)%nfid > 0 ) THEN
827            ivid = iom_varid( kiomid, cdvar, ldstop = .FALSE. )
828            SELECT CASE (iom_file(kiomid)%iolib)
829            CASE (jpioipsl )   ;   CALL iom_ioipsl_rstput( kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r1d = pvar )
830            CASE (jpnf90   )   ;   CALL iom_nf90_rstput(   kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r1d = pvar )
831            CASE (jprstdimg)   ;   IF( kt == kwrite )    CALL iom_rstdimg_rstput( kiomid, cdvar, ivid, pv_r1d = pvar )
832            CASE DEFAULT     
833               CALL ctl_stop( 'iom_rp1d: accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
834            END SELECT
835         ENDIF
836      ENDIF
837   END SUBROUTINE iom_rp1d
838
839   SUBROUTINE iom_rp2d( kt, kwrite, kiomid, cdvar, pvar, ktype )
840      INTEGER         , INTENT(in)                         ::   kt       ! ocean time-step
841      INTEGER         , INTENT(in)                         ::   kwrite   ! writing time-step
842      INTEGER         , INTENT(in)                         ::   kiomid   ! Identifier of the file
843      CHARACTER(len=*), INTENT(in)                         ::   cdvar    ! time axis name
844      REAL(wp)        , INTENT(in), DIMENSION(jpi,jpj    ) ::   pvar     ! written field
845      INTEGER         , INTENT(in), OPTIONAL               ::   ktype    ! variable external type
846      INTEGER :: ivid   ! variable id
847      IF( kiomid > 0 ) THEN
848         IF( iom_file(kiomid)%nfid > 0 ) THEN
849            ivid = iom_varid( kiomid, cdvar, ldstop = .FALSE. )
850            SELECT CASE (iom_file(kiomid)%iolib)
851            CASE (jpioipsl )   ;   CALL iom_ioipsl_rstput( kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r2d = pvar )
852            CASE (jpnf90   )   ;   CALL iom_nf90_rstput(   kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r2d = pvar )
853            CASE (jprstdimg)   ;   IF( kt == kwrite )   CALL iom_rstdimg_rstput( kiomid, cdvar, ivid, pv_r2d = pvar ) 
854            CASE DEFAULT     
855               CALL ctl_stop( 'iom_rp2d: accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
856            END SELECT
857         ENDIF
858      ENDIF
859   END SUBROUTINE iom_rp2d
860
861   SUBROUTINE iom_rp3d( kt, kwrite, kiomid, cdvar, pvar, ktype )
862      INTEGER         , INTENT(in)                         ::   kt       ! ocean time-step
863      INTEGER         , INTENT(in)                         ::   kwrite   ! writing time-step
864      INTEGER         , INTENT(in)                         ::   kiomid   ! Identifier of the file
865      CHARACTER(len=*), INTENT(in)                         ::   cdvar    ! time axis name
866      REAL(wp)        , INTENT(in), DIMENSION(jpi,jpj,jpk) ::   pvar     ! written field
867      INTEGER         , INTENT(in), OPTIONAL               ::   ktype    ! variable external type
868      INTEGER :: ivid   ! variable id
869      IF( kiomid > 0 ) THEN
870         IF( iom_file(kiomid)%nfid > 0 ) THEN
871            ivid = iom_varid( kiomid, cdvar, ldstop = .FALSE. )
872            SELECT CASE (iom_file(kiomid)%iolib)
873            CASE (jpioipsl )   ;   CALL iom_ioipsl_rstput( kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r3d = pvar )
874            CASE (jpnf90   )   ;   CALL iom_nf90_rstput(   kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r3d = pvar )
875            CASE (jprstdimg)   ;   IF( kt == kwrite )   CALL iom_rstdimg_rstput( kiomid, cdvar, ivid, pv_r3d = pvar )
876            CASE DEFAULT     
877               CALL ctl_stop( 'iom_rp3d: accepted IO library are only jpioipsl and jprstdimg' )
878            END SELECT
879         ENDIF
880      ENDIF
881   END SUBROUTINE iom_rp3d
882
883
884   !!----------------------------------------------------------------------
885   !!                   INTERFACE iom_rstput
886   !!----------------------------------------------------------------------
887   SUBROUTINE iom_p2d( cdname, pfield2d )
888      CHARACTER(LEN=*)            , INTENT(in) ::   cdname
889      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pfield2d
890#if defined key_ioserver
891      CALL event__write_field2D( cdname, pfield2d(nldi:nlei, nldj:nlej) )
892#endif
893   END SUBROUTINE iom_p2d
894
895   SUBROUTINE iom_p3d( cdname, pfield3d )
896      CHARACTER(LEN=*)                , INTENT(in) ::   cdname
897      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in) ::   pfield3d
898#if defined key_ioserver
899      CALL event__write_field3D( cdname, pfield3d(nldi:nlei, nldj:nlej, :) )
900#endif
901   END SUBROUTINE iom_p3d
902   !!----------------------------------------------------------------------
903
904
905#if defined key_ioserver
906
907   SUBROUTINE set_grid( cdname, plon, plat )
908      !!----------------------------------------------------------------------
909      !!                     ***  ROUTINE   ***
910      !!
911      !! ** Purpose :   
912      !!
913      !!----------------------------------------------------------------------
914      CHARACTER(LEN=*)            , INTENT(in) ::   cdname
915      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   plon
916      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   plat
917
918      CALL event__set_grid_dimension( cdname, jpiglo, jpjglo)
919      CALL event__set_grid_domain( cdname, nlei-nldi+1, nlej-nldj+1, nimpp+nldi-1, njmpp+nldj-1, &
920         &                         plon(nldi:nlei, nldj:nlej), plat(nldi:nlei, nldj:nlej) )
921      CALL event__set_grid_type_nemo( cdname )
922
923   END SUBROUTINE set_grid
924
925
926   SUBROUTINE iom_init_chkcpp
927      !!---------------------------------------------------------------------
928      !!                   ***  SUBROUTINE    ***
929      !!
930      !! ** Purpose : 
931      !!---------------------------------------------------------------------
932      USE zdfddm, ONLY :   lk_zdfddm      ! vertical  physics: double diffusion
933     
934#if defined key_dynspg_rl
935      CALL event__disable_field( "sossheig" )
936#else
937      CALL event__disable_field( "sobarstf" )
938#endif
939
940      !!#if ! ( ! defined key_dynspg_rl && defined key_ice_lim)
941      !!        CALL disable_field( "iowaflup" )
942      !!         CALL disable_field( "sowaflep" )
943      !!#endif
944
945#if ! defined key_coupled
946      CALL event__enable_field( "sohefldp" )
947      CALL event__enable_field( "sowafldp" )
948      CALL event__enable_field( "sosafldp" )
949#endif
950
951#if ( defined key_coupled && ! defined key_lim3 && ! defined key_lim2 )
952      CALL event__enable_field( "sohefldp" )
953      CALL event__enable_field( "sowafldp" )
954      CALL event__enable_field( "sosafldp" )
955#endif
956
957#if ! defined key_diaspr
958      CALL event__disable_field( "sosurfps" )
959#endif
960
961#if ! defined key_diahth
962      CALL event__disable_field( "sothedep" )
963      CALL event__disable_field( "so20chgt" )
964      CALL event__disable_field( "so28chgt" )
965      CALL event__disable_field( "sohtc300" )
966#endif
967
968#if defined key_coupled 
969# if defined key_lim3
970      Must be adapted to LIM3
971# else
972      CALL event__enable_field( "soicetem" )
973      CALL event__enable_field( "soicealb" )
974# endif 
975#endif 
976
977#if ! defined key_diaeiv
978      CALL event__disable_field( "vozoeivu" )
979      CALL event__disable_field( "vomeeivv" )
980      CALL event__disable_field( "voveeivw" )
981#endif
982
983#if ! defined key_dynspg_rl
984      CALL event__disable_field( "sozospgx" )
985      CALL event__disable_field( "somespgy" )
986#endif
987
988      IF( lk_zdfddm ) CALL event__enable_field( "voddmavs" )
989
990#if ! defined key_traldf_c2d
991      CALL event__disable_field( "soleahtw" )
992#endif
993
994#if ! defined key_traldf_eiv
995      CALL event__disable_field( "soleaeiw" )
996#endif
997
998   END SUBROUTINE iom_init_chkcpp
999
1000#else
1001
1002   SUBROUTINE iom_setkt( kt )
1003      INTEGER, INTENT(in   )::   kt 
1004   END SUBROUTINE iom_setkt
1005
1006#endif
1007
1008
1009   !!======================================================================
1010END MODULE iom
Note: See TracBrowser for help on using the repository browser.