| 1 | MODULE ldfeiv |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE ldfeiv *** |
|---|
| 4 | !! Ocean physics: variable eddy induced velocity coefficients |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | #if defined key_traldf_eiv && defined key_traldf_c2d |
|---|
| 7 | !!---------------------------------------------------------------------- |
|---|
| 8 | !! 'key_traldf_eiv' and eddy induced velocity |
|---|
| 9 | !! 'key_traldf_c2d' 2D tracer lateral mixing coef. |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! ldf_eiv : compute the eddy induced velocity coefficients |
|---|
| 12 | !! Same results but not same routine if 'key_autotasking' |
|---|
| 13 | !! is defined or not |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! * Modules used |
|---|
| 16 | USE oce ! ocean dynamics and tracers |
|---|
| 17 | USE dom_oce ! ocean space and time domain |
|---|
| 18 | USE ldftra_oce ! ocean tracer lateral physics |
|---|
| 19 | USE phycst ! physical constants |
|---|
| 20 | USE ldfslp ! iso-neutral slopes |
|---|
| 21 | USE flxrnf ! |
|---|
| 22 | USE in_out_manager ! I/O manager |
|---|
| 23 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 24 | |
|---|
| 25 | IMPLICIT NONE |
|---|
| 26 | PRIVATE |
|---|
| 27 | |
|---|
| 28 | !! * Routine accessibility |
|---|
| 29 | PUBLIC ldf_eiv ! routine called by step.F90 |
|---|
| 30 | |
|---|
| 31 | !! * Substitutions |
|---|
| 32 | # include "domzgr_substitute.h90" |
|---|
| 33 | # include "vectopt_loop_substitute.h90" |
|---|
| 34 | !!---------------------------------------------------------------------- |
|---|
| 35 | |
|---|
| 36 | CONTAINS |
|---|
| 37 | |
|---|
| 38 | # if defined key_autotasking |
|---|
| 39 | !!---------------------------------------------------------------------- |
|---|
| 40 | !! 'key_autotasking' : autotasking (j-slab) |
|---|
| 41 | !!---------------------------------------------------------------------- |
|---|
| 42 | |
|---|
| 43 | SUBROUTINE ldf_eiv( kt ) |
|---|
| 44 | !!---------------------------------------------------------------------- |
|---|
| 45 | !! *** ROUTINE ldf_eiv *** |
|---|
| 46 | !! |
|---|
| 47 | !! ** Purpose : Compute the eddy induced velocity coefficient from the |
|---|
| 48 | !! growth rate of baroclinic instability. |
|---|
| 49 | !! |
|---|
| 50 | !! ** Method : |
|---|
| 51 | !! |
|---|
| 52 | !! ** Action : uslp(), : i- and j-slopes of neutral surfaces |
|---|
| 53 | !! vslp() at u- and v-points, resp. |
|---|
| 54 | !! wslpi(), : i- and j-slopes of neutral surfaces |
|---|
| 55 | !! wslpj() at w-points. |
|---|
| 56 | !! |
|---|
| 57 | !! History : |
|---|
| 58 | !! 8.1 ! 99-03 (G. Madec, A. Jouzeau) Original code |
|---|
| 59 | !! 8.5 ! 02-06 (G. Madec) Free form, F90 |
|---|
| 60 | !!---------------------------------------------------------------------- |
|---|
| 61 | !! * Arguments |
|---|
| 62 | INTEGER, INTENT( in ) :: kt ! ocean time-step inedx |
|---|
| 63 | |
|---|
| 64 | !! * Local declarations |
|---|
| 65 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 66 | REAL(wp) :: & |
|---|
| 67 | zfw, ze3w, zn2, zf20, & ! temporary scalars |
|---|
| 68 | zaht, zaht_min |
|---|
| 69 | REAL(wp), DIMENSION(jpi,jpj) :: & |
|---|
| 70 | zn, zah, zhw, zross ! workspace |
|---|
| 71 | !!---------------------------------------------------------------------- |
|---|
| 72 | |
|---|
| 73 | IF( kt == nit000 ) THEN |
|---|
| 74 | IF(lwp) WRITE(numout,*) |
|---|
| 75 | IF(lwp) WRITE(numout,*) 'ldf_eiv : eddy induced velocity coefficients' |
|---|
| 76 | IF(lwp) WRITE(numout,*) '~~~~~~~ key_autotasking' |
|---|
| 77 | ENDIF |
|---|
| 78 | |
|---|
| 79 | ! ! =============== |
|---|
| 80 | DO jj = 2, jpjm1 ! Vertical slab |
|---|
| 81 | ! ! =============== |
|---|
| 82 | |
|---|
| 83 | ! 0. Local initialization |
|---|
| 84 | ! ----------------------- |
|---|
| 85 | zn (:,jj) = 0.e0 |
|---|
| 86 | zhw (:,jj) = 5.e0 |
|---|
| 87 | zah (:,jj) = 0.e0 |
|---|
| 88 | zross(:,jj) = 0.e0 |
|---|
| 89 | |
|---|
| 90 | ! 1. Compute lateral diffusive coefficient |
|---|
| 91 | ! ---------------------------------------- |
|---|
| 92 | |
|---|
| 93 | !CDIR NOVERRCHK |
|---|
| 94 | DO jk = 1, jpk |
|---|
| 95 | !CDIR NOVERRCHK |
|---|
| 96 | DO ji = 2, jpim1 |
|---|
| 97 | ! Take the max of N^2 and zero then take the vertical sum |
|---|
| 98 | ! of the square root of the resulting N^2 ( required to compute |
|---|
| 99 | ! internal Rossby radius Ro = .5 * sum_jpk(N) / f |
|---|
| 100 | zn2 = MAX( rn2(ji,jj,jk), 0.e0 ) |
|---|
| 101 | ze3w = fse3w(ji,jj,jk) * tmask(ji,jj,jk) |
|---|
| 102 | zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * fse3w(ji,jj,jk) |
|---|
| 103 | ! Compute elements required for the inverse time scale of baroclinic |
|---|
| 104 | ! eddies using the isopycnal slopes calculated in ldfslp.F : |
|---|
| 105 | ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w)) |
|---|
| 106 | zah(ji,jj) = zah(ji,jj) + zn2 & |
|---|
| 107 | * ( wslpi(ji,jj,jk) * wslpi(ji,jj,jk) & |
|---|
| 108 | + wslpj(ji,jj,jk) * wslpj(ji,jj,jk) ) & |
|---|
| 109 | * ze3w |
|---|
| 110 | zhw(ji,jj) = zhw(ji,jj) + ze3w |
|---|
| 111 | END DO |
|---|
| 112 | END DO |
|---|
| 113 | |
|---|
| 114 | !CDIR NOVERRCHK |
|---|
| 115 | DO ji = 2, jpim1 |
|---|
| 116 | zfw = MAX( ABS( 2. * omega * SIN( rad * gphit(ji,jj) ) ) , 1.e-10 ) |
|---|
| 117 | ! Rossby radius at w-point taken < 40km and > 2km |
|---|
| 118 | zross(ji,jj) = MAX( MIN( .4 * zn(ji,jj) / zfw, 40.e3 ), 2.e3 ) |
|---|
| 119 | ! Compute aeiw by multiplying Ro^2 and T^-1 |
|---|
| 120 | aeiw(ji,jj) = zross(ji,jj) * zross(ji,jj) * SQRT( zah(ji,jj) / zhw(ji,jj) ) * tmask(ji,jj,1) |
|---|
| 121 | ! Take the minimum between aeiw and 1000m^2/s for depth levels |
|---|
| 122 | ! lower than 20 (21 in w- point) |
|---|
| 123 | IF( mbathy(ji,jj) <= 21. ) aeiw(ji,jj) = MIN( aeiw(ji,jj), 1000. ) |
|---|
| 124 | END DO |
|---|
| 125 | |
|---|
| 126 | ! Decrease the coefficient in the tropics (20N-20S) |
|---|
| 127 | zf20 = 2. * omega * sin( rad * 20. ) |
|---|
| 128 | DO ji = 2, jpim1 |
|---|
| 129 | aeiw(ji,jj) = MIN( 1., ABS( ff(ji,jj) / zf20 ) ) * aeiw(ji,jj) |
|---|
| 130 | END DO |
|---|
| 131 | |
|---|
| 132 | ! ORCA R05: Take the minimum between aeiw and 1000m2/s |
|---|
| 133 | IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN ! ORCA R05 |
|---|
| 134 | DO ji = 2, jpim1 |
|---|
| 135 | aeiw(ji,jj) = MIN( aeiw(ji,jj), 1000. ) |
|---|
| 136 | END DO |
|---|
| 137 | ENDIF |
|---|
| 138 | ! ! =============== |
|---|
| 139 | END DO ! End of slab |
|---|
| 140 | ! ! =============== |
|---|
| 141 | |
|---|
| 142 | !,,,,,,,,,,,,,,,,,,,,,,,,,,,,,synchro,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,, |
|---|
| 143 | |
|---|
| 144 | ! lateral boundary condition on aeiw |
|---|
| 145 | CALL lbc_lnk( aeiw, 'W', 1. ) |
|---|
| 146 | |
|---|
| 147 | ! Average the diffusive coefficient at u- v- points |
|---|
| 148 | DO jj = 2, jpjm1 |
|---|
| 149 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 150 | aeiu(ji,jj) = .5 * (aeiw(ji,jj) + aeiw(ji+1,jj )) |
|---|
| 151 | aeiv(ji,jj) = .5 * (aeiw(ji,jj) + aeiw(ji ,jj+1)) |
|---|
| 152 | END DO |
|---|
| 153 | END DO |
|---|
| 154 | !,,,,,,,,,,,,,,,,,,,,,,,,,,,,,synchro,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,, |
|---|
| 155 | |
|---|
| 156 | ! lateral boundary condition on aeiu, aeiv |
|---|
| 157 | CALL lbc_lnk( aeiu, 'U', 1. ) |
|---|
| 158 | CALL lbc_lnk( aeiv, 'V', 1. ) |
|---|
| 159 | |
|---|
| 160 | IF(l_ctl) WRITE(numout,*) ' eiv - u: ', SUM( aeiu(:,:) ), ' v: ', SUM( aeiv(:,:) ) |
|---|
| 161 | |
|---|
| 162 | |
|---|
| 163 | ! ORCA R05: add a space variation on aht (=aeiv except at the equator and river mouth) |
|---|
| 164 | IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN |
|---|
| 165 | zf20 = 2. * omega * SIN( rad * 20. ) |
|---|
| 166 | zaht_min = 100. ! minimum value for aht |
|---|
| 167 | DO jj = 1, jpj |
|---|
| 168 | DO ji = 1, jpi |
|---|
| 169 | zaht = ( 1. - MIN( 1., ABS( ff(ji,jj) / zf20 ) ) ) * ( aht0 - zaht_min ) & |
|---|
| 170 | & + aht0 * upsrnfh(ji,jj) ! enhanced near river mouths |
|---|
| 171 | ahtu(ji,jj) = MAX( zaht_min, aeiu(ji,jj) ) + zaht |
|---|
| 172 | ahtv(ji,jj) = MAX( zaht_min, aeiv(ji,jj) ) + zaht |
|---|
| 173 | ahtw(ji,jj) = MAX( zaht_min, aeiw(ji,jj) ) + zaht |
|---|
| 174 | END DO |
|---|
| 175 | END DO |
|---|
| 176 | IF(l_ctl) WRITE(numout,*) ' aht - u: ', SUM( ahtu(:,:) ), ' v: ', SUM( ahtv(:,:) ), ' w: ', SUM( ahtw(:,:) ) |
|---|
| 177 | ENDIF |
|---|
| 178 | |
|---|
| 179 | END SUBROUTINE ldf_eiv |
|---|
| 180 | |
|---|
| 181 | # else |
|---|
| 182 | !!---------------------------------------------------------------------- |
|---|
| 183 | !! Default key k-j-i loops |
|---|
| 184 | !!---------------------------------------------------------------------- |
|---|
| 185 | |
|---|
| 186 | SUBROUTINE ldf_eiv( kt ) |
|---|
| 187 | !!---------------------------------------------------------------------- |
|---|
| 188 | !! *** ROUTINE ldf_eiv *** |
|---|
| 189 | !! |
|---|
| 190 | !! ** Purpose : Compute the eddy induced velocity coefficient from the |
|---|
| 191 | !! growth rate of baroclinic instability. |
|---|
| 192 | !! |
|---|
| 193 | !! ** Method : |
|---|
| 194 | !! |
|---|
| 195 | !! ** Action : - uslp(), : i- and j-slopes of neutral surfaces |
|---|
| 196 | !! - vslp() at u- and v-points, resp. |
|---|
| 197 | !! - wslpi(), : i- and j-slopes of neutral surfaces |
|---|
| 198 | !! - wslpj() at w-points. |
|---|
| 199 | !! |
|---|
| 200 | !! History : |
|---|
| 201 | !! 8.1 ! 99-03 (G. Madec, A. Jouzeau) Original code |
|---|
| 202 | !! 8.5 ! 02-06 (G. Madec) Free form, F90 |
|---|
| 203 | !!---------------------------------------------------------------------- |
|---|
| 204 | !! * Arguments |
|---|
| 205 | INTEGER, INTENT( in ) :: kt ! ocean time-step inedx |
|---|
| 206 | |
|---|
| 207 | !! * Local declarations |
|---|
| 208 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 209 | REAL(wp) :: & |
|---|
| 210 | zfw, ze3w, zn2, zf20, & ! temporary scalars |
|---|
| 211 | zaht, zaht_min |
|---|
| 212 | REAL(wp), DIMENSION(jpi,jpj) :: & |
|---|
| 213 | zn, zah, zhw, zross ! workspace |
|---|
| 214 | !!---------------------------------------------------------------------- |
|---|
| 215 | |
|---|
| 216 | IF( kt == nit000 ) THEN |
|---|
| 217 | IF(lwp) WRITE(numout,*) |
|---|
| 218 | IF(lwp) WRITE(numout,*) 'ldf_eiv : eddy induced velocity coefficients' |
|---|
| 219 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
|---|
| 220 | ENDIF |
|---|
| 221 | |
|---|
| 222 | ! 0. Local initialization |
|---|
| 223 | ! ----------------------- |
|---|
| 224 | zn (:,:) = 0.e0 |
|---|
| 225 | zhw (:,:) = 5.e0 |
|---|
| 226 | zah (:,:) = 0.e0 |
|---|
| 227 | zross(:,:) = 0.e0 |
|---|
| 228 | |
|---|
| 229 | |
|---|
| 230 | ! 1. Compute lateral diffusive coefficient |
|---|
| 231 | ! ---------------------------------------- |
|---|
| 232 | |
|---|
| 233 | DO jk = 1, jpk |
|---|
| 234 | # if defined key_vectopt_loop && ! defined key_autotasking |
|---|
| 235 | !CDIR NOVERRCHK |
|---|
| 236 | DO ji = 1, jpij ! vector opt. |
|---|
| 237 | ! Take the max of N^2 and zero then take the vertical sum |
|---|
| 238 | ! of the square root of the resulting N^2 ( required to compute |
|---|
| 239 | ! internal Rossby radius Ro = .5 * sum_jpk(N) / f |
|---|
| 240 | zn2 = MAX( rn2(ji,1,jk), 0.e0 ) |
|---|
| 241 | zn(ji,1) = zn(ji,1) + SQRT( zn2 ) * fse3w(ji,1,jk) |
|---|
| 242 | ! Compute elements required for the inverse time scale of baroclinic |
|---|
| 243 | ! eddies using the isopycnal slopes calculated in ldfslp.F : |
|---|
| 244 | ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w)) |
|---|
| 245 | ze3w = fse3w(ji,1,jk) * tmask(ji,1,jk) |
|---|
| 246 | zah(ji,1) = zah(ji,1) + zn2 & |
|---|
| 247 | * ( wslpi(ji,1,jk) * wslpi(ji,1,jk) & |
|---|
| 248 | + wslpj(ji,1,jk) * wslpj(ji,1,jk) ) & |
|---|
| 249 | * ze3w |
|---|
| 250 | zhw(ji,1) = zhw(ji,1) + ze3w |
|---|
| 251 | END DO |
|---|
| 252 | # else |
|---|
| 253 | DO jj = 2, jpjm1 |
|---|
| 254 | !CDIR NOVERRCHK |
|---|
| 255 | DO ji = 2, jpim1 |
|---|
| 256 | ! Take the max of N^2 and zero then take the vertical sum |
|---|
| 257 | ! of the square root of the resulting N^2 ( required to compute |
|---|
| 258 | ! internal Rossby radius Ro = .5 * sum_jpk(N) / f |
|---|
| 259 | zn2 = MAX( rn2(ji,jj,jk), 0.e0 ) |
|---|
| 260 | zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * fse3w(ji,jj,jk) |
|---|
| 261 | ! Compute elements required for the inverse time scale of baroclinic |
|---|
| 262 | ! eddies using the isopycnal slopes calculated in ldfslp.F : |
|---|
| 263 | ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w)) |
|---|
| 264 | ze3w = fse3w(ji,jj,jk) * tmask(ji,jj,jk) |
|---|
| 265 | zah(ji,jj) = zah(ji,jj) + zn2 & |
|---|
| 266 | * ( wslpi(ji,jj,jk) * wslpi(ji,jj,jk) & |
|---|
| 267 | + wslpj(ji,jj,jk) * wslpj(ji,jj,jk) ) & |
|---|
| 268 | * ze3w |
|---|
| 269 | zhw(ji,jj) = zhw(ji,jj) + ze3w |
|---|
| 270 | END DO |
|---|
| 271 | END DO |
|---|
| 272 | # endif |
|---|
| 273 | END DO |
|---|
| 274 | |
|---|
| 275 | DO jj = 2, jpjm1 |
|---|
| 276 | !CDIR NOVERRCHK |
|---|
| 277 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 278 | zfw = MAX( ABS( 2. * omega * SIN( rad * gphit(ji,jj) ) ) , 1.e-10 ) |
|---|
| 279 | ! Rossby radius at w-point taken < 40km and > 2km |
|---|
| 280 | zross(ji,jj) = MAX( MIN( .4 * zn(ji,jj) / zfw, 40.e3 ), 2.e3 ) |
|---|
| 281 | ! Compute aeiw by multiplying Ro^2 and T^-1 |
|---|
| 282 | aeiw(ji,jj) = zross(ji,jj) * zross(ji,jj) * SQRT( zah(ji,jj) / zhw(ji,jj) ) * tmask(ji,jj,1) |
|---|
| 283 | ! Take the minimum between aeiw and 1000m^2/s for depth levels |
|---|
| 284 | ! lower than 20 (21 in w- point) |
|---|
| 285 | IF( mbathy(ji,jj) <= 21. ) aeiw(ji,jj) = MIN( aeiw(ji,jj), 1000. ) |
|---|
| 286 | END DO |
|---|
| 287 | END DO |
|---|
| 288 | |
|---|
| 289 | ! Decrease the coefficient in the tropics (20N-20S) |
|---|
| 290 | zf20 = 2. * omega * sin( rad * 20. ) |
|---|
| 291 | DO jj = 2, jpjm1 |
|---|
| 292 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 293 | aeiw(ji,jj) = MIN( 1., ABS( ff(ji,jj) / zf20 ) ) * aeiw(ji,jj) |
|---|
| 294 | END DO |
|---|
| 295 | END DO |
|---|
| 296 | |
|---|
| 297 | ! ORCA R05: Take the minimum between aeiw and 1000m2/s |
|---|
| 298 | IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN |
|---|
| 299 | DO jj = 2, jpjm1 |
|---|
| 300 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 301 | aeiw(ji,jj) = MIN( aeiw(ji,jj), aeiv0 ) |
|---|
| 302 | END DO |
|---|
| 303 | END DO |
|---|
| 304 | ENDIF |
|---|
| 305 | |
|---|
| 306 | ! lateral boundary condition on aeiw |
|---|
| 307 | CALL lbc_lnk( aeiw, 'W', 1. ) |
|---|
| 308 | |
|---|
| 309 | ! Average the diffusive coefficient at u- v- points |
|---|
| 310 | DO jj = 2, jpjm1 |
|---|
| 311 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 312 | aeiu(ji,jj) = .5 * ( aeiw(ji,jj) + aeiw(ji+1,jj ) ) |
|---|
| 313 | aeiv(ji,jj) = .5 * ( aeiw(ji,jj) + aeiw(ji ,jj+1) ) |
|---|
| 314 | END DO |
|---|
| 315 | END DO |
|---|
| 316 | |
|---|
| 317 | ! lateral boundary condition on aeiu, aeiv |
|---|
| 318 | CALL lbc_lnk( aeiu, 'U', 1. ) |
|---|
| 319 | CALL lbc_lnk( aeiv, 'V', 1. ) |
|---|
| 320 | |
|---|
| 321 | IF(l_ctl) WRITE(numout,*) ' eiv - u: ', SUM( aeiu(:,:) ), ' v: ', SUM( aeiv(:,:) ) |
|---|
| 322 | |
|---|
| 323 | ! ORCA R05: add a space variation on aht (=aeiv except at the equator and river mouth) |
|---|
| 324 | IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN |
|---|
| 325 | zf20 = 2. * omega * SIN( rad * 20. ) |
|---|
| 326 | zaht_min = 100. ! minimum value for aht |
|---|
| 327 | DO jj = 1, jpj |
|---|
| 328 | DO ji = 1, jpi |
|---|
| 329 | zaht = ( 1. - MIN( 1., ABS( ff(ji,jj) / zf20 ) ) ) * ( aht0 - zaht_min ) & |
|---|
| 330 | & + aht0 * upsrnfh(ji,jj) ! enhanced near river mouths |
|---|
| 331 | ahtu(ji,jj) = MAX( MAX( zaht_min, aeiu(ji,jj) ) + zaht, aht0 ) |
|---|
| 332 | ahtv(ji,jj) = MAX( MAX( zaht_min, aeiv(ji,jj) ) + zaht, aht0 ) |
|---|
| 333 | ahtw(ji,jj) = MAX( MAX( zaht_min, aeiw(ji,jj) ) + zaht, aht0 ) |
|---|
| 334 | END DO |
|---|
| 335 | END DO |
|---|
| 336 | IF(l_ctl) WRITE(numout,*) ' aht - u: ', SUM( ahtu(:,:) ), ' v: ', SUM( ahtv(:,:) ), ' w: ', SUM( ahtw(:,:) ) |
|---|
| 337 | ENDIF |
|---|
| 338 | |
|---|
| 339 | END SUBROUTINE ldf_eiv |
|---|
| 340 | |
|---|
| 341 | # endif |
|---|
| 342 | |
|---|
| 343 | #else |
|---|
| 344 | !!---------------------------------------------------------------------- |
|---|
| 345 | !! Default option Dummy module |
|---|
| 346 | !!---------------------------------------------------------------------- |
|---|
| 347 | CONTAINS |
|---|
| 348 | SUBROUTINE ldf_eiv( kt ) ! Empty routine |
|---|
| 349 | WRITE(*,*) 'ldf_eiv: You should not have seen this print! error?', kt |
|---|
| 350 | END SUBROUTINE ldf_eiv |
|---|
| 351 | #endif |
|---|
| 352 | |
|---|
| 353 | !!====================================================================== |
|---|
| 354 | END MODULE ldfeiv |
|---|
