| 1 | MODULE sbcssr |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcssr *** |
|---|
| 4 | !! Surface module : heat and fresh water fluxes a restoring term toward observed SST/SSS |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-06 (G. Madec) Original code |
|---|
| 7 | !! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! sbc_ssr : add to sbc a restoring term toward SST/SSS climatology |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | USE oce ! ocean dynamics and tracers |
|---|
| 14 | USE dom_oce ! ocean space and time domain |
|---|
| 15 | USE sbc_oce ! surface boundary condition |
|---|
| 16 | USE phycst ! physical constants |
|---|
| 17 | USE daymod ! calendar |
|---|
| 18 | USE sbcrnf ! surface boundary condition : runoffs |
|---|
| 19 | USE fldread ! read input fields |
|---|
| 20 | USE iom ! I/O manager |
|---|
| 21 | USE in_out_manager ! I/O manager |
|---|
| 22 | USE lib_mpp ! distribued memory computing library |
|---|
| 23 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 24 | |
|---|
| 25 | IMPLICIT NONE |
|---|
| 26 | PRIVATE |
|---|
| 27 | |
|---|
| 28 | PUBLIC sbc_ssr ! routine called in sbcmod |
|---|
| 29 | |
|---|
| 30 | |
|---|
| 31 | REAL(wp), PUBLIC, DIMENSION(jpi,jpj) :: erp !: evaporation damping [kg/m2/s] |
|---|
| 32 | REAL(wp), PUBLIC, DIMENSION(jpi,jpj) :: qrp !: heat flux damping [w/m2] |
|---|
| 33 | |
|---|
| 34 | ! !!* Namelist namsbc_ssr * |
|---|
| 35 | INTEGER :: nn_sstr, nn_sssr ! SST/SSS restoring indicator |
|---|
| 36 | REAL(wp) :: dqdt , deds ! restoring factor on SST and SSS |
|---|
| 37 | LOGICAL :: ln_sssr_bnd ! flag to bound erp term |
|---|
| 38 | REAL(wp) :: rn_sssr_bnd ! ABS(Max./Min.) value of erp term [mm/day] |
|---|
| 39 | |
|---|
| 40 | REAL(wp) , ALLOCATABLE, DIMENSION(:) :: buffer ! Temporary buffer for exchange |
|---|
| 41 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_sst ! structure of input SST (file informations, fields read) |
|---|
| 42 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_sss ! structure of input SSS (file informations, fields read) |
|---|
| 43 | |
|---|
| 44 | !! * Substitutions |
|---|
| 45 | # include "domzgr_substitute.h90" |
|---|
| 46 | !!---------------------------------------------------------------------- |
|---|
| 47 | !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009) |
|---|
| 48 | !! $Id$ |
|---|
| 49 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
|---|
| 50 | !!---------------------------------------------------------------------- |
|---|
| 51 | |
|---|
| 52 | CONTAINS |
|---|
| 53 | |
|---|
| 54 | SUBROUTINE sbc_ssr( kt ) |
|---|
| 55 | !!--------------------------------------------------------------------- |
|---|
| 56 | !! *** ROUTINE sbc_ssr *** |
|---|
| 57 | !! |
|---|
| 58 | !! ** Purpose : Add to heat and/or freshwater fluxes a damping term |
|---|
| 59 | !! toward observed SST and/or SSS. |
|---|
| 60 | !! |
|---|
| 61 | !! ** Method : - Read namelist namsbc_ssr |
|---|
| 62 | !! - Read observed SST and/or SSS |
|---|
| 63 | !! - at each nscb time step |
|---|
| 64 | !! add a retroaction term on qns (nn_sstr = 1) |
|---|
| 65 | !! add a damping term on emps (nn_sssr = 1) |
|---|
| 66 | !! add a damping term on emp & emps (nn_sssr = 2) |
|---|
| 67 | !!--------------------------------------------------------------------- |
|---|
| 68 | INTEGER, INTENT(in ) :: kt ! ocean time step |
|---|
| 69 | !! |
|---|
| 70 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 71 | REAL(wp) :: zerp ! local scalar for evaporation damping |
|---|
| 72 | REAL(wp) :: zqrp ! local scalar for heat flux damping |
|---|
| 73 | REAL(wp) :: zsrp ! local scalar for unit conversion of deds factor |
|---|
| 74 | REAL(wp) :: zerp_bnd ! local scalar for unit conversion of rn_epr_max factor |
|---|
| 75 | INTEGER :: ierror ! return error code |
|---|
| 76 | !! |
|---|
| 77 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 78 | TYPE(FLD_N) :: sn_sst, sn_sss ! informations about the fields to be read |
|---|
| 79 | NAMELIST/namsbc_ssr/ cn_dir, nn_sstr, nn_sssr, dqdt, deds, sn_sst, sn_sss, ln_sssr_bnd, rn_sssr_bnd |
|---|
| 80 | !!---------------------------------------------------------------------- |
|---|
| 81 | ! |
|---|
| 82 | ! ! -------------------- ! |
|---|
| 83 | IF( kt == nit000 ) THEN ! First call kt=nit000 ! |
|---|
| 84 | ! ! -------------------- ! |
|---|
| 85 | nn_sstr = 0 !* set file information |
|---|
| 86 | nn_sssr = 0 |
|---|
| 87 | dqdt = -40.e0 |
|---|
| 88 | deds = -27.70 |
|---|
| 89 | cn_dir = './' ! directory in which the model is executed |
|---|
| 90 | ! ... default values (NB: frequency positive => hours, negative => months) |
|---|
| 91 | ! ! file ! frequency ! variable ! time intep ! clim ! 'yearly' or ! weights ! rotation ! |
|---|
| 92 | ! ! name ! (hours) ! name ! (T/F) ! (T/F) ! 'monthly' ! filename ! pairs ! |
|---|
| 93 | sn_sst = FLD_N( 'sst' , 24. , 'sst' , .false. , .false. , 'yearly' , '' , '' ) |
|---|
| 94 | sn_sss = FLD_N( 'sss' , -1. , 'sss' , .true. , .false. , 'yearly' , '' , '' ) |
|---|
| 95 | |
|---|
| 96 | REWIND ( numnam ) !* read in namlist namflx |
|---|
| 97 | READ( numnam, namsbc_ssr ) |
|---|
| 98 | |
|---|
| 99 | IF(lwp) THEN !* control print |
|---|
| 100 | WRITE(numout,*) |
|---|
| 101 | WRITE(numout,*) 'sbc_ssr : SST and/or SSS damping term ' |
|---|
| 102 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 103 | WRITE(numout,*) ' SST restoring term (Yes=1) nn_sstr = ', nn_sstr |
|---|
| 104 | WRITE(numout,*) ' SSS damping term (Yes=1, salt flux) nn_sssr = ', nn_sssr |
|---|
| 105 | WRITE(numout,*) ' (Yes=2, volume flux) ' |
|---|
| 106 | WRITE(numout,*) ' dQ/dT (restoring magnitude on SST) dqdt = ', dqdt, ' W/m2/K' |
|---|
| 107 | WRITE(numout,*) ' dE/dS (restoring magnitude on SST) deds = ', deds, ' mm/day' |
|---|
| 108 | WRITE(numout,*) ' flag to bound erp term ln_sssr_bnd = ', ln_sssr_bnd |
|---|
| 109 | WRITE(numout,*) ' ABS(Max./Min.) erp threshold rn_sssr_bnd = ', rn_sssr_bnd, ' mm/day' |
|---|
| 110 | ENDIF |
|---|
| 111 | |
|---|
| 112 | IF( nn_sstr == 1 ) THEN !* set sf_sst structure |
|---|
| 113 | ! |
|---|
| 114 | ALLOCATE( sf_sst(1), STAT=ierror ) |
|---|
| 115 | IF( ierror > 0 ) THEN |
|---|
| 116 | CALL ctl_stop( 'sbc_ssr: unable to allocate sf_sst structure' ) ; RETURN |
|---|
| 117 | ENDIF |
|---|
| 118 | ALLOCATE( sf_sst(1)%fnow(jpi,jpj) ) |
|---|
| 119 | ALLOCATE( sf_sst(1)%fdta(jpi,jpj,2) ) |
|---|
| 120 | ! |
|---|
| 121 | ! fill sf_sst with sn_sst and control print |
|---|
| 122 | CALL fld_fill( sf_sst, (/ sn_sst /), cn_dir, 'sbc_ssr', 'SST restoring term toward SST data', 'namsbc_ssr' ) |
|---|
| 123 | ENDIF |
|---|
| 124 | ! |
|---|
| 125 | IF( nn_sssr >= 1 ) THEN ! set sf_sss structure |
|---|
| 126 | ! |
|---|
| 127 | ALLOCATE( sf_sss(1), STAT=ierror ) |
|---|
| 128 | IF( ierror > 0 ) THEN |
|---|
| 129 | CALL ctl_stop( 'sbc_ssr: unable to allocate sf_sss structure' ) ; RETURN |
|---|
| 130 | ENDIF |
|---|
| 131 | ALLOCATE( sf_sss(1)%fnow(jpi,jpj) ) |
|---|
| 132 | ALLOCATE( sf_sss(1)%fdta(jpi,jpj,2) ) |
|---|
| 133 | ! |
|---|
| 134 | ! fill sf_sss with sn_sss and control print |
|---|
| 135 | CALL fld_fill( sf_sss, (/ sn_sss /), cn_dir, 'sbc_ssr', 'SSS restoring term toward SSS data', 'namsbc_ssr' ) |
|---|
| 136 | ENDIF |
|---|
| 137 | ! |
|---|
| 138 | ! Initialize qrp and erp if no restoring |
|---|
| 139 | IF( nn_sstr /= 1 ) qrp(:,:) = 0.e0 |
|---|
| 140 | IF( nn_sssr /= 1 .OR. nn_sssr /= 2 ) erp(:,:) = 0.e0 |
|---|
| 141 | ENDIF |
|---|
| 142 | |
|---|
| 143 | IF( nn_sstr + nn_sssr /= 0 ) THEN |
|---|
| 144 | ! |
|---|
| 145 | IF( nn_sstr == 1) CALL fld_read( kt, nn_fsbc, sf_sst ) ! Read SST data and provides it at kt |
|---|
| 146 | IF( nn_sssr >= 1) CALL fld_read( kt, nn_fsbc, sf_sss ) ! Read SSS data and provides it at kt |
|---|
| 147 | ! |
|---|
| 148 | ! ! ========================= ! |
|---|
| 149 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN ! Add restoring term ! |
|---|
| 150 | ! ! ========================= ! |
|---|
| 151 | ! |
|---|
| 152 | IF( nn_sstr == 1 ) THEN !* Temperature restoring term |
|---|
| 153 | !CDIR COLLAPSE |
|---|
| 154 | DO jj = 1, jpj |
|---|
| 155 | DO ji = 1, jpi |
|---|
| 156 | zqrp = dqdt * ( sst_m(ji,jj) - sf_sst(1)%fnow(ji,jj) ) |
|---|
| 157 | qns(ji,jj) = qns(ji,jj) + zqrp |
|---|
| 158 | qrp(ji,jj) = zqrp |
|---|
| 159 | END DO |
|---|
| 160 | END DO |
|---|
| 161 | CALL iom_put( "qrp", qrp ) ! heat flux damping |
|---|
| 162 | ENDIF |
|---|
| 163 | ! |
|---|
| 164 | IF( nn_sssr == 1 ) THEN !* Salinity damping term (salt flux, emps only) |
|---|
| 165 | zsrp = deds / rday ! from [mm/day] to [kg/m2/s] |
|---|
| 166 | !CDIR COLLAPSE |
|---|
| 167 | DO jj = 1, jpj |
|---|
| 168 | DO ji = 1, jpi |
|---|
| 169 | zerp = zsrp * ( 1. - 2.*rnfmsk(ji,jj) ) & ! No damping in vicinity of river mouths |
|---|
| 170 | & * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj) ) & |
|---|
| 171 | & / ( sss_m(ji,jj) + 1.e-20 ) |
|---|
| 172 | emps(ji,jj) = emps(ji,jj) + zerp |
|---|
| 173 | erp( ji,jj) = zerp |
|---|
| 174 | END DO |
|---|
| 175 | END DO |
|---|
| 176 | CALL iom_put( "erp", erp ) ! freshwater flux damping |
|---|
| 177 | ELSEIF( nn_sssr == 2 ) THEN !* Salinity damping term (volume flux, emp and emps) |
|---|
| 178 | zsrp = deds / rday ! from [mm/day] to [kg/m2/s] |
|---|
| 179 | zerp_bnd = rn_sssr_bnd / rday ! - - |
|---|
| 180 | !CDIR COLLAPSE |
|---|
| 181 | DO jj = 1, jpj |
|---|
| 182 | DO ji = 1, jpi |
|---|
| 183 | zerp = zsrp * ( 1. - 2.*rnfmsk(ji,jj) ) & ! No damping in vicinity of river mouths |
|---|
| 184 | & * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj) ) & |
|---|
| 185 | & / ( sss_m(ji,jj) + 1.e-20 ) |
|---|
| 186 | IF( ln_sssr_bnd ) zerp = SIGN( 1., zerp ) * MIN( zerp_bnd, ABS(zerp) ) |
|---|
| 187 | emp (ji,jj) = emp (ji,jj) + zerp |
|---|
| 188 | emps(ji,jj) = emps(ji,jj) + zerp |
|---|
| 189 | erp (ji,jj) = zerp |
|---|
| 190 | END DO |
|---|
| 191 | END DO |
|---|
| 192 | CALL iom_put( "erp", erp ) ! freshwater flux damping |
|---|
| 193 | ENDIF |
|---|
| 194 | ! |
|---|
| 195 | ENDIF |
|---|
| 196 | ! |
|---|
| 197 | ENDIF |
|---|
| 198 | ! |
|---|
| 199 | END SUBROUTINE sbc_ssr |
|---|
| 200 | |
|---|
| 201 | !!====================================================================== |
|---|
| 202 | END MODULE sbcssr |
|---|
