New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
albedo.F90 in trunk/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMO/OPA_SRC/SBC/albedo.F90 @ 888

Last change on this file since 888 was 888, checked in by ctlod, 16 years ago

merge dev_001_SBC branche with the trunk to include the New Surface Module package, see ticket: #113
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 10.6 KB
Line 
1MODULE albedo
2   !!======================================================================
3   !!                       ***  MODULE  albedo  ***
4   !! Ocean forcing:  bulk thermohaline forcing of the ocean (or ice)
5   !!=====================================================================
6   !! History :  8.0  !  01-04  (LIM 1.0)
7   !!            8.5  !  03-07  (C. Ethe, G. Madec)  Optimization (old name:shine)
8   !!            9.0  !  04-11  (C. Talandier)  add albedo_init
9   !!             -   !  01-06  (M. Vancoppenolle) LIM 3.0
10   !!             -   !  06-08  (G. Madec)  cleaning for surface module
11   !!----------------------------------------------------------------------
12   !!   albedo_ice  : albedo for   ice (clear and overcast skies)
13   !!   albedo_oce  : albedo for ocean (clear and overcast skies)
14   !!   albedo_init : initialisation of albedo computation
15   !!----------------------------------------------------------------------
16   USE phycst          ! physical constants
17   USE in_out_manager  ! I/O manager
18
19   IMPLICIT NONE
20   PRIVATE
21
22   PUBLIC albedo_ice   ! routine called sbcice_lim.F90
23   PUBLIC albedo_oce   ! routine called by ???
24
25   INTEGER  ::   albd_init = 0      !: control flag for initialization
26   REAL(wp) ::   zzero     = 0.e0   ! constant values
27   REAL(wp) ::   zone      = 1.e0   !    "       "
28
29   REAL(wp) ::   c1     = 0.05    ! constants values
30   REAL(wp) ::   c2     = 0.10    !    "        "
31   REAL(wp) ::   rmue   = 0.40    !  cosine of local solar altitude
32
33   !!* namelist namalb
34   REAL(wp) ::   &
35      cgren  = 0.06  ,     &   !  correction of the snow or ice albedo to take into account
36      !                        !  effects of cloudiness (Grenfell & Perovich, 1984)
37#if defined key_lim3
38      albice = 0.53  ,     &   !  albedo of melting ice in the arctic and antarctic (Shine & Hendersson-Sellers)
39#else
40      albice = 0.50  ,     &   !  albedo of melting ice in the arctic and antarctic (Shine & Hendersson-Sellers)
41#endif
42      alphd  = 0.80  ,     &   !  coefficients for linear interpolation used to compute
43      alphdi = 0.72  ,     &   !  albedo between two extremes values (Pyane, 1972)
44      alphc  = 0.65 
45
46   !!----------------------------------------------------------------------
47   !!   OPA 9.0 , LOCEAN-IPSL (2006)
48   !! $Id$
49   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51
52CONTAINS
53
54   SUBROUTINE albedo_ice( pt_ice, ph_ice, ph_snw, pa_ice_cs, pa_ice_os )
55      !!----------------------------------------------------------------------
56      !!               ***  ROUTINE albedo_ice  ***
57      !!         
58      !! ** Purpose :   Computation of the albedo of the snow/ice system
59      !!                as well as the ocean one
60      !!       
61      !! ** Method  : - Computation of the albedo of snow or ice (choose the
62      !!                rignt one by a large number of tests
63      !!              - Computation of the albedo of the ocean
64      !!
65      !! References :   Shine and Hendersson-Sellers 1985, JGR, 90(D1), 2243-2250.
66      !!----------------------------------------------------------------------
67      REAL(wp), INTENT(in   ), DIMENSION(:,:,:) ::   pt_ice      !  ice surface temperature
68      REAL(wp), INTENT(in   ), DIMENSION(:,:,:) ::   ph_ice      !  sea-ice thickness
69      REAL(wp), INTENT(in   ), DIMENSION(:,:,:) ::   ph_snw      !  snow thickness
70      REAL(wp), INTENT(  out), DIMENSION(:,:,:) ::   pa_ice_cs   !  albedo of ice under clear    sky
71      REAL(wp), INTENT(  out), DIMENSION(:,:,:) ::   pa_ice_os   !  albedo of ice under overcast sky
72      !!
73      INTEGER  ::   ji, jj, jl    ! dummy loop indices
74      INTEGER  ::   ijpl          ! number of ice categories (3rd dim of ice input arrays)
75      REAL(wp) ::   zalbpsnm      ! albedo of ice under clear sky when snow is melting
76      REAL(wp) ::   zalbpsnf      ! albedo of ice under clear sky when snow is freezing
77      REAL(wp) ::   zalbpsn       ! albedo of snow/ice system when ice is coverd by snow
78      REAL(wp) ::   zalbpic       ! albedo of snow/ice system when ice is free of snow
79      REAL(wp) ::   zithsn        ! = 1 for hsn >= 0 ( ice is cov. by snow ) ; = 0 otherwise (ice is free of snow)
80      REAL(wp) ::   zitmlsn       ! = 1 freezinz snow (pt_ice >=rt0_snow) ; = 0 melting snow (pt_ice<rt0_snow)
81      REAL(wp) ::   zihsc1        ! = 1 hsn <= c1 ; = 0 hsn > c1
82      REAL(wp) ::   zihsc2        ! = 1 hsn >= c2 ; = 0 hsn < c2
83      !!
84      LOGICAL , DIMENSION(jpi,jpj,SIZE(pt_ice,3)) ::   llmask
85      REAL(wp), DIMENSION(jpi,jpj,SIZE(pt_ice,3)) ::   zalbfz    ! = alphdi for freezing ice ; = albice for melting ice
86      REAL(wp), DIMENSION(jpi,jpj,SIZE(pt_ice,3)) ::   zficeth   !  function of ice thickness
87      !!---------------------------------------------------------------------
88     
89      ijpl = SIZE( pt_ice, 3 )                     ! number of ice categories
90
91      IF( albd_init == 0 )   CALL albedo_init      ! initialization
92
93      !---------------------------
94      !  Computation of  zficeth
95      !---------------------------
96      llmask = ( ph_snw == 0.e0 ) .AND. ( pt_ice >= rt0_ice )
97      ! ice free of snow and melts
98      WHERE( llmask )   ;   zalbfz = albice
99      ELSEWHERE         ;   zalbfz = alphdi
100      END WHERE
101
102      DO jl = 1, ijpl
103         DO jj = 1, jpj
104            DO ji = 1, jpi
105               IF( ph_ice(ji,jj,jl) > 1.5 ) THEN
106                  zficeth(ji,jj,jl) = zalbfz(ji,jj,jl)
107               ELSEIF( ph_ice(ji,jj,jl) > 1.0  .AND. ph_ice(ji,jj,jl) <= 1.5 ) THEN
108                  zficeth(ji,jj,jl) = 0.472 + 2.0 * ( zalbfz(ji,jj,jl) - 0.472 ) * ( ph_ice(ji,jj,jl) - 1.0 )
109               ELSEIF( ph_ice(ji,jj,jl) > 0.05 .AND. ph_ice(ji,jj,jl) <= 1.0 ) THEN
110                  zficeth(ji,jj,jl) = 0.2467 + 0.7049 * ph_ice(ji,jj,jl)                               &
111                     &                    - 0.8608 * ph_ice(ji,jj,jl) * ph_ice(ji,jj,jl)                 &
112                     &                    + 0.3812 * ph_ice(ji,jj,jl) * ph_ice(ji,jj,jl) * ph_ice (ji,jj,jl)
113               ELSE
114                  zficeth(ji,jj,jl) = 0.1 + 3.6 * ph_ice(ji,jj,jl) 
115               ENDIF
116            END DO
117         END DO
118      END DO
119     
120      !-----------------------------------------------
121      !    Computation of the snow/ice albedo system
122      !-------------------------- ---------------------
123     
124      !    Albedo of snow-ice for clear sky.
125      !-----------------------------------------------   
126      DO jl = 1, ijpl
127         DO jj = 1, jpj
128            DO ji = 1, jpi
129               !  Case of ice covered by snow.             
130               !                                        !  freezing snow       
131               zihsc1   = 1.0 - MAX( zzero , SIGN( zone , - ( ph_snw(ji,jj,jl) - c1 ) ) )
132               zalbpsnf = ( 1.0 - zihsc1 ) * (  zficeth(ji,jj,jl)                                        &
133                  &                           + ph_snw(ji,jj,jl) * ( alphd - zficeth(ji,jj,jl) ) / c1  )   &
134                  &     +         zihsc1   * alphd 
135               !                                        !  melting snow               
136               zihsc2   = MAX( zzero , SIGN( zone , ph_snw(ji,jj,jl) - c2 ) )
137               zalbpsnm = ( 1.0 - zihsc2 ) * ( albice + ph_snw(ji,jj,jl) * ( alphc - albice ) / c2 )       &
138                  &     +         zihsc2   * alphc 
139               !
140               zitmlsn  =  MAX( zzero , SIGN( zone , pt_ice(ji,jj,jl) - rt0_snow ) )   
141               zalbpsn  =  zitmlsn * zalbpsnm + ( 1.0 - zitmlsn ) * zalbpsnf
142           
143               !  Case of ice free of snow.
144               zalbpic  = zficeth(ji,jj,jl) 
145           
146               ! albedo of the system   
147               zithsn   = 1.0 - MAX( zzero , SIGN( zone , - ph_snw(ji,jj,jl) ) )
148               pa_ice_cs(ji,jj,jl) =  zithsn * zalbpsn + ( 1.0 - zithsn ) *  zalbpic
149            END DO
150         END DO
151      END DO
152     
153      !    Albedo of snow-ice for overcast sky.
154      !---------------------------------------------- 
155      pa_ice_os(:,:,:) = pa_ice_cs(:,:,:) + cgren       ! Oberhuber correction
156      !
157   END SUBROUTINE albedo_ice
158
159
160   SUBROUTINE albedo_oce( pa_oce_os , pa_oce_cs )
161      !!----------------------------------------------------------------------
162      !!               ***  ROUTINE albedo_oce  ***
163      !!
164      !! ** Purpose :   Computation of the albedo of the ocean
165      !!
166      !! ** Method  :   ....
167      !!----------------------------------------------------------------------
168      REAL(wp), DIMENSION(jpi,jpj), INTENT(out) ::   pa_oce_os   !  albedo of ocean under overcast sky
169      REAL(wp), DIMENSION(jpi,jpj), INTENT(out) ::   pa_oce_cs   !  albedo of ocean under clear sky
170      !!
171      REAL(wp) ::   zcoef   ! temporary scalar
172      !!----------------------------------------------------------------------
173      !
174      zcoef = 0.05 / ( 1.1 * rmue**1.4 + 0.15 )      ! Parameterization of Briegled and Ramanathan, 1982
175      pa_oce_cs(:,:) = zcoef               
176      pa_oce_os(:,:)  = 0.06                         ! Parameterization of Kondratyev, 1969 and Payne, 1972
177      !
178   END SUBROUTINE albedo_oce
179
180
181   SUBROUTINE albedo_init
182      !!----------------------------------------------------------------------
183      !!                 ***  ROUTINE albedo_init  ***
184      !!
185      !! ** Purpose :   initializations for the albedo parameters
186      !!
187      !! ** Method  :   Read the namelist namalb
188      !!----------------------------------------------------------------------
189      NAMELIST/namalb/ cgren, albice, alphd, alphdi, alphc
190      !!----------------------------------------------------------------------
191
192      ! set the initialization flag to 1
193      albd_init = 1           ! indicate that the initialization has been done
194
195      ! Read Namelist namalb : albedo parameters
196      REWIND( numnam )
197      READ  ( numnam, namalb )
198
199      IF(lwp) THEN               ! Control print
200         WRITE(numout,*)
201         WRITE(numout,*) 'albedo_init : set albedo parameters from namelist namalb'
202         WRITE(numout,*) '~~~~~~~~~~~'
203         WRITE(numout,*) '             correction for snow and ice albedo                    cgren  = ', cgren
204         WRITE(numout,*) '             albedo of melting ice in the arctic and antarctic     albice = ', albice
205         WRITE(numout,*) '             coefficients for linear                               alphd  = ', alphd
206         WRITE(numout,*) '             interpolation used to compute albedo                  alphdi = ', alphdi
207         WRITE(numout,*) '             between two extremes values (Pyane, 1972)             alphc  = ', alphc
208      ENDIF
209      !
210   END SUBROUTINE albedo_init
211
212   !!======================================================================
213END MODULE albedo
Note: See TracBrowser for help on using the repository browser.