New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iom_rstdimg.F90 in trunk/NEMO/OPA_SRC/IOM – NEMO

source: trunk/NEMO/OPA_SRC/IOM/iom_rstdimg.F90 @ 642

Last change on this file since 642 was 611, checked in by opalod, 17 years ago

nemo_v2_bugfix_015 : CT+SM : - correct dimg header record

  • overwrite variable in existing file
  • make good comments in ocean.output file related to time step write in restart file
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 29.4 KB
Line 
1MODULE iom_rstdimg
2   !!=====================================================================
3   !!                    ***  MODULE  iom_rstdimg ***
4   !! Input/Output manager :  Library to read input rstdimg files
5   !!====================================================================
6   !! History :  9.0  ! 06 09  (S. Masson) Original code
7   !!--------------------------------------------------------------------
8
9   !!--------------------------------------------------------------------
10   !!   iom_open       : open a file read only
11   !!   iom_close      : close a file or all files opened by iom
12   !!   iom_get        : read a field (interfaced to several routines)
13   !!   iom_gettime    : read the time axis kvid in the file
14   !!   iom_varid      : get the id of a variable in a file
15   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
16   !!--------------------------------------------------------------------
17   USE in_out_manager  ! I/O manager
18   USE dom_oce         ! ocean space and time domain
19   USE lbclnk          ! lateal boundary condition / mpp exchanges
20   USE iom_def         ! iom variables definitions
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC iom_rstdimg_open, iom_rstdimg_close, iom_rstdimg_get, iom_rstdimg_rstput
26
27   INTERFACE iom_rstdimg_get
28      MODULE PROCEDURE iom_rstdimg_g0d, iom_rstdimg_g123d
29   END INTERFACE
30   INTERFACE iom_rstdimg_rstput
31      MODULE PROCEDURE iom_rstdimg_rp0d, iom_rstdimg_rp123d
32   END INTERFACE
33
34   INTEGER, PARAMETER ::   jpvnl          = 32   ! variable name length
35     
36   !!----------------------------------------------------------------------
37   !!  OPA 9.0 , LOCEAN-IPSL (2006)
38   !! $Header$
39   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
40   !!----------------------------------------------------------------------
41
42CONTAINS
43
44   SUBROUTINE iom_rstdimg_open( cdname, kiomid, ldwrt, ldok, kdompar )
45      !!---------------------------------------------------------------------
46      !!                   ***  SUBROUTINE  iom_open  ***
47      !!
48      !! ** Purpose :  open an input file read only (return 0 if not found)
49      !!---------------------------------------------------------------------
50      CHARACTER(len=*)       , INTENT(inout) ::   cdname   ! File name
51      INTEGER                , INTENT(  out) ::   kiomid   ! iom identifier of the opened file
52      LOGICAL                , INTENT(in   ) ::   ldwrt    ! read or write the file?
53      LOGICAL                , INTENT(in   ) ::   ldok     ! check the existence
54      INTEGER, DIMENSION(2,5), INTENT(in   ) ::   kdompar  ! domain parameters:
55
56      CHARACTER(LEN=100)                      ::   clinfo                     ! info character
57      CHARACTER(LEN=100)                      ::   cltmp                      ! temporary character
58      INTEGER                                 ::   jv                         ! loop counter
59      INTEGER                                 ::   istop                      ! temporary storage of nstop
60      INTEGER                                 ::   idrst                      ! logical unit of the restart file
61      INTEGER                                 ::   iln                        ! lengths of character
62      INTEGER                                 ::   irecl8                     ! record length
63      INTEGER                                 ::   ios                        ! IO status
64      INTEGER                                 ::   irhd                       ! record of the header infos
65      INTEGER                                 ::   ivnum                      ! number of variables
66      INTEGER                                 ::   ishft                      ! counter shift
67      INTEGER                                 ::   inx, iny, inz              ! x,y,z dimension of the variable
68      INTEGER                                 ::   in0d, in1d, in2d, in3d     ! number of 0/1/2/3D variables
69      INTEGER                                 ::   ipni, ipnj, ipnij, iarea   ! domain decomposition
70      INTEGER                                 ::   iiglo, ijglo               ! domain global size
71      INTEGER                                 ::   jl                         ! loop variable
72      CHARACTER(LEN=jpvnl), DIMENSION(jpmax_vars) ::   clna0d, clna1d, clna2d, clna3d     ! name of 0/1/2/3D variables
73      REAL(wp),         DIMENSION(jpmax_vars) ::   zval0d, zval1d, zval2d, zval3d     ! value of 0d variables or record
74      !                                                                               ! position for 1/2/3D variables
75      !---------------------------------------------------------------------
76      clinfo = '                    iom_rstdimg_open ~~~  '
77      istop = nstop      ! store the actual value of nstop
78      ios = 0            ! default definition
79      kiomid = 0         ! default definition
80      ! get a free unit
81      idrst = getunit()  ! get a free logical unit for the restart file
82!!$#if defined key_agrif
83!!$      idrst = Agrif_Get_Unit()     
84!!$#endif
85      ! Open the file...
86      ! =============
87      IF( ldok ) THEN      ! Open existing file...
88         ! find the record length
89         OPEN( idrst, FILE = TRIM(cdname), FORM = 'unformatted', ACCESS = 'direct'   &
90            &       , RECL = 8, STATUS = 'old', ACTION = 'read', IOSTAT = ios, ERR = 987 )
91         READ( idrst, REC = 1, IOSTAT = ios, ERR = 987 ) irecl8
92         CLOSE( idrst )
93         ! Open the file with the appropriate record length and parameters
94         IF( ldwrt ) THEN  ! ... in readwrite mode
95            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READWRITE mode'
96            OPEN( idrst, FILE = TRIM(cdname), FORM = 'unformatted', ACCESS = 'direct'   &
97               &       , RECL = irecl8, STATUS = 'old', ACTION = 'readwrite', IOSTAT = ios, ERR = 987 )
98         ELSE              ! ... in read mode
99            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
100            OPEN( idrst, FILE = TRIM(cdname), FORM = 'unformatted', ACCESS = 'direct'   &
101               &       , RECL = irecl8, STATUS = 'old', ACTION = 'read'     , IOSTAT = ios, ERR = 987 )
102         ENDIF
103      ELSE                 ! the file does not exist
104         iln = INDEX( cdname, '.dimg' )
105         IF( ldwrt ) THEN  ! the file should be open in readwrite mode so we create it...
106            irecl8= MAX( kdompar(1,1) * kdompar(2,1) * wp, ( 8*jpnij + 15 ) * 4 )
107            IF( jpnij > 1 ) THEN
108               WRITE(cltmp,'(a,a,i4.4,a)') cdname(1:iln-1), '_', narea-1, '.dimg'
109               cdname = TRIM(cltmp)
110            ENDIF
111            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in READWRITE mode'
112            OPEN( idrst, FILE = TRIM(cdname), FORM = 'UNFORMATTED', ACCESS = 'DIRECT'   &
113               &       , RECL = irecl8, STATUS = 'new', ACTION = 'readwrite', IOSTAT = ios, ERR = 987 )
114         ELSE              ! the file should be open for read mode so it must exist...
115            CALL ctl_stop( TRIM(clinfo), 'File '//cdname(1:iln-1)//'* not found' )
116         ENDIF
117      ENDIF
118      ! Performs checks on the file
119      ! =============
120      IF( ldok ) THEN      ! old file
121         READ( idrst, REC = 1   , IOSTAT = ios, ERR = 987 )              &
122              &   irecl8, inx, iny, inz, in0d, in1d, in2d, in3d, irhd,   &
123              &   ipni, ipnj, ipnij, iarea, iiglo, ijglo
124         READ( idrst, REC = irhd, IOSTAT = ios, ERR = 987 )                       &
125            &   clna0d(1:in0d), zval0d(1:in0d), clna1d(1:in1d), zval1d(1:in1d),   &
126            &   clna2d(1:in2d), zval2d(1:in2d), clna3d(1:in3d), zval3d(1:in3d)
127         clinfo = TRIM(clinfo)//' file '//TRIM(cdname)
128         IF( iiglo /= jpiglo       )   CALL ctl_stop( TRIM(clinfo), 'Mismatch in global domain size in i direction' )
129         IF( ijglo /= jpjglo       )   CALL ctl_stop( TRIM(clinfo), 'Mismatch in global domain size in j direction' )
130         IF( inx   /= kdompar(1,1) )   CALL ctl_stop( TRIM(clinfo), 'Mismatch in local domain size in i direction' )
131         IF( iny   /= kdompar(2,1) )   CALL ctl_stop( TRIM(clinfo), 'Mismatch in local domain size in j direction' )
132         IF( inz   /= jpk          )   CALL ctl_stop( TRIM(clinfo), 'Mismatch in domain size in k direction' )
133         IF( ipni  /= jpni         )   CALL ctl_stop( TRIM(clinfo), 'Processor splitting changed along I' )
134         IF( ipnj  /= jpnj         )   CALL ctl_stop( TRIM(clinfo), 'Processor splitting changed along J' )
135         IF( ipnij /= jpnij        )   CALL ctl_stop( TRIM(clinfo), 'Total number of processors changed' )
136         IF( iarea /= narea        )   CALL ctl_stop( TRIM(clinfo), 'Mismatch in area numbering ...' )
137      ENDIF
138      ! fill file informations
139      ! =============
140      IF( istop == nstop ) THEN   ! no error within this routine
141!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
142         kiomid = 0
143         DO jl = jpmax_files, 1, -1
144            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
145         ENDDO
146         iom_file(kiomid)%name    = TRIM(cdname)
147         iom_file(kiomid)%nfid    = idrst
148         iom_file(kiomid)%iolib   = jprstdimg
149         iom_file(kiomid)%iduld   = -1
150         IF( ldok ) THEN      ! old file
151            ! read variables informations from the file header
152            IF(  TRIM(clna0d(1)) == 'no0d' )   in0d = 0
153            IF(  TRIM(clna1d(1)) == 'no1d' )   in1d = 0
154            IF(  TRIM(clna2d(1)) == 'no2d' )   in2d = 0
155            IF(  TRIM(clna3d(1)) == 'no3d' )   in3d = 0
156            ivnum = in0d + in1d + in2d + in3d
157            iom_file(kiomid)%nvars            = ivnum
158            iom_file(kiomid)%irec             = 2 + in1d + in2d + inz * in3d
159            iom_file(kiomid)%luld(   1:ivnum) = .FALSE.
160            iom_file(kiomid)%scf(    1:ivnum) = 1.
161            ! scalar variable
162            DO jv = 1, in0d
163               iom_file(kiomid)%cn_var(jv) = TRIM(clna0d(jv))
164               iom_file(kiomid)%nvid(  jv) = 1
165               iom_file(kiomid)%ndims( jv) = 0
166               iom_file(kiomid)%ofs(   jv) = zval0d(jv)   ! warning: trick... we use ofs to store the value
167            END DO
168            ! 1d variable
169            ishft = in0d
170            DO jv = 1, in1d
171               iom_file(kiomid)%cn_var(    ishft + jv) = TRIM(clna1d(jv))
172               iom_file(kiomid)%nvid(      ishft + jv) = zval1d(jv)
173               iom_file(kiomid)%ndims(     ishft + jv) = 1
174               iom_file(kiomid)%dimsz(1  , ishft + jv) = jpk
175               iom_file(kiomid)%ofs(       ishft + jv) = 0.
176            END DO
177            ! 2d variable
178            ishft = in0d + in1d
179            DO jv = 1, in2d
180               iom_file(kiomid)%cn_var(    ishft + jv) = TRIM(clna2d(jv))
181               iom_file(kiomid)%nvid(      ishft + jv) = zval2d(jv)
182               iom_file(kiomid)%ndims(     ishft + jv) = 2
183               iom_file(kiomid)%dimsz(1:2, ishft + jv) = (/ inx, iny /)
184               iom_file(kiomid)%ofs(       ishft + jv) = 0.
185            END DO
186            ! 3d variable
187            ishft = in0d + in1d + in2d 
188            DO jv = 1, in3d
189               iom_file(kiomid)%cn_var(    ishft + jv) = TRIM(clna3d(jv))
190               iom_file(kiomid)%nvid(      ishft + jv) = zval3d(jv)
191               iom_file(kiomid)%ndims(     ishft + jv) = 3
192               iom_file(kiomid)%dimsz(1:3, ishft + jv) = (/ inx, iny, jpk /)
193               iom_file(kiomid)%ofs(       ishft + jv) = 0.
194            END DO
195         ELSE                 ! new file
196            iom_file(kiomid)%nvars = 0
197            iom_file(kiomid)%irec  = 2
198            ! store file informations
199            WRITE( idrst, REC = 1, IOSTAT = ios, ERR = 987 ) irecl8, kdompar(:,1), jpk   ! store domain size
200         ENDIF
201      ENDIF
202987   CONTINUE
203      IF( ios /= 0 ) THEN
204         WRITE(ctmp1,*) '           iostat = ', ios
205         CALL ctl_stop( TRIM(clinfo), '   error in opening file '//TRIM(cdname), ctmp1 )
206      ENDIF
207      !
208   END SUBROUTINE iom_rstdimg_open
209
210
211   SUBROUTINE iom_rstdimg_close( kiomid )
212      !!--------------------------------------------------------------------
213      !!                   ***  SUBROUTINE  iom_rstdimg_close  ***
214      !!
215      !! ** Purpose : close an input file
216      !!--------------------------------------------------------------------
217      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
218      !
219      CHARACTER(LEN=100)                      ::   clinfo                     ! info character
220      INTEGER                                 ::   jv                         ! loop counter
221      INTEGER                                 ::   irecl8                     ! record length
222      INTEGER                                 ::   ios                        ! IO status
223      INTEGER                                 ::   irhd                       ! record of the header infos
224      INTEGER                                 ::   ivnum                      ! number of variables
225      INTEGER                                 ::   idrst                      ! file logical unit
226      INTEGER                                 ::   inx, iny, inz              ! x,y,z dimension of the variable
227      INTEGER                                 ::   in0d, in1d, in2d, in3d     ! number of 0/1/2/3D variables
228      CHARACTER(LEN=jpvnl), DIMENSION(jpmax_vars) ::   clna0d, clna1d, clna2d, clna3d    ! name of 0/1/2/3D variables
229      REAL(wp),          DIMENSION(jpmax_vars) ::   zval0d, zval1d, zval2d, zval3d    ! value of 0d variables or record
230      !                                                                               ! position for 1/2/3D variables
231      !---------------------------------------------------------------------
232      !
233      clinfo = '                    iom_rstdimg_close ~~~  '
234      idrst = iom_file(kiomid)%nfid   ! get back the logical unit of the restart file
235      ! test if we can write in the file (test with INQUIRE gives alsways YES even with read only files...)
236      READ(  idrst, REC = 1, IOSTAT = ios, ERR = 987 ) irecl8, inx, iny, inz   
237      WRITE( idrst, REC = 1, IOSTAT = ios            ) irecl8, inx, iny, inz   
238      ! We can write in the file => we update its header before closing
239      IF( ios == 0 ) THEN
240         READ( idrst, REC = 1, IOSTAT = ios, ERR = 987 ) irecl8, inx, iny, inz   ! get back domain size
241         irhd = iom_file(kiomid)%irec
242         ivnum = iom_file(kiomid)%nvars
243         in0d = 0   ;   in1d = 0   ;   in2d = 0   ;   in3d = 0
244         DO jv = 1, ivnum   ! loop on each variable to get its name and value/record position
245            SELECT CASE (iom_file(kiomid)%ndims(jv))
246            CASE (0)   ! scalar variable
247               in0d = in0d + 1
248               clna0d(in0d) = TRIM(iom_file(kiomid)%cn_var(jv))
249               zval0d(in0d) = iom_file(kiomid)%ofs(jv)   ! warning: trick... we use ofs to store the value
250            CASE (1)   ! 1d variable
251               in1d = in1d + 1
252               clna1d(in1d) = TRIM(iom_file(kiomid)%cn_var(jv))
253               zval1d(in1d) = iom_file(kiomid)%nvid(jv)
254            CASE (2)   ! 2d variable
255               in2d = in2d + 1
256               clna2d(in2d) = TRIM(iom_file(kiomid)%cn_var(jv))
257               zval2d(in2d) = iom_file(kiomid)%nvid(jv)
258            CASE (3)   ! 3d variable
259               in3d = in3d + 1
260               clna3d(in3d) = TRIM(iom_file(kiomid)%cn_var(jv))
261               zval3d(in3d) = iom_file(kiomid)%nvid(jv)
262            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo), 'Should not ne there...' )
263            END SELECT
264         END DO
265         ! force to have at least 1 variable in each list (not necessary (?), but safer...)
266         IF( in0d == 0 ) THEN   ;   in0d = 1   ;   clna0d(1) = 'no0d'   ;   zval0d(1) = -1.   ;   ENDIF
267         IF( in1d == 0 ) THEN   ;   in1d = 1   ;   clna1d(1) = 'no1d'   ;   zval1d(1) = -1.   ;   ENDIF
268         IF( in2d == 0 ) THEN   ;   in2d = 1   ;   clna2d(1) = 'no2d'   ;   zval2d(1) = -1.   ;   ENDIF
269         IF( in3d == 0 ) THEN   ;   in3d = 1   ;   clna3d(1) = 'no3d'   ;   zval3d(1) = -1.   ;   ENDIF
270         ! update the file header before closing it
271         WRITE( idrst, REC = 1, IOSTAT = ios, ERR = 987 )              &
272            &   irecl8, inx, iny, inz, in0d, in1d, in2d, in3d, irhd,   &
273            &   jpni, jpnj, jpnij, narea, jpiglo, jpjglo,              &
274            &   nlcit, nlcjt, nldit, nldjt, nleit, nlejt, nimppt, njmppt
275         IF( (ivnum * (jpvnl + wp)) > irecl8 ) THEN
276            CALL ctl_stop( TRIM(clinfo),   &
277                 &   'Last record size is too big... You could reduce the value of jpvnl' )
278         ELSE
279            WRITE( idrst, REC = irhd, IOSTAT = ios, ERR = 987 )                        &
280                 &   clna0d(1:in0d), zval0d(1:in0d), clna1d(1:in1d), zval1d(1:in1d),   &
281                 &   clna2d(1:in2d), zval2d(1:in2d), clna3d(1:in3d), zval3d(1:in3d)
282         ENDIF
283      ELSE
284         ios = 0   ! we cannot write in the file
285      ENDIF
286      !
287      CLOSE( idrst, IOSTAT = ios, ERR = 987 )
288987   CONTINUE
289      IF( ios /= 0 ) THEN
290         WRITE(ctmp1,*) '           iostat = ', ios
291         CALL ctl_stop( TRIM(clinfo),   &
292            &   '   error when updating the header of '//TRIM(iom_file(kiomid)%name), ctmp1 )
293      ENDIF
294      !   
295   END SUBROUTINE iom_rstdimg_close
296
297
298   SUBROUTINE iom_rstdimg_g0d( kiomid, kvid, pvar )
299      !!-----------------------------------------------------------------------
300      !!                  ***  ROUTINE  iom_rstdimg_g0d  ***
301      !!
302      !! ** Purpose : read a scalar with RSTDIMG
303      !!-----------------------------------------------------------------------
304      INTEGER,  INTENT(in   ) ::   kiomid    ! Identifier of the file
305      INTEGER,  INTENT(in   ) ::   kvid      ! variable id
306      REAL(wp), INTENT(  out) ::   pvar      ! read field
307      !---------------------------------------------------------------------
308      !
309      pvar = iom_file(kiomid)%ofs(kvid)   ! warning: trick... we use ofs to store the value
310      !
311   END SUBROUTINE iom_rstdimg_g0d
312
313
314   SUBROUTINE iom_rstdimg_rp0d( kiomid, cdvar, kvid, pv_r0d )
315      !!--------------------------------------------------------------------
316      !!                   ***  SUBROUTINE  iom_rstdimg_rstput  ***
317      !!
318      !! ** Purpose : write a scalar with RSTDIMG
319      !!--------------------------------------------------------------------
320      INTEGER                   , INTENT(in) ::   kiomid   ! Identifier of the file
321      CHARACTER(len=*)          , INTENT(in) ::   cdvar    ! time axis name
322      INTEGER                   , INTENT(in) ::   kvid     ! variable id
323      REAL(wp)                  , INTENT(in) ::   pv_r0d   ! written 0d field
324      !
325      CHARACTER(LEN=100) ::   clinfo     ! info character
326      INTEGER            ::   idvar      ! variable id
327      !---------------------------------------------------------------------
328      ! 
329      clinfo = '                    iom_rstdimg_rp0d ~~~  '
330      IF( kvid <= 0 ) THEN   !   new variable
331         idvar = iom_file(kiomid)%nvars + 1
332      ELSE                   !   the variable already exists in the file
333         idvar = kvid
334      ENDIF
335      IF( idvar <= jpmax_vars ) THEN
336         iom_file(kiomid)%nvars = idvar
337         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
338         iom_file(kiomid)%nvid(   idvar) = 1   ! useless, Od variables a strored in record 1
339         iom_file(kiomid)%ndims(  idvar) = 0
340         iom_file(kiomid)%luld(   idvar) = .FALSE.
341         iom_file(kiomid)%scf(    idvar) = 1.
342         iom_file(kiomid)%ofs(    idvar) = pv_r0d   ! warning: trick... we use ofs to store the value
343      ELSE
344         CALL ctl_stop( TRIM(clinfo), 'increase the value of jpmax_vars' )
345      ENDIF
346   END SUBROUTINE iom_rstdimg_rp0d
347
348
349   SUBROUTINE iom_rstdimg_g123d( kiomid, kdom  , kvid  , kstart, kcount,    &
350         &                          pv_r1d, pv_r2d, pv_r3d )
351      !!-----------------------------------------------------------------------
352      !!                  ***  ROUTINE  iom_rstdimg_g123d  ***
353      !!
354      !! ** Purpose : read a 1D/2D/3D variable with RSTDIMG
355      !!
356      !! ** Method : read ONE record at each CALL
357      !!-----------------------------------------------------------------------
358      INTEGER                    , INTENT(in   )           ::   kiomid     ! iom identifier of the file
359      INTEGER                    , INTENT(in   )           ::   kdom       ! Type of domain to be read
360      INTEGER                    , INTENT(in   )           ::   kvid       ! variable id
361      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart     ! start position of the reading in each axis
362      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount     ! number of points to be read in each axis
363      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d     ! read field (1D case)
364      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d     ! read field (2D case)
365      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d     ! read field (3D case)
366
367      CHARACTER(LEN=100) ::   clinfo               ! info character
368      INTEGER            ::   ios                  ! IO status
369      INTEGER            ::   jk                   ! loop counter
370      INTEGER            ::   idrst                ! logical unit of the restart file
371      INTEGER            ::   istop                ! temporary storage of nstop
372      INTEGER            ::   ix1, ix2, iy1, iy2   ! subdomain indexes
373      !---------------------------------------------------------------------
374      clinfo = '                    iom_rstdimg_g123d ~~~  '
375      !
376      istop = nstop                   ! store the actual value of nstop
377      idrst = iom_file(kiomid)%nfid   ! get back the logical unit of the restart file
378      IF( kdom == jpdom_data .OR. kdom == jpdom_global )   &
379            &   CALL ctl_stop( TRIM(clinfo), TRIM(iom_file(kiomid)%cn_var(kvid))//': case not coded for rstdimg files' )
380      !
381      IF( istop == nstop .AND. kvid > 0 ) THEN
382         IF( .NOT. PRESENT(pv_r1d) ) THEN
383            SELECT CASE (kdom)   ! find the right index of the array to be read
384            CASE (jpdom_local_full)      ;   ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
385            CASE (jpdom_local_noextra)   ;   ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
386            CASE (jpdom_local_noovlap)   ;   ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
387            CASE DEFAULT                 ;   CALL ctl_stop( clinfo, 'we should not be there...' )
388            END SELECT
389         ENDIF
390         IF(     PRESENT(pv_r1d) ) THEN   ! read 1D variables
391            READ( idrst, REC = iom_file(kiomid)%nvid(kvid), IOSTAT = ios, ERR = 987 )   pv_r1d(:)
392         ELSEIF( PRESENT(pv_r2d) ) THEN   ! read 2D variables
393            READ( idrst, REC = iom_file(kiomid)%nvid(kvid), IOSTAT = ios, ERR = 987 )   pv_r2d(ix1:ix2, iy1:iy2 )
394            SELECT CASE (kdom)
395            CASE (jpdom_local_noextra)   !--- Fill extra hallows (mpp)       
396               pv_r2d(nlci+1:jpi,      :   ) = 1.   
397               pv_r2d(      :   ,nlcj+1:jpj) = 1.           
398            CASE (jpdom_local_noovlap)   !--- Fill the overlap areas and extra hallows (mpp)
399               CALL lbc_lnk (pv_r2d,'Z',-999.,'no0')
400            CASE DEFAULT
401            END SELECT
402         ELSEIF( PRESENT(pv_r3d) ) THEN   ! read 3D variables
403            DO jk = 1, iom_file(kiomid)%dimsz(3,kvid)   ! do loop on each level
404               READ( idrst, REC = iom_file(kiomid)%nvid(kvid) + jk - 1, IOSTAT = ios, ERR = 987 )   &
405                     &      pv_r3d( ix1:ix2, iy1:iy2, jk )
406            END DO
407            SELECT CASE (kdom)
408            CASE (jpdom_local_noextra)   !--- Fill extra hallows (mpp)       
409               pv_r3d(nlci+1:jpi,      :   ,:) = 1.   
410               pv_r3d(      :   ,nlcj+1:jpj,:) = 1.           
411            CASE (jpdom_local_noovlap)   !--- Fill the overlap areas and extra hallows (mpp)
412               ! this if could be simplified with the new lbc_lnk that works with any size of the 3rd dimension
413               IF( kcount(3) == jpk ) THEN
414                  CALL lbc_lnk( pv_r3d,'Z',-999.,'no0' )
415               ELSE
416                  pv_r3d(nlei+1:jpi,      :   ,:) = 1.           
417                  pv_r3d(      :   ,nlej+1:jpj,:) = 1.           
418               ENDIF
419            CASE DEFAULT
420            END SELECT
421         ENDIF
422      ENDIF
423987   CONTINUE
424      IF( ios /= 0 ) THEN
425         WRITE(ctmp1,*) '           iostat = ', ios
426         CALL ctl_stop( TRIM(clinfo), '   IO error with file '//TRIM(iom_file(kiomid)%name), ctmp1 )
427      ENDIF
428      !
429   END SUBROUTINE iom_rstdimg_g123d
430
431
432   SUBROUTINE iom_rstdimg_rp123d( kiomid, cdvar, kvid, pv_r1d, pv_r2d, pv_r3d )
433      !!--------------------------------------------------------------------
434      !!                   ***  SUBROUTINE  iom_rstdimg_rstput  ***
435      !!
436      !! ** Purpose : write a 2D/3D variable with RSTDIMG
437      !!--------------------------------------------------------------------
438      INTEGER                         , INTENT(in)           ::   kiomid   ! Identifier of the file
439      CHARACTER(len=*)                , INTENT(in)           ::   cdvar    ! time axis name
440      INTEGER                         , INTENT(in)           ::   kvid     ! variable id
441      REAL(wp), DIMENSION(        jpk), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
442      REAL(wp), DIMENSION(jpi,jpj    ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
443      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
444      !
445      CHARACTER(LEN=100)    ::   clinfo               ! info character
446      INTEGER               ::   irecl8               ! reacord length
447      INTEGER               ::   ios                  ! IO status
448      INTEGER               ::   idrst                ! reacord length
449      INTEGER               ::   inx, iny, inz        ! x,y,z dimension of the variable
450      INTEGER               ::   idvar                ! variable id
451      INTEGER               ::   istop                ! temporary storage of nstop
452      INTEGER               ::   irec                 ! record number
453      INTEGER               ::   ix1, ix2, iy1, iy2   ! subdomain indexes
454      INTEGER               ::   jk                   ! loop counter
455      !---------------------------------------------------------------------
456      !
457      clinfo = '          iom_rstdimg_rp123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
458      istop = nstop                   ! store the actual value of nstop
459      irec = iom_file(kiomid)%irec    ! get back the record number of the variable
460      idrst = iom_file(kiomid)%nfid   ! get back the logical unit of the restart file
461      IF( kvid <= 0 ) THEN   !   new variable
462         idvar = iom_file(kiomid)%nvars + 1
463      ELSE                   !   the variable already exists in the file
464         idvar = kvid
465      ENDIF
466      IF( idvar > jpmax_vars )   CALL ctl_stop( TRIM(clinfo), 'increase the value of jpmax_vars' )
467      IF( .NOT. PRESENT(pv_r1d) ) THEN
468         ! find which part of data must be written
469         READ( idrst, REC = 1, IOSTAT = ios, ERR = 987 ) irecl8, inx, iny, inz
470         IF(     inx == (nlei - nldi + 1) .AND. iny == (nlej - nldj + 1) ) THEN
471            ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
472         ELSEIF( inx == nlci              .AND. iny == nlcj              ) THEN
473            ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
474         ELSEIF( inx == jpi               .AND. iny == jpj               ) THEN
475            ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
476         ELSE
477            CALL ctl_stop( clinfo, 'should have been an impossible case...' )
478         ENDIF
479      ENDIF
480      IF( istop == nstop ) THEN
481         ! write the data
482         IF(     PRESENT(pv_r1d) ) THEN   ! 1D variable
483            WRITE( idrst, REC = irec            , IOSTAT = ios, ERR = 987 ) pv_r1d(:)
484         ELSEIF( PRESENT(pv_r2d) ) THEN   ! 2D variable
485            WRITE( idrst, REC = irec            , IOSTAT = ios, ERR = 987 ) pv_r2d(ix1:ix2, iy1:iy2    )
486         ELSEIF( PRESENT(pv_r3d) ) THEN   ! 3D variable
487            DO jk = 1, jpk   ! do loop on each level
488               WRITE( idrst, REC = irec + jk - 1, IOSTAT = ios, ERR = 987 ) pv_r3d(ix1:ix2, iy1:iy2, jk)
489            END DO
490         ENDIF
491         ! fill the file informations
492         iom_file(kiomid)%nvars = idvar
493         IF(     PRESENT(pv_r1d) ) THEN
494            iom_file(kiomid)%irec              = irec + 1
495            iom_file(kiomid)%ndims(     idvar) = 1
496            iom_file(kiomid)%dimsz(1  , idvar) = inz
497         ELSEIF( PRESENT(pv_r2d) ) THEN
498            iom_file(kiomid)%irec              = irec + 1
499            iom_file(kiomid)%ndims(     idvar) = 2
500            iom_file(kiomid)%dimsz(1:2, idvar) = (/ inx, iny /)
501         ELSEIF( PRESENT(pv_r3d) ) THEN
502            iom_file(kiomid)%irec              = irec + inz
503            iom_file(kiomid)%ndims(     idvar) = 3
504            iom_file(kiomid)%dimsz(1:3, idvar) = (/ inx, iny, inz /)
505         ENDIF
506         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
507         iom_file(kiomid)%nvid(  idvar) = irec
508         iom_file(kiomid)%luld(  idvar) = .FALSE.
509         iom_file(kiomid)%scf(   idvar) = 1.
510         iom_file(kiomid)%ofs(   idvar) = 0.
511      ENDIF
512987   CONTINUE
513      IF( ios /= 0 ) THEN
514         WRITE(ctmp1,*) '           iostat = ', ios
515         CALL ctl_stop( TRIM(clinfo), '   IO error with file '//TRIM(iom_file(kiomid)%name), ctmp1 )
516      ELSE
517         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
518      ENDIF
519      !     
520   END SUBROUTINE iom_rstdimg_rp123d
521
522
523   !!======================================================================
524END MODULE iom_rstdimg
Note: See TracBrowser for help on using the repository browser.