1 | MODULE ldfeiv |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE ldfeiv *** |
---|
4 | !! Ocean physics: variable eddy induced velocity coefficients |
---|
5 | !!====================================================================== |
---|
6 | #if defined key_traldf_eiv && defined key_traldf_c2d |
---|
7 | !!---------------------------------------------------------------------- |
---|
8 | !! 'key_traldf_eiv' and eddy induced velocity |
---|
9 | !! 'key_traldf_c2d' 2D tracer lateral mixing coef. |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | !! ldf_eiv : compute the eddy induced velocity coefficients |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! * Modules used |
---|
14 | USE oce ! ocean dynamics and tracers |
---|
15 | USE dom_oce ! ocean space and time domain |
---|
16 | USE sbc_oce ! surface boundary condition: ocean |
---|
17 | USE sbcrnf ! river runoffs |
---|
18 | USE ldftra_oce ! ocean tracer lateral physics |
---|
19 | USE phycst ! physical constants |
---|
20 | USE ldfslp ! iso-neutral slopes |
---|
21 | USE in_out_manager ! I/O manager |
---|
22 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
23 | USE prtctl ! Print control |
---|
24 | |
---|
25 | IMPLICIT NONE |
---|
26 | PRIVATE |
---|
27 | |
---|
28 | !! * Routine accessibility |
---|
29 | PUBLIC ldf_eiv ! routine called by step.F90 |
---|
30 | !!---------------------------------------------------------------------- |
---|
31 | !! OPA 9.0 , LOCEAN-IPSL (2005) |
---|
32 | !! $Id$ |
---|
33 | !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt |
---|
34 | !!---------------------------------------------------------------------- |
---|
35 | !! * Substitutions |
---|
36 | # include "domzgr_substitute.h90" |
---|
37 | # include "vectopt_loop_substitute.h90" |
---|
38 | !!---------------------------------------------------------------------- |
---|
39 | |
---|
40 | CONTAINS |
---|
41 | |
---|
42 | SUBROUTINE ldf_eiv( kt ) |
---|
43 | !!---------------------------------------------------------------------- |
---|
44 | !! *** ROUTINE ldf_eiv *** |
---|
45 | !! |
---|
46 | !! ** Purpose : Compute the eddy induced velocity coefficient from the |
---|
47 | !! growth rate of baroclinic instability. |
---|
48 | !! |
---|
49 | !! ** Method : |
---|
50 | !! |
---|
51 | !! ** Action : - uslp(), : i- and j-slopes of neutral surfaces |
---|
52 | !! - vslp() at u- and v-points, resp. |
---|
53 | !! - wslpi(), : i- and j-slopes of neutral surfaces |
---|
54 | !! - wslpj() at w-points. |
---|
55 | !! |
---|
56 | !! History : |
---|
57 | !! 8.1 ! 99-03 (G. Madec, A. Jouzeau) Original code |
---|
58 | !! 8.5 ! 02-06 (G. Madec) Free form, F90 |
---|
59 | !!---------------------------------------------------------------------- |
---|
60 | !! * Arguments |
---|
61 | INTEGER, INTENT( in ) :: kt ! ocean time-step inedx |
---|
62 | |
---|
63 | !! * Local declarations |
---|
64 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
65 | REAL(wp) :: & |
---|
66 | zfw, ze3w, zn2, zf20, & ! temporary scalars |
---|
67 | zaht, zaht_min |
---|
68 | REAL(wp), DIMENSION(jpi,jpj) :: & |
---|
69 | zn, zah, zhw, zross ! workspace |
---|
70 | !!---------------------------------------------------------------------- |
---|
71 | |
---|
72 | IF( kt == nit000 ) THEN |
---|
73 | IF(lwp) WRITE(numout,*) |
---|
74 | IF(lwp) WRITE(numout,*) 'ldf_eiv : eddy induced velocity coefficients' |
---|
75 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
---|
76 | ENDIF |
---|
77 | |
---|
78 | ! 0. Local initialization |
---|
79 | ! ----------------------- |
---|
80 | zn (:,:) = 0.e0 |
---|
81 | zhw (:,:) = 5.e0 |
---|
82 | zah (:,:) = 0.e0 |
---|
83 | zross(:,:) = 0.e0 |
---|
84 | |
---|
85 | |
---|
86 | ! 1. Compute lateral diffusive coefficient |
---|
87 | ! ---------------------------------------- |
---|
88 | |
---|
89 | DO jk = 1, jpk |
---|
90 | # if defined key_vectopt_loop |
---|
91 | !CDIR NOVERRCHK |
---|
92 | DO ji = 1, jpij ! vector opt. |
---|
93 | ! Take the max of N^2 and zero then take the vertical sum |
---|
94 | ! of the square root of the resulting N^2 ( required to compute |
---|
95 | ! internal Rossby radius Ro = .5 * sum_jpk(N) / f |
---|
96 | zn2 = MAX( rn2(ji,1,jk), 0.e0 ) |
---|
97 | zn(ji,1) = zn(ji,1) + SQRT( zn2 ) * fse3w(ji,1,jk) |
---|
98 | ! Compute elements required for the inverse time scale of baroclinic |
---|
99 | ! eddies using the isopycnal slopes calculated in ldfslp.F : |
---|
100 | ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w)) |
---|
101 | ze3w = fse3w(ji,1,jk) * tmask(ji,1,jk) |
---|
102 | zah(ji,1) = zah(ji,1) + zn2 & |
---|
103 | * ( wslpi(ji,1,jk) * wslpi(ji,1,jk) & |
---|
104 | + wslpj(ji,1,jk) * wslpj(ji,1,jk) ) & |
---|
105 | * ze3w |
---|
106 | zhw(ji,1) = zhw(ji,1) + ze3w |
---|
107 | END DO |
---|
108 | # else |
---|
109 | DO jj = 2, jpjm1 |
---|
110 | !CDIR NOVERRCHK |
---|
111 | DO ji = 2, jpim1 |
---|
112 | ! Take the max of N^2 and zero then take the vertical sum |
---|
113 | ! of the square root of the resulting N^2 ( required to compute |
---|
114 | ! internal Rossby radius Ro = .5 * sum_jpk(N) / f |
---|
115 | zn2 = MAX( rn2(ji,jj,jk), 0.e0 ) |
---|
116 | zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * fse3w(ji,jj,jk) |
---|
117 | ! Compute elements required for the inverse time scale of baroclinic |
---|
118 | ! eddies using the isopycnal slopes calculated in ldfslp.F : |
---|
119 | ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w)) |
---|
120 | ze3w = fse3w(ji,jj,jk) * tmask(ji,jj,jk) |
---|
121 | zah(ji,jj) = zah(ji,jj) + zn2 & |
---|
122 | * ( wslpi(ji,jj,jk) * wslpi(ji,jj,jk) & |
---|
123 | + wslpj(ji,jj,jk) * wslpj(ji,jj,jk) ) & |
---|
124 | * ze3w |
---|
125 | zhw(ji,jj) = zhw(ji,jj) + ze3w |
---|
126 | END DO |
---|
127 | END DO |
---|
128 | # endif |
---|
129 | END DO |
---|
130 | |
---|
131 | DO jj = 2, jpjm1 |
---|
132 | !CDIR NOVERRCHK |
---|
133 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
134 | zfw = MAX( ABS( 2. * omega * SIN( rad * gphit(ji,jj) ) ) , 1.e-10 ) |
---|
135 | ! Rossby radius at w-point taken < 40km and > 2km |
---|
136 | zross(ji,jj) = MAX( MIN( .4 * zn(ji,jj) / zfw, 40.e3 ), 2.e3 ) |
---|
137 | ! Compute aeiw by multiplying Ro^2 and T^-1 |
---|
138 | aeiw(ji,jj) = zross(ji,jj) * zross(ji,jj) * SQRT( zah(ji,jj) / zhw(ji,jj) ) * tmask(ji,jj,1) |
---|
139 | END DO |
---|
140 | END DO |
---|
141 | |
---|
142 | IF( cp_cfg == "orca" .AND. jp_cfg == 2 ) THEN ! ORCA R02 |
---|
143 | DO jj = 2, jpjm1 |
---|
144 | !CDIR NOVERRCHK |
---|
145 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
146 | ! Take the minimum between aeiw and aeiv0 for depth levels |
---|
147 | ! lower than 20 (21 in w- point) |
---|
148 | IF( mbathy(ji,jj) <= 21. ) aeiw(ji,jj) = MIN( aeiw(ji,jj), 1000. ) |
---|
149 | END DO |
---|
150 | END DO |
---|
151 | ENDIF |
---|
152 | |
---|
153 | ! Decrease the coefficient in the tropics (20N-20S) |
---|
154 | zf20 = 2. * omega * sin( rad * 20. ) |
---|
155 | DO jj = 2, jpjm1 |
---|
156 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
157 | aeiw(ji,jj) = MIN( 1., ABS( ff(ji,jj) / zf20 ) ) * aeiw(ji,jj) |
---|
158 | END DO |
---|
159 | END DO |
---|
160 | |
---|
161 | ! ORCA R05: Take the minimum between aeiw and aeiv0 |
---|
162 | IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN |
---|
163 | DO jj = 2, jpjm1 |
---|
164 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
165 | aeiw(ji,jj) = MIN( aeiw(ji,jj), aeiv0 ) |
---|
166 | END DO |
---|
167 | END DO |
---|
168 | ENDIF |
---|
169 | |
---|
170 | ! lateral boundary condition on aeiw |
---|
171 | CALL lbc_lnk( aeiw, 'W', 1. ) |
---|
172 | |
---|
173 | ! Average the diffusive coefficient at u- v- points |
---|
174 | DO jj = 2, jpjm1 |
---|
175 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
176 | aeiu(ji,jj) = .5 * ( aeiw(ji,jj) + aeiw(ji+1,jj ) ) |
---|
177 | aeiv(ji,jj) = .5 * ( aeiw(ji,jj) + aeiw(ji ,jj+1) ) |
---|
178 | END DO |
---|
179 | END DO |
---|
180 | |
---|
181 | ! lateral boundary condition on aeiu, aeiv |
---|
182 | CALL lbc_lnk( aeiu, 'U', 1. ) |
---|
183 | CALL lbc_lnk( aeiv, 'V', 1. ) |
---|
184 | |
---|
185 | IF(ln_ctl) THEN |
---|
186 | CALL prt_ctl(tab2d_1=aeiu, clinfo1=' eiv - u: ', ovlap=1) |
---|
187 | CALL prt_ctl(tab2d_1=aeiv, clinfo1=' eiv - v: ', ovlap=1) |
---|
188 | ENDIF |
---|
189 | |
---|
190 | ! ORCA R05: add a space variation on aht (=aeiv except at the equator and river mouth) |
---|
191 | IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN |
---|
192 | zf20 = 2. * omega * SIN( rad * 20. ) |
---|
193 | zaht_min = 100. ! minimum value for aht |
---|
194 | DO jj = 1, jpj |
---|
195 | DO ji = 1, jpi |
---|
196 | zaht = ( 1. - MIN( 1., ABS( ff(ji,jj) / zf20 ) ) ) * ( aht0 - zaht_min ) & |
---|
197 | & + aht0 * rnfmsk(ji,jj) ! enhanced near river mouths |
---|
198 | ahtu(ji,jj) = MAX( MAX( zaht_min, aeiu(ji,jj) ) + zaht, aht0 ) |
---|
199 | ahtv(ji,jj) = MAX( MAX( zaht_min, aeiv(ji,jj) ) + zaht, aht0 ) |
---|
200 | ahtw(ji,jj) = MAX( MAX( zaht_min, aeiw(ji,jj) ) + zaht, aht0 ) |
---|
201 | END DO |
---|
202 | END DO |
---|
203 | IF(ln_ctl) THEN |
---|
204 | CALL prt_ctl(tab2d_1=ahtu, clinfo1=' aht - u: ', ovlap=1) |
---|
205 | CALL prt_ctl(tab2d_1=ahtv, clinfo1=' aht - v: ', ovlap=1) |
---|
206 | CALL prt_ctl(tab2d_1=ahtw, clinfo1=' aht - w: ', ovlap=1) |
---|
207 | ENDIF |
---|
208 | ENDIF |
---|
209 | |
---|
210 | IF( aeiv0 == 0.e0 ) THEN |
---|
211 | aeiu(:,:) = 0.e0 |
---|
212 | aeiv(:,:) = 0.e0 |
---|
213 | aeiw(:,:) = 0.e0 |
---|
214 | ENDIF |
---|
215 | |
---|
216 | END SUBROUTINE ldf_eiv |
---|
217 | |
---|
218 | #else |
---|
219 | !!---------------------------------------------------------------------- |
---|
220 | !! Default option Dummy module |
---|
221 | !!---------------------------------------------------------------------- |
---|
222 | CONTAINS |
---|
223 | SUBROUTINE ldf_eiv( kt ) ! Empty routine |
---|
224 | WRITE(*,*) 'ldf_eiv: You should not have seen this print! error?', kt |
---|
225 | END SUBROUTINE ldf_eiv |
---|
226 | #endif |
---|
227 | |
---|
228 | !!====================================================================== |
---|
229 | END MODULE ldfeiv |
---|