New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iom_rstdimg.F90 in trunk/NEMO/OPA_SRC/IOM – NEMO

source: trunk/NEMO/OPA_SRC/IOM/iom_rstdimg.F90 @ 596

Last change on this file since 596 was 588, checked in by opalod, 17 years ago

nemo_v2_bugfix_001 : SM + CT : - add an initialization of iom_file(kiomid)%luld(kiv) field

  • change "offset" to "add_offset" characters
  • use a loop instead of the MINLOC function to find the minimum value of an array
  • allow to write/read headers of DIMG files over 2 records (iom_rstdimg.F90)
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 28.5 KB
Line 
1MODULE iom_rstdimg
2   !!=====================================================================
3   !!                    ***  MODULE  iom_rstdimg ***
4   !! Input/Output manager :  Library to read input rstdimg files
5   !!====================================================================
6   !! History :  9.0  ! 06 09  (S. Masson) Original code
7   !!--------------------------------------------------------------------
8
9   !!--------------------------------------------------------------------
10   !!   iom_open       : open a file read only
11   !!   iom_close      : close a file or all files opened by iom
12   !!   iom_get        : read a field (interfaced to several routines)
13   !!   iom_gettime    : read the time axis kvid in the file
14   !!   iom_varid      : get the id of a variable in a file
15   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
16   !!--------------------------------------------------------------------
17   USE in_out_manager  ! I/O manager
18   USE dom_oce         ! ocean space and time domain
19   USE lbclnk          ! lateal boundary condition / mpp exchanges
20   USE iom_def         ! iom variables definitions
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC iom_rstdimg_open, iom_rstdimg_close, iom_rstdimg_get, iom_rstdimg_rstput
26
27   INTERFACE iom_rstdimg_get
28      MODULE PROCEDURE iom_rstdimg_g0d, iom_rstdimg_g123d
29   END INTERFACE
30   INTERFACE iom_rstdimg_rstput
31      MODULE PROCEDURE iom_rstdimg_rp0d, iom_rstdimg_rp123d
32   END INTERFACE
33
34   INTEGER, PARAMETER ::   jpvnl          = 32   ! variable name length
35     
36   !!----------------------------------------------------------------------
37   !!  OPA 9.0 , LOCEAN-IPSL (2006)
38   !! $Header$
39   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
40   !!----------------------------------------------------------------------
41
42CONTAINS
43
44   SUBROUTINE iom_rstdimg_open( cdname, kiomid, ldwrt, ldok, kdompar )
45      !!---------------------------------------------------------------------
46      !!                   ***  SUBROUTINE  iom_open  ***
47      !!
48      !! ** Purpose :  open an input file read only (return 0 if not found)
49      !!---------------------------------------------------------------------
50      CHARACTER(len=*)       , INTENT(inout) ::   cdname   ! File name
51      INTEGER                , INTENT(  out) ::   kiomid   ! iom identifier of the opened file
52      LOGICAL                , INTENT(in   ) ::   ldwrt    ! read or write the file?
53      LOGICAL                , INTENT(in   ) ::   ldok     ! check the existence
54      INTEGER, DIMENSION(2,5), INTENT(in   ) ::   kdompar  ! domain parameters:
55
56      CHARACTER(LEN=100)                      ::   clinfo                     ! info character
57      CHARACTER(LEN=100)                      ::   cltmp                      ! temporary character
58      INTEGER                                 ::   jv                         ! loop counter
59      INTEGER                                 ::   istop                      ! temporary storage of nstop
60      INTEGER                                 ::   idrst                      ! logical unit of the restart file
61      INTEGER                                 ::   iln                        ! lengths of character
62      INTEGER                                 ::   irecl8                     ! record length
63      INTEGER                                 ::   ios                        ! IO status
64      INTEGER                                 ::   irhd                       ! record of the header infos
65      INTEGER                                 ::   ivnum                      ! number of variables
66      INTEGER                                 ::   ishft                      ! counter shift
67      INTEGER                                 ::   inx, iny, inz              ! x,y,z dimension of the variable
68      INTEGER                                 ::   in0d, in1d, in2d, in3d     ! number of 0/1/2/3D variables
69      INTEGER                                 ::   ipni, ipnj, ipnij, iarea   ! domain decomposition
70      INTEGER                                 ::   jl                         ! loop variable
71      CHARACTER(LEN=jpvnl), DIMENSION(jpmax_vars) ::   clna0d, clna1d, clna2d, clna3d     ! name of 0/1/2/3D variables
72      REAL(wp),         DIMENSION(jpmax_vars) ::   zval0d, zval1d, zval2d, zval3d     ! value of 0d variables or record
73      !                                                                               ! position for 1/2/3D variables
74      !---------------------------------------------------------------------
75      clinfo = '                    iom_rstdimg_open ~~~  '
76      istop = nstop      ! store the actual value of nstop
77      ios = 0            ! default definition
78      kiomid = 0         ! default definition
79      ! get a free unit
80      idrst = getunit()  ! get a free logical unit for the restart file
81!!$#if defined key_agrif
82!!$      idrst = Agrif_Get_Unit()     
83!!$#endif
84      ! Open the file...
85      ! =============
86      IF( ldok ) THEN      ! Open existing file...
87         ! find the record length
88         OPEN( idrst, FILE = TRIM(cdname), FORM = 'unformatted', ACCESS = 'direct'   &
89            &       , RECL = 8, STATUS = 'old', ACTION = 'read', IOSTAT = ios, ERR = 987 )
90         READ( idrst, REC = 1, IOSTAT = ios, ERR = 987 ) irecl8
91         CLOSE( idrst )
92         ! Open the file with the appropriate record length and parameters
93         IF( ldwrt ) THEN  ! ... in readwrite mode
94            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READWRITE mode'
95            OPEN( idrst, FILE = TRIM(cdname), FORM = 'unformatted', ACCESS = 'direct'   &
96               &       , RECL = irecl8, STATUS = 'old', ACTION = 'readwrite', IOSTAT = ios, ERR = 987 )
97         ELSE              ! ... in read mode
98            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
99            OPEN( idrst, FILE = TRIM(cdname), FORM = 'unformatted', ACCESS = 'direct'   &
100               &       , RECL = irecl8, STATUS = 'old', ACTION = 'read'     , IOSTAT = ios, ERR = 987 )
101         ENDIF
102      ELSE                 ! the file does not exist
103         iln = INDEX( cdname, '.dimg' )
104         IF( ldwrt ) THEN  ! the file should be open in readwrite mode so we create it...
105            irecl8= MAX( kdompar(1,1) * kdompar(2,1) * wp, ( 8*jpnij + 15 ) * 4 )
106            IF( jpnij > 1 ) THEN
107               WRITE(cltmp,'(a,a,i4.4,a)') cdname(1:iln-1), '_', narea-1, '.dimg'
108               cdname = TRIM(cltmp)
109            ENDIF
110            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in READWRITE mode'
111            OPEN( idrst, FILE = TRIM(cdname), FORM = 'UNFORMATTED', ACCESS = 'DIRECT'   &
112               &       , RECL = irecl8, STATUS = 'new', ACTION = 'readwrite', IOSTAT = ios, ERR = 987 )
113         ELSE              ! the file should be open for read mode so it must exist...
114            CALL ctl_stop( TRIM(clinfo), 'File '//cdname(1:iln-1)//'* not found' )
115         ENDIF
116      ENDIF
117      ! Performs checks on the file
118      ! =============
119      IF( ldok ) THEN      ! old file
120         READ( idrst, REC = 1   , IOSTAT = ios, ERR = 987 )   &
121              &   irecl8, inx, iny, inz, in0d, in1d, in2d, in3d, irhd
122         READ( idrst, REC = irhd, IOSTAT = ios, ERR = 987 )   &
123            &   clna0d(1:in0d), zval0d(1:in0d), clna1d(1:in1d), zval1d(1:in1d),   &
124            &   clna2d(1:in2d), zval2d(1:in2d), clna3d(1:in3d), zval3d(1:in3d),   &
125            &   ipni, ipnj, ipnij, iarea 
126         clinfo = TRIM(clinfo)//' file '//TRIM(cdname)
127         IF( inx   /= kdompar(1,1) )   CALL ctl_stop( TRIM(clinfo), 'Mismatch in domain size in i direction' )
128         IF( iny   /= kdompar(2,1) )   CALL ctl_stop( TRIM(clinfo), 'Mismatch in domain size in j direction' )
129         IF( inz   /= jpk          )   CALL ctl_stop( TRIM(clinfo), 'Mismatch in domain size in k direction' )
130         IF( ipni  /= jpni         )   CALL ctl_stop( TRIM(clinfo), 'Processor splitting changed along I' )
131         IF( ipnj  /= jpnj         )   CALL ctl_stop( TRIM(clinfo), 'Processor splitting changed along J' )
132         IF( ipnij /= jpnij        )   CALL ctl_stop( TRIM(clinfo), 'Total number of processors changed' )
133         IF( iarea /= narea        )   CALL ctl_stop( TRIM(clinfo), 'Mismatch in area numbering ...' )
134      ENDIF
135      ! fill file informations
136      ! =============
137      IF( istop == nstop ) THEN   ! no error within this routine
138!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
139         kiomid = 0
140         DO jl = jpmax_files, 1, -1
141            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
142         ENDDO
143         iom_file(kiomid)%name    = TRIM(cdname)
144         iom_file(kiomid)%nfid    = idrst
145         iom_file(kiomid)%iolib   = jprstdimg
146         iom_file(kiomid)%iduld   = -1
147         IF( ldok ) THEN      ! old file
148            ! read variables informations from the file header
149            IF(  TRIM(clna0d(1)) == 'no0d' )   in0d = 0
150            IF(  TRIM(clna1d(1)) == 'no1d' )   in1d = 0
151            IF(  TRIM(clna2d(1)) == 'no2d' )   in2d = 0
152            IF(  TRIM(clna3d(1)) == 'no3d' )   in3d = 0
153            ivnum = in0d + in1d + in2d + in3d
154            iom_file(kiomid)%nvars            = ivnum
155            iom_file(kiomid)%irec             = 2 + in1d + in2d + inz * in3d
156            iom_file(kiomid)%luld(   1:ivnum) = .FALSE.
157            iom_file(kiomid)%scf(    1:ivnum) = 1.
158            ! scalar variable
159            DO jv = 1, in0d
160               iom_file(kiomid)%cn_var(jv) = TRIM(clna0d(jv))
161               iom_file(kiomid)%nvid(  jv) = 1
162               iom_file(kiomid)%ndims( jv) = 0
163               iom_file(kiomid)%ofs(   jv) = zval0d(jv)   ! warning: trick... we use ofs to store the value
164            END DO
165            ! 1d variable
166            ishft = in0d
167            DO jv = 1, in1d
168               iom_file(kiomid)%cn_var(    ishft + jv) = TRIM(clna1d(jv))
169               iom_file(kiomid)%nvid(      ishft + jv) = zval1d(jv)
170               iom_file(kiomid)%ndims(     ishft + jv) = 1
171               iom_file(kiomid)%dimsz(1  , ishft + jv) = jpk
172               iom_file(kiomid)%ofs(       ishft + jv) = 0.
173            END DO
174            ! 2d variable
175            ishft = in0d + in1d
176            DO jv = 1, in2d
177               iom_file(kiomid)%cn_var(    ishft + jv) = TRIM(clna2d(jv))
178               iom_file(kiomid)%nvid(      ishft + jv) = zval2d(jv)
179               iom_file(kiomid)%ndims(     ishft + jv) = 2
180               iom_file(kiomid)%dimsz(1:2, ishft + jv) = (/ inx, iny /)
181               iom_file(kiomid)%ofs(       ishft + jv) = 0.
182            END DO
183            ! 3d variable
184            ishft = in0d + in1d + in2d 
185            DO jv = 1, in3d
186               iom_file(kiomid)%cn_var(    ishft + jv) = TRIM(clna3d(jv))
187               iom_file(kiomid)%nvid(      ishft + jv) = zval3d(jv)
188               iom_file(kiomid)%ndims(     ishft + jv) = 3
189               iom_file(kiomid)%dimsz(1:3, ishft + jv) = (/ inx, iny, jpk /)
190               iom_file(kiomid)%ofs(       ishft + jv) = 0.
191            END DO
192         ELSE                 ! new file
193            iom_file(kiomid)%nvars = 0
194            iom_file(kiomid)%irec  = 2
195            ! store file informations
196            WRITE( idrst, REC = 1, IOSTAT = ios, ERR = 987 ) irecl8, kdompar(:,1), jpk   ! store domain size
197         ENDIF
198      ENDIF
199987   CONTINUE
200      IF( ios /= 0 ) THEN
201         WRITE(ctmp1,*) '           iostat = ', ios
202         CALL ctl_stop( TRIM(clinfo), '   error in opening file '//TRIM(cdname), ctmp1 )
203      ENDIF
204      !
205   END SUBROUTINE iom_rstdimg_open
206
207
208   SUBROUTINE iom_rstdimg_close( kiomid )
209      !!--------------------------------------------------------------------
210      !!                   ***  SUBROUTINE  iom_rstdimg_close  ***
211      !!
212      !! ** Purpose : close an input file
213      !!--------------------------------------------------------------------
214      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
215      !
216      CHARACTER(LEN=100)                      ::   clinfo                     ! info character
217      INTEGER                                 ::   jv                         ! loop counter
218      INTEGER                                 ::   irecl8                     ! record length
219      INTEGER                                 ::   ios                        ! IO status
220      INTEGER                                 ::   irhd                       ! record of the header infos
221      INTEGER                                 ::   ivnum                      ! number of variables
222      INTEGER                                 ::   idrst                      ! file logical unit
223      INTEGER                                 ::   inx, iny, inz              ! x,y,z dimension of the variable
224      INTEGER                                 ::   in0d, in1d, in2d, in3d     ! number of 0/1/2/3D variables
225      CHARACTER(LEN=jpvnl), DIMENSION(jpmax_vars) ::   clna0d, clna1d, clna2d, clna3d    ! name of 0/1/2/3D variables
226      REAL(wp),          DIMENSION(jpmax_vars) ::   zval0d, zval1d, zval2d, zval3d    ! value of 0d variables or record
227      !                                                                               ! position for 1/2/3D variables
228      !---------------------------------------------------------------------
229      !
230      clinfo = '                    iom_rstdimg_close ~~~  '
231      idrst = iom_file(kiomid)%nfid   ! get back the logical unit of the restart file
232      ! test if we can write in the file (test with INQUIRE gives alsways YES even with read only files...)
233      READ(  idrst, REC = 1, IOSTAT = ios, ERR = 987 ) irecl8, inx, iny, inz   
234      WRITE( idrst, REC = 1, IOSTAT = ios            ) irecl8, inx, iny, inz   
235      ! We can write in the file => we update its header before closing
236      IF( ios == 0 ) THEN
237         READ( idrst, REC = 1, IOSTAT = ios, ERR = 987 ) irecl8, inx, iny, inz   ! get back domain size
238         irhd = iom_file(kiomid)%irec
239         ivnum = iom_file(kiomid)%nvars
240         in0d = 0   ;   in1d = 0   ;   in2d = 0   ;   in3d = 0
241         DO jv = 1, ivnum   ! loop on each variable to get its name and value/record position
242            SELECT CASE (iom_file(kiomid)%ndims(jv))
243            CASE (0)   ! scalar variable
244               in0d = in0d + 1
245               clna0d(in0d) = TRIM(iom_file(kiomid)%cn_var(jv))
246               zval0d(in0d) = iom_file(kiomid)%ofs(jv)   ! warning: trick... we use ofs to store the value
247            CASE (1)   ! 1d variable
248               in1d = in1d + 1
249               clna1d(in1d) = TRIM(iom_file(kiomid)%cn_var(jv))
250               zval1d(in1d) = iom_file(kiomid)%nvid(jv)
251            CASE (2)   ! 2d variable
252               in2d = in2d + 1
253               clna2d(in2d) = TRIM(iom_file(kiomid)%cn_var(jv))
254               zval2d(in2d) = iom_file(kiomid)%nvid(jv)
255            CASE (3)   ! 3d variable
256               in3d = in3d + 1
257               clna3d(in3d) = TRIM(iom_file(kiomid)%cn_var(jv))
258               zval3d(in3d) = iom_file(kiomid)%nvid(jv)
259            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo), 'Should not ne there...' )
260            END SELECT
261         END DO
262         ! force to have at least 1 variable in each list (not necessary (?), but safer...)
263         IF( in0d == 0 ) THEN   ;   in0d = 1   ;   clna0d(1) = 'no0d'   ;   zval0d(1) = -1.   ;   ENDIF
264         IF( in1d == 0 ) THEN   ;   in1d = 1   ;   clna1d(1) = 'no1d'   ;   zval1d(1) = -1.   ;   ENDIF
265         IF( in2d == 0 ) THEN   ;   in2d = 1   ;   clna2d(1) = 'no2d'   ;   zval2d(1) = -1.   ;   ENDIF
266         IF( in3d == 0 ) THEN   ;   in3d = 1   ;   clna3d(1) = 'no3d'   ;   zval3d(1) = -1.   ;   ENDIF
267         ! update the file header before closing it
268         WRITE( idrst, REC = 1, IOSTAT = ios, ERR = 987 )   &
269            &   irecl8, inx, iny, inz, in0d, in1d, in2d, in3d, irhd,   &
270            &   jpni, jpnj, jpnij, narea, jpiglo, jpjglo,   &
271            &   nlcit, nlcjt, nldit, nldjt, nleit, nlejt, nimppt, njmppt
272         IF( (ivnum * (jpvnl + wp)) > irecl8 ) THEN
273            CALL ctl_stop( TRIM(clinfo),   &
274                 &   'Last record size is too big... You could reduce the value of jpvnl' )
275         ELSE
276            WRITE( idrst, REC = irhd, IOSTAT = ios, ERR = 987 )    &
277                 &   clna0d(1:in0d), zval0d(1:in0d), clna1d(1:in1d), zval1d(1:in1d),   &
278                 &   clna2d(1:in2d), zval2d(1:in2d), clna3d(1:in3d), zval3d(1:in3d)
279         ENDIF
280      ELSE
281         ios = 0   ! we cannot write in the file
282      ENDIF
283      !
284      CLOSE( idrst, IOSTAT = ios, ERR = 987 )
285987   CONTINUE
286      IF( ios /= 0 ) THEN
287         WRITE(ctmp1,*) '           iostat = ', ios
288         CALL ctl_stop( TRIM(clinfo),   &
289            &   '   error when updating the header of '//TRIM(iom_file(kiomid)%name), ctmp1 )
290      ENDIF
291      !   
292   END SUBROUTINE iom_rstdimg_close
293
294
295   SUBROUTINE iom_rstdimg_g0d( kiomid, kvid, pvar )
296      !!-----------------------------------------------------------------------
297      !!                  ***  ROUTINE  iom_rstdimg_g0d  ***
298      !!
299      !! ** Purpose : read a scalar with RSTDIMG
300      !!-----------------------------------------------------------------------
301      INTEGER,  INTENT(in   ) ::   kiomid    ! Identifier of the file
302      INTEGER,  INTENT(in   ) ::   kvid      ! variable id
303      REAL(wp), INTENT(  out) ::   pvar      ! read field
304      !---------------------------------------------------------------------
305      !
306      pvar = iom_file(kiomid)%ofs(kvid)   ! warning: trick... we use ofs to store the value
307      !
308   END SUBROUTINE iom_rstdimg_g0d
309
310
311   SUBROUTINE iom_rstdimg_rp0d( kiomid, cdvar, pv_r0d )
312      !!--------------------------------------------------------------------
313      !!                   ***  SUBROUTINE  iom_rstdimg_rstput  ***
314      !!
315      !! ** Purpose : write a scalar with RSTDIMG
316      !!--------------------------------------------------------------------
317      INTEGER                   , INTENT(in) ::   kiomid   ! Identifier of the file
318      CHARACTER(len=*)          , INTENT(in) ::   cdvar    ! time axis name
319      REAL(wp)                  , INTENT(in) ::   pv_r0d   ! written 0d field
320      !
321      CHARACTER(LEN=100) ::   clinfo     ! info character
322      INTEGER            ::   idvar      ! variable id
323      !---------------------------------------------------------------------
324      ! 
325      clinfo = '                    iom_rstdimg_rp0d ~~~  '
326      idvar = iom_file(kiomid)%nvars + 1
327      IF( idvar <= jpmax_vars ) THEN
328         iom_file(kiomid)%nvars = idvar
329         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
330         iom_file(kiomid)%nvid(   idvar) = 1   ! useless, Od variables a strored in record 1
331         iom_file(kiomid)%ndims(  idvar) = 0
332         iom_file(kiomid)%luld(   idvar) = .FALSE.
333         iom_file(kiomid)%scf(    idvar) = 1.
334         iom_file(kiomid)%ofs(    idvar) = pv_r0d   ! warning: trick... we use ofs to store the value
335      ELSE
336         CALL ctl_stop( TRIM(clinfo), 'increase the value of jpmax_vars' )
337      ENDIF
338   END SUBROUTINE iom_rstdimg_rp0d
339
340
341   SUBROUTINE iom_rstdimg_g123d( kiomid, kdom  , kvid  , kstart, kcount,    &
342         &                          pv_r1d, pv_r2d, pv_r3d )
343      !!-----------------------------------------------------------------------
344      !!                  ***  ROUTINE  iom_rstdimg_g123d  ***
345      !!
346      !! ** Purpose : read a 1D/2D/3D variable with RSTDIMG
347      !!
348      !! ** Method : read ONE record at each CALL
349      !!-----------------------------------------------------------------------
350      INTEGER                    , INTENT(in   )           ::   kiomid     ! iom identifier of the file
351      INTEGER                    , INTENT(in   )           ::   kdom       ! Type of domain to be read
352      INTEGER                    , INTENT(in   )           ::   kvid       ! variable id
353      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart     ! start position of the reading in each axis
354      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount     ! number of points to be read in each axis
355      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d     ! read field (1D case)
356      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d     ! read field (2D case)
357      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d     ! read field (3D case)
358
359      CHARACTER(LEN=100) ::   clinfo               ! info character
360      INTEGER            ::   ios                  ! IO status
361      INTEGER            ::   jk                   ! loop counter
362      INTEGER            ::   idrst                ! logical unit of the restart file
363      INTEGER            ::   istop                ! temporary storage of nstop
364      INTEGER            ::   ix1, ix2, iy1, iy2   ! subdomain indexes
365      !---------------------------------------------------------------------
366      clinfo = '                    iom_rstdimg_g123d ~~~  '
367      !
368      istop = nstop                   ! store the actual value of nstop
369      idrst = iom_file(kiomid)%nfid   ! get back the logical unit of the restart file
370      IF( kdom == jpdom_data .OR. kdom == jpdom_global )   &
371            &   CALL ctl_stop( TRIM(clinfo), TRIM(iom_file(kiomid)%cn_var(kvid))//': case not coded for rstdimg files' )
372      !
373      IF( istop == nstop .AND. kvid > 0 ) THEN
374         IF( .NOT. PRESENT(pv_r1d) ) THEN
375            SELECT CASE (kdom)   ! find the right index of the array to be read
376            CASE (jpdom_local_full)      ;   ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
377            CASE (jpdom_local_noextra)   ;   ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
378            CASE (jpdom_local_noovlap)   ;   ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
379            CASE DEFAULT                 ;   CALL ctl_stop( clinfo, 'we should not be there...' )
380            END SELECT
381         ENDIF
382         IF(     PRESENT(pv_r1d) ) THEN   ! read 1D variables
383            READ( idrst, REC = iom_file(kiomid)%nvid(kvid), IOSTAT = ios, ERR = 987 )   pv_r1d(:)
384         ELSEIF( PRESENT(pv_r2d) ) THEN   ! read 2D variables
385            READ( idrst, REC = iom_file(kiomid)%nvid(kvid), IOSTAT = ios, ERR = 987 )   pv_r2d(ix1:ix2, iy1:iy2 )
386            SELECT CASE (kdom)
387            CASE (jpdom_local_noextra)   !--- Fill extra hallows (mpp)       
388               pv_r2d(nlci+1:jpi,      :   ) = 1.   
389               pv_r2d(      :   ,nlcj+1:jpj) = 1.           
390            CASE (jpdom_local_noovlap)   !--- Fill the overlap areas and extra hallows (mpp)
391               CALL lbc_lnk (pv_r2d,'Z',-999.,'no0')
392            CASE DEFAULT
393            END SELECT
394         ELSEIF( PRESENT(pv_r3d) ) THEN   ! read 3D variables
395            DO jk = 1, iom_file(kiomid)%dimsz(3,kvid)   ! do loop on each level
396               READ( idrst, REC = iom_file(kiomid)%nvid(kvid) + jk - 1, IOSTAT = ios, ERR = 987 )   &
397                     &      pv_r3d( ix1:ix2, iy1:iy2, jk )
398            END DO
399            SELECT CASE (kdom)
400            CASE (jpdom_local_noextra)   !--- Fill extra hallows (mpp)       
401               pv_r3d(nlci+1:jpi,      :   ,:) = 1.   
402               pv_r3d(      :   ,nlcj+1:jpj,:) = 1.           
403            CASE (jpdom_local_noovlap)   !--- Fill the overlap areas and extra hallows (mpp)
404               ! this if could be simplified with the new lbc_lnk that works with any size of the 3rd dimension
405               IF( kcount(3) == jpk ) THEN
406                  CALL lbc_lnk( pv_r3d,'Z',-999.,'no0' )
407               ELSE
408                  pv_r3d(nlei+1:jpi,      :   ,:) = 1.           
409                  pv_r3d(      :   ,nlej+1:jpj,:) = 1.           
410               ENDIF
411            CASE DEFAULT
412            END SELECT
413         ENDIF
414      ENDIF
415987   CONTINUE
416      IF( ios /= 0 ) THEN
417         WRITE(ctmp1,*) '           iostat = ', ios
418         CALL ctl_stop( TRIM(clinfo), '   IO error with file '//TRIM(iom_file(kiomid)%name), ctmp1 )
419      ENDIF
420      !
421   END SUBROUTINE iom_rstdimg_g123d
422
423
424   SUBROUTINE iom_rstdimg_rp123d( kiomid, cdvar, pv_r1d, pv_r2d, pv_r3d )
425      !!--------------------------------------------------------------------
426      !!                   ***  SUBROUTINE  iom_rstdimg_rstput  ***
427      !!
428      !! ** Purpose : write a 2D/3D variable with RSTDIMG
429      !!--------------------------------------------------------------------
430      INTEGER                         , INTENT(in)           ::   kiomid   ! Identifier of the file
431      CHARACTER(len=*)                , INTENT(in)           ::   cdvar    ! time axis name
432      REAL(wp), DIMENSION(        jpk), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
433      REAL(wp), DIMENSION(jpi,jpj    ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
434      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
435      !
436      CHARACTER(LEN=100)    ::   clinfo               ! info character
437      INTEGER               ::   irecl8               ! reacord length
438      INTEGER               ::   ios                  ! IO status
439      INTEGER               ::   idrst                ! reacord length
440      INTEGER               ::   inx, iny, inz        ! x,y,z dimension of the variable
441      INTEGER               ::   idvar                ! variable id
442      INTEGER               ::   istop                ! temporary storage of nstop
443      INTEGER               ::   irec                 ! record number
444      INTEGER               ::   ix1, ix2, iy1, iy2   ! subdomain indexes
445      INTEGER               ::   jk                   ! loop counter
446      !---------------------------------------------------------------------
447      !
448      clinfo = '          iom_rstdimg_rp123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
449      istop = nstop                   ! store the actual value of nstop
450      irec = iom_file(kiomid)%irec    ! get back the record number of the variable
451      idrst = iom_file(kiomid)%nfid   ! get back the logical unit of the restart file
452      idvar = iom_file(kiomid)%nvars + 1
453      IF( idvar > jpmax_vars )   CALL ctl_stop( TRIM(clinfo), 'increase the value of jpmax_vars' )
454      IF( .NOT. PRESENT(pv_r1d) ) THEN
455         ! find which part of data must be written
456         READ( idrst, REC = 1, IOSTAT = ios, ERR = 987 ) irecl8, inx, iny, inz
457         IF(     inx == (nlei - nldi + 1) .AND. iny == (nlej - nldj + 1) ) THEN
458            ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
459         ELSEIF( inx == nlci              .AND. iny == nlcj              ) THEN
460            ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
461         ELSEIF( inx == jpi               .AND. iny == jpj               ) THEN
462            ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
463         ELSE
464            CALL ctl_stop( clinfo, 'should have been an impossible case...' )
465         ENDIF
466      ENDIF
467      IF( istop == nstop ) THEN
468         ! write the data
469         IF(     PRESENT(pv_r1d) ) THEN   ! 1D variable
470            WRITE( idrst, REC = irec            , IOSTAT = ios, ERR = 987 ) pv_r1d(:)
471         ELSEIF( PRESENT(pv_r2d) ) THEN   ! 2D variable
472            WRITE( idrst, REC = irec            , IOSTAT = ios, ERR = 987 ) pv_r2d(ix1:ix2, iy1:iy2    )
473         ELSEIF( PRESENT(pv_r3d) ) THEN   ! 3D variable
474            DO jk = 1, jpk   ! do loop on each level
475               WRITE( idrst, REC = irec + jk - 1, IOSTAT = ios, ERR = 987 ) pv_r3d(ix1:ix2, iy1:iy2, jk)
476            END DO
477         ENDIF
478         ! fill the file informations
479         iom_file(kiomid)%nvars = idvar
480         IF(     PRESENT(pv_r1d) ) THEN
481            iom_file(kiomid)%irec              = irec + 1
482            iom_file(kiomid)%ndims(     idvar) = 1
483            iom_file(kiomid)%dimsz(1  , idvar) = inz
484         ELSEIF( PRESENT(pv_r2d) ) THEN
485            iom_file(kiomid)%irec              = irec + 1
486            iom_file(kiomid)%ndims(     idvar) = 2
487            iom_file(kiomid)%dimsz(1:2, idvar) = (/ inx, iny /)
488         ELSEIF( PRESENT(pv_r3d) ) THEN
489            iom_file(kiomid)%irec              = irec + inz
490            iom_file(kiomid)%ndims(     idvar) = 3
491            iom_file(kiomid)%dimsz(1:3, idvar) = (/ inx, iny, inz /)
492         ENDIF
493         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
494         iom_file(kiomid)%nvid(  idvar) = irec
495         iom_file(kiomid)%luld(  idvar) = .FALSE.
496         iom_file(kiomid)%scf(   idvar) = 1.
497         iom_file(kiomid)%ofs(   idvar) = 0.
498      ENDIF
499987   CONTINUE
500      IF( ios /= 0 ) THEN
501         WRITE(ctmp1,*) '           iostat = ', ios
502         CALL ctl_stop( TRIM(clinfo), '   IO error with file '//TRIM(iom_file(kiomid)%name), ctmp1 )
503      ELSE
504         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
505      ENDIF
506      !     
507   END SUBROUTINE iom_rstdimg_rp123d
508
509
510   !!======================================================================
511END MODULE iom_rstdimg
Note: See TracBrowser for help on using the repository browser.