1 | MODULE sbcssr |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE sbcssr *** |
---|
4 | !! Surface module : add to heat and fresh water fluxes a restoring term |
---|
5 | !! toward observed SST/SSS |
---|
6 | !!====================================================================== |
---|
7 | !! History : 9.0 ! 06-06 (G. Madec) Original code |
---|
8 | !!---------------------------------------------------------------------- |
---|
9 | |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | !! sbc_ssr : add to sbc a restoring term toward SST/SSS climatology |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | USE oce ! ocean dynamics and tracers |
---|
14 | USE dom_oce ! ocean space and time domain |
---|
15 | USE sbc_oce ! surface boundary condition |
---|
16 | USE phycst ! physical constants |
---|
17 | USE daymod ! calendar |
---|
18 | USE sbcrnf ! surface boundary condition : runoffs |
---|
19 | USE fldread ! read input fields |
---|
20 | USE iom ! I/O manager |
---|
21 | USE in_out_manager ! I/O manager |
---|
22 | USE lib_mpp ! distribued memory computing library |
---|
23 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
24 | |
---|
25 | IMPLICIT NONE |
---|
26 | PRIVATE |
---|
27 | |
---|
28 | PUBLIC sbc_ssr ! routine called in sbcmod |
---|
29 | |
---|
30 | REAL(wp), ALLOCATABLE, DIMENSION(:) :: buffer ! Temporary buffer for exchange |
---|
31 | |
---|
32 | TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_sst ! structure of input SST (file informations, fields read) |
---|
33 | TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_sss ! structure of input SSS (file informations, fields read) |
---|
34 | |
---|
35 | REAL(wp), PUBLIC, DIMENSION(jpi,jpj) :: erp !: evaporation damping [kg/m2/s] |
---|
36 | REAL(wp), PUBLIC, DIMENSION(jpi,jpj) :: qrp !: heat flux damping [w/m2] |
---|
37 | |
---|
38 | !! * Namelist namsbc_ssr |
---|
39 | INTEGER :: nn_sstr, nn_sssr ! SST/SSS indicator |
---|
40 | REAL(wp) :: dqdt , deds ! restoring term factor |
---|
41 | |
---|
42 | !! * Substitutions |
---|
43 | # include "domzgr_substitute.h90" |
---|
44 | !!---------------------------------------------------------------------- |
---|
45 | !! OPA 9.0 , LOCEAN-IPSL (2006) |
---|
46 | !! $ Id: $ |
---|
47 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
---|
48 | !!---------------------------------------------------------------------- |
---|
49 | |
---|
50 | CONTAINS |
---|
51 | |
---|
52 | SUBROUTINE sbc_ssr( kt ) |
---|
53 | !!--------------------------------------------------------------------- |
---|
54 | !! *** ROUTINE sbc_ssr *** |
---|
55 | !! |
---|
56 | !! ** Purpose : Add to heat and/or freshwater fluxes a damping term |
---|
57 | !! toward observed SST and/or SSS. |
---|
58 | !! |
---|
59 | !! ** Method : - Read namelist namsbc_ssr |
---|
60 | !! - Read observed SST and/or SSS |
---|
61 | !! - at each nscb time step |
---|
62 | !! add a retroaction term on qns (nn_sstr = 1) |
---|
63 | !! add a damping term on emps (nn_sssr = 1) |
---|
64 | !! add a damping term on emp & emps (nn_sssr = 2) |
---|
65 | !!--------------------------------------------------------------------- |
---|
66 | INTEGER, INTENT(in ) :: kt ! ocean time step |
---|
67 | !! |
---|
68 | INTEGER :: ji, jj ! dummy loop indices |
---|
69 | REAL(wp) :: zerp ! local scalar for evaporation damping |
---|
70 | REAL(wp) :: zqrp ! local scalar for heat flux damping |
---|
71 | REAL(wp) :: zsrp ! local scalar for unit conversion of deds factor |
---|
72 | INTEGER :: ierror ! return error code |
---|
73 | !! |
---|
74 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
---|
75 | TYPE(FLD_N) :: sn_sst, sn_sss ! informations about the fields to be read |
---|
76 | NAMELIST/namsbc_ssr/ cn_dir, nn_sstr, nn_sssr, dqdt, deds, sn_sst, sn_sss |
---|
77 | !!---------------------------------------------------------------------- |
---|
78 | ! ! -------------------- ! |
---|
79 | IF( kt == nit000 ) THEN ! First call kt=nit000 ! |
---|
80 | ! ! -------------------- ! |
---|
81 | ! ! set file information |
---|
82 | nn_sstr = 0 |
---|
83 | nn_sssr = 0 |
---|
84 | dqdt = -40.e0 |
---|
85 | deds = -27.70 |
---|
86 | cn_dir = './' ! directory in which the model is executed |
---|
87 | ! ... default values (NB: frequency positive => hours, negative => months) |
---|
88 | ! ! file ! frequency ! variable ! time intep ! clim ! starting ! |
---|
89 | ! ! name ! (hours) ! name ! (T/F) ! (0/1) ! record ! |
---|
90 | sn_sst = FLD_N( 'sst' , 24. , 'sst' , .FALSE. , 0 , 0 ) |
---|
91 | sn_sss = FLD_N( 'sss' , -12. , 'sss' , .TRUE. , 0 , 0 ) |
---|
92 | |
---|
93 | REWIND ( numnam ) ! ... read in namlist namflx |
---|
94 | READ( numnam, namsbc_ssr ) |
---|
95 | |
---|
96 | IF(lwp) THEN ! control print |
---|
97 | WRITE(numout,*) |
---|
98 | WRITE(numout,*) 'sbc_ssr : SST and/or SSS damping term ' |
---|
99 | WRITE(numout,*) '~~~~~~~ ' |
---|
100 | WRITE(numout,*) ' SST restoring term (Yes=1) nn_sstr = ', nn_sstr |
---|
101 | WRITE(numout,*) ' SSS damping term (Yes=1, salt flux) nn_sssr = ', nn_sssr |
---|
102 | WRITE(numout,*) ' (Yes=2, volume flux) ' |
---|
103 | WRITE(numout,*) ' dQ/dT (restoring magnitude on SST) dqdt = ', dqdt, ' W/m2/K' |
---|
104 | WRITE(numout,*) ' dE/dS (restoring magnitude on SST) deds = ', deds, ' mm/day' |
---|
105 | ENDIF |
---|
106 | |
---|
107 | IF( nn_sstr == 1 ) THEN ! set sf_sst structure |
---|
108 | ! |
---|
109 | ALLOCATE( sf_sst(1), STAT=ierror ) |
---|
110 | IF( ierror > 0 ) THEN |
---|
111 | CALL ctl_stop( 'sbc_ssr: unable to allocate sf_sst structure' ) ; RETURN |
---|
112 | ENDIF |
---|
113 | ! namelist informations stored in sf_sst structures |
---|
114 | WRITE( sf_sst(1)%clrootname, '(a,a)' ) TRIM( cn_dir ), TRIM( sn_sst%clname ) |
---|
115 | sf_sst(1)%freqh = sn_sst%freqh |
---|
116 | sf_sst(1)%clvar = sn_sst%clvar |
---|
117 | sf_sst(1)%ln_tint = sn_sst%ln_tint |
---|
118 | sf_sst(1)%nclim = sn_sst%nclim |
---|
119 | sf_sst(1)%nstrec = sn_sst%nstrec |
---|
120 | IF(lwp) THEN ! control print |
---|
121 | WRITE(numout,*) ' SST restoring term toward SST data in the following file: ' |
---|
122 | WRITE(numout,*) ' root filename: ' , trim( sf_sst(1)%clrootname ), & |
---|
123 | & ' variable name: ' , trim( sf_sst(1)%clvar ) |
---|
124 | WRITE(numout,*) ' frequency: ' , sf_sst(1)%freqh , & |
---|
125 | & ' time interp: ' , sf_sst(1)%ln_tint , & |
---|
126 | & ' climatology: ' , sf_sst(1)%nclim , & |
---|
127 | & ' starting record: ', sf_sst(1)%nstrec |
---|
128 | ENDIF |
---|
129 | ENDIF |
---|
130 | ! |
---|
131 | IF( nn_sssr == 1 ) THEN ! set sf_sss structure |
---|
132 | ! |
---|
133 | ALLOCATE( sf_sss(1), STAT=ierror ) |
---|
134 | IF( ierror > 0 ) THEN |
---|
135 | CALL ctl_stop( 'sbc_ssr: unable to allocate sf_sss structure' ) ; RETURN |
---|
136 | ENDIF |
---|
137 | ! namelist informations stored in sf_sss structures |
---|
138 | WRITE( sf_sss(1)%clrootname, '(a,a)' ) TRIM( cn_dir ), TRIM( sn_sss%clname ) |
---|
139 | sf_sss(1)%freqh = sn_sss%freqh |
---|
140 | sf_sss(1)%clvar = sn_sss%clvar |
---|
141 | sf_sss(1)%ln_tint = sn_sss%ln_tint |
---|
142 | sf_sss(1)%nclim = sn_sss%nclim |
---|
143 | sf_sss(1)%nstrec = sn_sss%nstrec |
---|
144 | IF(lwp) THEN ! control print |
---|
145 | WRITE(numout,*) ' SSS dampming term toward SSS data in the following file: ' |
---|
146 | WRITE(numout,*) ' root filename: ' , trim( sf_sss(1)%clrootname ), & |
---|
147 | & ' variable name: ' , trim( sf_sss(1)%clvar ) |
---|
148 | WRITE(numout,*) ' frequency: ' , sf_sss(1)%freqh , & |
---|
149 | & ' time interp: ' , sf_sss(1)%ln_tint , & |
---|
150 | & ' climatology: ' , sf_sss(1)%nclim , & |
---|
151 | & ' starting record: ', sf_sss(1)%nstrec |
---|
152 | ENDIF |
---|
153 | ENDIF |
---|
154 | ! |
---|
155 | ! Initialize qrp and erp if no restoring |
---|
156 | IF( nn_sstr /= 1 ) qrp(:,:) = 0.e0 |
---|
157 | IF( nn_sssr /= 1 .OR. nn_sssr /= 2 ) erp(:,:) = 0.e0 |
---|
158 | ENDIF |
---|
159 | |
---|
160 | IF( nn_sstr + nn_sssr /= 0 ) THEN |
---|
161 | |
---|
162 | IF( nn_sstr == 1) CALL fld_read( kt, nn_fsbc, sf_sst ) ! Read SST data and provides it |
---|
163 | ! ! at the current time-step |
---|
164 | IF( nn_sssr == 1) CALL fld_read( kt, nn_fsbc, sf_sss ) ! Read SSS data and provides it |
---|
165 | ! ! at the current time-step |
---|
166 | |
---|
167 | ! ! ========================= ! |
---|
168 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN ! Add restoring term ! |
---|
169 | ! ! ========================= ! |
---|
170 | ! |
---|
171 | IF( nn_sstr == 1 ) THEN ! Temperature restoring term |
---|
172 | !CDIR COLLAPSE |
---|
173 | ! use zqrp scalar to optimize memory access (speedup the loop) |
---|
174 | DO jj = 1, jpj |
---|
175 | DO ji = 1, jpi |
---|
176 | zqrp = dqdt * ( sst_m(ji,jj) - sf_sst(1)%fnow(ji,jj) ) |
---|
177 | qns(ji,jj) = qns(ji,jj) + zqrp |
---|
178 | qrp(ji,jj) = zqrp |
---|
179 | END DO |
---|
180 | END DO |
---|
181 | ENDIF |
---|
182 | ! |
---|
183 | IF( nn_sssr == 1 ) THEN ! Salinity damping term (salt flux, emps only) |
---|
184 | !CDIR COLLAPSE |
---|
185 | ! use zerp scalar to optimize memory access (speedup the loop) |
---|
186 | DO jj = 1, jpj |
---|
187 | DO ji = 1, jpi |
---|
188 | zsrp = deds / rday ! from [mm/day] to [kg/m2/s] |
---|
189 | zerp = zsrp * ( 1. - 2.*rnfmsk(ji,jj) ) & ! No damping in vicinity of river mouths |
---|
190 | & * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj) ) & |
---|
191 | & / ( sss_m(ji,jj) + 1.e-20 ) |
---|
192 | emps(ji,jj) = emps(ji,jj) + zerp |
---|
193 | erp( ji,jj) = zerp |
---|
194 | END DO |
---|
195 | END DO |
---|
196 | ELSEIF( nn_sssr == 2 ) THEN ! Salinity damping term (volume flux, emp and emps) |
---|
197 | !CDIR COLLAPSE |
---|
198 | ! use zerp scalar to optimize memory access (speedup the loop) |
---|
199 | DO jj = 1, jpj |
---|
200 | DO ji = 1, jpi |
---|
201 | zsrp = deds / rday ! from [mm/day] to [kg/m2/s] |
---|
202 | zerp = zsrp * ( 1. - 2.*rnfmsk(ji,jj) ) & ! No damping in vicinity of river mouths |
---|
203 | & * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj) ) & |
---|
204 | & / ( sss_m(ji,jj) + 1.e-20 ) |
---|
205 | emp (ji,jj) = emp (ji,jj) + zerp |
---|
206 | emps(ji,jj) = emps(ji,jj) + zerp |
---|
207 | erp (ji,jj) = zerp |
---|
208 | END DO |
---|
209 | END DO |
---|
210 | ENDIF |
---|
211 | ! |
---|
212 | ENDIF |
---|
213 | ! |
---|
214 | ENDIF |
---|
215 | |
---|
216 | !!gm ... to be written ! Output sbc fields (using IOM) |
---|
217 | ! prevoir comment obtenir l info sst sss ssr |
---|
218 | ! |
---|
219 | END SUBROUTINE sbc_ssr |
---|
220 | |
---|
221 | !!====================================================================== |
---|
222 | END MODULE sbcssr |
---|