New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
flxrnf.F90 in trunk/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMO/OPA_SRC/SBC/flxrnf.F90 @ 60

Last change on this file since 60 was 18, checked in by opalod, 20 years ago

CT : UPDATE001 : First major NEMO update
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 14.8 KB
Line 
1MODULE flxrnf
2   !!======================================================================
3   !!                       ***  MODULE  flxrnf  ***
4   !! Ocean forcing:  runoff
5   !!=====================================================================
6#if defined key_orca_r05
7   !!----------------------------------------------------------------------
8   !!   'key_orca_r05'                               ORCA R05 configuration
9   !!----------------------------------------------------------------------
10#  include "flxrnf_ORCA_R05.h90"
11#else
12   !!----------------------------------------------------------------------
13   !!   Default option                                     Standard runoffs
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   flx_rnf      : monthly runoff read in a NetCDF file
18   !!----------------------------------------------------------------------
19   !! * Modules used
20   USE dom_oce         ! ocean space and time domain
21   USE phycst          ! physical constants
22   USE in_out_manager  ! I/O manager
23   USE daymod          ! calendar
24   USE ioipsl          ! NetCDF IPSL library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   !! * Routine accessibility
30   PUBLIC flx_rnf          ! routine call by step.F90
31
32   !! * Shared module variables
33   REAL(wp), PUBLIC, DIMENSION(jpi,jpj) ::   &  !:
34      runoff,           &  !: monthly runoff (kg/m2/s)
35      upsadv,           &  !: mixed adv scheme in straits vicinity (hori.)
36      upsrnfh              !: mixed adv scheme in runoffs vicinity (hori.)
37   REAL(wp), PUBLIC, DIMENSION(jpk) ::   &  !:
38      upsrnfz              !: mixed adv scheme in runoffs vicinity (vert.)
39   INTEGER, PUBLIC ::   &  !:
40      numrof  = 48 ,    &  !: logical unit for runoff data
41      nrunoff =  0 ,    &  !: runoff option (namelist)
42      nrnf1, nrnf2         !: first and second record used
43
44   !! * Module variable
45   REAL(wp), DIMENSION(jpi,jpj,2) ::   &  !:
46      rnfdta               !: monthly runoff data array (kg/m2/s)
47   !!----------------------------------------------------------------------
48   !!   OPA 9.0 , LODYC-IPSL  (2003)
49   !!----------------------------------------------------------------------
50
51CONTAINS
52
53   SUBROUTINE flx_rnf( kt )
54      !!----------------------------------------------------------------------
55      !!                  ***  ROUTINE flx_rnf  ***
56      !!       
57      !! ** Purpose :   Introduce a climatological run off forcing
58      !!
59      !! ** Method :
60      !!      Initialze each mouth of river with a monthly climatology
61      !!      provided from different data.
62      !!     C a u t i o n : upward water flux, runoff is negative
63      !!                     set at the last loop of the routine
64      !!
65      !! ** Action :
66      !!
67      !! References :
68      !!       J. D. Milliman and R. H. Meade, 1983 : world-wide delivery
69      !!          of river sediment to the oceans, journal of geology vol 91
70      !!          pp 1-21.
71      !!       G. L. Russell and J. R. Miller, 1990 : global river runoff
72      !!          calculated from a global atmospheric general circulation
73      !!          model, journal of hydrology, 117(1990), pp 241-254.
74      !!       F. Van Der Leeden, Troise F. L., Todd D. K. : the water
75      !!          encyclopedia, second edition, lewis publishers.
76      !!       J. W. Weatherly, J. E. Walsh : The effects of precipitation
77      !!          and river runoff in a coupled ice-ocean model of Arctic
78      !!          Climate dynamics 1996 12:785,798
79      !!       Jacobs et al. 1992. J. Glaciol. 38 (130) 375-387.
80      !!
81      !! History :
82      !!        !  94-10  (G.Madec, M. Pontaud, M. Imbard)  Original code
83      !!        !  97-03  (G.Madec)  time dependent version
84      !!        !  98-06  (J.M. Molines)  exact computation of zxy
85      !!                         for months that are not 30 days
86      !!        !  98-07  (M. Imbard)  ORCA and mpp option
87      !!        !  99-08  (J.P. Boulanger H.L.Ayina)  New rivers and
88      !!                         values given in m3/s
89      !!        !  00-04  (G. Madec, K. Roberts) add antarctica ice discharge.
90      !!        !  00-11  (R. Hordoir, E. Durand)  NetCDF FORMAT
91      !!   8.5  !  02-09  (G. Madec)  F90: Free form and module
92      !!----------------------------------------------------------------------
93      !! * arguments
94      INTEGER, INTENT( in  ) ::   kt       ! ocean time step
95
96      !! * Local declarations
97# if ! defined key_coupled
98      INTEGER ::   &
99         i15 , imois , iman,            &  ! temporary integers
100         idbd, idmeom                      !    "          "
101      REAL(wp) ::   zxy
102# endif
103      CHARACTER (len=32) ::   &
104         clname = 'runoff_1m_nomask'       ! monthly runoff filename
105      INTEGER, PARAMETER :: jpmois = 12
106      INTEGER  ::   ji, jj                 ! dummy loop indices
107      INTEGER  ::   ipi, ipj, ipk          ! temporary integers
108      INTEGER  ::   ii0, ii1, ij0, ij1     !    "          "
109      INTEGER, DIMENSION(jpmois) ::     &
110         istep                             ! temporary workspace
111      REAL(wp) ::   zdate0                 ! temporary scalars
112      REAL(wp), DIMENSION(jpk) ::       &
113         zlev                              ! temporary workspace
114      REAL(wp), DIMENSION(jpi,jpj) ::   &
115         zlon, zlat,                    &  ! temporary workspace
116         zcoefr                            ! coeff of advection link to runoff
117      !!----------------------------------------------------------------------
118     
119      IF( kt == nit000 ) THEN
120
121         SELECT CASE ( nrunoff )
122
123         CASE ( 0 )
124            IF(lwp) WRITE(numout,*)
125            IF(lwp) WRITE(numout,*) 'flx_rnf : No runoff in this simulation (nrunoff=0)'
126            IF(lwp) WRITE(numout,*) '~~~~~~~'
127           
128         CASE ( 1 )
129            IF(lwp) WRITE(numout,*)
130            IF(lwp) WRITE(numout,*) 'flx_rnf : monthly runoff (nrunoff=0)'
131            IF(lwp) WRITE(numout,*) '~~~~~~~'
132
133         CASE ( 2 )
134            IF(lwp) WRITE(numout,*)
135            IF(lwp) WRITE(numout,*) 'flx_rnf : monthly runoff with upsteam advection'
136            IF(lwp) WRITE(numout,*) '~~~~~~~   in the vicinity of river mouths (nrunoff=2)'
137
138         CASE DEFAULT
139            IF(lwp) WRITE(numout,cform_err)
140            IF(lwp) WRITE(numout,*)' Error nrunoff = ', nrunoff, ' /= 0, 1 or 2'
141            nstop = nstop + 1
142
143         END SELECT
144
145         ! Set runoffs and upstream coeff to zero
146         runoff (:,:) = 0.e0
147         upsrnfh(:,:) = 0.e0
148         upsrnfz(:)   = 0.e0 
149         upsadv (:,:) = 0.e0
150
151      ENDIF
152
153
154      ! 1. Initialization
155      ! -----------------
156
157      IF( nrunoff == 1 .OR. nrunoff == 2 ) THEN
158# if ! defined key_coupled
159
160         ! year, month, day
161
162         iman  = jpmois
163         i15   = nday / 16
164         imois = nmonth + i15 - 1
165         IF( imois == 0 )   imois = iman
166         ! Number of days in the month
167         IF( nleapy == 1 .AND. MOD( nyear, 4 ) == 0 ) THEN
168            idbd = nbiss(imois)
169         ELSEIF( nleapy > 1 ) THEN
170            idbd = nleapy
171         ELSE
172            idbd = nobis(imois)
173         ENDIF
174         ! Number of days between imois, 15 and the end of month
175         idmeom = idbd - 15
176# endif
177         ipi = jpiglo
178         ipj = jpjglo
179         ipk = jpk
180         
181         ! Open file
182
183         IF( kt == nit000 ) THEN
184            CALL flinopen( clname, mig(1), nlci, mjg(1), nlcj,    &
185                           .false., ipi, ipj, ipk, zlon,        &
186                           zlat, zlev, jpmois, istep, zdate0,   &
187                           rdt, numrof )
188            !   Title, dimensions and tests
189# if ! defined key_coupled
190            IF( iman /= jpmois ) THEN
191               IF(lwp) WRITE(numout,*)
192               IF(lwp) WRITE(numout,*) 'problem with time coordinates'
193               IF(lwp) WRITE(numout,*) ' iman ', iman, ' jpmois ', jpmois
194               nstop = nstop + 1
195            ENDIF
196            IF(lwp) WRITE(numout,*) iman, istep, zdate0, rdt, numrof
197            IF(lwp) WRITE(numout,*) 'numrof=', numrof
198            IF(lwp) WRITE(numout,*) 'jpmois=', jpmois
199            IF(lwp) WRITE(numout,*) 'rdt=', rdt
200# endif
201            IF(ipi /= jpidta .AND. ipj /= jpjdta .AND. ipk /= 1) THEN
202               IF(lwp)WRITE(numout,*) ' '
203               IF(lwp)WRITE(numout,*) 'problem with dimensions'
204               IF(lwp)WRITE(numout,*) ' ipi ', ipi, ' jpidta ', jpidta
205               IF(lwp)WRITE(numout,*) ' ipj ', ipj, ' jpjdta ', jpjdta
206               IF(lwp)WRITE(numout,*) ' ipk ', ipk, ' =? 1'
207               nstop = nstop + 1
208            ENDIF
209            IF(lwp)WRITE(numout,*) 'ipi=', ipi, ' ipj=', ipj, ' ipk=', ipk
210         ENDIF
211         
212# if ! defined key_coupled
213
214         ! 2. Read monthly file of runoff
215         ! ------------------------------
216
217         IF( kt == nit000 .OR. imois /= nrnf1 ) THEN
218
219            ! Calendar computation for interpolation
220            !     nrnf1 number of the first array record used in the simulation
221            !     nrnf2 number of the last  array record
222
223            nrnf1 = imois
224            nrnf2 = nrnf1 + 1
225            nrnf1 = MOD( nrnf1, iman )
226            IF( nrnf1 == 0 ) nrnf1 = iman
227            nrnf2 = MOD( nrnf2, iman )
228            IF( nrnf2 == 0 ) nrnf2 = iman
229           
230            IF(lwp) THEN
231               WRITE(numout,*)
232               WRITE(numout,*) ' runoff monthly field'
233               WRITE(numout,*) ' --------------------'
234               WRITE(numout,*) ' NetCDF format'
235               WRITE(numout,*)
236               WRITE(numout,*) 'first array record used nrnf1 ',nrnf1
237               WRITE(numout,*) 'last  array record used nrnf2 ',nrnf2
238               WRITE(numout,*)
239            ENDIF
240           
241            ! Read monthly runoff data in kg/m2/s
242
243            CALL flinget(numrof,'sorunoff',jpidta,jpjdta,1,jpmois   &
244                  ,nrnf1,nrnf1,mig(1),nlci,mjg(1),nlcj,rnfdta(1:nlci,1:nlcj,1))
245            CALL flinget(numrof,'sorunoff',jpidta,jpjdta,1,jpmois   &
246                  ,nrnf2,nrnf2,mig(1),nlci,mjg(1),nlcj,rnfdta(1:nlci,1:nlcj,2))
247
248            IF(lwp) WRITE(numout,*)
249            IF(lwp) WRITE(numout,*) ' read runoff field ok'
250            IF(lwp) WRITE(numout,*)
251
252         ENDIF
253
254         ! Linear interpolation and conversion in upward water flux
255         ! C a u t i o n : runoff is negative and in kg/m2/s
256
257         zxy = FLOAT( nday + idmeom - idbd * i15 ) / idbd
258
259         runoff(:,:) = -( (1.-zxy)*rnfdta(:,:,1) + zxy*rnfdta(:,:,2) )
260
261         ! Runoff reduction
262         DO jj = 1, jpj
263            DO ji = 1, jpi
264               IF( gphit(ji,jj) > 40 .AND. gphit(ji,jj) < 65 ) THEN
265                  runoff(ji,jj) = 0.85 * runoff(ji,jj)
266               ENDIF
267            END DO
268         END DO
269         
270# endif
271
272      ENDIF
273
274
275      ! 3. Mixed advection scheme
276      ! -------------------------
277
278      IF( nrunoff == 2 .AND. kt == nit000 ) THEN
279
280         ! Upstream and centered scheme in the vicinity of river mouths
281
282         !  Creates the array coef that contains the coefficient to affect to
283         !  the upstream scheme. advection scheme will be:
284         !  coefr * upstream + (1- coefr) centered
285         !  coefr must be between 0 and 1.
286
287         CALL flinget(numrof,'socoefr',jpidta,jpjdta,1,jpmois,nrnf1   &
288                     ,nrnf1,mig(1),nlci,mjg(1),nlcj,zcoefr(1:nlci,1:nlcj))
289
290         IF(lwp) WRITE(numout,*)
291         IF(lwp) WRITE(numout,*) ' read coefr for advection ok'
292         IF(lwp) WRITE(numout,*)
293         
294         upsrnfh(:,:) = zcoefr(:,:)
295         upsrnfz(:)   = 0.e0
296         upsrnfz(1)   = 1.0
297         upsrnfz(2)   = 1.0
298         upsrnfz(3)   = 0.5
299         upsrnfz(4)   = 0.25
300         upsrnfz(5)   = 0.125
301         
302         IF( cp_cfg == "orca" .AND. jp_cfg == 2 ) THEN
303            ! ORCA_R2 configuration : upstream scheme in the Sound Strait
304            ij0 = 116   ;   ij1 = 116
305            ii0 = 144   ;   ii1 = 144   ;   upsrnfh( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.25
306            ii0 = 145   ;   ii1 = 147   ;   upsrnfh( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.50
307            ii0 = 148   ;   ii1 = 148   ;   upsrnfh( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.25
308         ENDIF
309
310      ENDIF
311
312      ! Upstream and centered scheme in the vicinity of some straits
313
314      IF( kt == nit000 ) THEN
315
316         IF( cp_cfg == "orca" ) THEN
317
318            SELECT CASE ( jp_cfg )
319            !                                        ! =======================
320            CASE ( 4 )                               !  ORCA_R4 configuration
321               !                                     ! =======================
322
323               !                                          ! Gibraltar Strait
324               ii0 =  70   ;   ii1 =  71
325               ij0 =  52   ;   ij1 =  53   ;   upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.50
326         
327               !                                     ! =======================
328            CASE ( 2 )                               !  ORCA_R2 configuration
329               !                                     ! =======================
330
331               !                                          ! Gibraltar Strait
332               ij0 = 102   ;   ij1 = 102
333               ii0 = 138   ;   ii1 = 138   ;   upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.20
334               ii0 = 139   ;   ii1 = 139   ;   upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.40
335               ii0 = 140   ;   ii1 = 140   ;   upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.50
336               ij0 = 101   ;   ij1 = 102
337               ii0 = 141   ;   ii1 = 141   ;   upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.50
338
339               !                                          ! Bab el Mandeb Strait
340               ij0 =  87   ;   ij1 =  88
341               ii0 = 164   ;   ii1 = 164   ;   upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.10
342               ij0 =  88   ;   ij1 =  88
343               ii0 = 163   ;   ii1 = 163   ;   upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.25
344               ii0 = 162   ;   ii1 = 162   ;   upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.40
345               ii0 = 160   ;   ii1 = 161   ;   upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.50
346               ij0 =  89   ;   ij1 =  89
347               ii0 = 158   ;   ii1 = 160   ;   upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.25
348               ij0 =  90   ;   ij1 =  90
349               ii0 = 160   ;   ii1 = 160   ;   upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.25
350
351               !                                          ! Sound Strait
352               ij0 = 116   ;   ij1 = 116
353               ii0 = 145   ;   ii1 = 147   ;   upsadv( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ) = 0.50
354         
355            END SELECT
356
357         ENDIF
358
359      ENDIF
360     
361      ! 4. Closing all files
362      ! --------------------
363
364      IF( kt == nitend .AND. nrunoff >= 1 )   CALL flinclo( numrof )
365
366   END SUBROUTINE flx_rnf
367
368#endif
369   !!======================================================================
370END MODULE flxrnf
Note: See TracBrowser for help on using the repository browser.