New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in trunk/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 1308

Last change on this file since 1308 was 1267, checked in by ctlod, 15 years ago

stabilization of the sea-ice/ocean stress computation in using ub/vb before instead now fields
  • Property svn:keywords set to Id
File size: 8.4 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0   !  06-07  (G. Madec)  Original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   sbc_ssm        : calculate sea surface mean currents, temperature, 
11   !!                    and salinity over nn_fsbc time-step
12   !!----------------------------------------------------------------------
13   USE oce             ! ocean dynamics and tracers
14   USE dom_oce         ! ocean space and time domain
15   USE daymod          ! calendar
16   USE sbc_oce         ! Surface boundary condition: ocean fields
17   USE prtctl          ! Print control                    (prt_ctl routine)
18   USE restart         ! ocean restart
19   USE iom
20   USE in_out_manager  ! I/O manager
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   sbc_ssm    ! routine called by step.F90
26   
27   !! * Substitutions
28#  include "domzgr_substitute.h90"
29   !!----------------------------------------------------------------------
30   !!   OPA 9.0 , LOCEAN-IPSL (2006)
31   !! $Id$
32   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
33   !!----------------------------------------------------------------------
34
35CONTAINS
36
37   SUBROUTINE sbc_ssm( kt )
38      !!---------------------------------------------------------------------
39      !!                     ***  ROUTINE sbc_oce  ***
40      !!                     
41      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
42      !!                condition computation
43      !!               
44      !! ** Method  :   compute mean surface velocity (2 components at U and
45      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
46      !!      the periode (kt - nn_fsbc) to kt
47      !!---------------------------------------------------------------------
48      INTEGER, INTENT(in) ::   kt        ! ocean time step
49      !
50      REAL(wp) ::   zcoef       ! temporary scalar
51      REAL(wp) ::   zf_sbc      ! read sbc frequency
52      !!---------------------------------------------------------------------
53      !                                                   ! ---------------------------------------- !
54      IF( nn_fsbc == 1 ) THEN                             !      Instantaneous surface fields        !
55         !                                                ! ---------------------------------------- !
56         IF( kt == nit000 ) THEN
57            IF(lwp) WRITE(numout,*)
58            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
59            IF(lwp) WRITE(numout,*) '~~~~~~~ '
60         ENDIF
61         !
62         ssu_m(:,:) = ub(:,:,1)
63         ssv_m(:,:) = vb(:,:,1)
64         sst_m(:,:) = tn(:,:,1)
65         sss_m(:,:) = sn(:,:,1)
66         ssh_m(:,:) = sshn(:,:)
67         !
68      ELSE
69         !                                                ! ---------------------------------------- !
70         IF( kt == nit000) THEN                           !       Initialisation: 1st time-step      !
71            !                                             ! ---------------------------------------- !
72            IF(lwp) WRITE(numout,*)
73            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
74            !
75            IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
76               CALL iom_get( numror               , 'nn_fsbc', zf_sbc )   ! sbc frequency of previous run
77               CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )   ! sea surface mean velocity    (T-point)
78               CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )   !   "         "    velocity    (V-point)
79               CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )   !   "         "    temperature (T-point)
80               CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )   !   "         "    salinity    (T-point)
81               CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )   !   "         "    height      (T-point)
82               !
83               IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
84                  IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
85                     &                    'from ', zf_sbc, ' to ', nn_fsbc
86                  zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc
87                  ssu_m(:,:) = zcoef * ssu_m(:,:)
88                  ssv_m(:,:) = zcoef * ssv_m(:,:)
89                  sst_m(:,:) = zcoef * sst_m(:,:)
90                  sss_m(:,:) = zcoef * sss_m(:,:)
91                  ssh_m(:,:) = zcoef * ssh_m(:,:)
92               ELSE
93                  IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
94               ENDIF
95            ELSE
96               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
97               zcoef = REAL( nn_fsbc - 1, wp )
98               ssu_m(:,:) = zcoef * ub(:,:,1)
99               ssv_m(:,:) = zcoef * vb(:,:,1)
100               sst_m(:,:) = zcoef * tn(:,:,1)
101               sss_m(:,:) = zcoef * sn(:,:,1)
102               ssh_m(:,:) = zcoef * sshn(:,:)
103            ENDIF
104            !                                             ! ---------------------------------------- !
105         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
106            !                                             ! ---------------------------------------- !
107            ssu_m(:,:) = 0.e0      ! reset to zero ocean mean sbc fields
108            ssv_m(:,:) = 0.e0
109            sst_m(:,:) = 0.e0
110            sss_m(:,:) = 0.e0
111            ssh_m(:,:) = 0.e0
112         ENDIF
113         !                                                ! ---------------------------------------- !
114         !                                                !        Cumulate at each time step        !
115         !                                                ! ---------------------------------------- !
116         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
117         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
118         sst_m(:,:) = sst_m(:,:) + tn(:,:,1)
119         sss_m(:,:) = sss_m(:,:) + sn(:,:,1)
120         ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
121
122         !                                                ! ---------------------------------------- !
123         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
124            !                                             ! ---------------------------------------- !
125            zcoef = 1. / REAL( nn_fsbc, wp )
126            sst_m(:,:) = sst_m(:,:) * zcoef           ! mean SST             [Celcius]
127            sss_m(:,:) = sss_m(:,:) * zcoef           ! mean SSS             [psu]
128            ssu_m(:,:) = ssu_m(:,:) * zcoef           ! mean suface current  [m/s]
129            ssv_m(:,:) = ssv_m(:,:) * zcoef           !
130            ssh_m(:,:) = ssh_m(:,:) * zcoef           ! mean SSH             [m]
131            !
132         ENDIF
133         !                                                ! ---------------------------------------- !
134         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
135            !                                             ! ---------------------------------------- !
136            IF(lwp) WRITE(numout,*)
137            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
138               &                    'at it= ', kt,' date= ', ndastp
139            IF(lwp) WRITE(numout,*) '~~~~~~~'
140            zf_sbc = REAL( nn_fsbc, wp )
141            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
142            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
143            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
144            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
145            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
146            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
147            !
148         ENDIF
149         !
150      ENDIF
151      !
152   END SUBROUTINE sbc_ssm
153
154   !!======================================================================
155END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.